src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20 Package org.nitlanguage.gen;
  21
  22 /*****************************************************************************/
  23 Helpers
  24 /*****************************************************************************/
  25
  26 all = [0 .. 0xFF];
  27 lowercase = ['a' .. 'z'];
  28 uppercase = ['A' .. 'Z'];
  29 digit = ['0' .. '9'];
  30 letter = lowercase | uppercase | digit | '_';
  31
  32 tab = 9;
  33 cr = 13;
  34 lf = 10;
  35 any = [all - [cr + lf]];
  36 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  37
  38 // characers inside strings and super-strings (atomaton powaa)
  39 str_char
  40         = [any - [['"' + '{'] + '\']]
  41         | '\' any
  42         ;
  43 str_body = str_char*;
  44
  45 sstr_char
  46         = [any - [''' + '\']]
  47         | '\' any
  48         ;
  49
  50 sstr_body = sstr_char*;
  51
  52 long_str_char = str_char | cr | lf;
  53
  54 long_str_part
  55         = long_str_char
  56         | '"' long_str_char
  57         | '"' '"' long_str_char
  58         | '{' long_str_char
  59         | '{' '{' long_str_char
  60         ;
  61
  62 long_str_body = long_str_part*;
  63
  64 long_sstr_char = sstr_char | cr | lf;
  65 long_sstr_part
  66         = long_sstr_char
  67         | ''' long_sstr_char
  68         | ''' ''' long_sstr_char
  69         ;
  70
  71 long_sstr_body = long_sstr_part*;
  72
  73
  74 extern_code_char
  75         = [all - ['`' + '\']]
  76         | '\' all
  77         ;
  78 extern_code_body = extern_code_char*;
  79
  80 /*****************************************************************************/
  81 States
  82 /*****************************************************************************/
  83 initial;
  84
  85
  86 /*****************************************************************************/
  87 Tokens
  88 /*****************************************************************************/
  89
  90 blank = (' ' | tab)+;
  91
  92 eol = eol_helper;
  93 comment = '#' any* eol_helper?;
  94
  95 kwpackage = 'package';
  96 kwmodule = 'module';
  97 kwimport = 'import';
  98 kwclass = 'class';
  99 kwabstract = 'abstract';
 100 kwinterface = 'interface';
 101 kwenum = 'universal'|'enum';
 102 kwend = 'end';
 103 kwmeth = 'fun';
 104 kwtype = 'type';
 105 kwinit = 'init';
 106 kwredef = 'redef';
 107 kwis = 'is';
 108 kwdo = 'do';
 109 kwreadable = 'readable';
 110 kwwritable = 'writable';
 111 kwvar = 'var';
 112 kwintern = 'intern';
 113 kwextern = 'extern';
 114 kwprotected = 'protected';
 115 kwprivate = 'private';
 116 kwintrude = 'intrude';
 117 kwif = 'if';
 118 kwthen = 'then';
 119 kwelse = 'else';
 120 kwwhile = 'while';
 121 kwloop = 'loop';
 122 kwfor = 'for';
 123 kwin = 'in';
 124 kwand = 'and';
 125 kwor = 'or';
 126 kwnot = 'not';
 127 kwimplies = 'implies';
 128 kwreturn = 'return';
 129 kwcontinue = 'continue';
 130 kwbreak = 'break';
 131 kwabort = 'abort';
 132 kwassert = 'assert';
 133 kwnew = 'new';
 134 kwisa = 'isa';
 135 kwonce = 'once';
 136 kwsuper = 'super';
 137 kwself = 'self';
 138 kwtrue = 'true';
 139 kwfalse = 'false';
 140 kwnull = 'null';
 141 kwas = 'as';
 142 kwnullable = 'nullable';
 143 kwisset = 'isset';
 144 kwlabel = 'label';
 145 kwdebug = '__debug__';
 146
 147 opar = '(';
 148 cpar = ')';
 149 obra = '[';
 150 cbra = ']';
 151 comma = ',';
 152 column = ':';
 153 quad = '::';
 154 assign = '=';
 155 pluseq = '+=';
 156 minuseq = '-=';
 157 dotdotdot = '...';
 158 dotdot = '..';
 159 dot = '.';
 160 plus = '+';
 161 minus = '-';
 162 star = '*';
 163 slash = '/';
 164 percent = '%';
 165 eq = '==';
 166 ne = '!=';
 167 lt = '<';
 168 le = '<=';
 169 ll = '<<';
 170 gt = '>';
 171 ge = '>=';
 172 gg = '>>';
 173 starship = '<=>';
 174 bang='!';
 175 at='@';
 176
 177 classid = uppercase letter*;
 178 id = lowercase letter*;
 179 attrid = '_' lowercase letter*;
 180
 181 number = digit+;
 182 float = digit* '.' digit+;
 183 string = '"' str_body '"' | '"' '"' '"' long_str_body '"' '"' '"' | ''' ''' ''' long_sstr_body ''' ''' ''';
 184 start_string = '"' str_body '{' | '"' '"' '"' long_str_body '{' '{' '{';
 185 mid_string = '}' str_body '{' | '}' '}' '}' long_str_body '{' '{' '{';
 186 end_string = '}' str_body '"' | '}' '}' '}' long_str_body '"' '"' '"';
 187 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 188 bad_string = ('"'|'}') str_body | '"' '"' '"' long_str_body | ''' ''' ''' long_sstr_body;
 189 bad_char = ''' '\'? any;
 190
 191 extern_code_segment = '`' '{' extern_code_body '`' '}';
 192
 193 /*****************************************************************************/
 194 Ignored Tokens
 195 /*****************************************************************************/
 196
 197 blank;
 198
 199 /*****************************************************************************/
 200 Productions
 201 /*****************************************************************************/
 202
 203 /* MODULES *******************************************************************/
 204 module
 205         = moduledecl? [imports]:import* [extern_bodies]:extern_code_body* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(moduledecl, [imports.import], [extern_bodies.extern_code_block], [classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 206
 207 moduledecl
 208         = [doc]:no kwmodule no module_name annotation_withend? [n2]:n1 {-> New moduledecl(doc.doc, kwmodule, module_name, annotation_withend.annotations)};
 209
 210 import
 211         = {std} [doc]:no visibility kwimport no module_name annotation_withend? [n2]:n1 {-> New import.std(visibility, kwimport, module_name, annotation_withend.annotations)}
 212         | {no} [doc]:no visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 213         ;
 214
 215 implicit_top_class {-> classdef}
 216         = propdefs_toplevel+ {-> New classdef.top([propdefs_toplevel.propdef])};
 217
 218 implicit_main_class {-> classdef?}
 219         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 220         | {null} n {-> Null}
 221         ;
 222 implicit_main_meth {-> propdef}
 223         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 224         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 225         ;
 226
 227 /* CLASSES *******************************************************************/
 228 classdef
 229         = [doc]:no redef visibility classkind no qualified? classid formaldefs? line_annotations_forclass? extern_code_block? [superclasses]:superclass* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], line_annotations_forclass.annotations, extern_code_block, [superclasses.superclass], [propdefs.propdef], kwend)};
 230 redef {-> kwredef?}
 231         = kwredef? {-> kwredef};
 232 classkind
 233         = {concrete} kwclass
 234         | {abstract} kwabstract kwclass
 235         | {interface} kwinterface
 236         | {enum} kwenum
 237         | {extern} kwextern kwclass?
 238         ;
 239
 240 formaldefs {-> formaldef*}
 241         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 242 formaldefs_tail {-> formaldef}
 243         = comma no formaldef {-> formaldef};
 244 formaldef
 245         = classid annotations? typing? {-> New formaldef(classid, typing.type, annotations)};
 246
 247 superclass {-> superclass}
 248         = {super} no kwsuper [n2]:no type annotation_withend? {-> New superclass(kwsuper, type, annotation_withend.annotations)}
 249         ;
 250
 251 propdefs~toplevel {-> propdef}
 252         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 253         ;
 254 propdef~toplevel {-> propdef}
 255         = {meth} [doc]:no redef visibility kwmeth methid signature annotation_noend? kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, annotation_noend.annotations, stmtso.expr)}
 256         | {assign_return} [doc]:no redef visibility kwmeth methid signature_withret assign no assign_return {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature_withret.signature, Null, assign_return.expr)}
 257         | {nobody} [doc]:no redef visibility kwmeth methid signature annotation_withend {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, annotation_withend.annotations)}
 258 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, Null)}
 259 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 260         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? extern_calls? extern_code_block? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string, extern_calls, extern_code_block)}
 261         | {extern_implicit} [doc]:no redef visibility kwmeth methid signature extern_calls? extern_code_block {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, Null, extern_calls, extern_code_block)}
 262 !toplevel| {var} [doc]:no readable? writable? redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, Null, Null)}
 263 !toplevel| {var2} [doc]:no readable? writable? redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, Null, expr)}
 264 !toplevel| {var3} [doc]:no redef visibility kwvar id typing? writable2? annotation_withend? {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, annotation_withend.annotations, Null)}
 265 !toplevel| {var4} [doc]:no redef visibility kwvar id typing? writable2? assign [n2]:no expr annotation_withend? {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, annotation_withend.annotations, expr.expr)}
 266 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature annotation_noend? kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, annotation_noend.annotations, stmtso.expr)}
 267 !toplevel| {type} [doc]:no redef visibility kwtype classid typing annotation_withend? {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type, annotation_withend.annotations)}
 268 !toplevel| {extern_init} [doc]:no redef visibility kwnew methid? signature kwis kwextern string? extern_calls? extern_code_block? {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string, extern_calls, extern_code_block)}
 269 !toplevel| {extern_init_implicit} [doc]:no redef visibility kwnew methid? signature string? extern_calls? extern_code_block {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string, extern_calls, extern_code_block)}
 270         ;
 271 annotation_withend {-> annotations}
 272         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 273         | {more} kwis n1 line_annotations kwend {-> line_annotations.annotations}
 274         ;
 275 annotation_noend {-> annotations}
 276         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 277         | {more} kwis n1 line_annotations {-> line_annotations.annotations}
 278         ;
 279 readable {-> able}
 280         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 281         ;
 282 writable {-> able}
 283         = redef kwwritable {-> New able.write(redef.kwredef, Null, kwwritable)}
 284         ;
 285 writable2 {-> able}
 286         = redef visibility kwwritable {-> New able.write(redef.kwredef, visibility, kwwritable)}
 287         ;
 288
 289 visibility
 290         = {public} {-> New visibility.public()}
 291         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 292         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 293         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 294         ;
 295
 296 methid {-> methid}
 297         = {id} id {-> New methid.id(id)}
 298         | {plus} plus {-> New methid.plus(plus)}
 299         | {minus} minus {-> New methid.minus(minus)}
 300         | {star} star {-> New methid.star(star)}
 301         | {slash} slash {-> New methid.slash(slash)}
 302         | {percent} percent {-> New methid.percent(percent)}
 303         | {eq} eq {-> New methid.eq(eq)}
 304         | {ne} ne {-> New methid.ne(ne)}
 305         | {le} le {-> New methid.le(le)}
 306         | {ge} ge {-> New methid.ge(ge)}
 307         | {lt} lt {-> New methid.lt(lt)}
 308         | {gt} gt {-> New methid.gt(gt)}
 309         | {ll} ll {-> New methid.ll(ll)}
 310         | {gg} gg {-> New methid.gg(gg)}
 311         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 312         | {starship} starship {-> New methid.starship(starship)}
 313         | {assign} id assign {-> New methid.assign(id, assign)}
 314         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 315         ;
 316
 317 signature~withret {-> signature}
 318         = opar no params? cpar typing [no2]:no {-> New signature(opar, [params.param], cpar, typing.type)}
 319 !withret| {noret} opar no params? cpar [no2]:no {-> New signature(opar, [params.param], cpar, Null)}
 320         | {nopar} typing no {-> New signature(Null, [], Null, typing.type)}
 321 !withret| {noparnoret} no {-> New signature(Null, [], Null, Null)}
 322         ;
 323
 324 params {-> param*}
 325         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 326         ;
 327 params_tail {-> param}
 328         = comma no param {-> param};
 329 param
 330         = {untyped} id annotations? {-> New param(id, Null, Null, annotations)}
 331         | id annotations? typing dotdotdot? {-> New param(id, typing.type, dotdotdot, annotations)}
 332         ;
 333
 334 assign_return{-> expr}
 335         = expr_final {-> New expr.return(Null, expr_final.expr)}
 336         ;
 337
 338 extern_calls {-> extern_calls}
 339         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 340         ;
 341 extern_call_tail {-> extern_call}
 342         = comma no extern_call {-> extern_call};
 343 extern_call {-> extern_call}
 344     = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 345     | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 346         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 347     ;
 348 extern_call_prop {-> extern_call}
 349     = {local} methid {-> New extern_call.local_prop( methid )}
 350         | {full} classid quad methid {-> New extern_call.full_prop( classid, quad, methid )}
 351         | {init} classid {-> New extern_call.init_prop( classid )}
 352         ;
 353 extern_call_cast {-> extern_call}
 354     = {as_cast} [from_type]:type kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, kwas, to_type)}
 355         | {as_nullable} type kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 356         | {as_not_nullable} type kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 357         ;
 358
 359 in_language = kwin string;
 360 extern_code_block = in_language? extern_code_segment;
 361 extern_code_body {-> extern_code_block} = no extern_code_block {-> extern_code_block};
 362
 363 /* TYPES *********************************************************************/
 364 type~nobra~nopar {-> type}
 365         = {simple} kwnullable? classid annotations~nopar? {-> New type(kwnullable, classid, [], annotations~nopar.annotations)}
 366 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra annotations~nopar? {-> New type(kwnullable, classid, [types.type], annotations~nopar.annotations)}
 367         ;
 368 types {-> type*}
 369         = type types_tail* {-> [type, types_tail.type]};
 370 types_tail {-> type}
 371         = comma no type {-> type};
 372 typing {-> type}
 373         = column no type {-> type};
 374
 375 /* STATMENTS *****************************************************************/
 376 stmtso~withelse~withend {-> expr?}
 377         = {block} n stmtsnend {-> stmtsnend.expr}
 378         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 379         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 380 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 381         ;
 382 stmts {-> expr}
 383         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 384 stmtsn {-> expr}
 385         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 386 stmtsnend {-> expr}
 387         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 388 stmts_tail {-> expr}
 389         = n stmt {-> stmt.expr};
 390 stmt~withelse~noexpr~nopar {-> expr}
 391         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 392         | {assign} assignment~withelse~nopar {-> assignment~withelse~nopar.expr}
 393         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 394         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 395         | {abort} kwabort {-> New expr.abort(kwabort)}
 396         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 397         | {do} do~withelse {-> do~withelse.expr}
 398 !noexpr | {if} if~withelse {-> if~withelse.expr}
 399         | {while} while~withelse {-> while~withelse.expr}
 400         | {loop} loop~withelse {-> loop~withelse.expr}
 401         | {for} for~withelse {-> for~withelse.expr}
 402         | {assert} assert~withelse {-> assert~withelse.expr}
 403 !noexpr | {call} recv qualified? id args_nopar {-> New expr.call(recv.expr, id, args_nopar.exprs)}
 404 !noexpr | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, args_nopar.exprs)}
 405 !noexpr | {init} recv qualified? kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 406         | {debug_type_is} kwdebug kwtype type column expr_final~withelse {-> New expr.debug_type(kwdebug, kwtype, expr_final~withelse.expr, type) }
 407         ;
 408
 409 label= kwlabel id;
 410
 411 assign_continue~withelse{-> expr}
 412         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 413         ;
 414
 415 vardecl~withelse{-> expr}
 416         = kwvar id annotations? typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null, annotations)}
 417         | {assign} kwvar id annotations? typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr, annotations)}
 418         ;
 419
 420 assignment~withelse~nopar {-> expr}
 421         = {attr} recv~nopar qualified? attrid assign expr_final~withelse {-> New expr.attr_assign(recv~nopar.expr, attrid, assign, expr_final~withelse.expr)}
 422         | {call} recv~nopar qualified? id args assign expr_final~withelse {-> New expr.call_assign(recv~nopar.expr, id, args.exprs, assign,  expr_final~withelse.expr)}
 423         | {bra} expr_atom~nopar braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom~nopar.expr, braargs.exprs, assign,  expr_final~withelse.expr)}
 424         | {attr_re} recv~nopar qualified? attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv~nopar.expr, attrid, assign_op,  expr_final~withelse.expr)}
 425         | {call_re} recv~nopar qualified? id args assign_op expr_final~withelse {-> New expr.call_reassign(recv~nopar.expr, id, args.exprs, assign_op,  expr_final~withelse.expr)}
 426         | {bra_re} expr_atom~nopar braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom~nopar.expr, braargs.exprs, assign_op,  expr_final~withelse.expr)}
 427         ;
 428 assign_op
 429         = {plus} pluseq
 430         | {minus} minuseq
 431         ;
 432
 433 do~withelse {-> expr}
 434         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 435         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 436         ;
 437
 438 if~withelse {-> expr}
 439         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 440 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 441 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 442 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 443         ;
 444 elsepartblock {-> expr?}
 445         = {else} kwelse stmtso {-> stmtso.expr}
 446         | {empty} kwend {-> New expr.block([], kwend)}
 447         ;
 448
 449 loop~withelse {-> expr}
 450         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 451         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 452         ;
 453
 454 while~withelse {-> expr}
 455         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 456         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 457         ;
 458
 459 for~withelse {-> expr}
 460         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 461         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 462         ;
 463
 464 assert~withelse {-> expr}
 465         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 466 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 467         ;
 468 assertid {-> id}
 469         = id column {-> id};
 470
 471 /* EXPRESSIONS ***************************************************************/
 472 expr_final~nopar~withelse~nobra {-> expr}
 473         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 474         ;
 475
 476 expr~nopar~nobra {-> expr}
 477         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 478         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 479         ;
 480
 481 expr_and~nopar~nobra {-> expr}
 482         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 483         | {:or} expr_and~nopar~nobra :kwor :no expr_not~nopar~nobra
 484         | {:and} expr_and~nopar~nobra :kwand :no expr_not~nopar~nobra
 485         | {:or_else} expr_and~nopar~nobra :kwor :kwelse :no expr_not~nopar~nobra
 486         | {:implies} expr_and~nopar~nobra :kwimplies :no expr_not~nopar~nobra
 487         ;
 488
 489 expr_not~nopar~nobra {-> expr}
 490         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 491         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 492         ;
 493
 494 expr_eq~nopar~nobra {-> expr}
 495         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 496         | {:eq} expr_add~nopar~nobra :eq :no [expr2]:expr_add~nopar~nobra
 497         | {:ne} expr_add~nopar~nobra :ne :no [expr2]:expr_add~nopar~nobra
 498         | {:lt} expr_add~nopar~nobra :lt :no [expr2]:expr_add~nopar~nobra
 499         | {:le} expr_add~nopar~nobra :le :no [expr2]:expr_add~nopar~nobra
 500         | {:ll} expr_eq~nopar~nobra :ll :no [expr2]:expr_add~nopar~nobra
 501         | {:gt} expr_add~nopar~nobra :gt :no [expr2]:expr_add~nopar~nobra
 502         | {:ge} expr_add~nopar~nobra :ge :no [expr2]:expr_add~nopar~nobra
 503         | {:gg} expr_eq~nopar~nobra :gg :no [expr2]:expr_add~nopar~nobra
 504         | {:starship} expr_add~nopar~nobra :starship :no [expr2]:expr_add~nopar~nobra
 505         | {:isa} expr_add~nopar~nobra :kwisa :no type~nobra
 506         ;
 507
 508 expr_add~nopar~nobra {-> expr}
 509         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 510         | {:plus} expr_add~nopar~nobra :plus :no [expr2]:expr_mul~nopar~nobra
 511         | {:minus} expr_add~nopar~nobra :minus :no [expr2]:expr_mul~nopar~nobra
 512         ;
 513
 514 expr_mul~nopar~nobra {-> expr}
 515         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 516         | {:star} expr_mul~nopar~nobra :star :no [expr2]:expr_minus~nopar~nobra
 517         | {:slash} expr_mul~nopar~nobra :slash :no [expr2]:expr_minus~nopar~nobra
 518         | {:percent} expr_mul~nopar~nobra :percent :no [expr2]:expr_minus~nopar~nobra
 519         ;
 520
 521 expr_minus~nopar~nobra {-> expr}
 522         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 523         | {:uminus} minus :no expr_minus~nopar~nobra
 524         | {:once} kwonce :no expr_minus~nopar~nobra
 525         ;
 526
 527 expr_new~nopar~nobra {-> expr}
 528         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 529         | {new} kwnew no type~nobra_nopar args {-> New expr.new(kwnew, type~nobra_nopar.type, Null, args.exprs)}
 530         | {isset_attr} kwisset recv~nopar~nobra qualified? attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 531         ;
 532
 533 expr_atom~nopar~nobra {-> expr}
 534         = {attr} recv~nopar~nobra qualified? attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 535         | {call} recv~nopar~nobra qualified? id args {-> New expr.call(recv~nopar~nobra.expr, id, args.exprs)}
 536         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, args.exprs)}
 537         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 538 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs)}
 539         | {new} kwnew no type~nobra_nopar dot [n2]:no qualified? id args {-> New expr.new(kwnew, type~nobra_nopar.type, id, args.exprs)}
 540 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 541 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra annotations? {-> New expr.crange(obra, expr, expr2.expr, cbra, annotations)}
 542 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra annotations? {-> New expr.orange(obra, expr, expr2.expr, cbra, annotations)}
 543 !nobra!nopar    | {array} braargs annotations? {-> New expr.array(braargs.exprs, annotations)}
 544         | {self} kwself annotations? {-> New expr.self(kwself, annotations)}
 545         | {true} kwtrue annotations? {-> New expr.true(kwtrue, annotations)}
 546         | {false} kwfalse annotations? {-> New expr.false(kwfalse, annotations)}
 547         | {null} kwnull annotations? {-> New expr.null(kwnull, annotations)}
 548         | {int} number annotations? {-> New expr.int(number, annotations)}
 549         | {float} float annotations? {-> New expr.float(float, annotations)}
 550         | {char} char annotations? {-> New expr.char(char, annotations)}
 551         | {string} string annotations? {-> New expr.string(string, annotations)}
 552         | {superstring} superstring  {-> superstring.expr}
 553 !nopar  | {par} opar no expr [n2]:no cpar annotations? {-> New expr.par(opar, expr, cpar, annotations)}
 554         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 555         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 556         ;
 557
 558 superstring {-> expr}
 559         = superstring_start superstring_middle* superstring_end annotations? {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr], annotations)};
 560 superstring_start {-> expr*}
 561         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 562 start_string_p {-> expr}
 563         = start_string {-> New expr.start_string(start_string)};
 564 superstring_middle {-> expr*}
 565         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 566 mid_string_p {-> expr}
 567         = mid_string {-> New expr.mid_string(mid_string)};
 568 superstring_end {-> expr}
 569         = end_string {-> New expr.end_string(end_string)};
 570
 571 /* ANNOTATIONS *******************************************************************/
 572
 573 annotations~nopar {-> annotations}
 574         = {one} at one_annotation~nopar {-> New annotations(at, Null, [one_annotation~nopar.annotation], Null)}
 575         | {many} at opar no annotation_list [n2]:no cpar {-> New annotations(at, opar, [annotation_list.annotation], cpar)}
 576         ;
 577
 578 one_annotation~nopar {-> annotation}
 579         = {alone} atid annotations~nopar? {-> New annotation(atid, Null, [], Null, annotations~nopar.annotations)}
 580 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 581 !nopar  | {args} atid opar no at_args [n2]:no cpar annotations~nopar? {-> New annotation(atid, opar, [at_args.at_arg], cpar, annotations~nopar.annotations)}
 582         ;
 583
 584 many_annotations {-> annotations}
 585         = {many} annotation_list {-> New annotations(Null, Null, [annotation_list.annotation], Null)}
 586         ;
 587
 588 annotation_list {-> annotation*}
 589         = {many} one_annotation annotations_tail* {-> [one_annotation.annotation, annotations_tail.annotation] }
 590         ;
 591
 592 line_annotations~forclass {-> annotations}
 593         = line_annotation~forclass+ {-> New annotations(Null, Null, [line_annotation~forclass.annotation], Null) }
 594         ;
 595 line_annotation~forclass {-> annotation}
 596         = [doc]:no atid~forclass annotations? n1 {-> New annotation(atid~forclass.atid, Null, [], Null, annotations)}
 597         | {args} [doc]:no atid~forclass opar no at_args cpar annotations? n1 {-> New annotation(atid~forclass.atid, opar, [at_args.at_arg], cpar, annotations)}
 598         | {nopar} [doc]:no atid~forclass at_args_nopar n1 {-> New annotation(atid~forclass.atid, Null, [at_args_nopar.at_arg], Null, Null)}
 599         ;
 600
 601 annotations_tail {-> annotation}
 602         = comma no one_annotation {-> one_annotation.annotation}
 603         ;
 604
 605 at_args~nopar {-> at_arg* }
 606         = {many} at_arg~nopar at_args_tail* {-> [at_arg~nopar.at_arg, at_args_tail.at_arg]}
 607         ;
 608
 609 at_args_tail {-> at_arg}
 610         = comma no at_arg {-> at_arg}
 611         ;
 612
 613 at_arg~nopar {-> at_arg}
 614         = {type} type {-> New at_arg.type(type)}
 615         | {expr} expr~nopar {-> New at_arg.expr(expr~nopar.expr)}
 616         | {stmt} stmt_noexpr~nopar {-> New at_arg.expr(stmt_noexpr~nopar.expr)}
 617 !nopar  | {at} annotations {-> New at_arg.at(annotations.annotations)}
 618         ;
 619
 620 atid~forclass {-> atid}
 621         = {id}  id {-> New atid.id(id)}
 622 //!forclass     | {kwextern} qualified? kwextern {-> New atid.kwextern(kwextern)}
 623 //!forclass     | {kwintern} qualified? kwintern {-> New atid.kwintern(kwintern)}
 624 !forclass       | {kwreadable} kwreadable {-> New atid.kwreadable(kwreadable)}
 625 !forclass       | {kwwritable} kwwritable {-> New atid.kwwritable(kwwritable)}
 626         | {kwimport} kwimport {-> New atid.kwimport(kwimport)}
 627         ;
 628
 629 /* MISC **********************************************************************/
 630
 631 recv~nopar~nobra {-> expr}
 632         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 633         | {implicit} {-> New expr.implicit_self()}
 634         ;
 635
 636 args {-> exprs}
 637         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 638         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 639         | {empty} {-> New exprs.list([])}
 640         ;
 641 args_nopar {-> exprs}
 642         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 643         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 644         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 645         | {empty} {-> New exprs.list([])}
 646         ;
 647 braargs {-> exprs}
 648         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 649 expr_list {-> expr*}
 650         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 651 expr_tail {-> expr}
 652         = comma no expr [n2]:no {-> expr};
 653 idlist {-> id*}
 654         = opar no idlist_nopar [n2]:no cpar {-> [idlist_nopar.id]}
 655         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 656         ;
 657 idlist_nopar {-> id*}
 658         = {single} id {-> [id]}
 659         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 660         ;
 661
 662 module_name {-> module_name}
 663         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 664         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 665         ;
 666
 667 qualified
 668         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 669         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 670         ;
 671 modquad {-> id}
 672         = id quad no {-> id};
 673 classquad {-> classid}
 674         = classid quad no {-> classid};
 675
 676 n1      = {a} comment | {b} eol;
 677 n {-> doc?}
 678         = {a} n2? comment+ {-> New doc([comment])}
 679         | {b} n2 {-> Null}
 680         ;
 681 no {-> doc?}
 682         = {empty} {-> Null}
 683         | n {-> n.doc}
 684         ;
 685
 686 n2
 687         = {a} n2? comment+ eol+
 688         | {b} eol+
 689         ;
 690
 691 /*****************************************************************************/
 692 Abstract Syntax Tree
 693 /*****************************************************************************/
 694
 695 module  = moduledecl? [imports]:import* [extern_code_blocks]:extern_code_block* [classdefs]:classdef*;
 696
 697 moduledecl
 698         = doc? kwmodule [name]:module_name annotations?;
 699
 700 import  = {std} visibility kwimport [name]:module_name annotations?
 701         | {no} visibility kwimport kwend
 702         ;
 703
 704 visibility
 705         = {public}
 706         | {private} kwprivate
 707         | {protected} kwprotected
 708         | {intrude} kwintrude
 709         ;
 710
 711 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* annotations? extern_code_block? [superclasses]:superclass* [propdefs]:propdef* kwend
 712         | {top} [propdefs]:propdef*
 713         | {main} [propdefs]:propdef*
 714         ;
 715 classkind
 716         = {concrete} kwclass
 717         | {abstract} kwabstract kwclass
 718         | {interface} kwinterface
 719         | {enum} kwenum
 720         | {extern} kwextern kwclass?
 721         ;
 722 formaldef = [id]:classid type? annotations?;
 723 superclass = kwsuper type annotations?;
 724
 725
 726 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid? [id2]:id? type? annotations? expr?
 727         | {meth} doc? kwredef? visibility methid signature
 728         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature annotations?
 729         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 730         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string? extern_calls? extern_code_block?
 731         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature annotations? [block]:expr?
 732         | {concrete_init} doc? kwredef? visibility kwinit methid? signature annotations? [block]:expr?
 733         //| {concrete_new} doc? kwredef? visibility kwnew methid? signature [block]:expr?
 734         | {extern_init} doc? kwredef? visibility kwnew methid? signature [extern]:string? extern_calls? extern_code_block?
 735         | {main_meth} kwredef? [block]:expr?
 736         | {type} doc? kwredef? visibility kwtype [id]:classid type annotations?
 737         ;
 738
 739 able    = {read} kwredef? kwreadable
 740         | {write} kwredef? visibility? kwwritable
 741         ;
 742
 743 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 744
 745 signature = opar? [params]:param* cpar? type?;
 746
 747 param   = id type? dotdotdot? annotations?
 748         ;
 749
 750 type    = kwnullable? [id]:classid [types]:type* annotations?;
 751
 752 label = kwlabel id;
 753
 754 expr    = {block} expr* kwend?
 755         | {vardecl} kwvar id type? assign? expr? annotations?
 756         | {return} kwreturn? expr?
 757         | {break} kwbreak label? expr?
 758         | {abort} kwabort
 759         | {continue} kwcontinue? label? expr?
 760         | {do} kwdo [block]:expr? label?
 761         | {if} kwif expr [then]:expr? [else]:expr?
 762         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 763         | {while} kwwhile expr kwdo [block]:expr? label?
 764         | {loop} kwloop [block]:expr? label?
 765         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 766         | {assert} kwassert id? expr [else]:expr?
 767         | {once} kwonce expr
 768         | {send} expr
 769         | {binop} expr [expr2]:expr
 770         | {or} expr [expr2]:expr
 771         | {and} expr [expr2]:expr
 772         | {or_else} expr [expr2]:expr
 773         | {implies} expr [expr2]:expr
 774         | {not} kwnot expr
 775         | {eq} expr [expr2]:expr
 776         | {ne} expr [expr2]:expr
 777         | {lt} expr [expr2]:expr
 778         | {le} expr [expr2]:expr
 779         | {ll} expr [expr2]:expr
 780         | {gt} expr [expr2]:expr
 781         | {ge} expr [expr2]:expr
 782         | {gg} expr [expr2]:expr
 783         | {isa} expr type
 784         | {plus} expr [expr2]:expr
 785         | {minus} expr [expr2]:expr
 786         | {starship} expr [expr2]:expr
 787         | {star} expr [expr2]:expr
 788         | {slash} expr [expr2]:expr
 789         | {percent} expr [expr2]:expr
 790         | {uminus} minus expr
 791         | {new} kwnew type id? [args]:exprs
 792         | {attr} expr [id]:attrid
 793         | {attr_assign} expr [id]:attrid assign [value]:expr
 794         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 795         | {call} expr id [args]:exprs
 796         | {call_assign} expr id [args]:exprs assign [value]:expr
 797         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 798         | {super} qualified? kwsuper [args]:exprs
 799         | {init} expr kwinit [args]:exprs
 800         | {bra} expr [args]:exprs
 801         | {bra_assign} expr [args]:exprs assign [value]:expr
 802         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 803         | {var} id
 804         | {var_assign} id assign [value]:expr
 805         | {var_reassign} id assign_op [value]:expr
 806         | {range} expr [expr2]:expr annotations?
 807         | {crange} obra expr [expr2]:expr cbra annotations?
 808         | {orange} obra expr [expr2]:expr [cbra]:obra annotations?
 809         | {array} [exprs]:exprs annotations?
 810         | {self} kwself annotations?
 811         | {implicit_self}
 812         | {true} kwtrue annotations?
 813         | {false} kwfalse annotations?
 814         | {null} kwnull annotations?
 815         | {int} number annotations?
 816         | {float} float annotations?
 817         | {char} char annotations?
 818         | {string} string annotations?
 819         | {start_string} [string]:start_string
 820         | {mid_string} [string]:mid_string
 821         | {end_string} [string]:end_string
 822         | {superstring} [exprs]:expr* annotations?
 823         | {par} opar expr cpar annotations?
 824         | {as_cast} expr kwas opar type cpar
 825         | {as_notnull} expr kwas opar kwnot kwnull cpar
 826         | {isset_attr} kwisset expr [id]:attrid
 827         | {debug_type} kwdebug kwtype expr type
 828         ;
 829 exprs
 830         = {list} [exprs]:expr*
 831         | {par} opar [exprs]:expr* cpar
 832         | {bra} obra [exprs]:expr* cbra
 833         ;
 834 assign_op
 835         = {plus} pluseq
 836         | {minus} minuseq
 837         ;
 838
 839 module_name = quad? [path]:id* id;
 840 extern_calls = kwimport [extern_calls]:extern_call*
 841         ;
 842 extern_call =
 843         | {super} kwsuper
 844         | {local_prop} methid
 845         | {full_prop} classid quad? methid
 846         | {init_prop} classid
 847         | {cast_as} [from_type]:type kwas [to_type]:type
 848         | {as_nullable} type kwas kwnullable
 849         | {as_not_nullable} type kwas kwnot kwnullable
 850         ;
 851 in_language = kwin string;
 852 extern_code_block = in_language? extern_code_segment;
 853
 854 qualified = id* classid? ;
 855
 856 doc = comment+;
 857
 858 annotations = at? opar? [items]:annotation* cpar?;
 859
 860 annotation = atid opar? [args]:at_arg* cpar? annotations?;
 861
 862 at_arg
 863         = {type} type
 864         | {expr} expr
 865         | {at} annotations
 866         ;
 867 atid = {id} id | {kwextern} [id]:kwextern | {kwintern} [id]:kwintern | {kwreadable} [id]:kwreadable | {kwwritable} [id]:kwwritable | {kwimport} [id]:kwimport;
 868
 869 /*****************************************************************************/
 870