src/separate_erasure_compiler.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Separate compilation of a Nit program with generic type erasure
  16 module separate_erasure_compiler
  17
  18 intrude import separate_compiler
  19
  20 # Add separate erased compiler specific options
  21 redef class ToolContext
  22         # --erasure
  23         var opt_erasure: OptionBool = new OptionBool("Erase generic types", "--erasure")
  24         # --no-check-erasure-cast
  25         var opt_no_check_erasure_cast: OptionBool = new OptionBool("Disable implicit casts on unsafe return with erasure-typing policy (dangerous)", "--no-check-erasure-cast")
  26
  27         redef init
  28         do
  29                 super
  30                 self.option_context.add_option(self.opt_erasure, self.opt_no_check_erasure_cast)
  31         end
  32 end
  33
  34 redef class ModelBuilder
  35         fun run_separate_erasure_compiler(mainmodule: MModule, runtime_type_analysis: nullable RapidTypeAnalysis)
  36         do
  37                 var time0 = get_time
  38                 self.toolcontext.info("*** GENERATING C ***", 1)
  39
  40                 var compiler = new SeparateErasureCompiler(mainmodule, self, runtime_type_analysis)
  41                 compiler.compile_header
  42
  43                 # compile class structures
  44                 self.toolcontext.info("Property coloring", 2)
  45                 compiler.new_file("{mainmodule.name}.tables")
  46                 compiler.do_property_coloring
  47                 for m in mainmodule.in_importation.greaters do
  48                         for mclass in m.intro_mclasses do
  49                                 compiler.compile_class_to_c(mclass)
  50                         end
  51                 end
  52                 compiler.compile_color_consts(compiler.vt_layout.pos)
  53
  54                 # The main function of the C
  55                 compiler.new_file("{mainmodule.name}.main")
  56                 compiler.compile_main_function
  57
  58                 # compile methods
  59                 for m in mainmodule.in_importation.greaters do
  60                         self.toolcontext.info("Generate C for module {m}", 2)
  61                         compiler.new_file("{m.name}.sep")
  62                         compiler.compile_module_to_c(m)
  63                 end
  64
  65                 compiler.display_stats
  66
  67                 var time1 = get_time
  68                 self.toolcontext.info("*** END GENERATING C: {time1-time0} ***", 2)
  69                 write_and_make(compiler)
  70         end
  71 end
  72
  73 class SeparateErasureCompiler
  74         super SeparateCompiler
  75
  76         private var class_layout: nullable Layout[MClass]
  77         protected var vt_layout: nullable Layout[MVirtualTypeProp]
  78
  79         init(mainmodule: MModule, mmbuilder: ModelBuilder, runtime_type_analysis: nullable RapidTypeAnalysis) do
  80                 super
  81
  82                 var mclasses = new HashSet[MClass].from(mmbuilder.model.mclasses)
  83
  84                 var layout_builder: TypingLayoutBuilder[MClass]
  85                 var class_colorer = new MClassColorer(mainmodule)
  86                 if modelbuilder.toolcontext.opt_phmod_typing.value then
  87                         layout_builder = new MClassHasher(new PHModOperator, mainmodule)
  88                         class_colorer.build_layout(mclasses)
  89                 else if modelbuilder.toolcontext.opt_phand_typing.value then
  90                         layout_builder = new MClassHasher(new PHAndOperator, mainmodule)
  91                         class_colorer.build_layout(mclasses)
  92                 else if modelbuilder.toolcontext.opt_bm_typing.value then
  93                         layout_builder = new MClassBMizer(mainmodule)
  94                         class_colorer.build_layout(mclasses)
  95                 else
  96                         layout_builder = class_colorer
  97                 end
  98                 self.class_layout = layout_builder.build_layout(mclasses)
  99                 self.class_tables = self.build_class_typing_tables(mclasses)
 100
 101                 # lookup vt to build layout with
 102                 var vts = new HashMap[MClass, Set[MVirtualTypeProp]]
 103                 for mclass in mclasses do
 104                         vts[mclass] = new HashSet[MVirtualTypeProp]
 105                         for mprop in self.mainmodule.properties(mclass) do
 106                                 if mprop isa MVirtualTypeProp then
 107                                         vts[mclass].add(mprop)
 108                                 end
 109                         end
 110                 end
 111
 112                 # vt coloration
 113                 var vt_coloring = new MPropertyColorer[MVirtualTypeProp](mainmodule, class_colorer)
 114                 var vt_layout = vt_coloring.build_layout(vts)
 115                 self.vt_tables = build_vt_tables(mclasses, vt_layout)
 116                 self.vt_layout = vt_layout
 117         end
 118
 119         fun build_vt_tables(mclasses: Set[MClass], layout: Layout[MProperty]): Map[MClass, Array[nullable MPropDef]] do
 120                 var tables = new HashMap[MClass, Array[nullable MPropDef]]
 121                 for mclass in mclasses do
 122                         var table = new Array[nullable MPropDef]
 123                         # first, fill table from parents by reverse linearization order
 124                         var parents = new Array[MClass]
 125                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 126                                 parents = mclass.in_hierarchy(mainmodule).greaters.to_a
 127                                 self.mainmodule.linearize_mclasses(parents)
 128                         end
 129                         for parent in parents do
 130                                 if parent == mclass then continue
 131                                 for mproperty in self.mainmodule.properties(parent) do
 132                                         if not mproperty isa MVirtualTypeProp then continue
 133                                         var color = layout.pos[mproperty]
 134                                         if table.length <= color then
 135                                                 for i in [table.length .. color[ do
 136                                                         table[i] = null
 137                                                 end
 138                                         end
 139                                         for mpropdef in mproperty.mpropdefs do
 140                                                 if mpropdef.mclassdef.mclass == parent then
 141                                                         table[color] = mpropdef
 142                                                 end
 143                                         end
 144                                 end
 145                         end
 146
 147                         # then override with local properties
 148                         for mproperty in self.mainmodule.properties(mclass) do
 149                                 if not mproperty isa MVirtualTypeProp then continue
 150                                 var color = layout.pos[mproperty]
 151                                 if table.length <= color then
 152                                         for i in [table.length .. color[ do
 153                                                 table[i] = null
 154                                         end
 155                                 end
 156                                 for mpropdef in mproperty.mpropdefs do
 157                                         if mpropdef.mclassdef.mclass == mclass then
 158                                                 table[color] = mpropdef
 159                                         end
 160                                 end
 161                         end
 162                         tables[mclass] = table
 163                 end
 164                 return tables
 165         end
 166
 167         # Build class tables
 168         fun build_class_typing_tables(mclasses: Set[MClass]): Map[MClass, Array[nullable MClass]] do
 169                 var tables = new HashMap[MClass, Array[nullable MClass]]
 170                 var layout = self.class_layout
 171                 for mclass in mclasses do
 172                         var table = new Array[nullable MClass]
 173                         var supers = new Array[MClass]
 174                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 175                                 supers = mclass.in_hierarchy(mainmodule).greaters.to_a
 176                         end
 177                         for sup in supers do
 178                                 var color: Int
 179                                 if layout isa PHLayout[MClass, MClass] then
 180                                         color = layout.hashes[mclass][sup]
 181                                 else
 182                                         color = layout.pos[sup]
 183                                 end
 184                                 if table.length <= color then
 185                                         for i in [table.length .. color[ do
 186                                                 table[i] = null
 187                                         end
 188                                 end
 189                                 table[color] = sup
 190                         end
 191                         tables[mclass] = table
 192                 end
 193                 return tables
 194         end
 195
 196         redef fun compile_header_structs do
 197                 self.header.add_decl("typedef void(*nitmethod_t)(void); /* general C type representing a Nit method. */")
 198                 self.compile_header_attribute_structs
 199                 self.header.add_decl("struct class \{ int id; const char *name; int box_kind; int color; const struct vts_table *vts_table; const struct type_table *type_table; nitmethod_t vft[]; \}; /* general C type representing a Nit class. */")
 200                 self.header.add_decl("struct type_table \{ int size; int table[]; \}; /* colorized type table. */")
 201                 self.header.add_decl("struct vts_entry \{ short int is_nullable; const struct class *class; \}; /* link (nullable or not) between the vts and is bound. */")
 202
 203                 if self.vt_layout isa PHLayout[MClass, MVirtualTypeProp] then
 204                         self.header.add_decl("struct vts_table \{ int mask; const struct vts_entry vts[]; \}; /* vts list of a C type representation. */")
 205                 else
 206                         self.header.add_decl("struct vts_table \{ int dummy; const struct vts_entry vts[]; \}; /* vts list of a C type representation. */")
 207                 end
 208
 209                 if modelbuilder.toolcontext.opt_phmod_typing.value then
 210                         self.header.add_decl("#define HASH(mask, id) ((mask)%(id))")
 211                 else if modelbuilder.toolcontext.opt_phand_typing.value then
 212                         self.header.add_decl("#define HASH(mask, id) ((mask)&(id))")
 213                 end
 214
 215                 self.header.add_decl("typedef struct instance \{ const struct class *class; nitattribute_t attrs[1]; \} val; /* general C type representing a Nit instance. */")
 216         end
 217
 218         redef fun compile_class_to_c(mclass: MClass)
 219         do
 220                 var mtype = mclass.intro.bound_mtype
 221                 var c_name = mclass.c_name
 222                 var c_instance_name = mclass.c_instance_name
 223
 224                 var vft = self.method_tables[mclass]
 225                 var attrs = self.attr_tables[mclass]
 226                 var class_table = self.class_tables[mclass]
 227                 var v = self.new_visitor
 228
 229                 v.add_decl("/* runtime class {c_name} */")
 230
 231                 self.provide_declaration("class_{c_name}", "extern const struct class class_{c_name};")
 232                 v.add_decl("extern const struct type_table type_table_{c_name};")
 233
 234                 # Build class vft
 235                 v.add_decl("const struct class class_{c_name} = \{")
 236                 v.add_decl("{self.class_layout.ids[mclass]},")
 237                 v.add_decl("\"{mclass.name}\", /* class_name_string */")
 238                 v.add_decl("{self.box_kind_of(mclass)}, /* box_kind */")
 239                 var layout = self.class_layout
 240                 if layout isa PHLayout[MClass, MClass] then
 241                         v.add_decl("{layout.masks[mclass]},")
 242                 else
 243                         v.add_decl("{layout.pos[mclass]},")
 244                 end
 245                 if build_class_vts_table(mclass) then
 246                         v.require_declaration("vts_table_{c_name}")
 247                         v.add_decl("&vts_table_{c_name},")
 248                 else
 249                         v.add_decl("NULL,")
 250                 end
 251                 v.add_decl("&type_table_{c_name},")
 252                 v.add_decl("\{")
 253                 for i in [0 .. vft.length[ do
 254                         var mpropdef = vft[i]
 255                         if mpropdef == null then
 256                                 v.add_decl("NULL, /* empty */")
 257                         else
 258                                 if true or mpropdef.mclassdef.bound_mtype.ctype != "val*" then
 259                                         v.require_declaration("VIRTUAL_{mpropdef.c_name}")
 260                                         v.add_decl("(nitmethod_t)VIRTUAL_{mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 261                                 else
 262                                         v.require_declaration("{mpropdef.c_name}")
 263                                         v.add_decl("(nitmethod_t){mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 264                                 end
 265                         end
 266                 end
 267                 v.add_decl("\}")
 268                 v.add_decl("\};")
 269
 270                 # Build class type table
 271
 272                 v.add_decl("const struct type_table type_table_{c_name} = \{")
 273                 v.add_decl("{class_table.length},")
 274                 v.add_decl("\{")
 275                 for msuper in class_table do
 276                         if msuper == null then
 277                                 v.add_decl("-1, /* empty */")
 278                         else
 279                                 v.add_decl("{self.class_layout.ids[msuper]}, /* {msuper} */")
 280                         end
 281                 end
 282                 v.add_decl("\}")
 283                 v.add_decl("\};")
 284
 285                 if mtype.ctype != "val*" then
 286                         if mtype.mclass.name == "Pointer" or mtype.mclass.kind != extern_kind then
 287                                 #Build instance struct
 288                                 self.header.add_decl("struct instance_{c_instance_name} \{")
 289                                 self.header.add_decl("const struct class *class;")
 290                                 self.header.add_decl("{mtype.ctype} value;")
 291                                 self.header.add_decl("\};")
 292                         end
 293
 294                         #Build BOX
 295                         self.provide_declaration("BOX_{c_name}", "val* BOX_{c_name}({mtype.ctype});")
 296                         v.add_decl("/* allocate {mtype} */")
 297                         v.add_decl("val* BOX_{mtype.c_name}({mtype.ctype} value) \{")
 298                         v.add("struct instance_{c_instance_name}*res = nit_alloc(sizeof(struct instance_{c_instance_name}));")
 299                         v.require_declaration("class_{c_name}")
 300                         v.add("res->class = &class_{c_name};")
 301                         v.add("res->value = value;")
 302                         v.add("return (val*)res;")
 303                         v.add("\}")
 304                         return
 305                 else if mclass.name == "NativeArray" then
 306                         #Build instance struct
 307                         self.header.add_decl("struct instance_{c_name} \{")
 308                         self.header.add_decl("const struct class *class;")
 309                         self.header.add_decl("val* values[];")
 310                         self.header.add_decl("\};")
 311
 312                         #Build NEW
 313                         self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(int length);")
 314                         v.add_decl("/* allocate {mtype} */")
 315                         v.add_decl("{mtype.ctype} NEW_{c_name}(int length) \{")
 316                         var res = v.new_named_var(mtype, "self")
 317                         res.is_exact = true
 318                         var mtype_elt = mtype.arguments.first
 319                         v.add("{res} = nit_alloc(sizeof(struct instance_{c_name}) + length*sizeof({mtype_elt.ctype}));")
 320                         v.require_declaration("class_{c_name}")
 321                         v.add("{res}->class = &class_{c_name};")
 322                         v.add("return {res};")
 323                         v.add("\}")
 324                         return
 325                 end
 326
 327                 #Build NEW
 328                 self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(void);")
 329                 v.add_decl("/* allocate {mtype} */")
 330                 v.add_decl("{mtype.ctype} NEW_{c_name}(void) \{")
 331                 var res = v.new_named_var(mtype, "self")
 332                 res.is_exact = true
 333                 v.add("{res} = nit_alloc(sizeof(struct instance) + {attrs.length}*sizeof(nitattribute_t));")
 334                 v.require_declaration("class_{c_name}")
 335                 v.add("{res}->class = &class_{c_name};")
 336                 self.generate_init_attr(v, res, mtype)
 337                 v.add("return {res};")
 338                 v.add("\}")
 339         end
 340
 341         private fun build_class_vts_table(mclass: MClass): Bool do
 342                 if self.vt_tables[mclass].is_empty then return false
 343
 344                 self.provide_declaration("vts_table_{mclass.c_name}", "extern const struct vts_table vts_table_{mclass.c_name};")
 345
 346                 var v = new_visitor
 347                 v.add_decl("const struct vts_table vts_table_{mclass.c_name} = \{")
 348                 if self.vt_layout isa PHLayout[MClass, MVirtualTypeProp] then
 349                         #TODO redo this when PHPropertyLayoutBuilder will be implemented
 350                         #v.add_decl("{vt_masks[mclass]},")
 351                 else
 352                         v.add_decl("0, /* dummy */")
 353                 end
 354                 v.add_decl("\{")
 355
 356                 for vt in self.vt_tables[mclass] do
 357                         if vt == null then
 358                                 v.add_decl("\{-1, NULL\}, /* empty */")
 359                         else
 360                                 var is_null = 0
 361                                 var bound = retrieve_vt_bound(mclass.intro.bound_mtype, vt.as(MVirtualTypeDef).bound)
 362                                 while bound isa MNullableType do
 363                                         bound = retrieve_vt_bound(mclass.intro.bound_mtype, bound.mtype)
 364                                         is_null = 1
 365                                 end
 366                                 var vtclass = bound.as(MClassType).mclass
 367                                 v.require_declaration("class_{vtclass.c_name}")
 368                                 v.add_decl("\{{is_null}, &class_{vtclass.c_name}\}, /* {vt} */")
 369                         end
 370                 end
 371                 v.add_decl("\},")
 372                 v.add_decl("\};")
 373                 return true
 374         end
 375
 376         private fun retrieve_vt_bound(anchor: MClassType, mtype: nullable MType): MType do
 377                 if mtype == null then
 378                         print "NOT YET IMPLEMENTED: retrieve_vt_bound on null"
 379                         abort
 380                 end
 381                 if mtype isa MVirtualType then
 382                         return mtype.anchor_to(mainmodule, anchor)
 383                 else if mtype isa MParameterType then
 384                         return mtype.anchor_to(mainmodule, anchor)
 385                 else
 386                         return mtype
 387                 end
 388         end
 389
 390         redef fun new_visitor do return new SeparateErasureCompilerVisitor(self)
 391
 392         # Stats
 393
 394         private var class_tables: Map[MClass, Array[nullable MClass]]
 395         private var vt_tables: Map[MClass, Array[nullable MPropDef]]
 396
 397         redef fun display_sizes
 398         do
 399                 print "# size of subtyping tables"
 400                 print "\ttotal \tholes"
 401                 var total = 0
 402                 var holes = 0
 403                 for t, table in class_tables do
 404                         total += table.length
 405                         for e in table do if e == null then holes += 1
 406                 end
 407                 print "\t{total}\t{holes}"
 408
 409                 print "# size of resolution tables"
 410                 print "\ttotal \tholes"
 411                 total = 0
 412                 holes = 0
 413                 for t, table in vt_tables do
 414                         total += table.length
 415                         for e in table do if e == null then holes += 1
 416                 end
 417                 print "\t{total}\t{holes}"
 418
 419                 print "# size of methods tables"
 420                 print "\ttotal \tholes"
 421                 total = 0
 422                 holes = 0
 423                 for t, table in method_tables do
 424                         total += table.length
 425                         for e in table do if e == null then holes += 1
 426                 end
 427                 print "\t{total}\t{holes}"
 428
 429                 print "# size of attributes tables"
 430                 print "\ttotal \tholes"
 431                 total = 0
 432                 holes = 0
 433                 for t, table in attr_tables do
 434                         total += table.length
 435                         for e in table do if e == null then holes += 1
 436                 end
 437                 print "\t{total}\t{holes}"
 438         end
 439 end
 440
 441 class SeparateErasureCompilerVisitor
 442         super SeparateCompilerVisitor
 443
 444         redef fun compile_callsite(callsite, arguments)
 445         do
 446                 var res = super
 447                 if callsite.erasure_cast and not self.compiler.as(SeparateErasureCompiler).modelbuilder.toolcontext.opt_no_check_erasure_cast.value then
 448                         assert res != null
 449                         var mtype = callsite.msignature.return_mtype
 450                         assert mtype != null
 451                         self.add("/* Erasure cast for return {res} isa {mtype} */")
 452                         var cond = self.type_test(res, mtype, "erasure")
 453                         self.add("if (!{cond}) \{")
 454                         #var x = self.class_name_string(res)
 455                         #var y = self.class_name_string(arguments.first)
 456                         #self.add("fprintf(stderr, \"Erasure cast: expected {mtype} (self is %s), got %s for {res}\\n\", {y}, {x});")
 457                         self.add_abort("Cast failed")
 458                         self.add("\}")
 459                 end
 460                 return res
 461         end
 462
 463         redef fun init_instance(mtype)
 464         do
 465                 self.require_declaration("NEW_{mtype.mclass.c_name}")
 466                 return self.new_expr("NEW_{mtype.mclass.c_name}()", mtype)
 467         end
 468
 469         redef fun type_test(value, mtype, tag)
 470         do
 471                 self.add("/* type test for {value.inspect} isa {mtype} */")
 472
 473                 var res = self.new_var(bool_type)
 474
 475                 var cltype = self.get_name("cltype")
 476                 self.add_decl("int {cltype};")
 477                 var idtype = self.get_name("idtype")
 478                 self.add_decl("int {idtype};")
 479
 480                 var maybe_null = self.maybe_null(value)
 481                 var accept_null = "0"
 482                 if mtype isa MNullableType then
 483                         mtype = mtype.mtype
 484                         accept_null = "1"
 485                 end
 486                 if mtype isa MParameterType then
 487                         # Here we get the bound of the the formal type (eh, erasure...)
 488                         mtype = mtype.resolve_for(self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.mmodule, false)
 489                         if mtype isa MNullableType then
 490                                 mtype = mtype.mtype
 491                                 accept_null = "1"
 492                         end
 493                 end
 494
 495                 if value.mcasttype.is_subtype(self.frame.mpropdef.mclassdef.mmodule, self.frame.mpropdef.mclassdef.bound_mtype, mtype) then
 496                         self.add("{res} = 1; /* easy {value.inspect} isa {mtype}*/")
 497                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 498                                 self.compiler.count_type_test_skipped[tag] += 1
 499                                 self.add("count_type_test_skipped_{tag}++;")
 500                         end
 501                         return res
 502                 end
 503
 504                 var class_ptr
 505                 var type_table
 506                 if value.mtype.ctype == "val*" then
 507                         class_ptr = "{value}->class->"
 508                 else
 509                         var mclass = value.mtype.as(MClassType).mclass
 510                         self.require_declaration("class_{mclass.c_name}")
 511                         class_ptr = "class_{mclass.c_name}."
 512                 end
 513
 514                 if mtype isa MClassType then
 515                         self.require_declaration("class_{mtype.mclass.c_name}")
 516                         self.add("{cltype} = class_{mtype.mclass.c_name}.color;")
 517                         self.add("{idtype} = class_{mtype.mclass.c_name}.id;")
 518                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 519                                 self.compiler.count_type_test_resolved[tag] += 1
 520                                 self.add("count_type_test_resolved_{tag}++;")
 521                         end
 522                 else if mtype isa MVirtualType then
 523                         var recv = self.frame.arguments.first
 524                         var recv_ptr
 525                         if recv.mtype.ctype == "val*" then
 526                                 recv_ptr = "{recv}->class->"
 527                         else
 528                                 var mclass = recv.mtype.as(MClassType).mclass
 529                                 self.require_declaration("class_{mclass.c_name}")
 530                                 recv_ptr = "class_{mclass.c_name}."
 531                         end
 532                         var entry = self.get_name("entry")
 533                         self.add("struct vts_entry {entry};")
 534                         self.require_declaration(mtype.mproperty.const_color)
 535                         if self.compiler.as(SeparateErasureCompiler).vt_layout isa PHLayout[MClass, MVirtualTypeProp] then
 536                                 self.add("{entry} = {recv_ptr}vts_table->vts[HASH({recv_ptr}vts_table->mask, {mtype.mproperty.const_color})];")
 537                         else
 538                                 self.add("{entry} = {recv_ptr}vts_table->vts[{mtype.mproperty.const_color}];")
 539                         end
 540                         self.add("{cltype} = {entry}.class->color;")
 541                         self.add("{idtype} = {entry}.class->id;")
 542                         if maybe_null and accept_null == "0" then
 543                                 var is_nullable = self.get_name("is_nullable")
 544                                 self.add_decl("short int {is_nullable};")
 545                                 self.add("{is_nullable} = {entry}.is_nullable;")
 546                                 accept_null = is_nullable.to_s
 547                         end
 548                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 549                                 self.compiler.count_type_test_unresolved[tag] += 1
 550                                 self.add("count_type_test_unresolved_{tag}++;")
 551                         end
 552                 else
 553                         self.debug("type_test({value.inspect}, {mtype})")
 554                         abort
 555                 end
 556
 557                 # check color is in table
 558                 if maybe_null then
 559                         self.add("if({value} == NULL) \{")
 560                         self.add("{res} = {accept_null};")
 561                         self.add("\} else \{")
 562                 end
 563                 if self.compiler.as(SeparateErasureCompiler).class_layout isa PHLayout[MClass, MClass] then
 564                         self.add("{cltype} = HASH({class_ptr}color, {idtype});")
 565                 end
 566                 self.add("if({cltype} >= {class_ptr}type_table->size) \{")
 567                 self.add("{res} = 0;")
 568                 self.add("\} else \{")
 569                 self.add("{res} = {class_ptr}type_table->table[{cltype}] == {idtype};")
 570                 self.add("\}")
 571                 if maybe_null then
 572                         self.add("\}")
 573                 end
 574
 575                 return res
 576         end
 577
 578         redef fun class_name_string(value)
 579         do
 580                 var res = self.get_name("var_class_name")
 581                 self.add_decl("const char* {res};")
 582                 if value.mtype.ctype == "val*" then
 583                         self.add "{res} = {value} == NULL ? \"null\" : {value}->class->name;"
 584                 else
 585                         self.require_declaration("class_{value.mtype.c_name}")
 586                         self.add "{res} = class_{value.mtype.c_name}.name;"
 587                 end
 588                 return res
 589         end
 590
 591         redef fun array_instance(array, elttype)
 592         do
 593                 var nclass = self.get_class("NativeArray")
 594                 elttype = self.anchor(elttype)
 595                 var arraytype = self.get_class("Array").get_mtype([elttype])
 596                 var res = self.init_instance(arraytype)
 597                 self.add("\{ /* {res} = array_instance Array[{elttype}] */")
 598                 var nat = self.new_var(self.get_class("NativeArray").get_mtype([elttype]))
 599                 nat.is_exact = true
 600                 self.require_declaration("NEW_{nclass.c_name}")
 601                 self.add("{nat} = NEW_{nclass.c_name}({array.length});")
 602                 for i in [0..array.length[ do
 603                         var r = self.autobox(array[i], self.object_type)
 604                         self.add("((struct instance_{nclass.c_instance_name}*){nat})->values[{i}] = (val*) {r};")
 605                 end
 606                 var length = self.int_instance(array.length)
 607                 self.send(self.get_property("with_native", arraytype), [res, nat, length])
 608                 self.add("\}")
 609                 return res
 610         end
 611
 612         redef fun calloc_array(ret_type, arguments)
 613         do
 614                 var ret = ret_type.as(MClassType)
 615                 self.require_declaration("NEW_{ret.mclass.c_name}")
 616                 self.ret(self.new_expr("NEW_{ret.mclass.c_name}({arguments[1]})", ret_type))
 617         end
 618 end