src/separate_erasure_compiler.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Separate compilation of a Nit program with generic type erasure
  16 module separate_erasure_compiler
  17
  18 intrude import separate_compiler
  19
  20 # Add separate erased compiler specific options
  21 redef class ToolContext
  22         # --erasure
  23         var opt_erasure: OptionBool = new OptionBool("Erase generic types", "--erasure")
  24         # --no-check-erasure-cast
  25         var opt_no_check_erasure_cast: OptionBool = new OptionBool("Disable implicit casts on unsafe return with erasure-typing policy (dangerous)", "--no-check-erasure-cast")
  26
  27         redef init
  28         do
  29                 super
  30                 self.option_context.add_option(self.opt_erasure, self.opt_no_check_erasure_cast)
  31         end
  32 end
  33
  34 redef class ModelBuilder
  35         fun run_separate_erasure_compiler(mainmodule: MModule, runtime_type_analysis: RapidTypeAnalysis)
  36         do
  37                 var time0 = get_time
  38                 self.toolcontext.info("*** GENERATING C ***", 1)
  39
  40                 var compiler = new SeparateErasureCompiler(mainmodule, self, runtime_type_analysis)
  41                 compiler.compile_header
  42
  43                 # compile class structures
  44                 self.toolcontext.info("Property coloring", 2)
  45                 compiler.new_file("{mainmodule.name}.tables")
  46                 compiler.do_property_coloring
  47                 for m in mainmodule.in_importation.greaters do
  48                         for mclass in m.intro_mclasses do
  49                                 compiler.compile_class_to_c(mclass)
  50                         end
  51                 end
  52                 compiler.compile_color_consts(compiler.vt_layout.pos)
  53
  54                 # The main function of the C
  55                 compiler.new_file("{mainmodule.name}.main")
  56                 compiler.compile_main_function
  57
  58                 # compile methods
  59                 for m in mainmodule.in_importation.greaters do
  60                         self.toolcontext.info("Generate C for module {m}", 2)
  61                         compiler.new_file("{m.name}.sep")
  62                         compiler.compile_module_to_c(m)
  63                 end
  64
  65                 compiler.display_stats
  66
  67                 var time1 = get_time
  68                 self.toolcontext.info("*** END GENERATING C: {time1-time0} ***", 2)
  69                 write_and_make(compiler)
  70         end
  71 end
  72
  73 class SeparateErasureCompiler
  74         super SeparateCompiler
  75
  76         private var class_layout: nullable Layout[MClass]
  77         protected var vt_layout: nullable Layout[MVirtualTypeProp]
  78
  79         init(mainmodule: MModule, mmbuilder: ModelBuilder, runtime_type_analysis: RapidTypeAnalysis) do
  80                 super
  81
  82                 var mclasses = new HashSet[MClass].from(mmbuilder.model.mclasses)
  83
  84                 var layout_builder: TypingLayoutBuilder[MClass]
  85                 var class_colorer = new MClassColorer(mainmodule)
  86                 if modelbuilder.toolcontext.opt_phmod_typing.value then
  87                         layout_builder = new MClassHasher(new PHModOperator, mainmodule)
  88                         class_colorer.build_layout(mclasses)
  89                 else if modelbuilder.toolcontext.opt_phand_typing.value then
  90                         layout_builder = new MClassHasher(new PHAndOperator, mainmodule)
  91                         class_colorer.build_layout(mclasses)
  92                 else if modelbuilder.toolcontext.opt_bm_typing.value then
  93                         layout_builder = new MClassBMizer(mainmodule)
  94                         class_colorer.build_layout(mclasses)
  95                 else
  96                         layout_builder = class_colorer
  97                 end
  98                 self.class_layout = layout_builder.build_layout(mclasses)
  99                 self.class_tables = self.build_class_typing_tables(mclasses)
 100
 101                 # lookup vt to build layout with
 102                 var vts = new HashMap[MClass, Set[MVirtualTypeProp]]
 103                 for mclass in mclasses do
 104                         vts[mclass] = new HashSet[MVirtualTypeProp]
 105                         for mprop in self.mainmodule.properties(mclass) do
 106                                 if mprop isa MVirtualTypeProp then
 107                                         vts[mclass].add(mprop)
 108                                 end
 109                         end
 110                 end
 111
 112                 # vt coloration
 113                 var vt_coloring = new MPropertyColorer[MVirtualTypeProp](mainmodule, class_colorer)
 114                 var vt_layout = vt_coloring.build_layout(vts)
 115                 self.vt_tables = build_vt_tables(mclasses, vt_layout)
 116                 self.vt_layout = vt_layout
 117         end
 118
 119         fun build_vt_tables(mclasses: Set[MClass], layout: Layout[MProperty]): Map[MClass, Array[nullable MPropDef]] do
 120                 var tables = new HashMap[MClass, Array[nullable MPropDef]]
 121                 for mclass in mclasses do
 122                         var table = new Array[nullable MPropDef]
 123                         # first, fill table from parents by reverse linearization order
 124                         var parents = new Array[MClass]
 125                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 126                                 parents = mclass.in_hierarchy(mainmodule).greaters.to_a
 127                                 self.mainmodule.linearize_mclasses(parents)
 128                         end
 129                         for parent in parents do
 130                                 if parent == mclass then continue
 131                                 for mproperty in self.mainmodule.properties(parent) do
 132                                         if not mproperty isa MVirtualTypeProp then continue
 133                                         var color = layout.pos[mproperty]
 134                                         if table.length <= color then
 135                                                 for i in [table.length .. color[ do
 136                                                         table[i] = null
 137                                                 end
 138                                         end
 139                                         for mpropdef in mproperty.mpropdefs do
 140                                                 if mpropdef.mclassdef.mclass == parent then
 141                                                         table[color] = mpropdef
 142                                                 end
 143                                         end
 144                                 end
 145                         end
 146
 147                         # then override with local properties
 148                         for mproperty in self.mainmodule.properties(mclass) do
 149                                 if not mproperty isa MVirtualTypeProp then continue
 150                                 var color = layout.pos[mproperty]
 151                                 if table.length <= color then
 152                                         for i in [table.length .. color[ do
 153                                                 table[i] = null
 154                                         end
 155                                 end
 156                                 for mpropdef in mproperty.mpropdefs do
 157                                         if mpropdef.mclassdef.mclass == mclass then
 158                                                 table[color] = mpropdef
 159                                         end
 160                                 end
 161                         end
 162                         tables[mclass] = table
 163                 end
 164                 return tables
 165         end
 166
 167         # Build class tables
 168         fun build_class_typing_tables(mclasses: Set[MClass]): Map[MClass, Array[nullable MClass]] do
 169                 var tables = new HashMap[MClass, Array[nullable MClass]]
 170                 var layout = self.class_layout
 171                 for mclass in mclasses do
 172                         var table = new Array[nullable MClass]
 173                         var supers = new Array[MClass]
 174                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 175                                 supers = mclass.in_hierarchy(mainmodule).greaters.to_a
 176                         end
 177                         for sup in supers do
 178                                 var color: Int
 179                                 if layout isa PHLayout[MClass, MClass] then
 180                                         color = layout.hashes[mclass][sup]
 181                                 else
 182                                         color = layout.pos[sup]
 183                                 end
 184                                 if table.length <= color then
 185                                         for i in [table.length .. color[ do
 186                                                 table[i] = null
 187                                         end
 188                                 end
 189                                 table[color] = sup
 190                         end
 191                         tables[mclass] = table
 192                 end
 193                 return tables
 194         end
 195
 196         redef fun compile_header_structs do
 197                 self.header.add_decl("typedef void(*nitmethod_t)(void); /* general C type representing a Nit method. */")
 198                 self.compile_header_attribute_structs
 199                 self.header.add_decl("struct class \{ int id; const char *name; int box_kind; int color; const struct vts_table *vts_table; const struct type_table *type_table; nitmethod_t vft[]; \}; /* general C type representing a Nit class. */")
 200                 self.header.add_decl("struct type_table \{ int size; int table[]; \}; /* colorized type table. */")
 201                 self.header.add_decl("struct vts_entry \{ short int is_nullable; const struct class *class; \}; /* link (nullable or not) between the vts and is bound. */")
 202
 203                 if self.vt_layout isa PHLayout[MClass, MVirtualTypeProp] then
 204                         self.header.add_decl("struct vts_table \{ int mask; const struct vts_entry vts[]; \}; /* vts list of a C type representation. */")
 205                 else
 206                         self.header.add_decl("struct vts_table \{ int dummy; const struct vts_entry vts[]; \}; /* vts list of a C type representation. */")
 207                 end
 208
 209                 if modelbuilder.toolcontext.opt_phmod_typing.value then
 210                         self.header.add_decl("#define HASH(mask, id) ((mask)%(id))")
 211                 else if modelbuilder.toolcontext.opt_phand_typing.value then
 212                         self.header.add_decl("#define HASH(mask, id) ((mask)&(id))")
 213                 end
 214
 215                 self.header.add_decl("typedef struct instance \{ const struct class *class; nitattribute_t attrs[1]; \} val; /* general C type representing a Nit instance. */")
 216         end
 217
 218         redef fun compile_class_to_c(mclass: MClass)
 219         do
 220                 var mtype = mclass.intro.bound_mtype
 221                 var c_name = mclass.c_name
 222
 223                 var vft = self.method_tables[mclass]
 224                 var attrs = self.attr_tables[mclass]
 225                 var class_table = self.class_tables[mclass]
 226                 var v = self.new_visitor
 227
 228                 v.add_decl("/* runtime class {c_name} */")
 229
 230                 self.provide_declaration("class_{c_name}", "extern const struct class class_{c_name};")
 231                 v.add_decl("extern const struct type_table type_table_{c_name};")
 232
 233                 # Build class vft
 234                 v.add_decl("const struct class class_{c_name} = \{")
 235                 v.add_decl("{self.class_layout.ids[mclass]},")
 236                 v.add_decl("\"{mclass.name}\", /* class_name_string */")
 237                 v.add_decl("{self.box_kind_of(mclass)}, /* box_kind */")
 238                 var layout = self.class_layout
 239                 if layout isa PHLayout[MClass, MClass] then
 240                         v.add_decl("{layout.masks[mclass]},")
 241                 else
 242                         v.add_decl("{layout.pos[mclass]},")
 243                 end
 244                 if build_class_vts_table(mclass) then
 245                         v.require_declaration("vts_table_{c_name}")
 246                         v.add_decl("&vts_table_{c_name},")
 247                 else
 248                         v.add_decl("NULL,")
 249                 end
 250                 v.add_decl("&type_table_{c_name},")
 251                 v.add_decl("\{")
 252                 for i in [0 .. vft.length[ do
 253                         var mpropdef = vft[i]
 254                         if mpropdef == null then
 255                                 v.add_decl("NULL, /* empty */")
 256                         else
 257                                 if true or mpropdef.mclassdef.bound_mtype.ctype != "val*" then
 258                                         v.require_declaration("VIRTUAL_{mpropdef.c_name}")
 259                                         v.add_decl("(nitmethod_t)VIRTUAL_{mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 260                                 else
 261                                         v.require_declaration("{mpropdef.c_name}")
 262                                         v.add_decl("(nitmethod_t){mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 263                                 end
 264                         end
 265                 end
 266                 v.add_decl("\}")
 267                 v.add_decl("\};")
 268
 269                 # Build class type table
 270
 271                 v.add_decl("const struct type_table type_table_{c_name} = \{")
 272                 v.add_decl("{class_table.length},")
 273                 v.add_decl("\{")
 274                 for msuper in class_table do
 275                         if msuper == null then
 276                                 v.add_decl("-1, /* empty */")
 277                         else
 278                                 v.add_decl("{self.class_layout.ids[msuper]}, /* {msuper} */")
 279                         end
 280                 end
 281                 v.add_decl("\}")
 282                 v.add_decl("\};")
 283
 284                 if mtype.ctype != "val*" then
 285                         #Build instance struct
 286                         self.header.add_decl("struct instance_{c_name} \{")
 287                         self.header.add_decl("const struct class *class;")
 288                         self.header.add_decl("{mtype.ctype} value;")
 289                         self.header.add_decl("\};")
 290
 291                         #Build BOX
 292                         self.header.add_decl("val* BOX_{c_name}({mtype.ctype});")
 293                         v.add_decl("/* allocate {mtype} */")
 294                         v.add_decl("val* BOX_{mtype.c_name}({mtype.ctype} value) \{")
 295                         v.add("struct instance_{c_name}*res = nit_alloc(sizeof(struct instance_{c_name}));")
 296                         v.require_declaration("class_{c_name}")
 297                         v.add("res->class = &class_{c_name};")
 298                         v.add("res->value = value;")
 299                         v.add("return (val*)res;")
 300                         v.add("\}")
 301                         return
 302                 else if mclass.name == "NativeArray" then
 303                         #Build instance struct
 304                         self.header.add_decl("struct instance_{c_name} \{")
 305                         self.header.add_decl("const struct class *class;")
 306                         self.header.add_decl("val* values[];")
 307                         self.header.add_decl("\};")
 308
 309                         #Build NEW
 310                         self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(int length);")
 311                         v.add_decl("/* allocate {mtype} */")
 312                         v.add_decl("{mtype.ctype} NEW_{c_name}(int length) \{")
 313                         var res = v.new_named_var(mtype, "self")
 314                         res.is_exact = true
 315                         var mtype_elt = mtype.arguments.first
 316                         v.add("{res} = nit_alloc(sizeof(struct instance_{c_name}) + length*sizeof({mtype_elt.ctype}));")
 317                         v.require_declaration("class_{c_name}")
 318                         v.add("{res}->class = &class_{c_name};")
 319                         v.add("return {res};")
 320                         v.add("\}")
 321                         return
 322                 end
 323
 324                 #Build NEW
 325                 self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(void);")
 326                 v.add_decl("/* allocate {mtype} */")
 327                 v.add_decl("{mtype.ctype} NEW_{c_name}(void) \{")
 328                 var res = v.new_named_var(mtype, "self")
 329                 res.is_exact = true
 330                 v.add("{res} = nit_alloc(sizeof(struct instance) + {attrs.length}*sizeof(nitattribute_t));")
 331                 v.require_declaration("class_{c_name}")
 332                 v.add("{res}->class = &class_{c_name};")
 333                 self.generate_init_attr(v, res, mtype)
 334                 v.add("return {res};")
 335                 v.add("\}")
 336
 337                 generate_check_init_instance(mtype)
 338         end
 339
 340         private fun build_class_vts_table(mclass: MClass): Bool do
 341                 if self.vt_tables[mclass].is_empty then return false
 342
 343                 self.provide_declaration("vts_table_{mclass.c_name}", "extern const struct vts_table vts_table_{mclass.c_name};")
 344
 345                 var v = new_visitor
 346                 v.add_decl("const struct vts_table vts_table_{mclass.c_name} = \{")
 347                 if self.vt_layout isa PHLayout[MClass, MVirtualTypeProp] then
 348                         #TODO redo this when PHPropertyLayoutBuilder will be implemented
 349                         #v.add_decl("{vt_masks[mclass]},")
 350                 else
 351                         v.add_decl("0, /* dummy */")
 352                 end
 353                 v.add_decl("\{")
 354
 355                 for vt in self.vt_tables[mclass] do
 356                         if vt == null then
 357                                 v.add_decl("\{-1, NULL\}, /* empty */")
 358                         else
 359                                 var is_null = 0
 360                                 var bound = retrieve_vt_bound(mclass.intro.bound_mtype, vt.as(MVirtualTypeDef).bound)
 361                                 while bound isa MNullableType do
 362                                         bound = retrieve_vt_bound(mclass.intro.bound_mtype, bound.mtype)
 363                                         is_null = 1
 364                                 end
 365                                 var vtclass = bound.as(MClassType).mclass
 366                                 v.require_declaration("class_{vtclass.c_name}")
 367                                 v.add_decl("\{{is_null}, &class_{vtclass.c_name}\}, /* {vt} */")
 368                         end
 369                 end
 370                 v.add_decl("\},")
 371                 v.add_decl("\};")
 372                 return true
 373         end
 374
 375         private fun retrieve_vt_bound(anchor: MClassType, mtype: nullable MType): MType do
 376                 if mtype == null then
 377                         print "NOT YET IMPLEMENTED: retrieve_vt_bound on null"
 378                         abort
 379                 end
 380                 if mtype isa MVirtualType then
 381                         return mtype.anchor_to(mainmodule, anchor)
 382                 else if mtype isa MParameterType then
 383                         return mtype.anchor_to(mainmodule, anchor)
 384                 else
 385                         return mtype
 386                 end
 387         end
 388
 389         redef fun new_visitor do return new SeparateErasureCompilerVisitor(self)
 390
 391         # Stats
 392
 393         private var class_tables: Map[MClass, Array[nullable MClass]]
 394         private var vt_tables: Map[MClass, Array[nullable MPropDef]]
 395
 396         redef fun display_sizes
 397         do
 398                 print "# size of subtyping tables"
 399                 print "\ttotal \tholes"
 400                 var total = 0
 401                 var holes = 0
 402                 for t, table in class_tables do
 403                         total += table.length
 404                         for e in table do if e == null then holes += 1
 405                 end
 406                 print "\t{total}\t{holes}"
 407
 408                 print "# size of resolution tables"
 409                 print "\ttotal \tholes"
 410                 total = 0
 411                 holes = 0
 412                 for t, table in vt_tables do
 413                         total += table.length
 414                         for e in table do if e == null then holes += 1
 415                 end
 416                 print "\t{total}\t{holes}"
 417
 418                 print "# size of methods tables"
 419                 print "\ttotal \tholes"
 420                 total = 0
 421                 holes = 0
 422                 for t, table in method_tables do
 423                         total += table.length
 424                         for e in table do if e == null then holes += 1
 425                 end
 426                 print "\t{total}\t{holes}"
 427
 428                 print "# size of attributes tables"
 429                 print "\ttotal \tholes"
 430                 total = 0
 431                 holes = 0
 432                 for t, table in attr_tables do
 433                         total += table.length
 434                         for e in table do if e == null then holes += 1
 435                 end
 436                 print "\t{total}\t{holes}"
 437         end
 438 end
 439
 440 class SeparateErasureCompilerVisitor
 441         super SeparateCompilerVisitor
 442
 443         redef fun compile_callsite(callsite, arguments)
 444         do
 445                 var res = super
 446                 if callsite.erasure_cast and not self.compiler.as(SeparateErasureCompiler).modelbuilder.toolcontext.opt_no_check_erasure_cast.value then
 447                         assert res != null
 448                         var mtype = callsite.msignature.return_mtype
 449                         assert mtype != null
 450                         self.add("/* Erasure cast for return {res} isa {mtype} */")
 451                         var cond = self.type_test(res, mtype, "erasure")
 452                         self.add("if (!{cond}) \{")
 453                         #var x = self.class_name_string(res)
 454                         #var y = self.class_name_string(arguments.first)
 455                         #self.add("fprintf(stderr, \"Erasure cast: expected {mtype} (self is %s), got %s for {res}\\n\", {y}, {x});")
 456                         self.add_abort("Cast failed")
 457                         self.add("\}")
 458                 end
 459                 return res
 460         end
 461
 462         redef fun init_instance(mtype)
 463         do
 464                 self.require_declaration("NEW_{mtype.mclass.c_name}")
 465                 return self.new_expr("NEW_{mtype.mclass.c_name}()", mtype)
 466         end
 467
 468         redef fun type_test(value, mtype, tag)
 469         do
 470                 self.add("/* type test for {value.inspect} isa {mtype} */")
 471
 472                 var res = self.new_var(bool_type)
 473
 474                 var cltype = self.get_name("cltype")
 475                 self.add_decl("int {cltype};")
 476                 var idtype = self.get_name("idtype")
 477                 self.add_decl("int {idtype};")
 478
 479                 var maybe_null = self.maybe_null(value)
 480                 var accept_null = "0"
 481                 if mtype isa MNullableType then
 482                         mtype = mtype.mtype
 483                         accept_null = "1"
 484                 end
 485                 if mtype isa MParameterType then
 486                         # Here we get the bound of the the formal type (eh, erasure...)
 487                         mtype = mtype.resolve_for(self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.mmodule, false)
 488                         if mtype isa MNullableType then
 489                                 mtype = mtype.mtype
 490                                 accept_null = "1"
 491                         end
 492                 end
 493
 494                 if value.mcasttype.is_subtype(self.frame.mpropdef.mclassdef.mmodule, self.frame.mpropdef.mclassdef.bound_mtype, mtype) then
 495                         self.add("{res} = 1; /* easy {value.inspect} isa {mtype}*/")
 496                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 497                                 self.compiler.count_type_test_skipped[tag] += 1
 498                                 self.add("count_type_test_skipped_{tag}++;")
 499                         end
 500                         return res
 501                 end
 502
 503                 var class_ptr
 504                 var type_table
 505                 if value.mtype.ctype == "val*" then
 506                         class_ptr = "{value}->class->"
 507                 else
 508                         var mclass = value.mtype.as(MClassType).mclass
 509                         self.require_declaration("class_{mclass.c_name}")
 510                         class_ptr = "class_{mclass.c_name}."
 511                 end
 512
 513                 if mtype isa MClassType then
 514                         self.require_declaration("class_{mtype.mclass.c_name}")
 515                         self.add("{cltype} = class_{mtype.mclass.c_name}.color;")
 516                         self.add("{idtype} = class_{mtype.mclass.c_name}.id;")
 517                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 518                                 self.compiler.count_type_test_resolved[tag] += 1
 519                                 self.add("count_type_test_resolved_{tag}++;")
 520                         end
 521                 else if mtype isa MVirtualType then
 522                         var recv = self.frame.arguments.first
 523                         var recv_ptr
 524                         if recv.mtype.ctype == "val*" then
 525                                 recv_ptr = "{recv}->class->"
 526                         else
 527                                 var mclass = recv.mtype.as(MClassType).mclass
 528                                 self.require_declaration("class_{mclass.c_name}")
 529                                 recv_ptr = "class_{mclass.c_name}."
 530                         end
 531                         var entry = self.get_name("entry")
 532                         self.add("struct vts_entry {entry};")
 533                         self.require_declaration(mtype.mproperty.const_color)
 534                         if self.compiler.as(SeparateErasureCompiler).vt_layout isa PHLayout[MClass, MVirtualTypeProp] then
 535                                 self.add("{entry} = {recv_ptr}vts_table->vts[HASH({recv_ptr}vts_table->mask, {mtype.mproperty.const_color})];")
 536                         else
 537                                 self.add("{entry} = {recv_ptr}vts_table->vts[{mtype.mproperty.const_color}];")
 538                         end
 539                         self.add("{cltype} = {entry}.class->color;")
 540                         self.add("{idtype} = {entry}.class->id;")
 541                         if maybe_null and accept_null == "0" then
 542                                 var is_nullable = self.get_name("is_nullable")
 543                                 self.add_decl("short int {is_nullable};")
 544                                 self.add("{is_nullable} = {entry}.is_nullable;")
 545                                 accept_null = is_nullable.to_s
 546                         end
 547                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 548                                 self.compiler.count_type_test_unresolved[tag] += 1
 549                                 self.add("count_type_test_unresolved_{tag}++;")
 550                         end
 551                 else
 552                         self.debug("type_test({value.inspect}, {mtype})")
 553                         abort
 554                 end
 555
 556                 # check color is in table
 557                 if maybe_null then
 558                         self.add("if({value} == NULL) \{")
 559                         self.add("{res} = {accept_null};")
 560                         self.add("\} else \{")
 561                 end
 562                 if self.compiler.as(SeparateErasureCompiler).class_layout isa PHLayout[MClass, MClass] then
 563                         self.add("{cltype} = HASH({class_ptr}color, {idtype});")
 564                 end
 565                 self.add("if({cltype} >= {class_ptr}type_table->size) \{")
 566                 self.add("{res} = 0;")
 567                 self.add("\} else \{")
 568                 self.add("{res} = {class_ptr}type_table->table[{cltype}] == {idtype};")
 569                 self.add("\}")
 570                 if maybe_null then
 571                         self.add("\}")
 572                 end
 573
 574                 return res
 575         end
 576
 577         redef fun class_name_string(value)
 578         do
 579                 var res = self.get_name("var_class_name")
 580                 self.add_decl("const char* {res};")
 581                 if value.mtype.ctype == "val*" then
 582                         self.add "{res} = {value} == NULL ? \"null\" : {value}->class->name;"
 583                 else
 584                         self.require_declaration("class_{value.mtype.c_name}")
 585                         self.add "{res} = class_{value.mtype.c_name}.name;"
 586                 end
 587                 return res
 588         end
 589
 590         redef fun array_instance(array, elttype)
 591         do
 592                 var nclass = self.get_class("NativeArray")
 593                 elttype = self.anchor(elttype)
 594                 var arraytype = self.get_class("Array").get_mtype([elttype])
 595                 var res = self.init_instance(arraytype)
 596                 self.add("\{ /* {res} = array_instance Array[{elttype}] */")
 597                 var nat = self.new_var(self.get_class("NativeArray").get_mtype([elttype]))
 598                 nat.is_exact = true
 599                 self.require_declaration("NEW_{nclass.c_name}")
 600                 self.add("{nat} = NEW_{nclass.c_name}({array.length});")
 601                 for i in [0..array.length[ do
 602                         var r = self.autobox(array[i], self.object_type)
 603                         self.add("((struct instance_{nclass.c_name}*){nat})->values[{i}] = (val*) {r};")
 604                 end
 605                 var length = self.int_instance(array.length)
 606                 self.send(self.get_property("with_native", arraytype), [res, nat, length])
 607                 self.check_init_instance(res, arraytype)
 608                 self.add("\}")
 609                 return res
 610         end
 611
 612         redef fun calloc_array(ret_type, arguments)
 613         do
 614                 var ret = ret_type.as(MClassType)
 615                 self.require_declaration("NEW_{ret.mclass.c_name}")
 616                 self.ret(self.new_expr("NEW_{ret.mclass.c_name}({arguments[1]})", ret_type))
 617         end
 618 end