contrib/objcwrapper/src/objc_generator.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Code generation
  16 module objc_generator
  17
  18 import opts
  19
  20 import objc_model
  21
  22 redef class Sys
  23
  24         # Path to the output file
  25         var opt_output = new OptionString("Output file", "-o")
  26
  27         # Shall `init` methods/constructors be wrapped as methods?
  28         #
  29         # By default, these methods/constructors are wrapped as extern constructors.
  30         # So initializing an extern Objective-C object looks like:
  31         # ~~~nitish
  32         # var o = new NSArray.init_with_array(some_other_array)
  33         # ~~~
  34         #
  35         # If this option is set, the object must first be allocated and then initialized.
  36         # This is closer to the Objective-C behavior:
  37         # ~~~nitish
  38         # var o = new NSArray
  39         # o.init_with_array(some_other_array)
  40         # ~~~
  41         var opt_init_as_methods = new OptionBool(
  42                 "Wrap `init...` constructors as Nit methods instead of Nit constructors",
  43                 "--init-as-methods")
  44
  45         private var objc_to_nit_types: Map[String, String] is lazy do
  46                 var types = new HashMap[String, String]
  47                 types["char"] = "Byte"
  48                 types["short"] = "Int"
  49                 types["short int"] = "Int"
  50                 types["int"] = "Int"
  51                 types["long"] = "Int"
  52                 types["long int"] = "Int"
  53                 types["long long"] = "Int"
  54                 types["long long int"] = "Int"
  55                 types["float"] = "Float"
  56                 types["double"] = "Float"
  57                 types["long double"] = "Float"
  58
  59                 types["NSUInteger"] = "Int"
  60                 types["BOOL"] = "Bool"
  61                 types["id"] = "NSObject"
  62                 types["constid"] = "NSObject"
  63                 types["SEL"] = "NSObject"
  64                 types["void"] = "Pointer"
  65
  66                 return types
  67         end
  68 end
  69
  70 redef class ObjcModel
  71         redef fun knows_type(objc_type) do return super or
  72                 objc_to_nit_types.keys.has(objc_type)
  73 end
  74
  75 # Wrapper generator
  76 class CodeGenerator
  77
  78         # `ObjcModel` to wrap
  79         var model: ObjcModel
  80
  81         # Generate Nit code to wrap `classes`
  82         fun generate
  83         do
  84                 var classes = model.classes
  85
  86                 # Open specified path or stdin
  87                 var file
  88                 var path = opt_output.value
  89                 if path != null then
  90                         if path.file_extension != "nit" then
  91                                 print_error "Warning: output file path does not end with '.nit'"
  92                         end
  93
  94                         file = new FileWriter.open(path)
  95                 else
  96                         file = stdout
  97                 end
  98
  99                 # Generate code
 100                 file.write "import cocoa::foundation\n\n"
 101                 for classe in classes do
 102                         write_class(classe, file)
 103                 end
 104
 105                 if path != null then file.close
 106         end
 107
 108         private fun write_class(classe: ObjcClass, file: Writer)
 109         do
 110                 # Class header
 111                 file.write """
 112
 113 extern class {{{classe.name}}} in "ObjC" `{ {{{classe.name}}} * `}
 114 """
 115
 116                 # Supers
 117                 for super_name in classe.super_names do file.write """
 118         super {{{super_name}}}
 119 """
 120                 if classe.super_names.is_empty then file.write """
 121         super NSObject
 122 """
 123
 124                 file.write "\n"
 125
 126                 # Constructor or constructors
 127                 write_constructors(classe, file)
 128
 129                 # Attributes
 130                 for attribute in classe.attributes do
 131                         write_attribute(attribute, file)
 132                 end
 133
 134                 # Instance methods '-'
 135                 for method in classe.methods do
 136                         if not model.knows_all_types(method) then method.is_commented = true
 137
 138                         if not opt_init_as_methods.value and method.is_init then continue
 139                         if method.is_class_property then continue
 140
 141                         write_method_signature(method, file)
 142                         write_objc_method_call(method, file)
 143                 end
 144
 145                 file.write """
 146 end
 147 """
 148
 149                 # Class methods '+'
 150                 for method in classe.methods do
 151                         if not method.is_class_property then continue
 152
 153                         write_method_signature(method, file)
 154                         write_objc_method_call(method, file)
 155                 end
 156         end
 157
 158         private fun write_constructors(classe: ObjcClass, file: Writer)
 159         do
 160                 if opt_init_as_methods.value then
 161                         # A single constructor for `alloc`
 162                         file.write """
 163         new in "ObjC" `{
 164                 return [{{{classe.name}}} alloc];
 165         `}
 166
 167 """
 168                         return
 169                 end
 170
 171                 # A constructor per `init...` method
 172                 for method in classe.methods do
 173                         if not method.is_init then continue
 174
 175                         if not model.knows_all_types(method) then method.is_commented = true
 176
 177                         write_method_signature(method, file)
 178
 179                                 write_objc_init_call(classe.name, method, file)
 180                 end
 181         end
 182
 183         private fun write_attribute(attribute: ObjcAttribute, file: Writer)
 184         do
 185                 if not model.knows_type(attribute.return_type) then attribute.is_commented = true
 186
 187                 write_attribute_getter(attribute, file)
 188                 # TODO write_attribute_setter if there is no `readonly` annotation
 189         end
 190
 191         private fun write_attribute_getter(attribute: ObjcAttribute, file: Writer)
 192         do
 193                 var nit_attr_name = attribute.name.to_snake_case
 194                 var nit_attr_type = attribute.return_type.objc_to_nit_type
 195
 196                 var c = attribute.comment_str
 197
 198                 file.write """
 199 {{{c}}} fun {{{nit_attr_name}}}: {{{nit_attr_type}}} in "ObjC" `{
 200 {{{c}}}         return [self {{{attribute.name}}}];
 201 {{{c}}} `}
 202
 203 """
 204         end
 205
 206         private fun write_attribute_setter(attribute: ObjcAttribute, file: Writer)
 207         do
 208                 var nit_attr_name = attribute.name.to_snake_case
 209                 var nit_attr_type = attribute.return_type.objc_to_nit_type
 210
 211                 var c = attribute.comment_str
 212
 213                 file.write """
 214 {{{c}}} fun {{{nit_attr_name}}}=(value: {{{nit_attr_type}}}) in "ObjC" `{
 215 {{{c}}}         return self.{{{attribute.name}}} = value;
 216 {{{c}}} `}
 217
 218 """
 219         end
 220
 221         private fun write_method_signature(method: ObjcMethod, file: Writer)
 222         do
 223                 var c = method.comment_str
 224
 225                 # Build Nit method name
 226                 var name = ""
 227                 for param in method.params do
 228                         name += param.name[0].to_upper.to_s + param.name.substring_from(1)
 229                 end
 230                 name = name.to_snake_case
 231
 232                 if name == "init" then name = ""
 233
 234                 # If class method, prefix with class name
 235                 if method.is_class_property then name = "{method.objc_class.name.to_snake_case}_{name}"
 236
 237                 # Kind of method
 238                 var fun_keyword = "fun"
 239                 if not opt_init_as_methods.value and method.is_init then
 240                         fun_keyword = "new"
 241                 end
 242
 243                 # Params
 244                 var params = new Array[String]
 245                 for param in method.params do
 246                         if param.is_single then break
 247                         params.add "{param.variable_name}: {param.return_type.objc_to_nit_type}"
 248                 end
 249
 250                 var params_with_par = ""
 251                 if params.not_empty then params_with_par = "({params.join(", ")})"
 252
 253                 # Return
 254                 var ret = ""
 255                 if method.return_type != "void" and fun_keyword != "new" then
 256                         ret = ": {method.return_type.objc_to_nit_type}"
 257                 end
 258
 259                 file.write """
 260 {{{c}}}{{{fun_keyword}}} {{{name}}}{{{params_with_par}}}{{{ret}}} in "ObjC" `{
 261 """
 262         end
 263
 264         # Write a combined call to alloc and to a constructor/method
 265         private fun write_objc_init_call(class_name: String, method: ObjcMethod, file: Writer)
 266         do
 267                 # Method name and other params
 268                 var params = new Array[String]
 269                 for param in method.params do
 270                         if not param.is_single then
 271                                 params.add "{param.name}: {param.variable_name}"
 272                         else params.add param.name
 273                 end
 274
 275                 var c = method.comment_str
 276
 277                 file.write """
 278 {{{c}}} return [[{{{class_name}}} alloc] {{{params.join(" ")}}}];
 279 {{{c}}}`}
 280
 281 """
 282         end
 283
 284         private fun write_objc_method_call(method: ObjcMethod, file: Writer)
 285         do
 286                 # Is there a value to return?
 287                 var ret = ""
 288                 if method.return_type != "void" then ret = "return "
 289
 290                 # Method name and other params
 291                 var params = new Array[String]
 292                 for param in method.params do
 293                         if not param.is_single then
 294                                 params.add "{param.name}: {param.variable_name}"
 295                         else params.add param.name
 296                 end
 297
 298                 # Receiver, instance or class
 299                 var recv = "self"
 300                 if method.is_class_property then recv = method.objc_class.name
 301
 302                 var c = method.comment_str
 303
 304                 file.write """
 305 {{{c}}} {{{ret}}}[{{{recv}}} {{{params.join(" ")}}}];
 306 {{{c}}}`}
 307
 308 """
 309         end
 310 end
 311
 312 redef class Text
 313         # Nit equivalent to this type
 314         private fun objc_to_nit_type: String
 315         do
 316                 var types = sys.objc_to_nit_types
 317
 318                 if types.has_key(self) then
 319                         return types[self]
 320                 else
 321                         return to_s
 322                 end
 323         end
 324 end
 325
 326 redef class ObjcProperty
 327         private fun comment_str: String do if is_commented then
 328                 return "#"
 329         else return ""
 330 end
 331
 332 redef class ObjcMethod
 333         private fun indent: String do return if is_class_property then "" else "\t"
 334
 335         redef fun comment_str do return indent + super
 336 end