src/separate_erasure_compiler.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Separate compilation of a Nit program with generic type erasure
  16 module separate_erasure_compiler
  17
  18 intrude import separate_compiler
  19
  20 # Add separate erased compiler specific options
  21 redef class ToolContext
  22         # --erasure
  23         var opt_erasure: OptionBool = new OptionBool("Erase generic types", "--erasure")
  24         # --rta
  25         var opt_rta = new OptionBool("Activate RTA (implicit with --global and --separate)", "--rta")
  26         # --no-check-erasure-cast
  27         var opt_no_check_erasure_cast: OptionBool = new OptionBool("Disable implicit casts on unsafe return with erasure-typing policy (dangerous)", "--no-check-erasure-cast")
  28
  29         redef init
  30         do
  31                 super
  32                 self.option_context.add_option(self.opt_erasure, self.opt_no_check_erasure_cast, opt_rta)
  33         end
  34
  35         var erasure_compiler_phase = new ErasureCompilerPhase(self, null)
  36 end
  37
  38 class ErasureCompilerPhase
  39         super Phase
  40         redef fun process_mainmodule(mainmodule, given_mmodules) do
  41                 if not toolcontext.opt_erasure.value then return
  42
  43                 var modelbuilder = toolcontext.modelbuilder
  44                 var analysis = null
  45                 if toolcontext.opt_rta.value then
  46                         analysis = modelbuilder.do_rapid_type_analysis(mainmodule)
  47                 end
  48                 modelbuilder.run_separate_erasure_compiler(mainmodule, analysis)
  49         end
  50 end
  51
  52 redef class ModelBuilder
  53         fun run_separate_erasure_compiler(mainmodule: MModule, runtime_type_analysis: nullable RapidTypeAnalysis)
  54         do
  55                 var time0 = get_time
  56                 self.toolcontext.info("*** GENERATING C ***", 1)
  57
  58                 var compiler = new SeparateErasureCompiler(mainmodule, self, runtime_type_analysis)
  59                 compiler.compile_header
  60
  61                 # compile class structures
  62                 self.toolcontext.info("Property coloring", 2)
  63                 compiler.new_file("{mainmodule.name}.tables")
  64                 compiler.do_property_coloring
  65                 for m in mainmodule.in_importation.greaters do
  66                         for mclass in m.intro_mclasses do
  67                                 compiler.compile_class_to_c(mclass)
  68                         end
  69                 end
  70                 compiler.compile_color_consts(compiler.vt_colors)
  71
  72                 # The main function of the C
  73                 compiler.new_file("{mainmodule.name}.main")
  74                 compiler.compile_nitni_global_ref_functions
  75                 compiler.compile_main_function
  76
  77                 # compile methods
  78                 for m in mainmodule.in_importation.greaters do
  79                         self.toolcontext.info("Generate C for module {m}", 2)
  80                         compiler.new_file("{m.name}.sep")
  81                         compiler.compile_module_to_c(m)
  82                 end
  83
  84                 compiler.display_stats
  85
  86                 var time1 = get_time
  87                 self.toolcontext.info("*** END GENERATING C: {time1-time0} ***", 2)
  88                 write_and_make(compiler)
  89         end
  90 end
  91
  92 class SeparateErasureCompiler
  93         super SeparateCompiler
  94
  95         private var class_ids: Map[MClass, Int]
  96         private var class_colors: Map[MClass, Int]
  97         protected var vt_colors: Map[MVirtualTypeProp, Int]
  98
  99         init(mainmodule: MModule, mmbuilder: ModelBuilder, runtime_type_analysis: nullable RapidTypeAnalysis) do
 100                 super
 101
 102                 # Class coloring
 103                 var poset = mainmodule.flatten_mclass_hierarchy
 104                 var mclasses = new HashSet[MClass].from(poset)
 105                 var colorer = new POSetColorer[MClass]
 106                 colorer.colorize(poset)
 107                 class_ids = colorer.ids
 108                 class_colors = colorer.colors
 109                 class_tables = self.build_class_typing_tables(mclasses)
 110
 111                 # lookup vt to build layout with
 112                 var vts = new HashMap[MClass, Set[MVirtualTypeProp]]
 113                 for mclass in mclasses do
 114                         vts[mclass] = new HashSet[MVirtualTypeProp]
 115                         for mprop in self.mainmodule.properties(mclass) do
 116                                 if mprop isa MVirtualTypeProp then
 117                                         vts[mclass].add(mprop)
 118                                 end
 119                         end
 120                 end
 121
 122                 # vt coloration
 123                 var vt_colorer = new POSetBucketsColorer[MClass, MVirtualTypeProp](poset, colorer.conflicts)
 124                 vt_colors = vt_colorer.colorize(vts)
 125                 vt_tables = build_vt_tables(mclasses)
 126         end
 127
 128         fun build_vt_tables(mclasses: Set[MClass]): Map[MClass, Array[nullable MPropDef]] do
 129                 var tables = new HashMap[MClass, Array[nullable MPropDef]]
 130                 for mclass in mclasses do
 131                         var table = new Array[nullable MPropDef]
 132                         # first, fill table from parents by reverse linearization order
 133                         var parents = new Array[MClass]
 134                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 135                                 parents = mclass.in_hierarchy(mainmodule).greaters.to_a
 136                                 self.mainmodule.linearize_mclasses(parents)
 137                         end
 138                         for parent in parents do
 139                                 if parent == mclass then continue
 140                                 for mproperty in self.mainmodule.properties(parent) do
 141                                         if not mproperty isa MVirtualTypeProp then continue
 142                                         var color = vt_colors[mproperty]
 143                                         if table.length <= color then
 144                                                 for i in [table.length .. color[ do
 145                                                         table[i] = null
 146                                                 end
 147                                         end
 148                                         for mpropdef in mproperty.mpropdefs do
 149                                                 if mpropdef.mclassdef.mclass == parent then
 150                                                         table[color] = mpropdef
 151                                                 end
 152                                         end
 153                                 end
 154                         end
 155
 156                         # then override with local properties
 157                         for mproperty in self.mainmodule.properties(mclass) do
 158                                 if not mproperty isa MVirtualTypeProp then continue
 159                                 var color = vt_colors[mproperty]
 160                                 if table.length <= color then
 161                                         for i in [table.length .. color[ do
 162                                                 table[i] = null
 163                                         end
 164                                 end
 165                                 for mpropdef in mproperty.mpropdefs do
 166                                         if mpropdef.mclassdef.mclass == mclass then
 167                                                 table[color] = mpropdef
 168                                         end
 169                                 end
 170                         end
 171                         tables[mclass] = table
 172                 end
 173                 return tables
 174         end
 175
 176         # Build class tables
 177         fun build_class_typing_tables(mclasses: Set[MClass]): Map[MClass, Array[nullable MClass]] do
 178                 var tables = new HashMap[MClass, Array[nullable MClass]]
 179                 for mclass in mclasses do
 180                         var table = new Array[nullable MClass]
 181                         var supers = new Array[MClass]
 182                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 183                                 supers = mclass.in_hierarchy(mainmodule).greaters.to_a
 184                         end
 185                         for sup in supers do
 186                                 var color = class_colors[sup]
 187                                 if table.length <= color then
 188                                         for i in [table.length .. color[ do
 189                                                 table[i] = null
 190                                         end
 191                                 end
 192                                 table[color] = sup
 193                         end
 194                         tables[mclass] = table
 195                 end
 196                 return tables
 197         end
 198
 199         redef fun compile_header_structs do
 200                 self.header.add_decl("typedef void(*nitmethod_t)(void); /* general C type representing a Nit method. */")
 201                 self.compile_header_attribute_structs
 202                 self.header.add_decl("struct class \{ int id; const char *name; int box_kind; int color; const struct vts_table *vts_table; const struct type_table *type_table; nitmethod_t vft[]; \}; /* general C type representing a Nit class. */")
 203                 self.header.add_decl("struct type_table \{ int size; int table[]; \}; /* colorized type table. */")
 204                 self.header.add_decl("struct vts_entry \{ short int is_nullable; const struct class *class; \}; /* link (nullable or not) between the vts and is bound. */")
 205                 self.header.add_decl("struct vts_table \{ int dummy; const struct vts_entry vts[]; \}; /* vts list of a C type representation. */")
 206                 self.header.add_decl("typedef struct instance \{ const struct class *class; nitattribute_t attrs[1]; \} val; /* general C type representing a Nit instance. */")
 207         end
 208
 209         redef fun compile_class_to_c(mclass: MClass)
 210         do
 211                 var mtype = mclass.intro.bound_mtype
 212                 var c_name = mclass.c_name
 213                 var c_instance_name = mclass.c_instance_name
 214
 215                 var vft = self.method_tables[mclass]
 216                 var attrs = self.attr_tables[mclass]
 217                 var class_table = self.class_tables[mclass]
 218                 var v = self.new_visitor
 219
 220                 var rta = runtime_type_analysis
 221                 var is_dead = mclass.kind == abstract_kind or mclass.kind == interface_kind
 222                 if not is_dead and rta != null and not rta.live_classes.has(mclass) and mtype.ctype == "val*" and mclass.name != "NativeArray" then
 223                         is_dead = true
 224                 end
 225
 226                 v.add_decl("/* runtime class {c_name} */")
 227
 228                 self.provide_declaration("class_{c_name}", "extern const struct class class_{c_name};")
 229                 v.add_decl("extern const struct type_table type_table_{c_name};")
 230
 231                 # Build class vft
 232                 v.add_decl("const struct class class_{c_name} = \{")
 233                 v.add_decl("{class_ids[mclass]},")
 234                 v.add_decl("\"{mclass.name}\", /* class_name_string */")
 235                 v.add_decl("{self.box_kind_of(mclass)}, /* box_kind */")
 236                 v.add_decl("{class_colors[mclass]},")
 237                 if not is_dead then
 238                         if build_class_vts_table(mclass) then
 239                                 v.require_declaration("vts_table_{c_name}")
 240                                 v.add_decl("&vts_table_{c_name},")
 241                         else
 242                                 v.add_decl("NULL,")
 243                         end
 244                         v.add_decl("&type_table_{c_name},")
 245                         v.add_decl("\{")
 246                         for i in [0 .. vft.length[ do
 247                                 var mpropdef = vft[i]
 248                                 if mpropdef == null then
 249                                         v.add_decl("NULL, /* empty */")
 250                                 else
 251                                         assert mpropdef isa MMethodDef
 252                                         if rta != null and not rta.live_methoddefs.has(mpropdef) then
 253                                                 v.add_decl("NULL, /* DEAD {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 254                                                 continue
 255                                         end
 256                                         if true or mpropdef.mclassdef.bound_mtype.ctype != "val*" then
 257                                                 v.require_declaration("VIRTUAL_{mpropdef.c_name}")
 258                                                 v.add_decl("(nitmethod_t)VIRTUAL_{mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 259                                         else
 260                                                 v.require_declaration("{mpropdef.c_name}")
 261                                                 v.add_decl("(nitmethod_t){mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 262                                         end
 263                                 end
 264                         end
 265                         v.add_decl("\}")
 266                 end
 267                 v.add_decl("\};")
 268
 269                 # Build class type table
 270
 271                 v.add_decl("const struct type_table type_table_{c_name} = \{")
 272                 v.add_decl("{class_table.length},")
 273                 v.add_decl("\{")
 274                 for msuper in class_table do
 275                         if msuper == null then
 276                                 v.add_decl("-1, /* empty */")
 277                         else
 278                                 v.add_decl("{self.class_ids[msuper]}, /* {msuper} */")
 279                         end
 280                 end
 281                 v.add_decl("\}")
 282                 v.add_decl("\};")
 283
 284                 if mtype.ctype != "val*" then
 285                         if mtype.mclass.name == "Pointer" or mtype.mclass.kind != extern_kind then
 286                                 #Build instance struct
 287                                 self.header.add_decl("struct instance_{c_instance_name} \{")
 288                                 self.header.add_decl("const struct class *class;")
 289                                 self.header.add_decl("{mtype.ctype} value;")
 290                                 self.header.add_decl("\};")
 291                         end
 292
 293                         #Build BOX
 294                         self.provide_declaration("BOX_{c_name}", "val* BOX_{c_name}({mtype.ctype});")
 295                         v.add_decl("/* allocate {mtype} */")
 296                         v.add_decl("val* BOX_{mtype.c_name}({mtype.ctype} value) \{")
 297                         v.add("struct instance_{c_instance_name}*res = nit_alloc(sizeof(struct instance_{c_instance_name}));")
 298                         v.require_declaration("class_{c_name}")
 299                         v.add("res->class = &class_{c_name};")
 300                         v.add("res->value = value;")
 301                         v.add("return (val*)res;")
 302                         v.add("\}")
 303                         return
 304                 else if mclass.name == "NativeArray" then
 305                         #Build instance struct
 306                         self.header.add_decl("struct instance_{c_name} \{")
 307                         self.header.add_decl("const struct class *class;")
 308                         self.header.add_decl("int length;")
 309                         self.header.add_decl("val* values[];")
 310                         self.header.add_decl("\};")
 311
 312                         #Build NEW
 313                         self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(int length);")
 314                         v.add_decl("/* allocate {mtype} */")
 315                         v.add_decl("{mtype.ctype} NEW_{c_name}(int length) \{")
 316                         var res = v.get_name("self")
 317                         v.add_decl("struct instance_{c_name} *{res};")
 318                         var mtype_elt = mtype.arguments.first
 319                         v.add("{res} = nit_alloc(sizeof(struct instance_{c_name}) + length*sizeof({mtype_elt.ctype}));")
 320                         v.require_declaration("class_{c_name}")
 321                         v.add("{res}->class = &class_{c_name};")
 322                         v.add("{res}->length = length;")
 323                         v.add("return (val*){res};")
 324                         v.add("\}")
 325                         return
 326                 end
 327
 328                 #Build NEW
 329                 self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(void);")
 330                 v.add_decl("/* allocate {mtype} */")
 331                 v.add_decl("{mtype.ctype} NEW_{c_name}(void) \{")
 332                 if is_dead then
 333                         v.add_abort("{mclass} is DEAD")
 334                 else
 335
 336                         var res = v.new_named_var(mtype, "self")
 337                         res.is_exact = true
 338                         v.add("{res} = nit_alloc(sizeof(struct instance) + {attrs.length}*sizeof(nitattribute_t));")
 339                         v.require_declaration("class_{c_name}")
 340                         v.add("{res}->class = &class_{c_name};")
 341                         self.generate_init_attr(v, res, mtype)
 342                         v.set_finalizer res
 343                         v.add("return {res};")
 344                 end
 345                 v.add("\}")
 346         end
 347
 348         private fun build_class_vts_table(mclass: MClass): Bool do
 349                 if self.vt_tables[mclass].is_empty then return false
 350
 351                 self.provide_declaration("vts_table_{mclass.c_name}", "extern const struct vts_table vts_table_{mclass.c_name};")
 352
 353                 var v = new_visitor
 354                 v.add_decl("const struct vts_table vts_table_{mclass.c_name} = \{")
 355                 v.add_decl("0, /* dummy */")
 356                 v.add_decl("\{")
 357
 358                 for vt in self.vt_tables[mclass] do
 359                         if vt == null then
 360                                 v.add_decl("\{-1, NULL\}, /* empty */")
 361                         else
 362                                 var is_null = 0
 363                                 var bound = retrieve_vt_bound(mclass.intro.bound_mtype, vt.as(MVirtualTypeDef).bound)
 364                                 while bound isa MNullableType do
 365                                         bound = retrieve_vt_bound(mclass.intro.bound_mtype, bound.mtype)
 366                                         is_null = 1
 367                                 end
 368                                 var vtclass = bound.as(MClassType).mclass
 369                                 v.require_declaration("class_{vtclass.c_name}")
 370                                 v.add_decl("\{{is_null}, &class_{vtclass.c_name}\}, /* {vt} */")
 371                         end
 372                 end
 373                 v.add_decl("\},")
 374                 v.add_decl("\};")
 375                 return true
 376         end
 377
 378         private fun retrieve_vt_bound(anchor: MClassType, mtype: nullable MType): MType do
 379                 if mtype == null then
 380                         print "NOT YET IMPLEMENTED: retrieve_vt_bound on null"
 381                         abort
 382                 end
 383                 if mtype isa MVirtualType then
 384                         return mtype.anchor_to(mainmodule, anchor)
 385                 else if mtype isa MParameterType then
 386                         return mtype.anchor_to(mainmodule, anchor)
 387                 else
 388                         return mtype
 389                 end
 390         end
 391
 392         redef fun new_visitor do return new SeparateErasureCompilerVisitor(self)
 393
 394         # Stats
 395
 396         private var class_tables: Map[MClass, Array[nullable MClass]]
 397         private var vt_tables: Map[MClass, Array[nullable MPropDef]]
 398
 399         redef fun display_sizes
 400         do
 401                 print "# size of subtyping tables"
 402                 print "\ttotal \tholes"
 403                 var total = 0
 404                 var holes = 0
 405                 for t, table in class_tables do
 406                         total += table.length
 407                         for e in table do if e == null then holes += 1
 408                 end
 409                 print "\t{total}\t{holes}"
 410
 411                 print "# size of resolution tables"
 412                 print "\ttotal \tholes"
 413                 total = 0
 414                 holes = 0
 415                 for t, table in vt_tables do
 416                         total += table.length
 417                         for e in table do if e == null then holes += 1
 418                 end
 419                 print "\t{total}\t{holes}"
 420
 421                 print "# size of methods tables"
 422                 print "\ttotal \tholes"
 423                 total = 0
 424                 holes = 0
 425                 for t, table in method_tables do
 426                         total += table.length
 427                         for e in table do if e == null then holes += 1
 428                 end
 429                 print "\t{total}\t{holes}"
 430
 431                 print "# size of attributes tables"
 432                 print "\ttotal \tholes"
 433                 total = 0
 434                 holes = 0
 435                 for t, table in attr_tables do
 436                         total += table.length
 437                         for e in table do if e == null then holes += 1
 438                 end
 439                 print "\t{total}\t{holes}"
 440         end
 441 end
 442
 443 class SeparateErasureCompilerVisitor
 444         super SeparateCompilerVisitor
 445
 446         redef fun compile_callsite(callsite, arguments)
 447         do
 448                 var res = super
 449                 if callsite.erasure_cast and not self.compiler.as(SeparateErasureCompiler).modelbuilder.toolcontext.opt_no_check_erasure_cast.value then
 450                         assert res != null
 451                         var mtype = callsite.msignature.return_mtype
 452                         assert mtype != null
 453                         self.add("/* Erasure cast for return {res} isa {mtype} */")
 454                         var cond = self.type_test(res, mtype, "erasure")
 455                         self.add("if (!{cond}) \{")
 456                         #var x = self.class_name_string(res)
 457                         #var y = self.class_name_string(arguments.first)
 458                         #self.add("PRINT_ERROR(\"Erasure cast: expected {mtype} (self is %s), got %s for {res}\\n\", {y}, {x});")
 459                         self.add_abort("Cast failed")
 460                         self.add("\}")
 461                 end
 462                 return res
 463         end
 464
 465         redef fun init_instance(mtype)
 466         do
 467                 self.require_declaration("NEW_{mtype.mclass.c_name}")
 468                 return self.new_expr("NEW_{mtype.mclass.c_name}()", mtype)
 469         end
 470
 471         redef fun type_test(value, mtype, tag)
 472         do
 473                 self.add("/* type test for {value.inspect} isa {mtype} */")
 474
 475                 var res = self.new_var(bool_type)
 476
 477                 var cltype = self.get_name("cltype")
 478                 self.add_decl("int {cltype};")
 479                 var idtype = self.get_name("idtype")
 480                 self.add_decl("int {idtype};")
 481
 482                 var maybe_null = self.maybe_null(value)
 483                 var accept_null = "0"
 484                 if mtype isa MNullableType then
 485                         mtype = mtype.mtype
 486                         accept_null = "1"
 487                 end
 488                 if mtype isa MParameterType then
 489                         # Here we get the bound of the the formal type (eh, erasure...)
 490                         mtype = mtype.resolve_for(self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.mmodule, false)
 491                         if mtype isa MNullableType then
 492                                 mtype = mtype.mtype
 493                                 accept_null = "1"
 494                         end
 495                 end
 496
 497                 if value.mcasttype.is_subtype(self.frame.mpropdef.mclassdef.mmodule, self.frame.mpropdef.mclassdef.bound_mtype, mtype) then
 498                         self.add("{res} = 1; /* easy {value.inspect} isa {mtype}*/")
 499                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 500                                 self.compiler.count_type_test_skipped[tag] += 1
 501                                 self.add("count_type_test_skipped_{tag}++;")
 502                         end
 503                         return res
 504                 end
 505
 506                 var class_ptr
 507                 var type_table
 508                 if value.mtype.ctype == "val*" then
 509                         class_ptr = "{value}->class->"
 510                 else
 511                         var mclass = value.mtype.as(MClassType).mclass
 512                         self.require_declaration("class_{mclass.c_name}")
 513                         class_ptr = "class_{mclass.c_name}."
 514                 end
 515
 516                 if mtype isa MClassType then
 517                         self.require_declaration("class_{mtype.mclass.c_name}")
 518                         self.add("{cltype} = class_{mtype.mclass.c_name}.color;")
 519                         self.add("{idtype} = class_{mtype.mclass.c_name}.id;")
 520                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 521                                 self.compiler.count_type_test_resolved[tag] += 1
 522                                 self.add("count_type_test_resolved_{tag}++;")
 523                         end
 524                 else if mtype isa MVirtualType then
 525                         var recv = self.frame.arguments.first
 526                         var recv_ptr
 527                         if recv.mtype.ctype == "val*" then
 528                                 recv_ptr = "{recv}->class->"
 529                         else
 530                                 var mclass = recv.mtype.as(MClassType).mclass
 531                                 self.require_declaration("class_{mclass.c_name}")
 532                                 recv_ptr = "class_{mclass.c_name}."
 533                         end
 534                         var entry = self.get_name("entry")
 535                         self.add("struct vts_entry {entry};")
 536                         self.require_declaration(mtype.mproperty.const_color)
 537                         self.add("{entry} = {recv_ptr}vts_table->vts[{mtype.mproperty.const_color}];")
 538                         self.add("{cltype} = {entry}.class->color;")
 539                         self.add("{idtype} = {entry}.class->id;")
 540                         if maybe_null and accept_null == "0" then
 541                                 var is_nullable = self.get_name("is_nullable")
 542                                 self.add_decl("short int {is_nullable};")
 543                                 self.add("{is_nullable} = {entry}.is_nullable;")
 544                                 accept_null = is_nullable.to_s
 545                         end
 546                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 547                                 self.compiler.count_type_test_unresolved[tag] += 1
 548                                 self.add("count_type_test_unresolved_{tag}++;")
 549                         end
 550                 else
 551                         self.debug("type_test({value.inspect}, {mtype})")
 552                         abort
 553                 end
 554
 555                 # check color is in table
 556                 if maybe_null then
 557                         self.add("if({value} == NULL) \{")
 558                         self.add("{res} = {accept_null};")
 559                         self.add("\} else \{")
 560                 end
 561                 self.add("if({cltype} >= {class_ptr}type_table->size) \{")
 562                 self.add("{res} = 0;")
 563                 self.add("\} else \{")
 564                 self.add("{res} = {class_ptr}type_table->table[{cltype}] == {idtype};")
 565                 self.add("\}")
 566                 if maybe_null then
 567                         self.add("\}")
 568                 end
 569
 570                 return res
 571         end
 572
 573         redef fun class_name_string(value)
 574         do
 575                 var res = self.get_name("var_class_name")
 576                 self.add_decl("const char* {res};")
 577                 if value.mtype.ctype == "val*" then
 578                         self.add "{res} = {value} == NULL ? \"null\" : {value}->class->name;"
 579                 else
 580                         self.require_declaration("class_{value.mtype.c_name}")
 581                         self.add "{res} = class_{value.mtype.c_name}.name;"
 582                 end
 583                 return res
 584         end
 585
 586         redef fun native_array_instance(elttype, length)
 587         do
 588                 var nclass = self.get_class("NativeArray")
 589                 var mtype = nclass.get_mtype([elttype])
 590                 var res = self.new_var(mtype)
 591                 res.is_exact = true
 592                 self.require_declaration("NEW_{nclass.c_name}")
 593                 self.add("{res} = NEW_{nclass.c_name}({length});")
 594                 return res
 595         end
 596
 597         redef fun calloc_array(ret_type, arguments)
 598         do
 599                 var ret = ret_type.as(MClassType)
 600                 self.require_declaration("NEW_{ret.mclass.c_name}")
 601                 self.ret(self.new_expr("NEW_{ret.mclass.c_name}({arguments[1]})", ret_type))
 602         end
 603 end