src/modelize/modelize_class.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Analysis and verification of class definitions to instantiate model element
  18 module modelize_class
  19
  20 import modelbuilder
  21
  22 redef class ToolContext
  23         var modelize_class_phase: Phase = new ModelizeClassPhase(self, null)
  24 end
  25
  26 private class ModelizeClassPhase
  27         super Phase
  28
  29         redef fun process_nmodule(nmodule)
  30         do
  31                 toolcontext.modelbuilder.build_classes(nmodule)
  32         end
  33 end
  34
  35 redef class ModelBuilder
  36         # Visit the AST and create the `MClass` objects
  37         private fun build_a_mclass(nmodule: AModule, nclassdef: AClassdef)
  38         do
  39                 var mmodule = nmodule.mmodule.as(not null)
  40
  41                 var name: String
  42                 var nkind: nullable AClasskind
  43                 var mkind: MClassKind
  44                 var nvisibility: nullable AVisibility
  45                 var mvisibility: nullable MVisibility
  46                 var arity = 0
  47                 var names = new Array[String]
  48                 if nclassdef isa AStdClassdef then
  49                         name = nclassdef.n_id.text
  50                         nkind = nclassdef.n_classkind
  51                         mkind = nkind.mkind
  52                         nvisibility = nclassdef.n_visibility
  53                         mvisibility = nvisibility.mvisibility
  54                         arity = nclassdef.n_formaldefs.length
  55                         if mvisibility == protected_visibility then
  56                                 error(nvisibility, "Error: only properties can be protected.")
  57                                 return
  58                         else if mvisibility == intrude_visibility then
  59                                 error(nvisibility, "Error: intrude is not a legal visibility for classes.")
  60                                 return
  61                         end
  62                         # Collect formal parameter names
  63                         for i in [0..arity[ do
  64                                 var nfd = nclassdef.n_formaldefs[i]
  65                                 var ptname = nfd.n_id.text
  66                                 if names.has(ptname) then
  67                                         error(nfd, "Error: A formal parameter type `{ptname}' already exists")
  68                                         return
  69                                 end
  70                                 for c in ptname.chars do if c >= 'a' and c<= 'z' then
  71                                         warning(nfd, "formal-type-name", "Warning: lowercase in the formal parameter type {ptname}")
  72                                         break
  73                                 end
  74                                 names.add(ptname)
  75                         end
  76
  77                 else if nclassdef isa ATopClassdef then
  78                         name = "Object"
  79                         nkind = null
  80                         mkind = interface_kind
  81                         nvisibility = null
  82                         mvisibility = public_visibility
  83                 else if nclassdef isa AMainClassdef then
  84                         name = "Sys"
  85                         nkind = null
  86                         mkind = concrete_kind
  87                         nvisibility = null
  88                         mvisibility = public_visibility
  89                 else
  90                         abort
  91                 end
  92
  93                 var mclass = try_get_mclass_by_name(nclassdef, mmodule, name)
  94                 if mclass == null then
  95                         if nclassdef isa AStdClassdef and nclassdef.n_kwredef != null then
  96                                 error(nclassdef, "Redef error: No imported class {name} to refine.")
  97                                 return
  98                         end
  99                         mclass = new MClass(mmodule, name, names, mkind, mvisibility)
 100                         #print "new class {mclass}"
 101                 else if nclassdef isa AStdClassdef and nmodule.mclass2nclassdef.has_key(mclass) then
 102                         error(nclassdef, "Error: A class {name} is already defined at line {nmodule.mclass2nclassdef[mclass].location.line_start}.")
 103                         return
 104                 else if nclassdef isa AStdClassdef and nclassdef.n_kwredef == null then
 105                         error(nclassdef, "Redef error: {name} is an imported class. Add the redef keyword to refine it.")
 106                         return
 107                 else if arity != 0 and mclass.arity != arity then
 108                         error(nclassdef, "Redef error: Formal parameter arity missmatch; got {arity}, expected {mclass.arity}.")
 109                         return
 110                 else if nkind != null and mkind != concrete_kind and mclass.kind != mkind then
 111                         error(nkind, "Error: refinement changed the kind from a {mclass.kind} to a {mkind}")
 112                 else if nvisibility != null and mvisibility != public_visibility and mclass.visibility != mvisibility then
 113                         error(nvisibility, "Error: refinement changed the visibility from a {mclass.visibility} to a {mvisibility}")
 114                 end
 115                 nclassdef.mclass = mclass
 116                 if not nmodule.mclass2nclassdef.has_key(mclass) then
 117                         nmodule.mclass2nclassdef[mclass] = nclassdef
 118                         nclassdef.all_defs = [nclassdef]
 119                 else
 120                         nmodule.mclass2nclassdef[mclass].all_defs.add(nclassdef)
 121                 end
 122         end
 123
 124         # Visit the AST and create the `MClassDef` objects
 125         private fun build_a_mclassdef(nmodule: AModule, nclassdef: AClassdef)
 126         do
 127                 var mmodule = nmodule.mmodule.as(not null)
 128                 var objectclass = try_get_mclass_by_name(nmodule, mmodule, "Object")
 129                 var mclass = nclassdef.mclass
 130                 if mclass == null then return # Skip error
 131
 132                 # In case of non-standard AClassdef, try to attach to an already existing mclassdef
 133                 var other_nclassdef = nmodule.mclass2nclassdef[mclass]
 134                 if other_nclassdef != nclassdef then
 135                         assert not nclassdef isa AStdClassdef
 136                         nclassdef.mclassdef = other_nclassdef.mclassdef
 137                         return
 138                 end
 139
 140                 var bounds = new Array[MType]
 141                 if nclassdef isa AStdClassdef and mclass.arity > 0 then
 142                         # Revolve bound for formal parameters
 143                         for i in [0..mclass.arity[ do
 144                                 if nclassdef.n_formaldefs.is_empty then
 145                                         # Inherit the bound
 146                                         var bound = mclass.intro.bound_mtype.arguments[i]
 147                                         bounds.add(bound)
 148                                         continue
 149                                 end
 150
 151                                 var nfd = nclassdef.n_formaldefs[i]
 152                                 var pname = mclass.mparameters[i].name
 153                                 if nfd.n_id.text != pname then
 154                                         error(nfd.n_id, "Error: Formal parameter type #{i} `{nfd.n_id.text}` must be named `{pname}' as in the original definition in module `{mclass.intro.mmodule}`.")
 155                                 end
 156                                 var nfdt = nfd.n_type
 157                                 if nfdt != null then
 158                                         var bound = resolve_mtype_unchecked(mmodule, null, nfdt, false)
 159                                         if bound == null then return # Forward error
 160                                         if bound.need_anchor then
 161                                                 # No F-bounds!
 162                                                 error(nfd, "Error: Formal parameter type `{pname}' bounded with a formal parameter type")
 163                                         else
 164                                                 bounds.add(bound)
 165                                                 nfd.bound = bound
 166                                         end
 167                                         if bound isa MClassType and bound.mclass.kind == enum_kind then
 168                                                 warning(nfdt, "useless-bound", "Warning: Useless formal parameter type since `{bound}` cannnot have subclasses.")
 169                                         end
 170                                 else if mclass.mclassdefs.is_empty then
 171                                         # No bound, then implicitely bound by nullable Object
 172                                         var bound = objectclass.mclass_type.as_nullable
 173                                         bounds.add(bound)
 174                                         nfd.bound = bound
 175                                 else
 176                                         # Inherit the bound
 177                                         var bound = mclass.intro.bound_mtype.arguments[i]
 178                                         bounds.add(bound)
 179                                         nfd.bound = bound
 180                                 end
 181                         end
 182                 end
 183
 184                 var bound_mtype = mclass.get_mtype(bounds)
 185                 var mclassdef = new MClassDef(mmodule, bound_mtype, nclassdef.location)
 186                 nclassdef.mclassdef = mclassdef
 187                 self.mclassdef2nclassdef[mclassdef] = nclassdef
 188
 189                 if nclassdef isa AStdClassdef then
 190                         var ndoc = nclassdef.n_doc
 191                         if ndoc != null then
 192                                 var mdoc = ndoc.to_mdoc
 193                                 mclassdef.mdoc = mdoc
 194                                 mdoc.original_mentity = mclassdef
 195                         else if mclassdef.is_intro and mclass.visibility >= public_visibility then
 196                                 advice(nclassdef, "missing-doc", "Documentation warning: Undocumented public class `{mclass}`")
 197                         end
 198                 end
 199
 200                 if mclassdef.is_intro then
 201                         self.toolcontext.info("{mclassdef} introduces new {mclass.kind} {mclass.full_name}", 3)
 202                 else
 203                         self.toolcontext.info("{mclassdef} refine {mclass.kind} {mclass.full_name}", 3)
 204                 end
 205         end
 206
 207         # Visit the AST and set the super-types of the `MClassDef` objects
 208         private fun collect_a_mclassdef_inheritance(nmodule: AModule, nclassdef: AClassdef)
 209         do
 210                 var mmodule = nmodule.mmodule.as(not null)
 211                 var objectclass = try_get_mclass_by_name(nmodule, mmodule, "Object")
 212                 var pointerclass = try_get_mclass_by_name(nmodule, mmodule, "Pointer")
 213                 var mclass = nclassdef.mclass.as(not null)
 214                 var mclassdef = nclassdef.mclassdef.as(not null)
 215
 216                 # Do we need to specify Object as a super class?
 217                 var specobject = true
 218
 219                 # Do we need to specify Pointer as a super class? (is only valid
 220                 # if `nclassdef` is an extern class)
 221                 var specpointer = true
 222
 223                 var supertypes = new Array[MClassType]
 224                 if nclassdef isa AStdClassdef then
 225                         for nsc in nclassdef.n_superclasses do
 226                                 specobject = false
 227                                 var ntype = nsc.n_type
 228                                 var mtype = resolve_mtype_unchecked(mmodule, mclassdef, ntype, false)
 229                                 if mtype == null then continue # Skip because of error
 230                                 if not mtype isa MClassType then
 231                                         error(ntype, "Error: supertypes cannot be a formal type")
 232                                         return
 233                                 end
 234                                 if not mclass.kind.can_specialize(mtype.mclass.kind) then
 235                                         error(ntype, "Error: {mclass.kind} {mclass} cannot specialize {mtype.mclass.kind} {mtype.mclass}")
 236                                 end
 237                                 supertypes.add mtype
 238                                 #print "new super : {mclass} < {mtype}"
 239                                 if mtype.mclass.kind == extern_kind then specpointer = false
 240                         end
 241                 end
 242
 243                 if mclassdef.is_intro and objectclass != null then
 244                         if mclass.kind == extern_kind and mclass.name != "Pointer" then
 245                                 # it is an extern class, but not a Pointer
 246                                 if specpointer then supertypes.add pointerclass.mclass_type
 247                         else if specobject and mclass.name != "Object" then
 248                                 # it is a standard class without super class (but is not Object)
 249                                 supertypes.add objectclass.mclass_type
 250                         end
 251                 end
 252
 253                 mclassdef.set_supertypes(supertypes)
 254                 if not supertypes.is_empty then self.toolcontext.info("{mclassdef} new super-types: {supertypes.join(", ")}", 3)
 255         end
 256
 257         # Check the validity of the specialization heirarchy
 258         private fun check_supertypes(nmodule: AModule, nclassdef: AClassdef)
 259         do
 260                 var mmodule = nmodule.mmodule.as(not null)
 261                 var objectclass = try_get_mclass_by_name(nmodule, mmodule, "Object")
 262                 var mclass = nclassdef.mclass.as(not null)
 263                 var mclassdef = nclassdef.mclassdef.as(not null)
 264
 265                 for s in mclassdef.supertypes do
 266                         if s.is_subtype(mmodule, mclassdef.bound_mtype, mclassdef.bound_mtype) then
 267                                 error(nclassdef, "Error: Inheritance loop for class {mclass} with type {s}")
 268                         end
 269                 end
 270         end
 271
 272         # Build the classes of the module `nmodule`.
 273         # REQUIRE: classes of imported modules are already build. (let `phase` do the job)
 274         private fun build_classes(nmodule: AModule)
 275         do
 276                 var errcount = toolcontext.error_count
 277                 # Force building recursively
 278                 if nmodule.build_classes_is_done then return
 279                 nmodule.build_classes_is_done = true
 280                 var mmodule = nmodule.mmodule.as(not null)
 281                 for imp in mmodule.in_importation.direct_greaters do
 282
 283                         if not mmodule2nmodule.has_key(imp) then continue
 284                         build_classes(mmodule2nmodule[imp])
 285                 end
 286
 287                 if errcount != toolcontext.error_count then return
 288
 289                 # Create all classes
 290                 for nclassdef in nmodule.n_classdefs do
 291                         self.build_a_mclass(nmodule, nclassdef)
 292                 end
 293
 294                 if errcount != toolcontext.error_count then return
 295
 296                 # Create all classdefs
 297                 for nclassdef in nmodule.n_classdefs do
 298                         self.build_a_mclassdef(nmodule, nclassdef)
 299                 end
 300
 301                 if errcount != toolcontext.error_count then return
 302
 303                 # Create inheritance on all classdefs
 304                 for nclassdef in nmodule.n_classdefs do
 305                         self.collect_a_mclassdef_inheritance(nmodule, nclassdef)
 306                 end
 307
 308                 if errcount != toolcontext.error_count then return
 309
 310                 # Create the mclassdef hierarchy
 311                 for mclassdef in mmodule.mclassdefs do
 312                         mclassdef.add_in_hierarchy
 313                 end
 314
 315                 if errcount != toolcontext.error_count then return
 316
 317                 # Check inheritance
 318                 for nclassdef in nmodule.n_classdefs do
 319                         self.check_supertypes(nmodule, nclassdef)
 320                 end
 321
 322                 if errcount != toolcontext.error_count then return
 323
 324                 # Check unchecked ntypes
 325                 for nclassdef in nmodule.n_classdefs do
 326                         if nclassdef isa AStdClassdef then
 327                                 var mclassdef = nclassdef.mclassdef
 328                                 # check bound of formal parameter
 329                                 for nfd in  nclassdef.n_formaldefs do
 330                                         var nfdt = nfd.n_type
 331                                         if nfdt != null and nfdt.mtype != null then
 332                                                 var bound = resolve_mtype(mmodule, mclassdef, nfdt)
 333                                                 if bound == null then return # Forward error
 334                                         end
 335                                 end
 336                                 # check declared super types
 337                                 for nsc in nclassdef.n_superclasses do
 338                                         var ntype = nsc.n_type
 339                                         if ntype.mtype != null then
 340                                                 var mtype = resolve_mtype(mmodule, mclassdef, ntype)
 341                                                 if mtype == null then return # Forward error
 342                                         end
 343                                 end
 344                         end
 345                 end
 346
 347                 if errcount != toolcontext.error_count then return
 348
 349                 # Check clash of ancestors
 350                 for nclassdef in nmodule.n_classdefs do
 351                         var mclassdef = nclassdef.mclassdef.as(not null)
 352                         var superclasses = new HashMap[MClass, MClassType]
 353                         for scd in mclassdef.in_hierarchy.greaters do
 354                                 for st in scd.supertypes do
 355                                         if not superclasses.has_key(st.mclass) then
 356                                                 superclasses[st.mclass] = st
 357                                         else if superclasses[st.mclass] != st then
 358                                                 var st1 = superclasses[st.mclass].resolve_for(mclassdef.mclass.mclass_type, mclassdef.bound_mtype, mmodule, false)
 359                                                 var st2 = st.resolve_for(mclassdef.mclass.mclass_type, mclassdef.bound_mtype, mmodule, false)
 360                                                 if st1 != st2 then
 361                                                         error(nclassdef, "Error: Incompatibles ancestors for {mclassdef.mclass}: {st1}, {st2}")
 362                                                 end
 363                                         end
 364                                 end
 365                         end
 366                 end
 367
 368                 if errcount != toolcontext.error_count then return
 369
 370                 # TODO: Check that the super-class is not intrusive
 371
 372                 # Check that the superclasses are not already known (by transitivity)
 373                 for nclassdef in nmodule.n_classdefs do
 374                         if not nclassdef isa AStdClassdef then continue
 375                         var mclassdef = nclassdef.mclassdef.as(not null)
 376
 377                         # Get the direct superclasses
 378                         # Since we are a mclassdef, just look at the mclassdef hierarchy
 379                         var parents = new Array[MClass]
 380                         for sup in mclassdef.in_hierarchy.direct_greaters do
 381                                 parents.add(sup.mclass)
 382                         end
 383
 384                         # Used to track duplicates of superclasses
 385                         var seen_parents = new ArrayMap[MClass, AType]
 386
 387                         # The Object class
 388                         var objectclass = try_get_mclass_by_name(nmodule, mmodule, "Object")
 389
 390                         # Check each declared superclass to see if it belong to the direct superclass
 391                         for nsc in nclassdef.n_superclasses do
 392                                 var ntype = nsc.n_type
 393                                 var mtype = ntype.mtype
 394                                 if mtype == null then continue
 395                                 assert mtype isa MClassType
 396                                 var sc = mtype.mclass
 397                                 if not parents.has(sc) or sc == objectclass then
 398                                         # Skip the warning on generated code
 399                                         if ntype.location.file != null and not ntype.location.file.filename.is_empty then
 400                                                 warning(ntype, "useless-superclass", "Warning: superfluous super-class {mtype} in class {mclassdef.mclass}.")
 401                                         end
 402                                 else if not seen_parents.has_key(sc) then
 403                                         seen_parents[sc] = ntype
 404                                 else
 405                                         warning(ntype, "useless-superclass", "Warning: duplicated super-class {mtype} in class {mclassdef.mclass}.")
 406                                 end
 407                         end
 408                 end
 409         end
 410
 411         # Register the nclassdef associated to each mclassdef
 412         # FIXME: why not refine the `MClassDef` class with a nullable attribute?
 413         var mclassdef2nclassdef: HashMap[MClassDef, AClassdef] = new HashMap[MClassDef, AClassdef]
 414
 415         # Return the static type associated to the node `ntype`.
 416         # `mmodule` and `mclassdef` is the context where the call is made (used to understand formal types)
 417         # In case of problem, an error is displayed on `ntype` and null is returned.
 418         # FIXME: the name "resolve_mtype" is awful
 419         fun resolve_mtype_unchecked(mmodule: MModule, mclassdef: nullable MClassDef, ntype: AType, with_virtual: Bool): nullable MType
 420         do
 421                 var name = ntype.n_id.text
 422                 var res: MType
 423
 424                 # Check virtual type
 425                 if mclassdef != null and with_virtual then
 426                         var prop = try_get_mproperty_by_name(ntype, mclassdef, name).as(nullable MVirtualTypeProp)
 427                         if prop != null then
 428                                 if not ntype.n_types.is_empty then
 429                                         error(ntype, "Type error: formal type {name} cannot have formal parameters.")
 430                                 end
 431                                 res = prop.mvirtualtype
 432                                 if ntype.n_kwnullable != null then res = res.as_nullable
 433                                 ntype.mtype = res
 434                                 return res
 435                         end
 436                 end
 437
 438                 # Check parameter type
 439                 if mclassdef != null and mclassdef.parameter_names.has(name) then
 440                         if not ntype.n_types.is_empty then
 441                                 error(ntype, "Type error: formal type {name} cannot have formal parameters.")
 442                         end
 443                         for i in [0..mclassdef.parameter_names.length[ do
 444                                 if mclassdef.parameter_names[i] == name then
 445                                         res = mclassdef.mclass.mclass_type.arguments[i]
 446                                         if ntype.n_kwnullable != null then res = res.as_nullable
 447                                         ntype.mtype = res
 448                                         return res
 449                                 end
 450                         end
 451                         abort
 452                 end
 453
 454                 # Check class
 455                 var mclass = try_get_mclass_by_name(ntype, mmodule, name)
 456                 if mclass != null then
 457                         var arity = ntype.n_types.length
 458                         if arity != mclass.arity then
 459                                 if arity == 0 then
 460                                         error(ntype, "Type error: '{name}' is a generic class.")
 461                                 else if mclass.arity == 0 then
 462                                         error(ntype, "Type error: '{name}' is not a generic class.")
 463                                 else
 464                                         error(ntype, "Type error: '{name}' has {mclass.arity} parameters ({arity} are provided).")
 465                                 end
 466                                 return null
 467                         end
 468                         if arity == 0 then
 469                                 res = mclass.mclass_type
 470                                 if ntype.n_kwnullable != null then res = res.as_nullable
 471                                 ntype.mtype = res
 472                                 return res
 473                         else
 474                                 var mtypes = new Array[MType]
 475                                 for nt in ntype.n_types do
 476                                         var mt = resolve_mtype_unchecked(mmodule, mclassdef, nt, with_virtual)
 477                                         if mt == null then return null # Forward error
 478                                         mtypes.add(mt)
 479                                 end
 480                                 res = mclass.get_mtype(mtypes)
 481                                 if ntype.n_kwnullable != null then res = res.as_nullable
 482                                 ntype.mtype = res
 483                                 return res
 484                         end
 485                 end
 486
 487                 # If everything fail, then give up :(
 488                 error(ntype, "Type error: class {name} not found in module {mmodule}.")
 489                 return null
 490         end
 491
 492         # Return the static type associated to the node `ntype`.
 493         # `mmodule` and `mclassdef` is the context where the call is made (used to understand formal types)
 494         # In case of problem, an error is displayed on `ntype` and null is returned.
 495         # FIXME: the name "resolve_mtype" is awful
 496         fun resolve_mtype(mmodule: MModule, mclassdef: nullable MClassDef, ntype: AType): nullable MType
 497         do
 498                 var mtype = ntype.mtype
 499                 if mtype == null then mtype = resolve_mtype_unchecked(mmodule, mclassdef, ntype, true)
 500                 if mtype == null then return null # Forward error
 501
 502                 if ntype.checked_mtype then return mtype
 503                 if mtype isa MGenericType then
 504                         var mclass = mtype.mclass
 505                         for i in [0..mclass.arity[ do
 506                                 var bound = mclass.intro.bound_mtype.arguments[i]
 507                                 var nt = ntype.n_types[i]
 508                                 var mt = resolve_mtype(mmodule, mclassdef, nt)
 509                                 if mt == null then return null # forward error
 510                                 var anchor
 511                                 if mclassdef != null then anchor = mclassdef.bound_mtype else anchor = null
 512                                 if not mt.is_subtype(mmodule, anchor, bound) then
 513                                         error(nt, "Type error: expected {bound}, got {mt}")
 514                                         return null
 515                                 end
 516                         end
 517                 end
 518                 ntype.checked_mtype = true
 519                 return mtype
 520         end
 521
 522 end
 523
 524 redef class AModule
 525         # Flag that indicate if the class building is already completed
 526         var build_classes_is_done: Bool = false
 527         # What is the AClassdef associated to a `MClass`?
 528         # Used to check multiple definition of a class.
 529         var mclass2nclassdef: Map[MClass, AClassdef] = new HashMap[MClass, AClassdef]
 530 end
 531
 532 redef class AClassdef
 533         # The associated MClass once build by a `ModelBuilder`
 534         var mclass: nullable MClass
 535         # The associated MClassDef once build by a `ModelBuilder`
 536         var mclassdef: nullable MClassDef
 537         # All (self and other) definitions for the same mclassdef
 538         var all_defs: nullable Array[AClassdef]
 539 end
 540
 541 redef class AClasskind
 542         # The class kind associated with the AST node class
 543         private fun mkind: MClassKind is abstract
 544 end
 545 redef class AConcreteClasskind
 546         redef fun mkind do return concrete_kind
 547 end
 548 redef class AAbstractClasskind
 549         redef fun mkind do return abstract_kind
 550 end
 551 redef class AInterfaceClasskind
 552         redef fun mkind do return interface_kind
 553 end
 554 redef class AEnumClasskind
 555         redef fun mkind do return enum_kind
 556 end
 557 redef class AExternClasskind
 558         redef fun mkind do return extern_kind
 559 end
 560
 561 redef class AFormaldef
 562         # The associated parameter type
 563         var mtype: nullable MParameterType = null
 564
 565         # The associated bound
 566         var bound: nullable MType = null
 567 end
 568
 569 redef class AType
 570         # The mtype associated to the node
 571         var mtype: nullable MType = null
 572
 573         # Is the mtype a valid one?
 574         var checked_mtype: Bool = false
 575 end