src/phase.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Phases of the processing of nit programs
  16 module phase
  17
  18 import toolcontext
  19 import parser
  20 import poset
  21
  22 redef class ToolContext
  23         # The various registered phases to performs
  24         # The order in the poset is the dependence of phases
  25         #
  26         # While you can directly modify the poset (nodes and edges),
  27         # it is often simpler to use the constructor in `Phase`
  28         var phases = new POSet[Phase]
  29
  30         # --disable-phase
  31         var opt_disable_phase = new OptionArray("DEBUG: Disable a specific phase; use `list` to get the list.", "--disable-phase")
  32
  33         # --disable-phase
  34         var opt_sloppy = new OptionBool("DEBUG: force lazy semantic analysis of the source-code", "--sloppy")
  35
  36         redef init
  37         do
  38                 super
  39
  40                 option_context.add_option(opt_disable_phase, opt_sloppy)
  41         end
  42
  43         redef fun process_options(args)
  44         do
  45                 super
  46
  47                 for v in opt_disable_phase.value do
  48                         if v == "list" then
  49                                 for p in phases_list do
  50                                         var deps = p.in_hierarchy.direct_greaters
  51                                         if deps.is_empty then
  52                                                 print p
  53                                         else
  54                                                 print "{p} (dep: {deps.join(", ")})"
  55                                         end
  56                                 end
  57                                 exit 0
  58                         end
  59
  60                         var found = false
  61                         for p in phases do
  62                                 if v != p.to_s then continue
  63                                 found = true
  64                                 p.disabled = true
  65                         end
  66                         if not found then fatal_error(null, "Error: no phase named `{v}`. Use `list` to list all phases.")
  67                 end
  68
  69                 if opt_sloppy.value then semantize_is_lazy = true
  70         end
  71
  72         # The list of registered phases in the application order.
  73         var phases_list: Sequence[Phase] is lazy do
  74                 var phases = self.phases.to_a
  75                 self.phases.sort(phases)
  76                 return phases
  77         end
  78
  79         # Is `phase_process_npropdef` not called automatically by `run_phases`?
  80         #
  81         # When set to true, it is the responsibility of the tools
  82         #
  83         # Is false by default.
  84         var semantize_is_lazy = false is writable
  85
  86         # Set of already analyzed modules.
  87         private var phased_modules = new HashSet[AModule]
  88
  89         # Run all registered phases on a set of modules
  90         fun run_phases(nmodules: Collection[AModule])
  91         do
  92                 var time0 = get_time
  93                 self.info("*** SEMANTIC ANALYSIS ***", 1)
  94                 #phases.show_dot
  95
  96                 var phases = phases_list
  97
  98                 for phase in phases do
  99                         self.info(" registered phases: {phase}", 2)
 100                 end
 101
 102                 for nmodule in nmodules do
 103                         if phased_modules.has(nmodule) then continue
 104                         phased_modules.add nmodule
 105
 106                         self.info("Semantic analysis module {nmodule.location.file.filename}", 2)
 107
 108                         var vannot = new AnnotationPhaseVisitor
 109                         vannot.enter_visit(nmodule)
 110
 111                         for phase in phases do
 112                                 if phase.disabled then continue
 113                                 self.info(" phase: {phase}", 3)
 114                                 assert phase.toolcontext == self
 115                                 var errcount = self.error_count
 116                                 phase.process_nmodule(nmodule)
 117                                 if errcount != self.error_count then
 118                                         self.check_errors
 119                                         break
 120                                 end
 121                                 errcount = self.error_count
 122                                 for nclassdef in nmodule.n_classdefs do
 123                                         assert phase.toolcontext == self
 124                                         phase.process_nclassdef(nclassdef)
 125                                         if not semantize_is_lazy then for npropdef in nclassdef.n_propdefs do
 126                                                 assert phase.toolcontext == self
 127                                                 phase_process_npropdef(phase, npropdef)
 128                                         end
 129                                 end
 130                                 if errcount != self.error_count then
 131                                         self.check_errors
 132                                         break
 133                                 end
 134                                 for na in vannot.annotations do
 135                                         var p = na.parent
 136                                         if p isa AAnnotations then p = p.parent
 137                                         assert p != null
 138                                         phase.process_annotated_node(p, na)
 139                                 end
 140                                 if errcount != self.error_count then
 141                                         self.check_errors
 142                                         break
 143                                 end
 144                         end
 145                         self.check_errors
 146                 end
 147
 148                 var time1 = get_time
 149                 self.info("*** END SEMANTIC ANALYSIS: {time1-time0} ***", 2)
 150
 151                 errors_info
 152         end
 153
 154         # Process the given `phase` on the `npropdef`
 155         # Called by `run_phases`
 156         protected fun phase_process_npropdef(phase: Phase, npropdef: APropdef)
 157         do
 158                 phase.process_npropdef(npropdef)
 159         end
 160
 161         # Run the phase on the given npropdef.
 162         # Does nothing if `semantize_is_lazy` is false.
 163         fun run_phases_on_npropdef(npropdef: APropdef)
 164         do
 165                 if not semantize_is_lazy then return
 166                 if npropdef.is_phased then return
 167                 npropdef.is_phased = true
 168
 169                 #self.info("Semantic analysis of property {npropdef.location.file.filename}", 0)
 170
 171                 var phases = phases_list
 172                 for phase in phases do
 173                         if phase.disabled then continue
 174                         assert phase.toolcontext == self
 175                         phase_process_npropdef(phase, npropdef)
 176                         self.check_errors
 177                 end
 178         end
 179 end
 180
 181 redef class APropdef
 182         # Is the propdef already analyzed by `run_phases_on_npropdef`.
 183         # Unused unless `semantize_is_lazy` is true.
 184         private var is_phased = false
 185 end
 186
 187 # Collect all annotation
 188 private class AnnotationPhaseVisitor
 189         super Visitor
 190
 191         # The collected annotations
 192         var annotations = new Array[AAnnotation]
 193
 194         redef fun visit(n)
 195         do
 196                 n.visit_all(self)
 197                 if n isa AAnnotation then annotations.add n
 198         end
 199 end
 200
 201 # Abstraction of steps in the analysis/processing of Nit programs
 202 # Specific phases should implements one of the `process_*` method
 203 abstract class Phase
 204         # The toolcontext instance attached to the phase
 205         var toolcontext: ToolContext
 206
 207         # The dependence relation of the phase with the other phases
 208         var in_hierarchy: POSetElement[Phase] is noinit
 209
 210         # The explicit dependences, used to initialize `in_importation`
 211         var depends: nullable Collection[Phase]
 212
 213         # Initialize and register a phase to the toolcontext
 214         init
 215         do
 216                 in_hierarchy = toolcontext.phases.add_node(self)
 217                 var depends = self.depends
 218                 if depends != null then
 219                         for d in depends do
 220                                 toolcontext.phases.add_edge(self, d)
 221                         end
 222                 end
 223         end
 224
 225         # By default, the name is the lowercased prefix of the classname
 226         redef fun to_s do return class_name.strip_extension("Phase").to_lower
 227
 228         # Is the phase globally disabled?
 229         # A disabled phase is not called automatically called by `ToolContext::run_phases` and cie.
 230         #
 231         # Warning: disabling a phase may cause subsequent phases to work in a degraded way or to fail.
 232         var disabled = false is writable
 233
 234         # Specific actions to execute on the whole tree of a module
 235         # @toimplement
 236         fun process_nmodule(nmodule: AModule) do end
 237
 238         # Specific actions to execute on the tree of a class definition
 239         # Note that the order of the visit is the one of the file
 240         # @toimplement
 241         fun process_nclassdef(nclassdef: AClassdef) do end
 242
 243         # Specific actions to execute on the tree of a property
 244         # Note that the order of the visit is the one of the file
 245         # @toimplement
 246         fun process_npropdef(npropdef: APropdef) do end
 247
 248         # Specific actions to execute on annotated nodes
 249         # Note that the order of the visit is the one of the file
 250         # @toimplement
 251         fun process_annotated_node(node: ANode, nat: AAnnotation) do end
 252 end