src/model/mpackage.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Modelisation of a Nit package
  16 module mpackage
  17
  18 import model_base
  19 private import more_collections
  20 import poset
  21 import mdoc
  22
  23 # A Nit package, that encompass a product
  24 class MPackage
  25         super MConcern
  26
  27         # The name of the package
  28         redef var name
  29
  30         redef fun full_name do return name
  31
  32         redef var c_name = name.to_cmangle is lazy
  33
  34         # The model of the package
  35         redef var model
  36
  37         redef var location
  38
  39         # The root of the group tree
  40         var root: nullable MGroup = null is writable
  41
  42         # The group tree, as a POSet
  43         var mgroups = new POSet[MGroup]
  44
  45         redef fun to_s do return name
  46
  47         init
  48         do
  49                 model.mpackages.add(self)
  50                 model.mpackage_by_name.add_one(name, self)
  51         end
  52
  53         # MPackage are always roots of the concerns hierarchy
  54         redef fun parent_concern do return null
  55
  56         redef fun mdoc_or_fallback
  57         do
  58                 var mdoc = self.mdoc
  59                 if mdoc != null then return mdoc
  60                 var root = self.root
  61                 if root != null then return root.mdoc_or_fallback
  62                 return null
  63         end
  64
  65         # Does `self` have a source file?
  66         fun has_source: Bool do return location.file != null
  67
  68         # The path to `self`
  69         fun package_path: nullable String do
  70                 if not has_source then return null
  71                 return location.file.as(not null).filename
  72         end
  73
  74         # Is `self` in its own directory?
  75         fun is_expanded: Bool do
  76                 var path = package_path
  77                 if path == null then return false
  78                 return not path.has_suffix(".nit")
  79         end
  80 end
  81
  82 # A group of modules in a package
  83 class MGroup
  84         super MConcern
  85
  86         # The name of the group
  87         # empty name for a default group in a single-module package
  88         redef var name
  89
  90         redef var location
  91
  92         # The enclosing package
  93         var mpackage: MPackage
  94
  95         # The parent group if any
  96         # see `in_nesting` for more
  97         var parent: nullable MGroup
  98
  99         # Fully qualified name.
 100         # It includes each parent group separated by `>`.
 101         # The full_name is terminated by `>` to avoid collision with other entities.
 102         #
 103         # E.g. `core>` and `core>collection>`
 104         redef fun full_name
 105         do
 106                 var p = parent
 107                 if p == null then return "{name}>"
 108                 return "{p.full_name}{name}>"
 109         end
 110
 111         # The group is the group tree on the package (`mpackage.mgroups`)
 112         # nested groups (children) are smaller
 113         # nesting group (see `parent`) is bigger
 114         var in_nesting: POSetElement[MGroup] is noinit
 115
 116         # Is `self` the root of its package?
 117         fun is_root: Bool do return mpackage.root == self
 118
 119         # The filepath (usually a directory) of the group, if any
 120         #
 121         # safe alias to `location.file.filename`
 122         fun filepath: nullable String do
 123                 var res
 124                 res = self.location.file
 125                 if res == null then return null
 126                 return res.filename
 127         end
 128
 129         init
 130         do
 131                 var tree = mpackage.mgroups
 132                 self.in_nesting = tree.add_node(self)
 133                 var parent = self.parent
 134                 if parent != null then
 135                         tree.add_edge(self, parent)
 136                 end
 137         end
 138
 139         redef fun model do return mpackage.model
 140
 141         redef fun parent_concern do
 142                 if not is_root then return parent
 143                 return mpackage
 144         end
 145
 146         redef fun to_s do return name
 147 end
 148
 149 redef class Model
 150         # packages of the model
 151         var mpackages = new Array[MPackage]
 152
 153         # Collections of package grouped by their names
 154         private var mpackage_by_name = new MultiHashMap[String, MPackage]
 155
 156         # Return all package named `name`
 157         # If such a package is not yet loaded, null is returned (instead of an empty array)
 158         fun get_mpackages_by_name(name: String): nullable Array[MPackage]
 159         do
 160                 if mpackage_by_name.has_key(name) then
 161                         return mpackage_by_name[name]
 162                 else
 163                         return null
 164                 end
 165         end
 166 end