src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper;
  59
  60 kwpackage = 'package';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwuniversal = 'universal';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'fun';
  69 kwtype = 'type';
  70 kwinit = 'init';
  71 kwredef = 'redef';
  72 kwis = 'is';
  73 kwdo = 'do';
  74 kwreadable = 'readable';
  75 kwwritable = 'writable';
  76 kwvar = 'var';
  77 kwintern = 'intern';
  78 kwextern = 'extern';
  79 kwprotected = 'protected';
  80 kwprivate = 'private';
  81 kwintrude = 'intrude';
  82 kwif = 'if';
  83 kwthen = 'then';
  84 kwelse = 'else';
  85 kwwhile = 'while';
  86 kwloop = 'loop';
  87 kwfor = 'for';
  88 kwin = 'in';
  89 kwand = 'and';
  90 kwor = 'or';
  91 kwnot = 'not';
  92 kwreturn = 'return';
  93 kwcontinue = 'continue';
  94 kwbreak = 'break';
  95 kwabort = 'abort';
  96 kwassert = 'assert';
  97 kwnew = 'new';
  98 kwisa = 'isa';
  99 kwonce = 'once';
 100 kwsuper = 'super';
 101 kwself = 'self';
 102 kwtrue = 'true';
 103 kwfalse = 'false';
 104 kwnull = 'null';
 105 kwas = 'as';
 106 kwnullable = 'nullable';
 107 kwisset = 'isset';
 108 kwlabel = 'label';
 109
 110 opar = '(';
 111 cpar = ')';
 112 obra = '[';
 113 cbra = ']';
 114 comma = ',';
 115 column = ':';
 116 quad = '::';
 117 assign = '=';
 118 pluseq = '+=';
 119 minuseq = '-=';
 120 dotdotdot = '...';
 121 dotdot = '..';
 122 dot = '.';
 123 plus = '+';
 124 minus = '-';
 125 star = '*';
 126 slash = '/';
 127 percent = '%';
 128 eq = '==';
 129 ne = '!=';
 130 lt = '<';
 131 le = '<=';
 132 gt = '>';
 133 ge = '>=';
 134 starship = '<=>';
 135 bang='!';
 136
 137 classid = uppercase letter*;
 138 id = lowercase letter*;
 139 attrid = '_' lowercase letter*;
 140
 141 number = digit+;
 142 float = digit* '.' digit+;
 143 char = ''' [any - ''']* ''';
 144 string = '"' str_body '"';
 145 start_string = '"' str_body '{';
 146 mid_string = '}' str_body '{';
 147 end_string = '}' str_body '"';
 148
 149
 150 /*****************************************************************************/
 151 Ignored Tokens
 152 /*****************************************************************************/
 153
 154 blank;
 155
 156 /*****************************************************************************/
 157 Productions
 158 /*****************************************************************************/
 159
 160 /* MODULES *******************************************************************/
 161 module
 162         = packagedecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(packagedecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 163
 164 packagedecl
 165         = [doc]:no kwpackage no id [n2]:n1 {-> New packagedecl(doc.doc, kwpackage, id)};
 166
 167 import
 168         = {std} [doc]:no visibility kwimport no id [n2]:n1              {-> New import.std(visibility, kwimport, id)}
 169         | {no} [doc]:no visibility kwimport no kwend [n2]:n1    {-> New import.no(visibility, kwimport, kwend)}
 170         ;
 171
 172 implicit_top_class {-> classdef}
 173         = propdefs_toplevel+ {-> New classdef.top([propdefs_toplevel.propdef])};
 174
 175 implicit_main_class {-> classdef?}
 176         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 177         | {null} n {-> Null}
 178         ;
 179 implicit_main_meth {-> propdef}
 180         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 181         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 182         ;
 183
 184 /* CLASSES *******************************************************************/
 185 classdef
 186         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef])};
 187 redef {-> kwredef?}
 188         = kwredef? {-> kwredef};
 189 classkind
 190         = {concrete} kwclass
 191         | {abstract} kwabstract kwclass
 192         | {interface} kwinterface
 193         | {universal} kwuniversal
 194         ;
 195
 196 formaldefs {-> formaldef*}
 197         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 198 formaldefs_tail {-> formaldef}
 199         = comma no formaldef {-> formaldef};
 200 formaldef
 201         = classid typing? {-> New formaldef(classid, typing.type)};
 202
 203 special {-> superclass}
 204         = {special} no kwspecial [n2]:no type {-> New superclass(kwspecial, Null, type)}
 205         | {super} no kwsuper [n2]:no type {-> New superclass(Null, kwsuper, type)}
 206         ;
 207
 208 propdefs~toplevel {-> propdef}
 209         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 210         ;
 211 propdef~toplevel {-> propdef}
 212         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 213         | {assign_return} [doc]:no redef visibility kwmeth methid signature_withret assign no assign_return {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature_withret.signature, assign_return.expr)}
 214 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 215 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 216         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string)}
 217 !toplevel| {var} [doc]:no readable? writable? redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, typing.type, Null)}
 218 !toplevel| {var2} [doc]:no readable? writable? redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, typing.type, expr)}
 219 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 220 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 221         ;
 222 readable {-> able}
 223         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 224         ;
 225 writable {-> able}
 226         = redef kwwritable {-> New able.write(redef.kwredef, kwwritable)}
 227         ;
 228
 229 visibility
 230         = {public} {-> New visibility.public()}
 231         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 232         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 233         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 234         ;
 235
 236 methid {-> methid}
 237         = {id} id {-> New methid.id(id)}
 238         | {plus} plus {-> New methid.plus(plus)}
 239         | {minus} minus {-> New methid.minus(minus)}
 240         | {star} star {-> New methid.star(star)}
 241         | {slash} slash {-> New methid.slash(slash)}
 242         | {percent} percent {-> New methid.percent(percent)}
 243         | {eq} eq {-> New methid.eq(eq)}
 244         | {ne} ne {-> New methid.ne(ne)}
 245         | {le} le {-> New methid.le(le)}
 246         | {ge} ge {-> New methid.ge(ge)}
 247         | {lt} lt {-> New methid.lt(lt)}
 248         | {gt} gt {-> New methid.gt(gt)}
 249         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 250         | {starship} starship {-> New methid.starship(starship)}
 251         | {assign} id assign {-> New methid.assign(id, assign)}
 252         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 253         ;
 254
 255 signature~withret {-> signature}
 256         = params? typing closure_decls {-> New signature([params.param], typing.type, [closure_decls.closure_decl])}
 257         | {noclosures} params? typing no {-> New signature([params.param], typing.type, [])}
 258 !withret| {noret} params? closure_decls {-> New signature([params.param], Null, [closure_decls.closure_decl])}
 259 !withret| {noretnoclosures} params? no {-> New signature([params.param], Null, [])}
 260         ;
 261
 262 signature_noclosures {-> signature}
 263         = params? typing? {-> New signature([params.param], typing.type, [])};
 264
 265 params {-> param*}
 266         = opar no param params_tail* [n2]:no cpar {-> [param, params_tail.param]}
 267         | {empty} opar no cpar {-> []}
 268         ;
 269 params_tail {-> param}
 270         = comma no param {-> param};
 271 param
 272         = {untyped} id {-> New param(id, Null, Null)}
 273         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 274         ;
 275
 276 closure_decls {->closure_decl*}
 277         = no closure_decl+ {-> [closure_decl]};
 278 closure_decl
 279         = kwbreak? bang id signature_noclosures n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, Null)}
 280         | {optionnal} kwbreak? bang id signature_noclosures kwdo stmtso n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, stmtso.expr)}
 281         | {assign} kwbreak? bang id signature_noclosures assign no assign_continue n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, assign_continue.expr)}
 282         ;
 283
 284 assign_return{-> expr}
 285         = expr_final {-> New expr.return(Null, expr_final.expr)}
 286         ;
 287
 288
 289 /* TYPES *********************************************************************/
 290 type~nobra {-> type}
 291         = {simple} kwnullable? classid {-> New type(kwnullable, classid, [])}
 292 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra {-> New type(kwnullable, classid, [types.type])}
 293         ;
 294 types {-> type*}
 295         = type types_tail* {-> [type, types_tail.type]};
 296 types_tail {-> type}
 297         = comma no type {-> type};
 298 typing {-> type}
 299         = column no type {-> type};
 300
 301 /* STATMENTS *****************************************************************/
 302 stmtso~withelse~withend {-> expr?}
 303         = {block} n stmtsn kwend {-> stmtsn.expr}
 304         | {emptyblock} n kwend {-> New expr.block([])}
 305         | {emptyoneline} kwend {-> New expr.block([])}
 306 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 307         ;
 308 stmts {-> expr}
 309         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr])};
 310 stmtsn {-> expr}
 311         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr])};
 312 stmts_tail {-> expr}
 313         = n stmt {-> stmt.expr};
 314 stmt~withelse {-> expr}
 315         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 316         | {assign} assignment~withelse {-> assignment~withelse.expr}
 317         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 318         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 319         | {abort} kwabort {-> New expr.abort(kwabort)}
 320         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 321         | {do} do~withelse {-> do~withelse.expr}
 322         | {if} if~withelse {-> if~withelse.expr}
 323         | {while} while~withelse {-> while~withelse.expr}
 324         | {loop} loop~withelse {-> loop~withelse.expr}
 325         | {for} for~withelse {-> for~withelse.expr}
 326         | {assert} assert~withelse {-> assert~withelse.expr}
 327         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, [args_nopar.expr], [closure_defs~withelse.closure_def])}
 328         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, [args_nopar.expr])}
 329         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, [args_nopar.expr])}
 330         ;
 331
 332 label= kwlabel id;
 333
 334 closure_defs~withelse {-> closure_def*}
 335         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 336         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 337         ;
 338
 339 closure_def_last~withelse {-> closure_def}
 340         = bang [id]:closure_id idlist? kwdo stmtso_withend label {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso_withend.expr, label)}
 341         | {nolabel} bang [id]:closure_id idlist? kwdo stmtso~withelse {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso~withelse.expr, Null)}
 342         | {assign} bang [id]:closure_id idlist? assign no assign_continue~withelse {-> New closure_def(bang, id, [idlist.id], Null, assign_continue~withelse.expr, Null)}
 343         ;
 344
 345 closure_def {-> closure_def}
 346         = bang [id]:closure_id idlist? kwdo n stmtsn {-> New closure_def(bang, id, [idlist.id], kwdo, stmtsn.expr, Null)}
 347         | {empty} bang [id]:closure_id idlist? kwdo n {-> New closure_def(bang, id, [idlist.id], kwdo, Null, Null)}
 348         ;
 349 closure_id
 350         = {simple} id
 351         | {break} kwbreak
 352         ;
 353
 354 assign_continue~withelse{-> expr}
 355         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 356         ;
 357
 358 vardecl~withelse{-> expr}
 359         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 360         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 361         ;
 362
 363 assignment~withelse {-> expr}
 364         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 365         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, [args.expr], assign,  expr_final~withelse.expr)}
 366         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, [braargs.expr], assign,  expr_final~withelse.expr)}
 367         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 368         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, [args.expr], assign_op,  expr_final~withelse.expr)}
 369         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, [braargs.expr], assign_op,  expr_final~withelse.expr)}
 370         ;
 371 assign_op
 372         = {plus} pluseq
 373         | {minus} minuseq
 374         ;
 375
 376 do~withelse {-> expr}
 377         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 378         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 379         ;
 380
 381 if~withelse {-> expr}
 382         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 383 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 384 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 385 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 386         ;
 387 elsepartblock {-> expr?}
 388         = {else} kwelse stmtso {-> stmtso.expr}
 389         | {empty} kwend {-> Null}
 390         ;
 391
 392 loop~withelse {-> expr}
 393         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 394         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 395         ;
 396
 397 while~withelse {-> expr}
 398         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 399         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 400         ;
 401
 402 for~withelse {-> expr}
 403         = kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, id, expr, kwdo, stmtso_withend.expr, label)}
 404         | {nolabel} kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, id, expr, kwdo, stmtso~withelse.expr, Null)}
 405         ;
 406
 407 assert~withelse {-> expr}
 408         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 409 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 410         ;
 411 assertid {-> id}
 412         = id column {-> id};
 413
 414 /* EXPRESSIONS ***************************************************************/
 415 expr_final~nopar~withelse~nobra {-> expr}
 416         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 417         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, [args.expr], [closure_defs~withelse.closure_def])}
 418 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, [braargs.expr], [closure_defs~withelse.closure_def])}
 419         ;
 420
 421 expr~nopar~nobra {-> expr}
 422         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 423         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 424         ;
 425
 426 expr_and~nopar~nobra {-> expr}
 427         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 428         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 429         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 430         | {or_else} expr_and~nopar~nobra kwor kwelse no expr_not~nopar~nobra {-> New expr.or_else(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 431         ;
 432
 433 expr_not~nopar~nobra {-> expr}
 434         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 435         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 436         ;
 437
 438 expr_eq~nopar~nobra {-> expr}
 439         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 440         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 441         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 442         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 443         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 444         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 445         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 446         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 447         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 448         | {isa} expr_add~nopar~nobra kwisa no type~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nobra.type)}
 449         ;
 450
 451 expr_add~nopar~nobra {-> expr}
 452         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 453         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 454         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 455         ;
 456
 457 expr_mul~nopar~nobra {-> expr}
 458         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 459         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 460         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 461         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 462         ;
 463
 464 expr_minus~nopar~nobra {-> expr}
 465         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 466         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 467         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 468         ;
 469
 470 expr_new~nopar~nobra {-> expr}
 471         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 472         | {new} kwnew no type~nobra args {-> New expr.new(kwnew, type~nobra.type, Null, [args.expr])}
 473         | {isset_attr} kwisset recv~nopar~nobra attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 474         ;
 475
 476 expr_atom~nopar~nobra {-> expr}
 477         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 478         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, [args.expr], [])}
 479         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, [args.expr])}
 480         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, [args.expr])}
 481 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, [braargs.expr], [])}
 482         | {new} kwnew no type~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nobra.type, id, [args.expr])}
 483 // FIXME: Why are these 3 !nopar mandatory?
 484 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(expr, expr2.expr)}
 485 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(expr, expr2.expr)}
 486 !nobra!nopar    | {array} braargs {-> New expr.array([braargs.expr])}
 487         | {self} kwself {-> New expr.self(kwself)}
 488         | {true} kwtrue {-> New expr.true(kwtrue)}
 489         | {false} kwfalse {-> New expr.false(kwfalse)}
 490         | {null} kwnull {-> New expr.null(kwnull)}
 491         | {int} number  {-> New expr.int(number)}
 492         | {float} float  {-> New expr.float(float)}
 493         | {char} char  {-> New expr.char(char)}
 494         | {string} string  {-> New expr.string(string)}
 495         | {superstring} superstring  {-> superstring.expr}
 496 !nopar  | {par} opar expr cpar {-> expr}
 497         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, type)}
 498         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, kwnot, kwnull)}
 499         ;
 500
 501 superstring {-> expr}
 502         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 503 superstring_start {-> expr*}
 504         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 505 start_string_p {-> expr}
 506         = start_string {-> New expr.start_string(start_string)};
 507 superstring_middle {-> expr*}
 508         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 509 mid_string_p {-> expr}
 510         = mid_string {-> New expr.mid_string(mid_string)};
 511 superstring_end {-> expr}
 512         = end_string {-> New expr.end_string(end_string)};
 513
 514 /* MISC **********************************************************************/
 515
 516 recv~nopar~nobra {-> expr}
 517         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 518         | {implicit} {-> New expr.implicit_self()}
 519         ;
 520
 521 args {-> expr*}
 522         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 523         | {emptypar} opar no cpar {-> []}
 524         | {empty} {-> []}
 525         ;
 526 args_nopar {-> expr*}
 527         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 528         | {onearg} expr_nopar {-> [expr_nopar.expr]}
 529         | {emptypar} opar no cpar {-> []}
 530         | {empty} {-> []}
 531         ;
 532 braargs {-> expr*}
 533         = obra no expr [n2]:no args_tail* cbra {-> [expr, args_tail.expr]};
 534 args_tail {-> expr}
 535         = comma no expr [n2]:no {-> expr};
 536 idlist {-> id*}
 537         = opar idlist_nopar cpar {-> [idlist_nopar.id]}
 538         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 539         ;
 540 idlist_nopar {-> id*}
 541         = {single} id {-> [id]}
 542         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 543         ;
 544
 545 qualified
 546         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 547         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 548         ;
 549 modquad {-> id}
 550         = id quad no {-> id};
 551 classquad {-> classid}
 552         = classid quad no {-> classid};
 553
 554 n1      = {a} comment | {b} eol;
 555 n {-> doc?}
 556         = {a} n2? comment+ {-> New doc([comment])}
 557         | {b} n2 {-> Null}
 558         ;
 559 no {-> doc?}
 560         = {empty} {-> Null}
 561         | n {-> n.doc}
 562         ;
 563
 564 n2
 565         = {a} n2? comment+ eol+
 566         | {b} eol+
 567         ;
 568
 569 /*****************************************************************************/
 570 Abstract Syntax Tree
 571 /*****************************************************************************/
 572
 573 module  = packagedecl? [imports]:import* [classdefs]:classdef*;
 574
 575 packagedecl
 576         = doc? kwpackage id;
 577
 578 import  = {std} visibility kwimport id
 579         | {no} visibility kwimport kwend
 580         ;
 581
 582 visibility
 583         = {public}
 584         | {private} kwprivate
 585         | {protected} kwprotected
 586         | {intrude} kwintrude
 587         ;
 588
 589 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef*
 590         | {top} [propdefs]:propdef*
 591         | {main} [propdefs]:propdef*
 592         ;
 593 classkind
 594         = {concrete} kwclass
 595         | {abstract} kwabstract kwclass
 596         | {interface} kwinterface
 597         | {universal} kwuniversal
 598         ;
 599 formaldef = [id]:classid type?;
 600 superclass = kwspecial? kwsuper? type;
 601
 602
 603 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid type? expr?
 604         | {meth} doc? kwredef? visibility methid signature
 605         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 606         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 607         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string?
 608         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 609         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 610         | {main_meth} kwredef? [block]:expr?
 611         | {type} doc? kwredef? visibility kwtype [id]:classid type
 612         ;
 613
 614 able    = {read} kwredef? kwreadable
 615         | {write} kwredef? kwwritable
 616         ;
 617
 618 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 619
 620 signature = [params]:param* type? [closure_decls]:closure_decl*;
 621
 622 param   = id type? dotdotdot?
 623         ;
 624
 625 closure_decl = kwbreak? bang id signature expr?
 626         ;
 627
 628 type    = kwnullable? [id]:classid [types]:type*;
 629
 630 label = kwlabel id;
 631
 632 expr    = {block} expr*
 633         | {vardecl} kwvar id type? assign? expr?
 634         | {return} kwreturn? expr?
 635         | {break} kwbreak label? expr?
 636         | {abort} kwabort
 637         | {continue} kwcontinue? label? expr?
 638         | {do} kwdo [block]:expr? label?
 639         | {if} kwif expr [then]:expr? [else]:expr?
 640         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 641         | {while} kwwhile expr kwdo [block]:expr? label?
 642         | {loop} kwloop [block]:expr? label?
 643         | {for} kwfor id expr kwdo [block]:expr? label?
 644         | {assert} kwassert id? expr [else]:expr?
 645         | {once} kwonce expr
 646         | {send} expr
 647         | {binop} expr [expr2]:expr
 648         | {or} expr [expr2]:expr
 649         | {and} expr [expr2]:expr
 650         | {or_else} expr [expr2]:expr
 651         | {not} kwnot expr
 652         | {eq} expr [expr2]:expr
 653         | {ee} expr [expr2]:expr
 654         | {ne} expr [expr2]:expr
 655         | {lt} expr [expr2]:expr
 656         | {le} expr [expr2]:expr
 657         | {gt} expr [expr2]:expr
 658         | {ge} expr [expr2]:expr
 659         | {isa} expr type
 660         | {plus} expr [expr2]:expr
 661         | {minus} expr [expr2]:expr
 662         | {starship} expr [expr2]:expr
 663         | {star} expr [expr2]:expr
 664         | {slash} expr [expr2]:expr
 665         | {percent} expr [expr2]:expr
 666         | {uminus} minus expr
 667         | {new} kwnew type id? [args]:expr*
 668         | {attr} expr [id]:attrid
 669         | {attr_assign} expr [id]:attrid assign [value]:expr
 670         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 671         | {call} expr id [args]:expr* [closure_defs]:closure_def*
 672         | {call_assign} expr id [args]:expr* assign [value]:expr
 673         | {call_reassign} expr id [args]:expr* assign_op [value]:expr
 674         | {super} qualified? kwsuper [args]:expr*
 675         | {init} expr kwinit [args]:expr*
 676         | {bra} expr [args]:expr* [closure_defs]:closure_def*
 677         | {bra_assign} expr [args]:expr* assign [value]:expr
 678         | {bra_reassign} expr [args]:expr* assign_op [value]:expr
 679         | {closure_call} id [args]:expr* [closure_defs]:closure_def*
 680         | {var} id
 681         | {var_assign} id assign [value]:expr
 682         | {var_reassign} id assign_op [value]:expr
 683         | {range} expr [expr2]:expr
 684         | {crange} expr [expr2]:expr
 685         | {orange} expr [expr2]:expr
 686         | {array} [exprs]:expr*
 687         | {self} kwself
 688         | {implicit_self}
 689         | {true} kwtrue
 690         | {false} kwfalse
 691         | {null} kwnull
 692         | {int} number
 693         | {float} float
 694         | {char} char
 695         | {string} string
 696         | {start_string} [string]:start_string
 697         | {mid_string} [string]:mid_string
 698         | {end_string} [string]:end_string
 699         | {superstring} [exprs]:expr*
 700         | {par} expr
 701         | {as_cast} expr kwas type
 702         | {as_notnull} expr kwas kwnot kwnull
 703         | {isset_attr} kwisset expr [id]:attrid
 704         ;
 705 assign_op
 706         = {plus} pluseq
 707         | {minus} minuseq
 708         ;
 709
 710 closure_def
 711         = bang [id]:closure_id [ids]:id* kwdo? expr? label?
 712         ;
 713 closure_id
 714         = {simple} id
 715         | {break} kwbreak
 716         ;
 717
 718 qualified = id* classid? ;
 719
 720 doc = comment+;
 721
 722 /*****************************************************************************/
 723