contrib/nitiwiki/src/wiki_html.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # HTML wiki rendering
  16 module wiki_html
  17
  18 import wiki_links
  19 import markdown::decorators
  20
  21 redef class Nitiwiki
  22
  23         # Render HTML output looking for changes in the markdown sources.
  24         redef fun render do
  25                 super
  26                 if not root_section.is_dirty and not force_render then return
  27                 var out_dir = expand_path(config.root_dir, config.out_dir)
  28                 out_dir.mkdir
  29                 copy_assets
  30                 root_section.add_child make_sitemap
  31                 root_section.render
  32         end
  33
  34         # Copy the asset directory to the (public) output directory.
  35         private fun copy_assets do
  36                 var src = expand_path(config.root_dir, config.assets_dir)
  37                 var out = expand_path(config.root_dir, config.out_dir)
  38                 if need_render(src, expand_path(out, config.assets_dir)) then
  39                         if src.file_exists then sys.system "cp -R {src} {out}"
  40                 end
  41         end
  42
  43         # Build the wiki sitemap page.
  44         private fun make_sitemap: WikiSitemap do
  45                 var sitemap = new WikiSitemap(self, "sitemap")
  46                 sitemap.is_dirty = true
  47                 return sitemap
  48         end
  49
  50         # Markdown processor used for inline element such as titles in TOC.
  51         private var inline_processor: MarkdownProcessor is lazy do
  52                 var proc = new MarkdownProcessor
  53                 proc.emitter.decorator = new InlineDecorator
  54                 return proc
  55         end
  56
  57         # Inline markdown (remove h1, p, ... elements).
  58         private fun inline_md(md: Writable): Writable do
  59                 return inline_processor.process(md.write_to_string)
  60         end
  61 end
  62
  63 redef class WikiEntry
  64         # Get a `<a>` template link to `self`
  65         fun tpl_link: Writable do
  66                 return "<a href=\"{url}\">{title}</a>"
  67         end
  68 end
  69
  70 redef class WikiSection
  71
  72         # Output directory (where to ouput the HTML pages for this section).
  73         redef fun out_path: String do
  74                 if parent == null then
  75                         return wiki.config.out_dir
  76                 else
  77                         return wiki.expand_path(parent.out_path, name)
  78                 end
  79         end
  80
  81         redef fun render do
  82                 if not is_dirty and not wiki.force_render then return
  83                 if is_new then
  84                         out_full_path.mkdir
  85                 else
  86                         sys.system "touch {out_full_path}"
  87                 end
  88                 if has_source then
  89                         wiki.message("Render section {out_path}", 1)
  90                         copy_files
  91                 end
  92                 var index = self.index
  93                 if index isa WikiSectionIndex then
  94                         wiki.message("Render auto-index for section {out_path}", 1)
  95                         index.is_dirty = true
  96                         add_child index
  97                 end
  98                 super
  99         end
 100
 101         # Copy attached files from `src_path` to `out_path`.
 102         private fun copy_files do
 103                 assert has_source
 104                 var dir = src_full_path.to_s
 105                 for name in dir.files do
 106                         if name == wiki.config_filename then continue
 107                         if name.has_suffix(".md") then continue
 108                         if has_child(name) then continue
 109                         var src = wiki.expand_path(dir, name)
 110                         var out = wiki.expand_path(out_full_path, name)
 111                         if not wiki.need_render(src, out) then continue
 112                         sys.system "cp -R {src} {out_full_path}"
 113                 end
 114         end
 115
 116         redef fun tpl_link do return index.tpl_link
 117
 118         # Render the section hierarchy as a html tree.
 119         #
 120         # `limit` is used to specify the max-depth of the tree.
 121         #
 122         # The generated tree will be something like this:
 123         #
 124         # ~~~html
 125         # <ul>
 126         #  <li>section 1</li>
 127         #  <li>section 2
 128         #   <ul>
 129         #    <li>section 2.1</li>
 130         #    <li>section 2.2</li>
 131         #   </ul>
 132         #  </li>
 133         # </ul>
 134         # ~~~
 135         fun tpl_tree(limit: Int): Template do
 136                 return tpl_tree_intern(limit, 1)
 137         end
 138
 139         # Build the template tree for this section recursively.
 140         protected fun tpl_tree_intern(limit, count: Int): Template do
 141                 var out = new Template
 142                 var index = index
 143                 out.add "<li>"
 144                 out.add tpl_link
 145                 if (limit < 0 or count < limit) and
 146                    (children.length > 1 or (children.length == 1)) then
 147                         out.add " <ul>"
 148                         for child in children.values do
 149                                 if child == index then continue
 150                                 if child isa WikiArticle then
 151                                         out.add "<li>"
 152                                         out.add child.tpl_link
 153                                         out.add "</li>"
 154                                 else if child isa WikiSection and not child.is_hidden then
 155                                         out.add child.tpl_tree_intern(limit, count + 1)
 156                                 end
 157                         end
 158                         out.add " </ul>"
 159                 end
 160                 out.add "</li>"
 161                 return out
 162         end
 163 end
 164
 165 redef class WikiArticle
 166
 167         redef fun out_path: String do
 168                 if parent == null then
 169                         return wiki.expand_path(wiki.config.out_dir, "{name}.html")
 170                 else
 171                         return wiki.expand_path(parent.out_path, "{name}.html")
 172                 end
 173         end
 174
 175         redef fun render do
 176                 super
 177                 if not is_dirty and not wiki.force_render then return
 178                 wiki.message("Render article {name}", 2)
 179                 var file = out_full_path
 180                 file.dirname.mkdir
 181                 tpl_page.write_to_file file
 182         end
 183
 184
 185         # Replace macros in the template by wiki data.
 186         private fun tpl_page: TemplateString do
 187                 var tpl = wiki.load_template(template_file)
 188                 if tpl.has_macro("TOP_MENU") then
 189                         tpl.replace("TOP_MENU", tpl_menu)
 190                 end
 191                 if tpl.has_macro("HEADER") then
 192                         tpl.replace("HEADER", tpl_header)
 193                 end
 194                 if tpl.has_macro("BODY") then
 195                         tpl.replace("BODY", tpl_article)
 196                 end
 197                 if tpl.has_macro("FOOTER") then
 198                         tpl.replace("FOOTER", tpl_footer)
 199                 end
 200                 return tpl
 201         end
 202
 203         # Generate the HTML header for this article.
 204         fun tpl_header: Writable do
 205                 var file = header_file
 206                 if not wiki.has_template(file) then return ""
 207                 return wiki.load_template(file)
 208         end
 209
 210         # Generate the HTML page for this article.
 211         fun tpl_article: TplArticle do
 212                 var article = new TplArticle
 213                 article.body = content
 214                 if wiki.config.auto_breadcrumbs then
 215                         article.breadcrumbs = new TplBreadcrumbs(self)
 216                 end
 217                 article.sidebar = tpl_sidebar
 218                 article.sidebar_pos = wiki.config.sidebar
 219                 return article
 220         end
 221
 222         # Sidebar for this page.
 223         var tpl_sidebar: TplSidebar is lazy do
 224                 var res = new TplSidebar
 225                 if wiki.config.auto_summary then
 226                         res.blocks.add tpl_summary
 227                 end
 228                 res.blocks.add_all sidebar.blocks
 229                 return res
 230         end
 231
 232         # Generate the HTML summary for this article.
 233         #
 234         # Based on `headlines`
 235         fun tpl_summary: Writable do
 236                 var headlines = self.headlines
 237                 var tpl = new Template
 238                 tpl.add "<ul class=\"summary list-unstyled\">"
 239                 var iter = headlines.iterator
 240                 while iter.is_ok do
 241                         var hl = iter.item
 242                         # parse title as markdown
 243                         var title = wiki.inline_md(hl.title)
 244                         tpl.add "<li><a href=\"#{hl.id}\">{title}</a>"
 245                         iter.next
 246                         if iter.is_ok then
 247                                 if iter.item.level > hl.level then
 248                                         tpl.add "<ul class=\"list-unstyled\">"
 249                                 else if iter.item.level < hl.level then
 250                                         tpl.add "</li>"
 251                                         tpl.add "</ul>"
 252                                 end
 253                         else
 254                                 tpl.add "</li>"
 255                         end
 256                 end
 257                 tpl.add "</ul>"
 258                 return tpl
 259         end
 260
 261         # Generate the HTML menu for this article.
 262         fun tpl_menu: Writable do
 263                 var file = menu_file
 264                 if not wiki.has_template(file) then return ""
 265                 var tpl = wiki.load_template(file)
 266                 if tpl.has_macro("MENUS") then
 267                         var items = new Template
 268                         for child in wiki.root_section.children.values do
 269                                 if child isa WikiArticle and child.is_index then continue
 270                                 if child isa WikiSection and child.is_hidden then continue
 271                                 items.add "<li"
 272                                 if self == child or self.breadcrumbs.has(child) then
 273                                         items.add " class=\"active\""
 274                                 end
 275                                 items.add ">"
 276                                 items.add child.tpl_link
 277                                 items.add "</li>"
 278                         end
 279                         tpl.replace("MENUS", items)
 280                 end
 281                 return tpl
 282         end
 283
 284         # Generate the HTML footer for this article.
 285         fun tpl_footer: Writable do
 286                 var file = footer_file
 287                 if not wiki.has_template(file) then return ""
 288                 var tpl = wiki.load_template(file)
 289                 var time = new Tm.gmtime
 290                 if tpl.has_macro("YEAR") then
 291                         tpl.replace("YEAR", (time.year + 1900).to_s)
 292                 end
 293                 if tpl.has_macro("GEN_TIME") then
 294                         tpl.replace("GEN_TIME", time.to_s)
 295                 end
 296                 if tpl.has_macro("LAST_CHANGES") then
 297                         var url = "{wiki.config.last_changes}{src_path or else ""}"
 298                         tpl.replace("LAST_CHANGES", url)
 299                 end
 300                 if tpl.has_macro("EDIT") then
 301                         var url = "{wiki.config.edit}{src_path or else ""}"
 302                         tpl.replace("EDIT", url)
 303                 end
 304                 return tpl
 305         end
 306 end
 307
 308 # A `WikiArticle` that contains the sitemap tree.
 309 class WikiSitemap
 310         super WikiArticle
 311
 312         redef fun tpl_article do
 313                 var article = new TplArticle.with_title("Sitemap")
 314                 article.body = new TplPageTree(wiki.root_section, -1)
 315                 return article
 316         end
 317
 318         redef var is_dirty = false
 319 end
 320
 321 # A `WikiArticle` that contains the section index tree.
 322 redef class WikiSectionIndex
 323
 324         redef var is_dirty = false
 325
 326         redef fun tpl_article do
 327                 var article = new TplArticle.with_title(section.title)
 328                 article.body = new TplPageTree(section, -1)
 329                 article.breadcrumbs = new TplBreadcrumbs(self)
 330                 return article
 331         end
 332 end
 333
 334 # Article HTML output.
 335 class TplArticle
 336         super Template
 337
 338         # Article title.
 339         var title: nullable Writable = null
 340
 341         # Article HTML body.
 342         var body: nullable Writable = null
 343
 344         # Sidebar of this article (if any).
 345         var sidebar: nullable TplSidebar = null
 346
 347         # Position of the sidebar.
 348         #
 349         # See `WikiConfig::sidebar`.
 350         var sidebar_pos: String = "left"
 351
 352         # Breadcrumbs from wiki root to this article.
 353         var breadcrumbs: nullable TplBreadcrumbs = null
 354
 355         # Init `self` with a `title`.
 356         init with_title(title: Writable) do
 357                 self.title = title
 358         end
 359
 360         redef fun rendering do
 361                 if sidebar_pos == "left" then render_sidebar
 362                 if sidebar == null then
 363                         add "<div class=\"col-sm-12 content\">"
 364                 else
 365                         add "<div class=\"col-sm-9 content\">"
 366                 end
 367                 if body != null then
 368                         add "<article>"
 369                         if breadcrumbs != null then
 370                                 add breadcrumbs.as(not null)
 371                         end
 372                         if title != null then
 373                                 add "<h1>"
 374                                 add title.as(not null)
 375                                 add "</h1>"
 376                         end
 377                         add     body.as(not null)
 378                         add " </article>"
 379                 end
 380                 add "</div>"
 381                 if sidebar_pos == "right" then render_sidebar
 382         end
 383
 384         private fun render_sidebar do
 385                 if sidebar == null then return
 386                 add "<div class=\"col-sm-3 sidebar\">"
 387                 add sidebar.as(not null)
 388                 add "</div>"
 389         end
 390 end
 391
 392 # A collection of HTML blocks displayed on the side of a page.
 393 class TplSidebar
 394         super Template
 395
 396         # Blocks are `Stremable` pieces that will be rendered in the sidebar.
 397         var blocks = new Array[Writable]
 398
 399         redef fun rendering do
 400                 for block in blocks do
 401                         add "<nav class=\"sideblock\">"
 402                         add block
 403                         add "</nav>"
 404                 end
 405         end
 406 end
 407
 408 # An HTML breadcrumbs that show the path from a `WikiArticle` to the `Nitiwiki` root.
 409 class TplBreadcrumbs
 410         super Template
 411
 412         # Bread crumb article.
 413         var article: WikiArticle
 414
 415         redef fun rendering do
 416                 var path = article.breadcrumbs
 417                 if path.is_empty or path.length <= 2 and article.is_index then return
 418                 add "<ol class=\"breadcrumb\">"
 419                 for entry in path do
 420                         if entry == path.last then
 421                                 add "<li class=\"active\">"
 422                                 add entry.title
 423                                 add "</li>"
 424                         else
 425                                 if article.parent == entry and article.is_index then continue
 426                                 add "<li>"
 427                                 add entry.tpl_link
 428                                 add "</li>"
 429                         end
 430                 end
 431                 add "</ol>"
 432         end
 433 end
 434
 435 # An HTML tree that show the section pages structure.
 436 class TplPageTree
 437         super Template
 438
 439         # Builds the page tree from `root`.
 440         var root: WikiSection
 441
 442         # Limits the tree depth to `max_depth` levels.
 443         var max_depth: Int
 444
 445         redef fun rendering do
 446                 add "<ul>"
 447                 add root.tpl_tree(-1)
 448                 add "</ul>"
 449         end
 450 end