src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper;
  59
  60 kwpackage = 'package';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwuniversal = 'universal';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'fun';
  69 kwtype = 'type';
  70 kwinit = 'init';
  71 kwredef = 'redef';
  72 kwis = 'is';
  73 kwdo = 'do';
  74 kwreadable = 'readable';
  75 kwwritable = 'writable';
  76 kwvar = 'var';
  77 kwintern = 'intern';
  78 kwextern = 'extern';
  79 kwprotected = 'protected';
  80 kwprivate = 'private';
  81 kwintrude = 'intrude';
  82 kwif = 'if';
  83 kwthen = 'then';
  84 kwelse = 'else';
  85 kwwhile = 'while';
  86 kwloop = 'loop';
  87 kwfor = 'for';
  88 kwin = 'in';
  89 kwand = 'and';
  90 kwor = 'or';
  91 kwnot = 'not';
  92 kwreturn = 'return';
  93 kwcontinue = 'continue';
  94 kwbreak = 'break';
  95 kwabort = 'abort';
  96 kwassert = 'assert';
  97 kwnew = 'new';
  98 kwisa = 'isa';
  99 kwonce = 'once';
 100 kwsuper = 'super';
 101 kwself = 'self';
 102 kwtrue = 'true';
 103 kwfalse = 'false';
 104 kwnull = 'null';
 105 kwas = 'as';
 106 kwnullable = 'nullable';
 107 kwisset = 'isset';
 108 kwlabel = 'label';
 109
 110 opar = '(';
 111 cpar = ')';
 112 obra = '[';
 113 cbra = ']';
 114 comma = ',';
 115 column = ':';
 116 quad = '::';
 117 assign = '=';
 118 pluseq = '+=';
 119 minuseq = '-=';
 120 dotdotdot = '...';
 121 dotdot = '..';
 122 dot = '.';
 123 plus = '+';
 124 minus = '-';
 125 star = '*';
 126 slash = '/';
 127 percent = '%';
 128 eq = '==';
 129 ne = '!=';
 130 lt = '<';
 131 le = '<=';
 132 gt = '>';
 133 ge = '>=';
 134 starship = '<=>';
 135 bang='!';
 136
 137 classid = uppercase letter*;
 138 id = lowercase letter*;
 139 attrid = '_' lowercase letter*;
 140
 141 number = digit+;
 142 float = digit* '.' digit+;
 143 char = ''' [any - ''']* ''';
 144 string = '"' str_body '"';
 145 start_string = '"' str_body '{';
 146 mid_string = '}' str_body '{';
 147 end_string = '}' str_body '"';
 148
 149
 150 /*****************************************************************************/
 151 Ignored Tokens
 152 /*****************************************************************************/
 153
 154 blank;
 155
 156 /*****************************************************************************/
 157 Productions
 158 /*****************************************************************************/
 159
 160 /* MODULES *******************************************************************/
 161 module
 162         = packagedecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(packagedecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 163
 164 packagedecl
 165         = [doc]:no kwpackage no id [n2]:n1 {-> New packagedecl(doc.doc, kwpackage, id)};
 166
 167 import
 168         = {std} [doc]:no visibility kwimport no id [n2]:n1              {-> New import.std(visibility, kwimport, id)}
 169         | {no} [doc]:no visibility kwimport no kwend [n2]:n1    {-> New import.no(visibility, kwimport, kwend)}
 170         ;
 171
 172 implicit_top_class {-> classdef}
 173         = propdefs_toplevel {-> New classdef.top([propdefs_toplevel.propdef])};
 174
 175 implicit_main_class {-> classdef?}
 176         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 177         | {null} n {-> Null}
 178         ;
 179 implicit_main_meth {-> propdef}
 180         = [doc]:no stmts no {-> New propdef.main_meth(Null, stmts.expr)};
 181
 182 /* CLASSES *******************************************************************/
 183 classdef
 184         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs? [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef])};
 185 redef {-> kwredef?}
 186         = kwredef? {-> kwredef};
 187 classkind
 188         = {concrete} kwclass
 189         | {abstract} kwabstract kwclass
 190         | {interface} kwinterface
 191         | {universal} kwuniversal
 192         ;
 193
 194 formaldefs {-> formaldef*}
 195         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 196 formaldefs_tail {-> formaldef}
 197         = comma no formaldef {-> formaldef};
 198 formaldef
 199         = classid typing? {-> New formaldef(classid, typing.type)};
 200
 201 special {-> superclass}
 202         = no kwspecial [n2]:no type {-> New superclass(kwspecial, type)};
 203
 204 propdefs~toplevel {-> propdef*}
 205         = propdef~toplevel n1 propdefs_tail~toplevel* {-> [propdef~toplevel.propdef, propdefs_tail~toplevel.propdef]}
 206         ;
 207 propdefs_tail~toplevel {-> propdef}
 208         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 209         ;
 210 propdef~toplevel {-> propdef}
 211         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 212         | {assign_return} [doc]:no redef visibility kwmeth methid_noassign signature_withret assign no assign_return {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid_noassign.methid, signature_withret.signature, assign_return.expr)}
 213 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 214 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 215         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string)}
 216 !toplevel| {var} [doc]:no readable writable redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, typing.type, Null)}
 217 !toplevel| {var2} [doc]:no readable writable redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, typing.type, expr)}
 218 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 219 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 220         ;
 221 readable {-> able?}
 222         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 223         | {empty} {-> Null}
 224         ;
 225 writable {-> able?}
 226         = redef kwwritable {-> New able.write(redef.kwredef, kwwritable)}
 227         | {empty} {-> Null}
 228         ;
 229
 230 visibility
 231         = {public} {-> New visibility.public()}
 232         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 233         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 234         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 235         ;
 236
 237 methid~noassign {-> methid}
 238         = {id} id {-> New methid.id(id)}
 239         | {plus} plus {-> New methid.plus(plus)}
 240         | {minus} minus {-> New methid.minus(minus)}
 241         | {star} star {-> New methid.star(star)}
 242         | {slash} slash {-> New methid.slash(slash)}
 243         | {percent} percent {-> New methid.percent(percent)}
 244         | {eq} eq {-> New methid.eq(eq)}
 245         | {ne} ne {-> New methid.ne(ne)}
 246         | {le} le {-> New methid.le(le)}
 247         | {ge} ge {-> New methid.ge(ge)}
 248         | {lt} lt {-> New methid.lt(lt)}
 249         | {gt} gt {-> New methid.gt(gt)}
 250         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 251         | {starship} starship {-> New methid.starship(starship)}
 252 !noassign       | {assign} id assign {-> New methid.assign(id, assign)}
 253 !noassign       | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 254         ;
 255
 256 signature~withret {-> signature}
 257         = params? typing closure_decls {-> New signature([params.param], typing.type, [closure_decls.closure_decl])}
 258         | {noclosures} params? typing no {-> New signature([params.param], typing.type, [])}
 259 !withret| {noret} params? closure_decls {-> New signature([params.param], Null, [closure_decls.closure_decl])}
 260 !withret| {noretnoclosures} params? no {-> New signature([params.param], Null, [])}
 261         ;
 262
 263 signature_noclosures {-> signature}
 264         = params? typing? {-> New signature([params.param], typing.type, [])};
 265
 266 params {-> param*}
 267         = opar no param params_tail* [n2]:no cpar {-> [param, params_tail.param]}
 268         | {empty} opar no cpar {-> []}
 269         ;
 270 params_tail {-> param}
 271         = comma no param {-> param};
 272 param
 273         = {untyped} id {-> New param(id, Null, Null)}
 274         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 275         ;
 276
 277 closure_decls {->closure_decl*}
 278         = no closure_decl+ {-> [closure_decl]};
 279 closure_decl
 280         = kwbreak? bang id signature_noclosures n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, Null)}
 281         | {optionnal} kwbreak? bang id signature_noclosures kwdo stmtso n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, stmtso.expr)}
 282         | {assign} kwbreak? bang id signature_noclosures assign no assign_continue n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, assign_continue.expr)}
 283         ;
 284
 285 assign_return{-> expr}
 286         = expr_final {-> New expr.return(Null, expr_final.expr)}
 287         ;
 288
 289
 290 /* TYPES *********************************************************************/
 291 type~nobra {-> type}
 292         = {simple} kwnullable? classid {-> New type(kwnullable, classid, [])}
 293 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra {-> New type(kwnullable, classid, [types.type])}
 294         ;
 295 types {-> type*}
 296         = type types_tail* {-> [type, types_tail.type]};
 297 types_tail {-> type}
 298         = comma no type {-> type};
 299 typing {-> type}
 300         = column no type {-> type};
 301
 302 /* STATMENTS *****************************************************************/
 303 stmtso~withelse~withend {-> expr?}
 304         = {block} n stmts [n2]:n kwend {-> stmts.expr}
 305         | {emptyblock} n kwend {-> New expr.block([])}
 306         | {emptyoneline} kwend {-> New expr.block([])}
 307 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 308         ;
 309 stmts {-> expr}
 310         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr])};
 311 stmts_tail {-> expr}
 312         = n stmt {-> stmt.expr};
 313 stmt~withelse {-> expr}
 314         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 315         | {assign} assignment~withelse {-> assignment~withelse.expr}
 316         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 317         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 318         | {abort} kwabort {-> New expr.abort(kwabort)}
 319         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 320         | {do} do~withelse {-> do~withelse.expr}
 321         | {if} if~withelse {-> if~withelse.expr}
 322         | {while} while~withelse {-> while~withelse.expr}
 323         | {loop} loop~withelse {-> loop~withelse.expr}
 324         | {for} for~withelse {-> for~withelse.expr}
 325         | {assert} assert~withelse {-> assert~withelse.expr}
 326         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, [args_nopar.expr], [closure_defs~withelse.closure_def])}
 327         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, [args_nopar.expr])}
 328         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, [args_nopar.expr])}
 329         ;
 330
 331 label= kwlabel id;
 332
 333 closure_defs~withelse {-> closure_def*}
 334         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 335         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 336         ;
 337
 338 closure_def_last~withelse {-> closure_def}
 339         = bang [id]:closure_id idlist? kwdo stmtso~withelse_withend label? {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso~withelse_withend.expr, label)}
 340         | {noend} bang [id]:closure_id idlist? kwdo stmt~withelse {-> New closure_def(bang, id, [idlist.id], kwdo, stmt~withelse.expr, Null)}
 341         | {assign} bang [id]:closure_id idlist? assign no assign_continue~withelse {-> New closure_def(bang, id, [idlist.id], Null, assign_continue~withelse.expr, Null)}
 342         ;
 343
 344 closure_def {-> closure_def}
 345         = bang [id]:closure_id idlist? kwdo n stmts [n2]:n {-> New closure_def(bang, id, [idlist.id], kwdo, stmts.expr, Null)}
 346         | {empty} bang [id]:closure_id idlist? kwdo n {-> New closure_def(bang, id, [idlist.id], kwdo, Null, Null)}
 347         ;
 348 closure_id
 349         = {simple} id
 350         | {break} kwbreak
 351         ;
 352
 353 assign_continue~withelse{-> expr}
 354         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 355         ;
 356
 357 vardecl~withelse{-> expr}
 358         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 359         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 360         ;
 361
 362 assignment~withelse {-> expr}
 363         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 364         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, [args.expr], assign,  expr_final~withelse.expr)}
 365         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, [braargs.expr], assign,  expr_final~withelse.expr)}
 366         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 367         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, [args.expr], assign_op,  expr_final~withelse.expr)}
 368         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, [braargs.expr], assign_op,  expr_final~withelse.expr)}
 369         ;
 370 assign_op
 371         = {plus} pluseq
 372         | {minus} minuseq
 373         ;
 374
 375 do~withelse {-> expr}
 376         = kwdo stmtso~withelse_withend label? {-> New expr.do(kwdo, stmtso~withelse_withend.expr, label)}
 377         | {noend} kwdo stmt~withelse {-> New expr.do(kwdo, stmt~withelse.expr, Null)}
 378         ;
 379
 380 if~withelse {-> expr}
 381         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 382 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 383 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmts [n4]:n elsepartblock {-> New expr.if(kwif, expr, stmts.expr, elsepartblock.expr)}
 384 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 385         ;
 386 elsepartblock {-> expr?}
 387         = {else} kwelse stmtso {-> stmtso.expr}
 388         | {empty} kwend {-> Null}
 389         ;
 390
 391 loop~withelse {-> expr}
 392         = kwloop stmtso~withelse_withend label? {-> New expr.loop(kwloop, stmtso~withelse_withend.expr, label)}
 393         | {noend} kwloop stmt~withelse {-> New expr.loop(kwloop, stmt~withelse.expr, Null)}
 394         ;
 395
 396 while~withelse {-> expr}
 397         = kwwhile no expr [n2]:no kwdo stmtso~withelse_withend label? {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse_withend.expr, label)}
 398         | {noend} kwwhile no expr [n2]:no kwdo stmt~withelse {-> New expr.while(kwwhile, expr, kwdo, stmt~withelse.expr, Null)}
 399         ;
 400
 401 for~withelse {-> expr}
 402         = kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse_withend label? {-> New expr.for(kwfor, id, expr, kwdo, stmtso~withelse_withend.expr, label)}
 403         | {noend} kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmt~withelse {-> New expr.for(kwfor, id, expr, kwdo, stmt~withelse.expr, Null)}
 404         ;
 405
 406 assert~withelse {-> expr}
 407         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 408 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 409         ;
 410 assertid {-> id}
 411         = id column {-> id};
 412
 413 /* EXPRESSIONS ***************************************************************/
 414 expr_final~nopar~withelse~nobra {-> expr}
 415         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 416         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, [args.expr], [closure_defs~withelse.closure_def])}
 417 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, [braargs.expr], [closure_defs~withelse.closure_def])}
 418         ;
 419
 420 expr~nopar~nobra {-> expr}
 421         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 422         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 423         ;
 424
 425 expr_and~nopar~nobra {-> expr}
 426         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 427         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 428         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 429         ;
 430
 431 expr_not~nopar~nobra {-> expr}
 432         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 433         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 434         ;
 435
 436 expr_eq~nopar~nobra {-> expr}
 437         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 438         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 439         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 440         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 441         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 442         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 443         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 444         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 445         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 446         | {isa} expr_add~nopar~nobra kwisa no type~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nobra.type)}
 447         ;
 448
 449 expr_add~nopar~nobra {-> expr}
 450         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 451         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 452         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 453         ;
 454
 455 expr_mul~nopar~nobra {-> expr}
 456         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 457         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 458         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 459         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 460         ;
 461
 462 expr_minus~nopar~nobra {-> expr}
 463         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 464         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 465         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 466         ;
 467
 468 expr_new~nopar~nobra {-> expr}
 469         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 470         | {new} kwnew no type~nobra args {-> New expr.new(kwnew, type~nobra.type, Null, [args.expr])}
 471         | {isset_attr} kwisset recv~nopar~nobra attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 472         ;
 473
 474 expr_atom~nopar~nobra {-> expr}
 475         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 476         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, [args.expr], [])}
 477         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, [args.expr])}
 478         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, [args.expr])}
 479 !nobra!nopar    | {bra} expr_atom braargs {-> New expr.bra(expr_atom.expr, [braargs.expr], [])}
 480         | {new} kwnew no type~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nobra.type, id, [args.expr])}
 481 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(expr, expr2.expr)}
 482 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(expr, expr2.expr)}
 483 !nobra!nopar    | {array} braargs {-> New expr.array([braargs.expr])}
 484         | {self} kwself {-> New expr.self(kwself)}
 485         | {true} kwtrue {-> New expr.true(kwtrue)}
 486         | {false} kwfalse {-> New expr.false(kwfalse)}
 487         | {null} kwnull {-> New expr.null(kwnull)}
 488         | {int} number  {-> New expr.int(number)}
 489         | {float} float  {-> New expr.float(float)}
 490         | {char} char  {-> New expr.char(char)}
 491         | {string} string  {-> New expr.string(string)}
 492         | {superstring} superstring  {-> superstring.expr}
 493 !nopar  | {par} opar expr cpar {-> expr}
 494         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, type)}
 495         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, kwnot, kwnull)}
 496         ;
 497
 498 superstring {-> expr}
 499         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 500 superstring_start {-> expr*}
 501         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 502 start_string_p {-> expr}
 503         = start_string {-> New expr.start_string(start_string)};
 504 superstring_middle {-> expr*}
 505         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 506 mid_string_p {-> expr}
 507         = mid_string {-> New expr.mid_string(mid_string)};
 508 superstring_end {-> expr}
 509         = end_string {-> New expr.end_string(end_string)};
 510
 511 /* MISC **********************************************************************/
 512
 513 recv~nopar~nobra {-> expr}
 514         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 515         | {implicit} {-> New expr.implicit_self()}
 516         ;
 517
 518 args {-> expr*}
 519         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 520         | {emptypar} opar no cpar {-> []}
 521         | {empty} {-> []}
 522         ;
 523 args_nopar {-> expr*}
 524         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 525         | {onearg} expr_nopar {-> [expr_nopar.expr]}
 526         | {emptypar} opar no cpar {-> []}
 527         | {empty} {-> []}
 528         ;
 529 braargs {-> expr*}
 530         = obra no expr [n2]:no args_tail* cbra {-> [expr, args_tail.expr]};
 531 args_tail {-> expr}
 532         = comma no expr [n2]:no {-> expr};
 533 idlist {-> id*}
 534         = opar idlist_nopar cpar {-> [idlist_nopar.id]}
 535         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 536         ;
 537 idlist_nopar {-> id*}
 538         = {single} id {-> [id]}
 539         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 540         ;
 541
 542 qualified
 543         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 544         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 545         ;
 546 modquad {-> id}
 547         = id quad no {-> id};
 548 classquad {-> classid}
 549         = classid quad no {-> classid};
 550
 551 n1      = {a} comment | {b} eol;
 552 n {-> doc?}
 553         = {a} n2? comment+ {-> New doc([comment])}
 554         | {b} n2 {-> Null}
 555         ;
 556 no {-> doc?}
 557         = {empty} {-> Null}
 558         | n {-> n.doc}
 559         ;
 560
 561 n2
 562         = {a} n2? comment+ eol+
 563         | {b} eol+
 564         ;
 565
 566 /*****************************************************************************/
 567 Abstract Syntax Tree
 568 /*****************************************************************************/
 569
 570 module  = packagedecl? [imports]:import* [classdefs]:classdef*;
 571
 572 packagedecl
 573         = doc? kwpackage id;
 574
 575 import  = {std} visibility kwimport id
 576         | {no} visibility kwimport kwend
 577         ;
 578
 579 visibility
 580         = {public}
 581         | {private} kwprivate
 582         | {protected} kwprotected
 583         | {intrude} kwintrude
 584         ;
 585
 586 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef*
 587         | {top} [propdefs]:propdef*
 588         | {main} [propdefs]:propdef*
 589         ;
 590 classkind
 591         = {concrete} kwclass
 592         | {abstract} kwabstract kwclass
 593         | {interface} kwinterface
 594         | {universal} kwuniversal
 595         ;
 596 formaldef = [id]:classid type?;
 597 superclass = kwspecial type;
 598
 599
 600 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid type? expr?
 601         | {meth} doc? kwredef? visibility methid signature
 602         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 603         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 604         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string?
 605         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 606         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 607         | {main_meth} kwredef? [block]:expr?
 608         | {type} doc? kwredef? visibility kwtype [id]:classid type
 609         ;
 610
 611 able    = {read} kwredef? kwreadable
 612         | {write} kwredef? kwwritable
 613         ;
 614
 615 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 616
 617 signature = [params]:param* type? [closure_decls]:closure_decl*;
 618
 619 param   = id type? dotdotdot?
 620         ;
 621
 622 closure_decl = kwbreak? bang id signature expr?
 623         ;
 624
 625 type    = kwnullable? [id]:classid [types]:type*;
 626
 627 label = kwlabel id;
 628
 629 expr    = {block} expr*
 630         | {vardecl} kwvar id type? assign? expr?
 631         | {return} kwreturn? expr?
 632         | {break} kwbreak label? expr?
 633         | {abort} kwabort
 634         | {continue} kwcontinue? label? expr?
 635         | {do} kwdo [block]:expr? label?
 636         | {if} kwif expr [then]:expr? [else]:expr?
 637         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 638         | {while} kwwhile expr kwdo [block]:expr? label?
 639         | {loop} kwloop [block]:expr? label?
 640         | {for} kwfor id expr kwdo [block]:expr? label?
 641         | {assert} kwassert id? expr [else]:expr?
 642         | {once} kwonce expr
 643         | {send} expr
 644         | {binop} expr [expr2]:expr
 645         | {or} expr [expr2]:expr
 646         | {and} expr [expr2]:expr
 647         | {not} kwnot expr
 648         | {eq} expr [expr2]:expr
 649         | {ee} expr [expr2]:expr
 650         | {ne} expr [expr2]:expr
 651         | {lt} expr [expr2]:expr
 652         | {le} expr [expr2]:expr
 653         | {gt} expr [expr2]:expr
 654         | {ge} expr [expr2]:expr
 655         | {isa} expr type
 656         | {plus} expr [expr2]:expr
 657         | {minus} expr [expr2]:expr
 658         | {starship} expr [expr2]:expr
 659         | {star} expr [expr2]:expr
 660         | {slash} expr [expr2]:expr
 661         | {percent} expr [expr2]:expr
 662         | {uminus} minus expr
 663         | {new} kwnew type id? [args]:expr*
 664         | {attr} expr [id]:attrid
 665         | {attr_assign} expr [id]:attrid assign [value]:expr
 666         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 667         | {call} expr id [args]:expr* [closure_defs]:closure_def*
 668         | {call_assign} expr id [args]:expr* assign [value]:expr
 669         | {call_reassign} expr id [args]:expr* assign_op [value]:expr
 670         | {super} qualified? kwsuper [args]:expr*
 671         | {init} expr kwinit [args]:expr*
 672         | {bra} expr [args]:expr* [closure_defs]:closure_def*
 673         | {bra_assign} expr [args]:expr* assign [value]:expr
 674         | {bra_reassign} expr [args]:expr* assign_op [value]:expr
 675         | {closure_call} id [args]:expr* [closure_defs]:closure_def*
 676         | {var} id
 677         | {var_assign} id assign [value]:expr
 678         | {var_reassign} id assign_op [value]:expr
 679         | {range} expr [expr2]:expr
 680         | {crange} expr [expr2]:expr
 681         | {orange} expr [expr2]:expr
 682         | {array} [exprs]:expr*
 683         | {self} kwself
 684         | {implicit_self}
 685         | {true} kwtrue
 686         | {false} kwfalse
 687         | {null} kwnull
 688         | {int} number
 689         | {float} float
 690         | {char} char
 691         | {string} string
 692         | {start_string} [string]:start_string
 693         | {mid_string} [string]:mid_string
 694         | {end_string} [string]:end_string
 695         | {superstring} [exprs]:expr*
 696         | {par} expr
 697         | {as_cast} expr kwas type
 698         | {as_notnull} expr kwas kwnot kwnull
 699         | {isset_attr} kwisset expr [id]:attrid
 700         ;
 701 assign_op
 702         = {plus} pluseq
 703         | {minus} minuseq
 704         ;
 705
 706 closure_def
 707         = bang [id]:closure_id [ids]:id* kwdo? expr? label?
 708         ;
 709 closure_id
 710         = {simple} id
 711         | {break} kwbreak
 712         ;
 713
 714 qualified = id* classid? ;
 715
 716 doc = comment+;
 717
 718 /*****************************************************************************/
 719