src/model/model_base.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # The abstract concept of model and related common things
  18 module model_base
  19
  20 # The container class of a Nit object-oriented model.
  21 # A model knows modules, classes and properties and can retrieve them.
  22 class Model
  23 end
  24
  25 # A named and possibly documented entity in the model.
  26 # This class is useful to generalize presentation of entities to the human.
  27 abstract class MEntity
  28         # The short (unqualified) name of this model entity.
  29         #
  30         # The short-name is based from the identifiers used to declare or denote the entity.
  31         # It is usually globally ambiguous but is often enough in a precise local context.
  32         #
  33         # It is suitable to use the short-name in message to the user.
  34         # However, special care must be used in case of potential ambiguities or name conflict.
  35         fun name: String is abstract
  36
  37         # A fully-qualified name of this model entity.
  38         #
  39         # The full-name is based on the short name and is usually prefixed by the name of an outer entity.
  40         # Usually the quad (`::`) is used to separate the different names.
  41         #
  42         # The full-name is expected to be unique and unambiguous in lawful Nit models for the same kind of entity.
  43         #
  44         # It is often suitable to use it in message to the user.
  45         # However, some full-name could be long and verbose,
  46         #
  47         # See the specific implementation in subclasses for details.
  48         fun full_name: String is abstract
  49
  50         # A fully-qualified C-like identifier of this model entity.
  51         #
  52         # The C-name is a name that respects the rule of identifiers in the C language:
  53         # it is only made of alphanumeric characters and starts with a letter (or a underscore).
  54         #
  55         # The C-name can be seen as a mangled version of the `full_name`.
  56         # Therefore, it is expected to be unique and unambiguous in lawful Nit models for the same kind of entity.
  57         #
  58         # The C-name is used by tools that need some identifiers in generated files to designate the
  59         # entity.
  60         #
  61         # Is is not suitable to use it directly with the user (e.g. in message) and
  62         # indirect use should be restricted (e.g. to name a web-page)
  63         fun c_name: String is abstract
  64
  65         # A Model Entity has a direct link to its model
  66         fun model: Model is abstract
  67 end
  68
  69 # Something that represents a concern
  70 abstract class MConcern
  71         super MEntity
  72         # The concern that contains `self` or null if `self` is the root of the concern hierarchy
  73         fun parent_concern: nullable MConcern is abstract
  74 end
  75
  76 # A visibility (for modules, class and properties)
  77 # Valid visibility are:
  78 #
  79 #  * `intrude_visibility`
  80 #  * `public_visibility`
  81 #  * `protected_visibility`
  82 #  * `none_visibility`
  83 #  * `private_visiblity`
  84 #
  85 # Note this class is basically an enum.
  86 # FIXME: use a real enum once user-defined enums are available
  87 class MVisibility
  88         super Comparable
  89         redef type OTHER: MVisibility
  90
  91         redef var to_s: String
  92
  93         private var level: Int
  94
  95         # TODO: private init because enumeration.
  96
  97         # Is self give less visibility than other
  98         # none < private < protected < public < intrude
  99         redef fun <(other)
 100         do
 101                 return self.level < other.level
 102         end
 103 end
 104
 105 # The visibility level `intrude`
 106 fun intrude_visibility: MVisibility do return once new MVisibility("intrude", 5)
 107 # The visibility level `public`
 108 fun public_visibility: MVisibility do return once new MVisibility("public", 4)
 109 # The visibility level `protected`
 110 fun protected_visibility: MVisibility do return once new MVisibility("protected", 3)
 111 # The visibility level `private`
 112 fun private_visibility: MVisibility do return once new MVisibility("private", 2)
 113 # The visibility level `none` (no visibility)
 114 fun none_visibility: MVisibility do return once new MVisibility("none", 1)