lib/gamnit/flat.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Simple API for 2D games, based around `Sprite` and `App::update`
  16 #
  17 # Client programs should implement `App::update` to execute game logic and
  18 # add instances of `Sprite` to `App::sprites` and `App::ui_sprites`.
  19 # At each frame, all sprites are drawn to the screen.
  20 #
  21 # This system relies on two cameras `App::world_camera` and `App::ui_camera`.
  22 #
  23 # * `App::world_camera` applies a perspective effect to draw the game world.
  24 #   This camera is designed to be moved around to see the world as well as to zoom in and out.
  25 #   It is used to position the sprites in `App::sprites`.
  26 #
  27 # * `App::ui_camera` is a simple orthogonal camera to display UI objects.
  28 #   This camera should mostly be still, it can still move for chock effects and the like.
  29 #   It can be used to standardize the size of the UI across devices.
  30 #   It is used to position the sprites in `App::ui_sprites`.
  31 #
  32 # See the sample game at `contrib/asteronits/`.
  33 module flat
  34
  35 import glesv2
  36
  37 import geometry::points_and_lines
  38 import matrix::projection
  39 import more_collections
  40 import realtime
  41
  42 import gamnit
  43 import gamnit::cameras
  44 import gamnit::limit_fps
  45
  46 # Image to draw on screen
  47 class Sprite
  48
  49         # Texture drawn to screen
  50         var texture: Texture is writable
  51
  52         # Position of this sprite in world coordinates
  53         var center: Point3d[Float] is writable
  54
  55         # Rotation on the Z axis
  56         var rotation = 0.0 is writable
  57
  58         # Scale applied to this sprite
  59         var scale = 1.0 is writable
  60
  61         # Transparency applied to the texture on draw
  62         var alpha = 1.0 is writable
  63
  64         private fun draw
  65         do
  66                 var simple_2d_program = app.simple_2d_program
  67
  68                 glActiveTexture gl_TEXTURE0
  69                 glBindTexture(gl_TEXTURE_2D, texture.root.gl_texture)
  70
  71                 simple_2d_program.translation.array_enabled = false
  72                 simple_2d_program.color.array_enabled = false
  73                 simple_2d_program.scale.array_enabled = false
  74
  75                 simple_2d_program.translation.uniform(center.x, -center.y, center.z, 0.0)
  76                 simple_2d_program.color.uniform(1.0, 1.0, 1.0, alpha)
  77                 simple_2d_program.scale.uniform scale
  78
  79                 simple_2d_program.use_texture.uniform true
  80                 simple_2d_program.texture.uniform 0
  81                 simple_2d_program.tex_coord.array(texture.texture_coords, 2)
  82                 simple_2d_program.coord.array(texture.vertices, 3)
  83
  84                 simple_2d_program.rotation.uniform new Matrix.rotation(rotation, 0.0, 0.0, 1.0)
  85
  86                 glDrawArrays(gl_TRIANGLE_STRIP, 0, 4)
  87         end
  88 end
  89
  90 redef class App
  91         # Default graphic program to draw `sprites`
  92         var simple_2d_program = new Simple2dProgram is lazy # TODO private
  93
  94         # Camera for world objects with perspective
  95         #
  96         # By default, the camera is configured to respect the resolution
  97         # of the screen in world coordinates at `z == 0.0`.
  98         var world_camera: EulerCamera is lazy do
  99                 var camera = new EulerCamera(app.display.as(not null))
 100
 101                 # Aim for pixel resolution at level 0
 102                 camera.reset_height
 103                 camera.near = 100.0
 104
 105                 return camera
 106         end
 107
 108         # Camera for UI elements using an orthogonal view
 109         var ui_camera: UICamera = new UICamera(app.display.as(not null)) is lazy
 110
 111         # Live sprites to draw in reference to `world_camera`
 112         var sprites: Sequence[Sprite] = new List[Sprite]
 113
 114         # UI sprites to draw in reference to `ui_camera`, over world `sprites`
 115         var ui_sprites: Sequence[Sprite] = new List[Sprite]
 116
 117         private var clock = new Clock
 118
 119         redef fun on_create
 120         do
 121                 super
 122
 123                 var display = display
 124                 assert display != null
 125
 126                 var gl_error = glGetError
 127                 assert gl_error == gl_NO_ERROR else print gl_error
 128
 129                 # Prepare program
 130                 var program = simple_2d_program
 131                 program.compile_and_link
 132
 133                 var gamnit_error = program.error
 134                 assert gamnit_error == null else print_error gamnit_error
 135
 136                 # Enable blending
 137                 gl.capabilities.blend.enable
 138                 glBlendFunc(gl_SRC_ALPHA, gl_ONE_MINUS_SRC_ALPHA)
 139
 140                 # Enable depth test
 141                 gl.capabilities.depth_test.enable
 142                 glDepthFunc gl_LEQUAL
 143                 glDepthMask true
 144
 145                 # Prepare viewport and background color
 146                 glViewport(0, 0, display.width, display.height)
 147                 glClearColor(0.0, 0.0, 0.0, 1.0)
 148
 149                 gl_error = glGetError
 150                 assert gl_error == gl_NO_ERROR else print gl_error
 151
 152                 # Prepare to draw
 153                 for tex in all_root_textures do
 154                         tex.load
 155
 156                         glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_MIN_FILTER, gl_LINEAR)
 157                         glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_MAG_FILTER, gl_LINEAR)
 158
 159                         gamnit_error = tex.error
 160                         assert gamnit_error == null else print_error gamnit_error
 161                 end
 162         end
 163
 164         redef fun frame_core(display)
 165         do
 166                 # Prepare to draw, clear buffers
 167                 glClear(gl_COLOR_BUFFER_BIT | gl_DEPTH_BUFFER_BIT)
 168
 169                 # Check errors
 170                 var gl_error = glGetError
 171                 assert gl_error == gl_NO_ERROR else print gl_error
 172
 173                 # Update game logic and set sprites
 174                 var dt = clock.lapse.to_f
 175                 update dt
 176
 177                 # Draw and flip screen
 178                 frame_core_draw display
 179                 display.flip
 180
 181                 # Check errors
 182                 gl_error = glGetError
 183                 assert gl_error == gl_NO_ERROR else print gl_error
 184         end
 185
 186         # Draw the whole screen, all `glDraw...` calls should be executed here
 187         protected fun frame_core_draw(display: GamnitDisplay) do frame_core_flat display
 188
 189         # Draw sprites in `sprites` and `ui_sprites`
 190         protected fun frame_core_flat(display: GamnitDisplay)
 191         do
 192                 simple_2d_program.use
 193
 194                 # Set constant configs
 195                 simple_2d_program.coord.array_enabled = true
 196                 simple_2d_program.tex_coord.array_enabled = true
 197                 simple_2d_program.color.array_enabled = false
 198
 199                 # TODO optimize this draw to store constant values on the GPU
 200                 # World sprites
 201                 simple_2d_program.mvp.uniform world_camera.mvp_matrix
 202                 for sprite in sprites do sprite.draw
 203
 204                 # Reset only the depth buffer
 205                 glClear gl_DEPTH_BUFFER_BIT
 206
 207                 # UI sprites
 208                 simple_2d_program.mvp.uniform ui_camera.mvp_matrix
 209                 for sprite in ui_sprites do sprite.draw
 210         end
 211
 212         # Main method to refine in clients to update game logic and `sprites`
 213         fun update(dt: Float) do end
 214
 215         # Display `texture` as a splash screen
 216         #
 217         # Load `texture` if needed and resets `ui_camera` to 1080 units on the Y axis.
 218         fun show_splash_screen(texture: Texture)
 219         do
 220                 texture.load
 221
 222                 ui_camera.reset_height 1080.0
 223
 224                 var splash = new Sprite(texture, ui_camera.center)
 225                 ui_sprites.add splash
 226
 227                 var display = display
 228                 assert display != null
 229                 glClear gl_COLOR_BUFFER_BIT
 230                 frame_core_flat display
 231                 display.flip
 232
 233                 ui_sprites.remove splash
 234         end
 235
 236         redef fun on_stop
 237         do
 238                 # Clean up
 239                 simple_2d_program.delete
 240
 241                 # Close gamnit
 242                 var display = display
 243                 if display != null then display.close
 244         end
 245 end
 246
 247 redef class Texture
 248
 249         # Vertices coordinates of the base geometry
 250         private var vertices: Array[Float] is lazy do
 251                 var mod = 1.0
 252                 var w = width * mod
 253                 var h = height * mod
 254                 var a = [-0.5*w, -0.5*h, 0.0]
 255                 var b = [ 0.5*w, -0.5*h, 0.0]
 256                 var c = [-0.5*w,  0.5*h, 0.0]
 257                 var d = [ 0.5*w,  0.5*h, 0.0]
 258
 259                 var vertices = new Array[Float]
 260                 for v in [c, d, a, b] do vertices.add_all v
 261                 return vertices
 262         end
 263
 264         # Coordinates of this texture on the `root` texture, with `[0..1.0]`
 265         private var texture_coords: Array[Float] is lazy do
 266                 var a = [offset_left,  offset_bottom]
 267                 var b = [offset_right, offset_bottom]
 268                 var c = [offset_left,  offset_top]
 269                 var d = [offset_right, offset_top]
 270
 271                 var texture_coords = new Array[Float]
 272                 for v in [c, d, a, b] do texture_coords.add_all v
 273                 return texture_coords
 274         end
 275 end
 276
 277 # Graphic program to display simple models with a texture, translation, rotation and scale
 278 class Simple2dProgram
 279         super GamnitProgramFromSource
 280
 281         redef var vertex_shader_source = """
 282                 // Vertex coordinates
 283                 attribute vec4 coord;
 284
 285                 // Vertex color tint
 286                 attribute vec4 color;
 287
 288                 // Vertex translation
 289                 attribute vec4 translation;
 290
 291                 // Vertex scaling
 292                 attribute float scale;
 293
 294                 // Vertex coordinates on textures
 295                 attribute vec2 tex_coord;
 296
 297                 // Model view projection matrix
 298                 uniform mat4 mvp;
 299
 300                 // Rotation matrix
 301                 uniform mat4 rotation;
 302
 303                 // Output for the fragment shader
 304                 varying vec4 v_color;
 305                 varying vec2 v_coord;
 306
 307                 void main()
 308                 {
 309                         v_color = color;
 310                         gl_Position = (vec4(coord.xyz * scale, 1.0) * rotation + translation) * mvp;
 311                         v_coord = tex_coord;
 312                 }
 313                 """ @ glsl_vertex_shader
 314
 315         redef var fragment_shader_source = """
 316                 precision mediump float;
 317
 318                 // Does this object use a texture?
 319                 uniform bool use_texture;
 320
 321                 // Texture to apply on this object
 322                 uniform sampler2D texture;
 323
 324                 // Input from the vertex shader
 325                 varying vec4 v_color;
 326                 varying vec2 v_coord;
 327
 328                 void main()
 329                 {
 330                         if(use_texture) {
 331                                 gl_FragColor = v_color * texture2D(texture, v_coord);
 332                                 if (gl_FragColor.a == 0.0) discard;
 333                         } else {
 334                                 gl_FragColor = v_color;
 335                         }
 336                 }
 337                 """ @ glsl_fragment_shader
 338
 339         # Vertices coordinates
 340         var coord = attributes["coord"].as(AttributeVec4) is lazy
 341
 342         # Should this program use the texture `texture`?
 343         var use_texture = uniforms["use_texture"].as(UniformBool) is lazy
 344
 345         # Visible texture unit
 346         var texture = uniforms["texture"].as(UniformSampler2D) is lazy
 347
 348         # Coordinates on the textures, per vertex
 349         var tex_coord = attributes["tex_coord"].as(AttributeVec2) is lazy
 350
 351         # Color tint per vertex
 352         var color = attributes["color"].as(AttributeVec4) is lazy
 353
 354         # Translation applied to each vertex
 355         var translation = attributes["translation"].as(AttributeVec4) is lazy
 356
 357         # Rotation matrix
 358         var rotation = uniforms["rotation"].as(UniformMat4) is lazy
 359
 360         # Scaling per vertex
 361         var scale = attributes["scale"].as(AttributeFloat) is lazy
 362
 363         # Model view projection matrix
 364         var mvp = uniforms["mvp"].as(UniformMat4) is lazy
 365 end
 366
 367 redef class Point3d[N]
 368         # Get a new `Point3d[Float]` with an offset of each axis of `x, y, z`
 369         fun offset(x, y, z: Numeric): Point3d[Float]
 370         do
 371                 return new Point3d[Float](self.x.to_f+x.to_f, self.y.to_f+y.to_f, self.z.to_f+z.to_f)
 372         end
 373 end