lib/standard/string.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2004-2008 Jean Privat <jean@pryen.org>
   4 # Copyright 2006-2008 Floréal Morandat <morandat@lirmm.fr>
   5 #
   6 # This file is free software, which comes along with NIT.  This software is
   7 # distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
   8 # without  even  the implied warranty of  MERCHANTABILITY or  FITNESS FOR A
   9 # PARTICULAR PURPOSE.  You can modify it is you want,  provided this header
  10 # is kept unaltered, and a notification of the changes is added.
  11 # You  are  allowed  to  redistribute it and sell it, alone or is a part of
  12 # another product.
  13
  14 # Basic manipulations of strings of characters
  15 module string
  16
  17 import math
  18 import collection
  19 intrude import collection::array
  20
  21 `{
  22 #include <stdio.h>
  23 #include <string.h>
  24 `}
  25
  26 ###############################################################################
  27 # String                                                                      #
  28 ###############################################################################
  29
  30 # High-level abstraction for all text representations
  31 abstract class Text
  32         super Comparable
  33         super StringCapable
  34
  35         redef type OTHER: Text
  36
  37         # Type of self (used for factorization of several methods, ex : substring_from, empty...)
  38         type SELFTYPE: Text
  39
  40         # Gets a view on the chars of the Text object
  41         #
  42         #     assert "hello".chars.to_a == ['h', 'e', 'l', 'l', 'o']
  43         fun chars: SequenceRead[Char] is abstract
  44
  45         # Number of characters contained in self.
  46         #
  47         #     assert "12345".length == 5
  48         #     assert "".length == 0
  49         fun length: Int is abstract
  50
  51         # Create a substring.
  52         #
  53         #     assert "abcd".substring(1, 2)      ==  "bc"
  54         #     assert "abcd".substring(-1, 2)     ==  "a"
  55         #     assert "abcd".substring(1, 0)      ==  ""
  56         #     assert "abcd".substring(2, 5)      ==  "cd"
  57         #
  58         # A `from` index < 0 will be replaced by 0.
  59         # Unless a `count` value is > 0 at the same time.
  60         # In this case, `from += count` and `count -= from`.
  61         fun substring(from: Int, count: Int): SELFTYPE is abstract
  62
  63         # Iterates on the substrings of self if any
  64         fun substrings: Iterator[Text] is abstract
  65
  66         # Is the current Text empty (== "")
  67         #
  68         #     assert "".is_empty
  69         #     assert not "foo".is_empty
  70         fun is_empty: Bool do return self.length == 0
  71
  72         # Returns an empty Text of the right type
  73         #
  74         # This method is used internally to get the right
  75         # implementation of an empty string.
  76         protected fun empty: SELFTYPE is abstract
  77
  78         # Gets the first char of the Text
  79         #
  80         # DEPRECATED : Use self.chars.first instead
  81         fun first: Char do return self.chars[0]
  82
  83         # Access a character at `index` in the string.
  84         #
  85         #     assert "abcd"[2]         == 'c'
  86         #
  87         # DEPRECATED : Use self.chars.[] instead
  88         fun [](index: Int): Char do return self.chars[index]
  89
  90         # Gets the index of the first occurence of 'c'
  91         #
  92         # Returns -1 if not found
  93         #
  94         # DEPRECATED : Use self.chars.index_of instead
  95         fun index_of(c: Char): Int
  96         do
  97                 return index_of_from(c, 0)
  98         end
  99
 100         # Gets the last char of self
 101         #
 102         # DEPRECATED : Use self.chars.last instead
 103         fun last: Char do return self.chars[length-1]
 104
 105         # Gets the index of the first occurence of ´c´ starting from ´pos´
 106         #
 107         # Returns -1 if not found
 108         #
 109         # DEPRECATED : Use self.chars.index_of_from instead
 110         fun index_of_from(c: Char, pos: Int): Int
 111         do
 112                 var iter = self.chars.iterator_from(pos)
 113                 while iter.is_ok do
 114                         if iter.item == c then return iter.index
 115                         iter.next
 116                 end
 117                 return -1
 118         end
 119
 120         # Gets the last index of char ´c´
 121         #
 122         # Returns -1 if not found
 123         #
 124         # DEPRECATED : Use self.chars.last_index_of instead
 125         fun last_index_of(c: Char): Int
 126         do
 127                 return last_index_of_from(c, length - 1)
 128         end
 129
 130         # Return a null terminated char *
 131         fun to_cstring: NativeString do return flatten.to_cstring
 132
 133         # The index of the last occurrence of an element starting from pos (in reverse order).
 134         #
 135         #     var s = "/etc/bin/test/test.nit"
 136         #     assert s.last_index_of_from('/', s.length-1) == 13
 137         #     assert s.last_index_of_from('/', 12)         == 8
 138         #
 139         # Returns -1 if not found
 140         #
 141         # DEPRECATED : Use self.chars.last_index_of_from instead
 142         fun last_index_of_from(item: Char, pos: Int): Int
 143         do
 144                 var iter = self.chars.reverse_iterator_from(pos)
 145                 while iter.is_ok do
 146                         if iter.item == item then return iter.index
 147                         iter.next
 148                 end
 149                 return -1
 150         end
 151
 152         # Gets an iterator on the chars of self
 153         #
 154         # DEPRECATED : Use self.chars.iterator instead
 155         fun iterator: Iterator[Char]
 156         do
 157                 return self.chars.iterator
 158         end
 159
 160
 161         # Gets an Array containing the chars of self
 162         #
 163         # DEPRECATED : Use self.chars.to_a instead
 164         fun to_a: Array[Char] do return chars.to_a
 165
 166         # Create a substring from `self` beginning at the `from` position
 167         #
 168         #     assert "abcd".substring_from(1)    ==  "bcd"
 169         #     assert "abcd".substring_from(-1)   ==  "abcd"
 170         #     assert "abcd".substring_from(2)    ==  "cd"
 171         #
 172         # As with substring, a `from` index < 0 will be replaced by 0
 173         fun substring_from(from: Int): SELFTYPE
 174         do
 175                 if from >= self.length then return empty
 176                 if from < 0 then from = 0
 177                 return substring(from, length - from)
 178         end
 179
 180         # Does self have a substring `str` starting from position `pos`?
 181         #
 182         #     assert "abcd".has_substring("bc",1)            ==  true
 183         #     assert "abcd".has_substring("bc",2)            ==  false
 184         #
 185         # Returns true iff all characters of `str` are presents
 186         # at the expected index in `self.`
 187         # The first character of `str` being at `pos`, the second
 188         # character being at `pos+1` and so on...
 189         #
 190         # This means that all characters of `str` need to be inside `self`.
 191         #
 192         #     assert "abcd".has_substring("xab", -1)         == false
 193         #     assert "abcd".has_substring("cdx", 2)          == false
 194         #
 195         # And that the empty string is always a valid substring.
 196         #
 197         #     assert "abcd".has_substring("", 2)             == true
 198         #     assert "abcd".has_substring("", 200)           == true
 199         fun has_substring(str: String, pos: Int): Bool
 200         do
 201                 if str.is_empty then return true
 202                 if pos < 0 or pos + str.length > length then return false
 203                 var myiter = self.chars.iterator_from(pos)
 204                 var itsiter = str.chars.iterator
 205                 while myiter.is_ok and itsiter.is_ok do
 206                         if myiter.item != itsiter.item then return false
 207                         myiter.next
 208                         itsiter.next
 209                 end
 210                 if itsiter.is_ok then return false
 211                 return true
 212         end
 213
 214         # Is this string prefixed by `prefix`?
 215         #
 216         #     assert "abcd".has_prefix("ab")           ==  true
 217         #     assert "abcbc".has_prefix("bc")          ==  false
 218         #     assert "ab".has_prefix("abcd")           ==  false
 219         fun has_prefix(prefix: String): Bool do return has_substring(prefix,0)
 220
 221         # Is this string suffixed by `suffix`?
 222         #
 223         #     assert "abcd".has_suffix("abc")        ==  false
 224         #     assert "abcd".has_suffix("bcd")        ==  true
 225         fun has_suffix(suffix: String): Bool do return has_substring(suffix, length - suffix.length)
 226
 227         # If `self` contains only digits, return the corresponding integer
 228         #
 229         #     assert "123".to_i        == 123
 230         #     assert "-1".to_i         == -1
 231         fun to_i: Int
 232         do
 233                 # Shortcut
 234                 return to_s.to_cstring.atoi
 235         end
 236
 237         # If `self` contains a float, return the corresponding float
 238         #
 239         #     assert "123".to_f        == 123.0
 240         #     assert "-1".to_f         == -1.0
 241         #     assert "-1.2e-3".to_f    == -0.0012
 242         fun to_f: Float
 243         do
 244                 # Shortcut
 245                 return to_s.to_cstring.atof
 246         end
 247
 248         # If `self` contains only digits and alpha <= 'f', return the corresponding integer.
 249         #
 250         #     assert "ff".to_hex == 255
 251         fun to_hex: Int do return a_to(16)
 252
 253         # If `self` contains only digits and letters, return the corresponding integer in a given base
 254         #
 255         #     assert "120".a_to(3)     == 15
 256         fun a_to(base: Int) : Int
 257         do
 258                 var i = 0
 259                 var neg = false
 260
 261                 for j in [0..length[ do
 262                         var c = chars[j]
 263                         var v = c.to_i
 264                         if v > base then
 265                                 if neg then
 266                                         return -i
 267                                 else
 268                                         return i
 269                                 end
 270                         else if v < 0 then
 271                                 neg = true
 272                         else
 273                                 i = i * base + v
 274                         end
 275                 end
 276                 if neg then
 277                         return -i
 278                 else
 279                         return i
 280                 end
 281         end
 282
 283         # Returns `true` if the string contains only Numeric values (and one "," or one "." character)
 284         #
 285         #     assert "123".is_numeric  == true
 286         #     assert "1.2".is_numeric  == true
 287         #     assert "1,2".is_numeric  == true
 288         #     assert "1..2".is_numeric == false
 289         fun is_numeric: Bool
 290         do
 291                 var has_point_or_comma = false
 292                 for i in [0..length[ do
 293                         var c = chars[i]
 294                         if not c.is_numeric then
 295                                 if (c == '.' or c == ',') and not has_point_or_comma then
 296                                         has_point_or_comma = true
 297                                 else
 298                                         return false
 299                                 end
 300                         end
 301                 end
 302                 return true
 303         end
 304
 305         # Returns `true` if the string contains only Hex chars
 306         #
 307         #     assert "048bf".is_hex  == true
 308         #     assert "ABCDEF".is_hex  == true
 309         #     assert "0G".is_hex == false
 310         fun is_hex: Bool
 311         do
 312                 for i in [0..length[ do
 313                         var c = chars[i]
 314                         if not (c >= 'a' and c <= 'f') and
 315                            not (c >= 'A' and c <= 'F') and
 316                            not (c >= '0' and c <= '9') then return false
 317                 end
 318                 return true
 319         end
 320
 321         # Are all letters in `self` upper-case ?
 322         #
 323         #     assert "HELLO WORLD".is_upper == true
 324         #     assert "%$&%!".is_upper       == true
 325         #     assert "hello world".is_upper == false
 326         #     assert "Hello World".is_upper == false
 327         fun is_upper: Bool
 328         do
 329                 for i in [0..length[ do
 330                         var char = chars[i]
 331                         if char.is_lower then return false
 332                 end
 333                 return true
 334         end
 335
 336         # Are all letters in `self` lower-case ?
 337         #
 338         #     assert "hello world".is_lower == true
 339         #     assert "%$&%!".is_lower       == true
 340         #     assert "Hello World".is_lower == false
 341         fun is_lower: Bool
 342         do
 343                 for i in [0..length[ do
 344                         var char = chars[i]
 345                         if char.is_upper then return false
 346                 end
 347                 return true
 348         end
 349
 350         # Removes the whitespaces at the beginning of self
 351         #
 352         #     assert " \n\thello \n\t".l_trim == "hello \n\t"
 353         #
 354         # A whitespace is defined as any character which ascii value is less than or equal to 32
 355         fun l_trim: SELFTYPE
 356         do
 357                 var iter = self.chars.iterator
 358                 while iter.is_ok do
 359                         if iter.item.ascii > 32 then break
 360                         iter.next
 361                 end
 362                 if iter.index == length then return self.empty
 363                 return self.substring_from(iter.index)
 364         end
 365
 366         # Removes the whitespaces at the end of self
 367         #
 368         #     assert " \n\thello \n\t".r_trim == " \n\thello"
 369         #
 370         # A whitespace is defined as any character which ascii value is less than or equal to 32
 371         fun r_trim: SELFTYPE
 372         do
 373                 var iter = self.chars.reverse_iterator
 374                 while iter.is_ok do
 375                         if iter.item.ascii > 32 then break
 376                         iter.next
 377                 end
 378                 if iter.index < 0 then return self.empty
 379                 return self.substring(0, iter.index + 1)
 380         end
 381
 382         # Trims trailing and preceding white spaces
 383         # A whitespace is defined as any character which ascii value is less than or equal to 32
 384         #
 385         #     assert "  Hello  World !  ".trim   == "Hello  World !"
 386         #     assert "\na\nb\tc\t".trim          == "a\nb\tc"
 387         fun trim: SELFTYPE do return (self.l_trim).r_trim
 388
 389         # Justify a self in a space of `length`
 390         #
 391         # `left` is the space ratio on the left side.
 392         # * 0.0 for left-justified (no space at the left)
 393         # * 1.0 for right-justified (all spaces at the left)
 394         # * 0.5 for centered (half the spaces at the left)
 395         #
 396         #     assert "hello".justify(10, 0.0)  == "hello     "
 397         #     assert "hello".justify(10, 1.0)  == "     hello"
 398         #     assert "hello".justify(10, 0.5)  == "  hello   "
 399         #
 400         # If `length` is not enough, `self` is returned as is.
 401         #
 402         #     assert "hello".justify(2, 0.0)   == "hello"
 403         #
 404         # REQUIRE: left >= 0.0 and left <= 1.0
 405         # ENSURE: `self.length <= length implies result.length == length`
 406         # ENSURE: `self.length >= length implies result == self
 407         fun justify(length: Int, left: Float): SELFTYPE
 408         do
 409                 var diff = length - self.length
 410                 if diff <= 0 then return self
 411                 assert left >= 0.0 and left <= 1.0
 412                 var before = (diff.to_f * left).to_i
 413                 return " " * before + self + " " * (diff-before)
 414         end
 415
 416         # Mangle a string to be a unique string only made of alphanumeric characters
 417         fun to_cmangle: String
 418         do
 419                 var res = new FlatBuffer
 420                 var underscore = false
 421                 for i in [0..length[ do
 422                         var c = chars[i]
 423                         if (c >= 'a' and c <= 'z') or (c >='A' and c <= 'Z') then
 424                                 res.add(c)
 425                                 underscore = false
 426                                 continue
 427                         end
 428                         if underscore then
 429                                 res.append('_'.ascii.to_s)
 430                                 res.add('d')
 431                         end
 432                         if c >= '0' and c <= '9' then
 433                                 res.add(c)
 434                                 underscore = false
 435                         else if c == '_' then
 436                                 res.add(c)
 437                                 underscore = true
 438                         else
 439                                 res.add('_')
 440                                 res.append(c.ascii.to_s)
 441                                 res.add('d')
 442                                 underscore = false
 443                         end
 444                 end
 445                 return res.to_s
 446         end
 447
 448         # Escape " \ ' and non printable characters using the rules of literal C strings and characters
 449         #
 450         #     assert "abAB12<>&".escape_to_c         == "abAB12<>&"
 451         #     assert "\n\"'\\".escape_to_c         == "\\n\\\"\\'\\\\"
 452         fun escape_to_c: String
 453         do
 454                 var b = new FlatBuffer
 455                 for i in [0..length[ do
 456                         var c = chars[i]
 457                         if c == '\n' then
 458                                 b.append("\\n")
 459                         else if c == '\0' then
 460                                 b.append("\\0")
 461                         else if c == '"' then
 462                                 b.append("\\\"")
 463                         else if c == '\'' then
 464                                 b.append("\\\'")
 465                         else if c == '\\' then
 466                                 b.append("\\\\")
 467                         else if c.ascii < 32 then
 468                                 b.append("\\{c.ascii.to_base(8, false)}")
 469                         else
 470                                 b.add(c)
 471                         end
 472                 end
 473                 return b.to_s
 474         end
 475
 476         # Escape additionnal characters
 477         # The result might no be legal in C but be used in other languages
 478         #
 479         #     assert "ab|\{\}".escape_more_to_c("|\{\}") == "ab\\|\\\{\\\}"
 480         fun escape_more_to_c(chars: String): String
 481         do
 482                 var b = new FlatBuffer
 483                 for c in escape_to_c.chars do
 484                         if chars.chars.has(c) then
 485                                 b.add('\\')
 486                         end
 487                         b.add(c)
 488                 end
 489                 return b.to_s
 490         end
 491
 492         # Escape to C plus braces
 493         #
 494         #     assert "\n\"'\\\{\}".escape_to_nit      == "\\n\\\"\\'\\\\\\\{\\\}"
 495         fun escape_to_nit: String do return escape_more_to_c("\{\}")
 496
 497         # Return a string where Nit escape sequences are transformed.
 498         #
 499         #     var s = "\\n"
 500         #     assert s.length        ==  2
 501         #     var u = s.unescape_nit
 502         #     assert u.length        ==  1
 503         #     assert u.chars[0].ascii      ==  10 # (the ASCII value of the "new line" character)
 504         fun unescape_nit: String
 505         do
 506                 var res = new FlatBuffer.with_capacity(self.length)
 507                 var was_slash = false
 508                 for i in [0..length[ do
 509                         var c = chars[i]
 510                         if not was_slash then
 511                                 if c == '\\' then
 512                                         was_slash = true
 513                                 else
 514                                         res.add(c)
 515                                 end
 516                                 continue
 517                         end
 518                         was_slash = false
 519                         if c == 'n' then
 520                                 res.add('\n')
 521                         else if c == 'r' then
 522                                 res.add('\r')
 523                         else if c == 't' then
 524                                 res.add('\t')
 525                         else if c == '0' then
 526                                 res.add('\0')
 527                         else
 528                                 res.add(c)
 529                         end
 530                 end
 531                 return res.to_s
 532         end
 533
 534         # Encode `self` to percent (or URL) encoding
 535         #
 536         #     assert "aBc09-._~".to_percent_encoding == "aBc09-._~"
 537         #     assert "%()< >".to_percent_encoding == "%25%28%29%3c%20%3e"
 538         #     assert ".com/post?e=asdf&f=123".to_percent_encoding == ".com%2fpost%3fe%3dasdf%26f%3d123"
 539         fun to_percent_encoding: String
 540         do
 541                 var buf = new FlatBuffer
 542
 543                 for i in [0..length[ do
 544                         var c = chars[i]
 545                         if (c >= '0' and c <= '9') or
 546                            (c >= 'a' and c <= 'z') or
 547                            (c >= 'A' and c <= 'Z') or
 548                            c == '-' or c == '.' or
 549                            c == '_' or c == '~'
 550                         then
 551                                 buf.add c
 552                         else buf.append "%{c.ascii.to_hex}"
 553                 end
 554
 555                 return buf.to_s
 556         end
 557
 558         # Decode `self` from percent (or URL) encoding to a clear string
 559         #
 560         # Replace invalid use of '%' with '?'.
 561         #
 562         #     assert "aBc09-._~".from_percent_encoding == "aBc09-._~"
 563         #     assert "%25%28%29%3c%20%3e".from_percent_encoding == "%()< >"
 564         #     assert ".com%2fpost%3fe%3dasdf%26f%3d123".from_percent_encoding == ".com/post?e=asdf&f=123"
 565         #     assert "%25%28%29%3C%20%3E".from_percent_encoding == "%()< >"
 566         #     assert "incomplete %".from_percent_encoding == "incomplete ?"
 567         #     assert "invalid % usage".from_percent_encoding == "invalid ? usage"
 568         fun from_percent_encoding: String
 569         do
 570                 var buf = new FlatBuffer
 571
 572                 var i = 0
 573                 while i < length do
 574                         var c = chars[i]
 575                         if c == '%' then
 576                                 if i + 2 >= length then
 577                                         # What follows % has been cut off
 578                                         buf.add '?'
 579                                 else
 580                                         i += 1
 581                                         var hex_s = substring(i, 2)
 582                                         if hex_s.is_hex then
 583                                                 var hex_i = hex_s.to_hex
 584                                                 buf.add hex_i.ascii
 585                                                 i += 1
 586                                         else
 587                                                 # What follows a % is not Hex
 588                                                 buf.add '?'
 589                                                 i -= 1
 590                                         end
 591                                 end
 592                         else buf.add c
 593
 594                         i += 1
 595                 end
 596
 597                 return buf.to_s
 598         end
 599
 600         # Escape the four characters `<`, `>`, `&`, and `"` with their html counterpart
 601         #
 602         #     assert "a&b->\"x\"".html_escape      ==  "a&amp;b-&gt;&quot;x&quot;"
 603         fun html_escape: SELFTYPE
 604         do
 605                 var buf = new FlatBuffer
 606
 607                 for i in [0..length[ do
 608                         var c = chars[i]
 609                         if c == '&' then
 610                                 buf.append "&amp;"
 611                         else if c == '<' then
 612                                 buf.append "&lt;"
 613                         else if c == '>' then
 614                                 buf.append "&gt;"
 615                         else if c == '"' then
 616                                 buf.append "&quot;"
 617                         else buf.add c
 618                 end
 619
 620                 return buf.to_s
 621         end
 622
 623         # Equality of text
 624         # Two pieces of text are equals if thez have the same characters in the same order.
 625         #
 626         #     assert "hello" == "hello"
 627         #     assert "hello" != "HELLO"
 628         #     assert "hello" == "hel"+"lo"
 629         #
 630         # Things that are not Text are not equal.
 631         #
 632         #     assert "9" != '9'
 633         #     assert "9" != ['9']
 634         #     assert "9" != 9
 635         #
 636         #     assert "9".chars.first == '9'   # equality of Char
 637         #     assert "9".chars       == ['9'] # equality of Sequence
 638         #     assert "9".to_i        == 9     # equality of Int
 639         redef fun ==(o)
 640         do
 641                 if o == null then return false
 642                 if not o isa Text then return false
 643                 if self.is_same_instance(o) then return true
 644                 if self.length != o.length then return false
 645                 return self.chars == o.chars
 646         end
 647
 648         # Lexicographical comparaison
 649         #
 650         #     assert "abc" < "xy"
 651         #     assert "ABC" < "abc"
 652         redef fun <(other)
 653         do
 654                 var self_chars = self.chars.iterator
 655                 var other_chars = other.chars.iterator
 656
 657                 while self_chars.is_ok and other_chars.is_ok do
 658                         if self_chars.item < other_chars.item then return true
 659                         if self_chars.item > other_chars.item then return false
 660                         self_chars.next
 661                         other_chars.next
 662                 end
 663
 664                 if self_chars.is_ok then
 665                         return false
 666                 else
 667                         return true
 668                 end
 669         end
 670
 671         # Escape string used in labels for graphviz
 672         #
 673         #   assert ">><<".escape_to_dot == "\\>\\>\\<\\<"
 674         fun escape_to_dot: String
 675         do
 676                 return escape_more_to_c("|\{\}<>")
 677         end
 678
 679         # Flat representation of self
 680         fun flatten: FlatText is abstract
 681
 682         private var hash_cache: nullable Int = null
 683
 684         redef fun hash
 685         do
 686                 if hash_cache == null then
 687                         # djb2 hash algorithm
 688                         var h = 5381
 689
 690                         for i in [0..length[ do
 691                                 var char = chars[i]
 692                                 h = h.lshift(5) + h + char.ascii
 693                         end
 694
 695                         hash_cache = h
 696                 end
 697                 return hash_cache.as(not null)
 698         end
 699
 700 end
 701
 702 # All kinds of array-based text representations.
 703 abstract class FlatText
 704         super Text
 705
 706         # Underlying C-String (`char*`)
 707         #
 708         # Warning : Might be void in some subclasses, be sure to check
 709         # if set before using it.
 710         private var items: NativeString is noinit
 711
 712         # Real items, used as cache for to_cstring is called
 713         private var real_items: nullable NativeString = null
 714
 715         redef var length: Int = 0
 716
 717         init do end
 718
 719         redef fun output
 720         do
 721                 var i = 0
 722                 while i < length do
 723                         items[i].output
 724                         i += 1
 725                 end
 726         end
 727
 728         redef fun flatten do return self
 729 end
 730
 731 # Abstract class for the SequenceRead compatible
 732 # views on String and Buffer objects
 733 private abstract class StringCharView
 734         super SequenceRead[Char]
 735
 736         type SELFTYPE: Text
 737
 738         private var target: SELFTYPE
 739
 740         redef fun is_empty do return target.is_empty
 741
 742         redef fun length do return target.length
 743
 744         redef fun iterator: IndexedIterator[Char] do return self.iterator_from(0)
 745
 746         redef fun reverse_iterator do return self.reverse_iterator_from(self.length - 1)
 747 end
 748
 749 # View on Buffer objects, extends Sequence
 750 # for mutation operations
 751 private abstract class BufferCharView
 752         super StringCharView
 753         super Sequence[Char]
 754
 755         redef type SELFTYPE: Buffer
 756
 757 end
 758
 759 abstract class String
 760         super Text
 761
 762         redef type SELFTYPE: String
 763
 764         redef fun to_s do return self
 765
 766         # Concatenates `o` to `self`
 767         #
 768         #     assert "hello" + "world"  == "helloworld"
 769         #     assert "" + "hello" + ""  == "hello"
 770         fun +(o: Text): SELFTYPE is abstract
 771
 772         # Concatenates self `i` times
 773         #
 774         #     assert "abc" * 4 == "abcabcabcabc"
 775         #     assert "abc" * 1 == "abc"
 776         #     assert "abc" * 0 == ""
 777         fun *(i: Int): SELFTYPE is abstract
 778
 779         fun insert_at(s: String, pos: Int): SELFTYPE is abstract
 780
 781         # Returns a reversed version of self
 782         #
 783         #     assert "hello".reversed  == "olleh"
 784         #     assert "bob".reversed    == "bob"
 785         #     assert "".reversed       == ""
 786         fun reversed: SELFTYPE is abstract
 787
 788         # A upper case version of `self`
 789         #
 790         #     assert "Hello World!".to_upper     == "HELLO WORLD!"
 791         fun to_upper: SELFTYPE is abstract
 792
 793         # A lower case version of `self`
 794         #
 795         #     assert "Hello World!".to_lower     == "hello world!"
 796         fun to_lower : SELFTYPE is abstract
 797
 798         # Takes a camel case `self` and converts it to snake case
 799         #
 800         #     assert "randomMethodId".to_snake_case == "random_method_id"
 801         #
 802         # If `self` is upper, it is returned unchanged
 803         #
 804         #     assert "RANDOM_METHOD_ID".to_snake_case == "RANDOM_METHOD_ID"
 805         #
 806         # If the identifier is prefixed by an underscore, the underscore is ignored
 807         #
 808         #     assert "_privateField".to_snake_case == "_private_field"
 809         fun to_snake_case: SELFTYPE
 810         do
 811                 if self.is_upper then return self
 812
 813                 var new_str = new FlatBuffer.with_capacity(self.length)
 814                 var is_first_char = true
 815
 816                 for i in [0..length[ do
 817                         var char = chars[i]
 818                         if is_first_char then
 819                                 new_str.add(char.to_lower)
 820                                 is_first_char = false
 821                         else if char.is_upper then
 822                                 new_str.add('_')
 823                                 new_str.add(char.to_lower)
 824                         else
 825                                 new_str.add(char)
 826                         end
 827                 end
 828
 829                 return new_str.to_s
 830         end
 831
 832         # Takes a snake case `self` and converts it to camel case
 833         #
 834         #     assert "random_method_id".to_camel_case == "randomMethodId"
 835         #
 836         # If the identifier is prefixed by an underscore, the underscore is ignored
 837         #
 838         #     assert "_private_field".to_camel_case == "_privateField"
 839         #
 840         # If `self` is upper, it is returned unchanged
 841         #
 842         #     assert "RANDOM_ID".to_camel_case == "RANDOM_ID"
 843         #
 844         # If there are several consecutive underscores, they are considered as a single one
 845         #
 846         #     assert "random__method_id".to_camel_case == "randomMethodId"
 847         fun to_camel_case: SELFTYPE
 848         do
 849                 if self.is_upper then return self
 850
 851                 var new_str = new FlatBuffer
 852                 var is_first_char = true
 853                 var follows_us = false
 854
 855                 for i in [0..length[ do
 856                         var char = chars[i]
 857                         if is_first_char then
 858                                 new_str.add(char)
 859                                 is_first_char = false
 860                         else if char == '_' then
 861                                 follows_us = true
 862                         else if follows_us then
 863                                 new_str.add(char.to_upper)
 864                                 follows_us = false
 865                         else
 866                                 new_str.add(char)
 867                         end
 868                 end
 869
 870                 return new_str.to_s
 871         end
 872
 873         # Returns a capitalized `self`
 874         #
 875         # Letters that follow a letter are lowercased
 876         # Letters that follow a non-letter are upcased.
 877         #
 878         # SEE : `Char::is_letter` for the definition of letter.
 879         #
 880         #    assert "jAVASCRIPT".capitalized == "Javascript"
 881         #    assert "i am root".capitalized == "I Am Root"
 882         #    assert "ab_c -ab0c ab\nc".capitalized == "Ab_C -Ab0C Ab\nC"
 883         fun capitalized: SELFTYPE do
 884                 if length == 0 then return self
 885
 886                 var buf = new FlatBuffer.with_capacity(length)
 887
 888                 var curr = chars[0].to_upper
 889                 var prev = curr
 890                 buf[0] = curr
 891
 892                 for i in [1 .. length[ do
 893                         prev = curr
 894                         curr = self[i]
 895                         if prev.is_letter then
 896                                 buf[i] = curr.to_lower
 897                         else
 898                                 buf[i] = curr.to_upper
 899                         end
 900                 end
 901
 902                 return buf.to_s
 903         end
 904 end
 905
 906 private class FlatSubstringsIter
 907         super Iterator[FlatText]
 908
 909         var tgt: nullable FlatText
 910
 911         redef fun item do
 912                 assert is_ok
 913                 return tgt.as(not null)
 914         end
 915
 916         redef fun is_ok do return tgt != null
 917
 918         redef fun next do tgt = null
 919 end
 920
 921 # Immutable strings of characters.
 922 class FlatString
 923         super FlatText
 924         super String
 925
 926         # Index in _items of the start of the string
 927         private var index_from: Int is noinit
 928
 929         # Indes in _items of the last item of the string
 930         private var index_to: Int is noinit
 931
 932         redef var chars: SequenceRead[Char] = new FlatStringCharView(self)
 933
 934         redef fun [](index)
 935         do
 936                 # Check that the index (+ index_from) is not larger than indexTo
 937                 # In other terms, if the index is valid
 938                 assert index >= 0
 939                 assert (index + index_from) <= index_to
 940                 return items[index + index_from]
 941         end
 942
 943         ################################################
 944         #       AbstractString specific methods        #
 945         ################################################
 946
 947         redef fun reversed
 948         do
 949                 var native = calloc_string(self.length + 1)
 950                 var length = self.length
 951                 var items = self.items
 952                 var pos = 0
 953                 var ipos = length-1
 954                 while pos < length do
 955                         native[pos] = items[ipos]
 956                         pos += 1
 957                         ipos -= 1
 958                 end
 959                 return native.to_s_with_length(self.length)
 960         end
 961
 962         redef fun substring(from, count)
 963         do
 964                 assert count >= 0
 965
 966                 if from < 0 then
 967                         count += from
 968                         if count < 0 then count = 0
 969                         from = 0
 970                 end
 971
 972                 var realFrom = index_from + from
 973
 974                 if (realFrom + count) > index_to then return new FlatString.with_infos(items, index_to - realFrom + 1, realFrom, index_to)
 975
 976                 if count == 0 then return empty
 977
 978                 var to = realFrom + count - 1
 979
 980                 return new FlatString.with_infos(items, to - realFrom + 1, realFrom, to)
 981         end
 982
 983         redef fun empty do return "".as(FlatString)
 984
 985         redef fun to_upper
 986         do
 987                 var outstr = calloc_string(self.length + 1)
 988                 var out_index = 0
 989
 990                 var myitems = self.items
 991                 var index_from = self.index_from
 992                 var max = self.index_to
 993
 994                 while index_from <= max do
 995                         outstr[out_index] = myitems[index_from].to_upper
 996                         out_index += 1
 997                         index_from += 1
 998                 end
 999
1000                 outstr[self.length] = '\0'
1001
1002                 return outstr.to_s_with_length(self.length)
1003         end
1004
1005         redef fun to_lower
1006         do
1007                 var outstr = calloc_string(self.length + 1)
1008                 var out_index = 0
1009
1010                 var myitems = self.items
1011                 var index_from = self.index_from
1012                 var max = self.index_to
1013
1014                 while index_from <= max do
1015                         outstr[out_index] = myitems[index_from].to_lower
1016                         out_index += 1
1017                         index_from += 1
1018                 end
1019
1020                 outstr[self.length] = '\0'
1021
1022                 return outstr.to_s_with_length(self.length)
1023         end
1024
1025         redef fun output
1026         do
1027                 var i = self.index_from
1028                 var imax = self.index_to
1029                 while i <= imax do
1030                         items[i].output
1031                         i += 1
1032                 end
1033         end
1034
1035         ##################################################
1036         #              String Specific Methods           #
1037         ##################################################
1038
1039         private init with_infos(items: NativeString, len: Int, from: Int, to: Int)
1040         do
1041                 self.items = items
1042                 length = len
1043                 index_from = from
1044                 index_to = to
1045         end
1046
1047         redef fun to_cstring: NativeString
1048         do
1049                 if real_items != null then
1050                         return real_items.as(not null)
1051                 else
1052                         var newItems = calloc_string(length + 1)
1053                         self.items.copy_to(newItems, length, index_from, 0)
1054                         newItems[length] = '\0'
1055                         self.real_items = newItems
1056                         return newItems
1057                 end
1058         end
1059
1060         redef fun ==(other)
1061         do
1062                 if not other isa FlatString then return super
1063
1064                 if self.object_id == other.object_id then return true
1065
1066                 var my_length = length
1067
1068                 if other.length != my_length then return false
1069
1070                 var my_index = index_from
1071                 var its_index = other.index_from
1072
1073                 var last_iteration = my_index + my_length
1074
1075                 var itsitems = other.items
1076                 var myitems = self.items
1077
1078                 while my_index < last_iteration do
1079                         if myitems[my_index] != itsitems[its_index] then return false
1080                         my_index += 1
1081                         its_index += 1
1082                 end
1083
1084                 return true
1085         end
1086
1087         redef fun <(other)
1088         do
1089                 if not other isa FlatString then return super
1090
1091                 if self.object_id == other.object_id then return false
1092
1093                 var my_curr_char : Char
1094                 var its_curr_char : Char
1095
1096                 var curr_id_self = self.index_from
1097                 var curr_id_other = other.index_from
1098
1099                 var my_items = self.items
1100                 var its_items = other.items
1101
1102                 var my_length = self.length
1103                 var its_length = other.length
1104
1105                 var max_iterations = curr_id_self + my_length
1106
1107                 while curr_id_self < max_iterations do
1108                         my_curr_char = my_items[curr_id_self]
1109                         its_curr_char = its_items[curr_id_other]
1110
1111                         if my_curr_char != its_curr_char then
1112                                 if my_curr_char < its_curr_char then return true
1113                                 return false
1114                         end
1115
1116                         curr_id_self += 1
1117                         curr_id_other += 1
1118                 end
1119
1120                 return my_length < its_length
1121         end
1122
1123         redef fun +(s)
1124         do
1125                 var my_length = self.length
1126                 var its_length = s.length
1127
1128                 var total_length = my_length + its_length
1129
1130                 var target_string = calloc_string(my_length + its_length + 1)
1131
1132                 self.items.copy_to(target_string, my_length, index_from, 0)
1133                 if s isa FlatString then
1134                         s.items.copy_to(target_string, its_length, s.index_from, my_length)
1135                 else if s isa FlatBuffer then
1136                         s.items.copy_to(target_string, its_length, 0, my_length)
1137                 else
1138                         var curr_pos = my_length
1139                         for i in [0..s.length[ do
1140                                 var c = s.chars[i]
1141                                 target_string[curr_pos] = c
1142                                 curr_pos += 1
1143                         end
1144                 end
1145
1146                 target_string[total_length] = '\0'
1147
1148                 return target_string.to_s_with_length(total_length)
1149         end
1150
1151         redef fun *(i)
1152         do
1153                 assert i >= 0
1154
1155                 var my_length = self.length
1156
1157                 var final_length = my_length * i
1158
1159                 var my_items = self.items
1160
1161                 var target_string = calloc_string((final_length) + 1)
1162
1163                 target_string[final_length] = '\0'
1164
1165                 var current_last = 0
1166
1167                 for iteration in [1 .. i] do
1168                         my_items.copy_to(target_string, my_length, 0, current_last)
1169                         current_last += my_length
1170                 end
1171
1172                 return target_string.to_s_with_length(final_length)
1173         end
1174
1175         redef fun hash
1176         do
1177                 if hash_cache == null then
1178                         # djb2 hash algorithm
1179                         var h = 5381
1180                         var i = index_from
1181
1182                         var myitems = items
1183
1184                         while i <= index_to do
1185                                 h = h.lshift(5) + h + myitems[i].ascii
1186                                 i += 1
1187                         end
1188
1189                         hash_cache = h
1190                 end
1191
1192                 return hash_cache.as(not null)
1193         end
1194
1195         redef fun substrings do return new FlatSubstringsIter(self)
1196 end
1197
1198 private class FlatStringReverseIterator
1199         super IndexedIterator[Char]
1200
1201         var target: FlatString
1202
1203         var target_items: NativeString
1204
1205         var curr_pos: Int
1206
1207         init with_pos(tgt: FlatString, pos: Int)
1208         do
1209                 target = tgt
1210                 target_items = tgt.items
1211                 curr_pos = pos + tgt.index_from
1212         end
1213
1214         redef fun is_ok do return curr_pos >= target.index_from
1215
1216         redef fun item do return target_items[curr_pos]
1217
1218         redef fun next do curr_pos -= 1
1219
1220         redef fun index do return curr_pos - target.index_from
1221
1222 end
1223
1224 private class FlatStringIterator
1225         super IndexedIterator[Char]
1226
1227         var target: FlatString
1228
1229         var target_items: NativeString
1230
1231         var curr_pos: Int
1232
1233         init with_pos(tgt: FlatString, pos: Int)
1234         do
1235                 target = tgt
1236                 target_items = tgt.items
1237                 curr_pos = pos + target.index_from
1238         end
1239
1240         redef fun is_ok do return curr_pos <= target.index_to
1241
1242         redef fun item do return target_items[curr_pos]
1243
1244         redef fun next do curr_pos += 1
1245
1246         redef fun index do return curr_pos - target.index_from
1247
1248 end
1249
1250 private class FlatStringCharView
1251         super StringCharView
1252
1253         redef type SELFTYPE: FlatString
1254
1255         redef fun [](index)
1256         do
1257                 # Check that the index (+ index_from) is not larger than indexTo
1258                 # In other terms, if the index is valid
1259                 assert index >= 0
1260                 var target = self.target
1261                 assert (index + target.index_from) <= target.index_to
1262                 return target.items[index + target.index_from]
1263         end
1264
1265         redef fun iterator_from(start) do return new FlatStringIterator.with_pos(target, start)
1266
1267         redef fun reverse_iterator_from(start) do return new FlatStringReverseIterator.with_pos(target, start)
1268
1269 end
1270
1271 abstract class Buffer
1272         super Text
1273
1274         redef type SELFTYPE: Buffer
1275
1276         # Specific implementations MUST set this to `true` in order to invalidate caches
1277         protected var is_dirty = true
1278
1279         # Copy-On-Write flag
1280         #
1281         # If the `Buffer` was to_s'd, the next in-place altering
1282         # operation will cause the current `Buffer` to be re-allocated.
1283         #
1284         # The flag will then be set at `false`.
1285         protected var written = false
1286
1287         # Modifies the char contained at pos `index`
1288         #
1289         # DEPRECATED : Use self.chars.[]= instead
1290         fun []=(index: Int, item: Char) is abstract
1291
1292         # Adds a char `c` at the end of self
1293         #
1294         # DEPRECATED : Use self.chars.add instead
1295         fun add(c: Char) is abstract
1296
1297         # Clears the buffer
1298         #
1299         #     var b = new FlatBuffer
1300         #     b.append "hello"
1301         #     assert not b.is_empty
1302         #     b.clear
1303         #     assert b.is_empty
1304         fun clear is abstract
1305
1306         # Enlarges the subsequent array containing the chars of self
1307         fun enlarge(cap: Int) is abstract
1308
1309         # Adds the content of text `s` at the end of self
1310         #
1311         #     var b = new FlatBuffer
1312         #     b.append "hello"
1313         #     b.append "world"
1314         #     assert b == "helloworld"
1315         fun append(s: Text) is abstract
1316
1317         # `self` is appended in such a way that `self` is repeated `r` times
1318         #
1319         #     var b = new FlatBuffer
1320         #     b.append "hello"
1321         #     b.times 3
1322         #     assert b == "hellohellohello"
1323         fun times(r: Int) is abstract
1324
1325         # Reverses itself in-place
1326         #
1327         #     var b = new FlatBuffer
1328         #     b.append("hello")
1329         #     b.reverse
1330         #     assert b == "olleh"
1331         fun reverse is abstract
1332
1333         # Changes each lower-case char in `self` by its upper-case variant
1334         #
1335         #     var b = new FlatBuffer
1336         #     b.append("Hello World!")
1337         #     b.upper
1338         #     assert b == "HELLO WORLD!"
1339         fun upper is abstract
1340
1341         # Changes each upper-case char in `self` by its lower-case variant
1342         #
1343         #     var b = new FlatBuffer
1344         #     b.append("Hello World!")
1345         #     b.lower
1346         #     assert b == "hello world!"
1347         fun lower is abstract
1348
1349         # Capitalizes each word in `self`
1350         #
1351         # Letters that follow a letter are lowercased
1352         # Letters that follow a non-letter are upcased.
1353         #
1354         # SEE: `Char::is_letter` for the definition of a letter.
1355         #
1356         #    var b = new FlatBuffer.from("jAVAsCriPt")"
1357         #    b.capitalize
1358         #    assert b == "Javascript"
1359         #    b = new FlatBuffer.from("i am root")
1360         #    b.capitalize
1361         #    assert b == "I Am Root"
1362         #    b = new FlatBuffer.from("ab_c -ab0c ab\nc")
1363         #    b.capitalize
1364         #    assert b == "Ab_C -Ab0C Ab\nC"
1365         fun capitalize do
1366                 if length == 0 then return
1367                 var c = self[0].to_upper
1368                 self[0] = c
1369                 var prev: Char = c
1370                 for i in [1 .. length[ do
1371                         prev = c
1372                         c = self[i]
1373                         if prev.is_letter then
1374                                 self[i] = c.to_lower
1375                         else
1376                                 self[i] = c.to_upper
1377                         end
1378                 end
1379         end
1380
1381         redef fun hash
1382         do
1383                 if is_dirty then hash_cache = null
1384                 return super
1385         end
1386
1387         # In Buffers, the internal sequence of character is mutable
1388         # Thus, `chars` can be used to modify the buffer.
1389         redef fun chars: Sequence[Char] is abstract
1390 end
1391
1392 # Mutable strings of characters.
1393 class FlatBuffer
1394         super FlatText
1395         super Buffer
1396
1397         redef type SELFTYPE: FlatBuffer
1398
1399         redef var chars: Sequence[Char] = new FlatBufferCharView(self)
1400
1401         private var capacity: Int = 0
1402
1403         redef fun substrings do return new FlatSubstringsIter(self)
1404
1405         # Re-copies the `NativeString` into a new one and sets it as the new `Buffer`
1406         #
1407         # This happens when an operation modifies the current `Buffer` and
1408         # the Copy-On-Write flag `written` is set at true.
1409         private fun reset do
1410                 var nns = new NativeString(capacity)
1411                 items.copy_to(nns, length, 0, 0)
1412                 items = nns
1413                 written = false
1414         end
1415
1416         redef fun [](index)
1417         do
1418                 assert index >= 0
1419                 assert index  < length
1420                 return items[index]
1421         end
1422
1423         redef fun []=(index, item)
1424         do
1425                 is_dirty = true
1426                 if index == length then
1427                         add(item)
1428                         return
1429                 end
1430                 if written then reset
1431                 assert index >= 0 and index < length
1432                 items[index] = item
1433         end
1434
1435         redef fun add(c)
1436         do
1437                 is_dirty = true
1438                 if capacity <= length then enlarge(length + 5)
1439                 items[length] = c
1440                 length += 1
1441         end
1442
1443         redef fun clear do
1444                 is_dirty = true
1445                 if written then reset
1446                 length = 0
1447         end
1448
1449         redef fun empty do return new FlatBuffer
1450
1451         redef fun enlarge(cap)
1452         do
1453                 var c = capacity
1454                 if cap <= c then return
1455                 while c <= cap do c = c * 2 + 2
1456                 # The COW flag can be set at false here, since
1457                 # it does a copy of the current `Buffer`
1458                 written = false
1459                 var a = calloc_string(c+1)
1460                 if length > 0 then items.copy_to(a, length, 0, 0)
1461                 items = a
1462                 capacity = c
1463         end
1464
1465         redef fun to_s: String
1466         do
1467                 written = true
1468                 if length == 0 then items = new NativeString(1)
1469                 return new FlatString.with_infos(items, length, 0, length - 1)
1470         end
1471
1472         redef fun to_cstring
1473         do
1474                 if is_dirty then
1475                         var new_native = calloc_string(length + 1)
1476                         new_native[length] = '\0'
1477                         if length > 0 then items.copy_to(new_native, length, 0, 0)
1478                         real_items = new_native
1479                         is_dirty = false
1480                 end
1481                 return real_items.as(not null)
1482         end
1483
1484         # Create a new empty string.
1485         init do end
1486
1487         init from(s: Text)
1488         do
1489                 capacity = s.length + 1
1490                 length = s.length
1491                 items = calloc_string(capacity)
1492                 if s isa FlatString then
1493                         s.items.copy_to(items, length, s.index_from, 0)
1494                 else if s isa FlatBuffer then
1495                         s.items.copy_to(items, length, 0, 0)
1496                 else
1497                         var curr_pos = 0
1498                         for i in [0..s.length[ do
1499                                 var c = s.chars[i]
1500                                 items[curr_pos] = c
1501                                 curr_pos += 1
1502                         end
1503                 end
1504         end
1505
1506         # Create a new empty string with a given capacity.
1507         init with_capacity(cap: Int)
1508         do
1509                 assert cap >= 0
1510                 # _items = new NativeString.calloc(cap)
1511                 items = calloc_string(cap+1)
1512                 capacity = cap
1513                 length = 0
1514         end
1515
1516         redef fun append(s)
1517         do
1518                 if s.is_empty then return
1519                 is_dirty = true
1520                 var sl = s.length
1521                 if capacity < length + sl then enlarge(length + sl)
1522                 if s isa FlatString then
1523                         s.items.copy_to(items, sl, s.index_from, length)
1524                 else if s isa FlatBuffer then
1525                         s.items.copy_to(items, sl, 0, length)
1526                 else
1527                         var curr_pos = self.length
1528                         for i in [0..s.length[ do
1529                                 var c = s.chars[i]
1530                                 items[curr_pos] = c
1531                                 curr_pos += 1
1532                         end
1533                 end
1534                 length += sl
1535         end
1536
1537         # Copies the content of self in `dest`
1538         fun copy(start: Int, len: Int, dest: Buffer, new_start: Int)
1539         do
1540                 var self_chars = self.chars
1541                 var dest_chars = dest.chars
1542                 for i in [0..len-1] do
1543                         dest_chars[new_start+i] = self_chars[start+i]
1544                 end
1545         end
1546
1547         redef fun substring(from, count)
1548         do
1549                 assert count >= 0
1550                 count += from
1551                 if from < 0 then from = 0
1552                 if count > length then count = length
1553                 if from < count then
1554                         var r = new FlatBuffer.with_capacity(count - from)
1555                         while from < count do
1556                                 r.chars.push(items[from])
1557                                 from += 1
1558                         end
1559                         return r
1560                 else
1561                         return new FlatBuffer
1562                 end
1563         end
1564
1565         redef fun reverse
1566         do
1567                 written = false
1568                 var ns = calloc_string(capacity)
1569                 var si = length - 1
1570                 var ni = 0
1571                 var it = items
1572                 while si >= 0 do
1573                         ns[ni] = it[si]
1574                         ni += 1
1575                         si -= 1
1576                 end
1577                 items = ns
1578         end
1579
1580         redef fun times(repeats)
1581         do
1582                 var x = new FlatString.with_infos(items, length, 0, length - 1)
1583                 for i in [1..repeats[ do
1584                         append(x)
1585                 end
1586         end
1587
1588         redef fun upper
1589         do
1590                 if written then reset
1591                 var it = items
1592                 var id = length - 1
1593                 while id >= 0 do
1594                         it[id] = it[id].to_upper
1595                         id -= 1
1596                 end
1597         end
1598
1599         redef fun lower
1600         do
1601                 if written then reset
1602                 var it = items
1603                 var id = length - 1
1604                 while id >= 0 do
1605                         it[id] = it[id].to_lower
1606                         id -= 1
1607                 end
1608         end
1609 end
1610
1611 private class FlatBufferReverseIterator
1612         super IndexedIterator[Char]
1613
1614         var target: FlatBuffer
1615
1616         var target_items: NativeString
1617
1618         var curr_pos: Int
1619
1620         init with_pos(tgt: FlatBuffer, pos: Int)
1621         do
1622                 target = tgt
1623                 if tgt.length > 0 then target_items = tgt.items
1624                 curr_pos = pos
1625         end
1626
1627         redef fun index do return curr_pos
1628
1629         redef fun is_ok do return curr_pos >= 0
1630
1631         redef fun item do return target_items[curr_pos]
1632
1633         redef fun next do curr_pos -= 1
1634
1635 end
1636
1637 private class FlatBufferCharView
1638         super BufferCharView
1639         super StringCapable
1640
1641         redef type SELFTYPE: FlatBuffer
1642
1643         redef fun [](index) do return target.items[index]
1644
1645         redef fun []=(index, item)
1646         do
1647                 assert index >= 0 and index <= length
1648                 if index == length then
1649                         add(item)
1650                         return
1651                 end
1652                 target.items[index] = item
1653         end
1654
1655         redef fun push(c)
1656         do
1657                 target.add(c)
1658         end
1659
1660         redef fun add(c)
1661         do
1662                 target.add(c)
1663         end
1664
1665         fun enlarge(cap: Int)
1666         do
1667                 target.enlarge(cap)
1668         end
1669
1670         redef fun append(s)
1671         do
1672                 var my_items = target.items
1673                 var s_length = s.length
1674                 if target.capacity < s.length then enlarge(s_length + target.length)
1675         end
1676
1677         redef fun iterator_from(pos) do return new FlatBufferIterator.with_pos(target, pos)
1678
1679         redef fun reverse_iterator_from(pos) do return new FlatBufferReverseIterator.with_pos(target, pos)
1680
1681 end
1682
1683 private class FlatBufferIterator
1684         super IndexedIterator[Char]
1685
1686         var target: FlatBuffer
1687
1688         var target_items: NativeString
1689
1690         var curr_pos: Int
1691
1692         init with_pos(tgt: FlatBuffer, pos: Int)
1693         do
1694                 target = tgt
1695                 if tgt.length > 0 then target_items = tgt.items
1696                 curr_pos = pos
1697         end
1698
1699         redef fun index do return curr_pos
1700
1701         redef fun is_ok do return curr_pos < target.length
1702
1703         redef fun item do return target_items[curr_pos]
1704
1705         redef fun next do curr_pos += 1
1706
1707 end
1708
1709 ###############################################################################
1710 # Refinement                                                                  #
1711 ###############################################################################
1712
1713 redef class Object
1714         # User readable representation of `self`.
1715         fun to_s: String do return inspect
1716
1717         # The class name of the object in NativeString format.
1718         private fun native_class_name: NativeString is intern
1719
1720         # The class name of the object.
1721         #
1722         #    assert 5.class_name == "Int"
1723         fun class_name: String do return native_class_name.to_s
1724
1725         # Developer readable representation of `self`.
1726         # Usually, it uses the form "<CLASSNAME:#OBJECTID bla bla bla>"
1727         fun inspect: String
1728         do
1729                 return "<{inspect_head}>"
1730         end
1731
1732         # Return "CLASSNAME:#OBJECTID".
1733         # This function is mainly used with the redefinition of the inspect method
1734         protected fun inspect_head: String
1735         do
1736                 return "{class_name}:#{object_id.to_hex}"
1737         end
1738 end
1739
1740 redef class Bool
1741         #     assert true.to_s         == "true"
1742         #     assert false.to_s        == "false"
1743         redef fun to_s
1744         do
1745                 if self then
1746                         return once "true"
1747                 else
1748                         return once "false"
1749                 end
1750         end
1751 end
1752
1753 redef class Int
1754
1755         # Wrapper of strerror C function
1756         private fun strerror_ext: NativeString is extern `{
1757                 return strerror(recv);
1758         `}
1759
1760         # Returns a string describing error number
1761         fun strerror: String do return strerror_ext.to_s
1762
1763         # Fill `s` with the digits in base `base` of `self` (and with the '-' sign if 'signed' and negative).
1764         # assume < to_c max const of char
1765         private fun fill_buffer(s: Buffer, base: Int, signed: Bool)
1766         do
1767                 var n: Int
1768                 # Sign
1769                 if self < 0 then
1770                         n = - self
1771                         s.chars[0] = '-'
1772                 else if self == 0 then
1773                         s.chars[0] = '0'
1774                         return
1775                 else
1776                         n = self
1777                 end
1778                 # Fill digits
1779                 var pos = digit_count(base) - 1
1780                 while pos >= 0 and n > 0 do
1781                         s.chars[pos] = (n % base).to_c
1782                         n = n / base # /
1783                         pos -= 1
1784                 end
1785         end
1786
1787         # C function to convert an nit Int to a NativeString (char*)
1788         private fun native_int_to_s: NativeString is extern "native_int_to_s"
1789
1790         # return displayable int in base 10 and signed
1791         #
1792         #     assert 1.to_s            == "1"
1793         #     assert (-123).to_s       == "-123"
1794         redef fun to_s do
1795                 return native_int_to_s.to_s
1796         end
1797
1798         # return displayable int in hexadecimal
1799         #
1800         #     assert 1.to_hex  == "1"
1801         #     assert (-255).to_hex  == "-ff"
1802         fun to_hex: String do return to_base(16,false)
1803
1804         # return displayable int in base base and signed
1805         fun to_base(base: Int, signed: Bool): String
1806         do
1807                 var l = digit_count(base)
1808                 var s = new FlatBuffer.from(" " * l)
1809                 fill_buffer(s, base, signed)
1810                 return s.to_s
1811         end
1812 end
1813
1814 redef class Float
1815         # Pretty representation of `self`, with decimals as needed from 1 to a maximum of 3
1816         #
1817         #     assert 12.34.to_s       == "12.34"
1818         #     assert (-0120.030).to_s == "-120.03"
1819         #
1820         # see `to_precision` for a custom precision.
1821         redef fun to_s do
1822                 var str = to_precision( 3 )
1823                 if is_inf != 0 or is_nan then return str
1824                 var len = str.length
1825                 for i in [0..len-1] do
1826                         var j = len-1-i
1827                         var c = str.chars[j]
1828                         if c == '0' then
1829                                 continue
1830                         else if c == '.' then
1831                                 return str.substring( 0, j+2 )
1832                         else
1833                                 return str.substring( 0, j+1 )
1834                         end
1835                 end
1836                 return str
1837         end
1838
1839         # `String` representation of `self` with the given number of `decimals`
1840         #
1841         #     assert 12.345.to_precision(0)    == "12"
1842         #     assert 12.345.to_precision(3)    == "12.345"
1843         #     assert (-12.345).to_precision(3) == "-12.345"
1844         #     assert (-0.123).to_precision(3)  == "-0.123"
1845         #     assert 0.999.to_precision(2)     == "1.00"
1846         #     assert 0.999.to_precision(4)     == "0.9990"
1847         fun to_precision(decimals: Int): String
1848         do
1849                 if is_nan then return "nan"
1850
1851                 var isinf = self.is_inf
1852                 if isinf == 1 then
1853                         return "inf"
1854                 else if isinf == -1 then
1855                         return  "-inf"
1856                 end
1857
1858                 if decimals == 0 then return self.to_i.to_s
1859                 var f = self
1860                 for i in [0..decimals[ do f = f * 10.0
1861                 if self > 0.0 then
1862                         f = f + 0.5
1863                 else
1864                         f = f - 0.5
1865                 end
1866                 var i = f.to_i
1867                 if i == 0 then return "0." + "0"*decimals
1868
1869                 # Prepare both parts of the float, before and after the "."
1870                 var s = i.abs.to_s
1871                 var sl = s.length
1872                 var p1
1873                 var p2
1874                 if sl > decimals then
1875                         # Has something before the "."
1876                         p1 = s.substring(0, sl-decimals)
1877                         p2 = s.substring(sl-decimals, decimals)
1878                 else
1879                         p1 = "0"
1880                         p2 = "0"*(decimals-sl) + s
1881                 end
1882
1883                 if i < 0 then p1 = "-" + p1
1884
1885                 return p1 + "." + p2
1886         end
1887
1888         # `self` representation with `nb` digits after the '.'.
1889         #
1890         #     assert 12.345.to_precision_native(1) == "12.3"
1891         #     assert 12.345.to_precision_native(2) == "12.35"
1892         #     assert 12.345.to_precision_native(3) == "12.345"
1893         #     assert 12.345.to_precision_native(4) == "12.3450"
1894         fun to_precision_native(nb: Int): String import NativeString.to_s `{
1895                 int size;
1896                 char *str;
1897
1898                 size = snprintf(NULL, 0, "%.*f", (int)nb, recv);
1899                 str = malloc(size + 1);
1900                 sprintf(str, "%.*f", (int)nb, recv );
1901
1902                 return NativeString_to_s( str );
1903         `}
1904 end
1905
1906 redef class Char
1907         #     assert 'x'.to_s    == "x"
1908         redef fun to_s
1909         do
1910                 var s = new FlatBuffer.with_capacity(1)
1911                 s.chars[0] = self
1912                 return s.to_s
1913         end
1914
1915         # Returns true if the char is a numerical digit
1916         #
1917         #      assert '0'.is_numeric
1918         #      assert '9'.is_numeric
1919         #      assert not 'a'.is_numeric
1920         #      assert not '?'.is_numeric
1921         fun is_numeric: Bool
1922         do
1923                 return self >= '0' and self <= '9'
1924         end
1925
1926         # Returns true if the char is an alpha digit
1927         #
1928         #      assert 'a'.is_alpha
1929         #      assert 'Z'.is_alpha
1930         #      assert not '0'.is_alpha
1931         #      assert not '?'.is_alpha
1932         fun is_alpha: Bool
1933         do
1934                 return (self >= 'a' and self <= 'z') or (self >= 'A' and self <= 'Z')
1935         end
1936
1937         # Returns true if the char is an alpha or a numeric digit
1938         #
1939         #      assert 'a'.is_alphanumeric
1940         #      assert 'Z'.is_alphanumeric
1941         #      assert '0'.is_alphanumeric
1942         #      assert '9'.is_alphanumeric
1943         #      assert not '?'.is_alphanumeric
1944         fun is_alphanumeric: Bool
1945         do
1946                 return self.is_numeric or self.is_alpha
1947         end
1948 end
1949
1950 redef class Collection[E]
1951         # Concatenate elements.
1952         redef fun to_s
1953         do
1954                 var s = new FlatBuffer
1955                 for e in self do if e != null then s.append(e.to_s)
1956                 return s.to_s
1957         end
1958
1959         # Concatenate and separate each elements with `sep`.
1960         #
1961         #     assert [1, 2, 3].join(":")         == "1:2:3"
1962         #     assert [1..3].join(":")            == "1:2:3"
1963         fun join(sep: Text): String
1964         do
1965                 if is_empty then return ""
1966
1967                 var s = new FlatBuffer # Result
1968
1969                 # Concat first item
1970                 var i = iterator
1971                 var e = i.item
1972                 if e != null then s.append(e.to_s)
1973
1974                 # Concat other items
1975                 i.next
1976                 while i.is_ok do
1977                         s.append(sep)
1978                         e = i.item
1979                         if e != null then s.append(e.to_s)
1980                         i.next
1981                 end
1982                 return s.to_s
1983         end
1984 end
1985
1986 redef class Array[E]
1987
1988         # Fast implementation
1989         redef fun to_s
1990         do
1991                 var l = length
1992                 if l == 0 then return ""
1993                 if l == 1 then if self[0] == null then return "" else return self[0].to_s
1994                 var its = _items
1995                 var na = new NativeArray[String](l)
1996                 var i = 0
1997                 var sl = 0
1998                 var mypos = 0
1999                 while i < l do
2000                         var itsi = its[i]
2001                         if itsi == null then
2002                                 i += 1
2003                                 continue
2004                         end
2005                         var tmp = itsi.to_s
2006                         sl += tmp.length
2007                         na[mypos] = tmp
2008                         i += 1
2009                         mypos += 1
2010                 end
2011                 var ns = new NativeString(sl + 1)
2012                 ns[sl] = '\0'
2013                 i = 0
2014                 var off = 0
2015                 while i < mypos do
2016                         var tmp = na[i]
2017                         var tpl = tmp.length
2018                         if tmp isa FlatString then
2019                                 tmp.items.copy_to(ns, tpl, tmp.index_from, off)
2020                                 off += tpl
2021                         else
2022                                 for j in tmp.substrings do
2023                                         var s = j.as(FlatString)
2024                                         var slen = s.length
2025                                         s.items.copy_to(ns, slen, s.index_from, off)
2026                                         off += slen
2027                                 end
2028                         end
2029                         i += 1
2030                 end
2031                 return ns.to_s_with_length(sl)
2032         end
2033 end
2034
2035 redef class Map[K,V]
2036         # Concatenate couple of 'key value'.
2037         # key and value are separated by `couple_sep`.
2038         # each couple is separated each couple with `sep`.
2039         #
2040         #     var m = new ArrayMap[Int, String]
2041         #     m[1] = "one"
2042         #     m[10] = "ten"
2043         #     assert m.join("; ", "=") == "1=one; 10=ten"
2044         fun join(sep: String, couple_sep: String): String
2045         do
2046                 if is_empty then return ""
2047
2048                 var s = new FlatBuffer # Result
2049
2050                 # Concat first item
2051                 var i = iterator
2052                 var k = i.key
2053                 var e = i.item
2054                 s.append("{k}{couple_sep}{e or else "<null>"}")
2055
2056                 # Concat other items
2057                 i.next
2058                 while i.is_ok do
2059                         s.append(sep)
2060                         k = i.key
2061                         e = i.item
2062                         s.append("{k}{couple_sep}{e or else "<null>"}")
2063                         i.next
2064                 end
2065                 return s.to_s
2066         end
2067 end
2068
2069 ###############################################################################
2070 # Native classes                                                              #
2071 ###############################################################################
2072
2073 # Native strings are simple C char *
2074 extern class NativeString `{ char* `}
2075         super StringCapable
2076         # Creates a new NativeString with a capacity of `length`
2077         new(length: Int) is intern
2078         fun [](index: Int): Char is intern
2079         fun []=(index: Int, item: Char) is intern
2080         fun copy_to(dest: NativeString, length: Int, from: Int, to: Int) is intern
2081
2082         # Position of the first nul character.
2083         fun cstring_length: Int
2084         do
2085                 var l = 0
2086                 while self[l] != '\0' do l += 1
2087                 return l
2088         end
2089         fun atoi: Int is intern
2090         fun atof: Float is extern "atof"
2091
2092         redef fun to_s
2093         do
2094                 return to_s_with_length(cstring_length)
2095         end
2096
2097         fun to_s_with_length(length: Int): FlatString
2098         do
2099                 assert length >= 0
2100                 var str = new FlatString.with_infos(self, length, 0, length - 1)
2101                 str.real_items = self
2102                 return str
2103         end
2104
2105         fun to_s_with_copy: FlatString
2106         do
2107                 var length = cstring_length
2108                 var new_self = calloc_string(length + 1)
2109                 copy_to(new_self, length, 0, 0)
2110                 var str = new FlatString.with_infos(new_self, length, 0, length - 1)
2111                 str.real_items = self
2112                 return str
2113         end
2114 end
2115
2116 # StringCapable objects can create native strings
2117 interface StringCapable
2118         protected fun calloc_string(size: Int): NativeString is intern
2119 end
2120
2121 redef class Sys
2122         private var args_cache: nullable Sequence[String]
2123
2124         # The arguments of the program as given by the OS
2125         fun program_args: Sequence[String]
2126         do
2127                 if _args_cache == null then init_args
2128                 return _args_cache.as(not null)
2129         end
2130
2131         # The name of the program as given by the OS
2132         fun program_name: String
2133         do
2134                 return native_argv(0).to_s
2135         end
2136
2137         # Initialize `program_args` with the contents of `native_argc` and `native_argv`.
2138         private fun init_args
2139         do
2140                 var argc = native_argc
2141                 var args = new Array[String].with_capacity(0)
2142                 var i = 1
2143                 while i < argc do
2144                         args[i-1] = native_argv(i).to_s
2145                         i += 1
2146                 end
2147                 _args_cache = args
2148         end
2149
2150         # First argument of the main C function.
2151         private fun native_argc: Int is intern
2152
2153         # Second argument of the main C function.
2154         private fun native_argv(i: Int): NativeString is intern
2155 end
2156
2157 # Comparator that efficienlty use `to_s` to compare things
2158 #
2159 # The comparaison call `to_s` on object and use the result to order things.
2160 #
2161 #     var a = [1, 2, 3, 10, 20]
2162 #     (new CachedAlphaComparator).sort(a)
2163 #     assert a == [1, 10, 2, 20, 3]
2164 #
2165 # Internally the result of `to_s` is cached in a HashMap to counter
2166 # uneficient implementation of `to_s`.
2167 #
2168 # Note: it caching is not usefull, see `alpha_comparator`
2169 class CachedAlphaComparator
2170         super Comparator
2171         redef type COMPARED: Object
2172
2173         private var cache = new HashMap[Object, String]
2174
2175         private fun do_to_s(a: Object): String do
2176                 if cache.has_key(a) then return cache[a]
2177                 var res = a.to_s
2178                 cache[a] = res
2179                 return res
2180         end
2181
2182         redef fun compare(a, b) do
2183                 return do_to_s(a) <=> do_to_s(b)
2184         end
2185 end
2186
2187 # see `alpha_comparator`
2188 private class AlphaComparator
2189         super Comparator
2190         redef fun compare(a, b) do return a.to_s <=> b.to_s
2191 end
2192
2193 # Stateless comparator that naively use `to_s` to compare things.
2194 #
2195 # Note: the result of `to_s` is not cached, thus can be invoked a lot
2196 # on a single instace. See `CachedAlphaComparator` as an alternative.
2197 #
2198 #     var a = [1, 2, 3, 10, 20]
2199 #     alpha_comparator.sort(a)
2200 #     assert a == [1, 10, 2, 20, 3]
2201 fun alpha_comparator: Comparator do return once new AlphaComparator
2202
2203 # The arguments of the program as given by the OS
2204 fun args: Sequence[String]
2205 do
2206         return sys.program_args
2207 end