lib/standard/file.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2004-2008 Jean Privat <jean@pryen.org>
   4 # Copyright 2008 Floréal Morandat <morandat@lirmm.fr>
   5 # Copyright 2008 Jean-Sébastien Gélinas <calestar@gmail.com>
   6 #
   7 # This file is free software, which comes along with NIT.  This software is
   8 # distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
   9 # without  even  the implied warranty of  MERCHANTABILITY or  FITNESS FOR A
  10 # PARTICULAR PURPOSE.  You can modify it is you want,  provided this header
  11 # is kept unaltered, and a notification of the changes is added.
  12 # You  are  allowed  to  redistribute it and sell it, alone or is a part of
  13 # another product.
  14
  15 # File manipulations (create, read, write, etc.)
  16 module file
  17
  18 intrude import stream
  19 intrude import ropes
  20 import string_search
  21 import time
  22
  23 in "C Header" `{
  24         #include <dirent.h>
  25         #include <string.h>
  26         #include <sys/types.h>
  27         #include <sys/stat.h>
  28         #include <unistd.h>
  29 `}
  30
  31 # File Abstract Stream
  32 abstract class FStream
  33         super IOS
  34         # The path of the file.
  35         var path: nullable String = null
  36
  37         # The FILE *.
  38         var _file: nullable NativeFile = null
  39
  40         fun file_stat: FileStat
  41         do return _file.file_stat end
  42 end
  43
  44 # File input stream
  45 class IFStream
  46         super FStream
  47         super BufferedIStream
  48         # Misc
  49
  50         # Open the same file again.
  51         # The original path is reused, therefore the reopened file can be a different file.
  52         fun reopen
  53         do
  54                 if not eof then close
  55                 _file = new NativeFile.io_open_read(path.to_cstring)
  56                 end_reached = false
  57                 _buffer_pos = 0
  58                 _buffer.clear
  59         end
  60
  61         redef fun close
  62         do
  63                 var i = _file.io_close
  64                 end_reached = true
  65         end
  66
  67         redef fun fill_buffer
  68         do
  69                 var nb = _file.io_read(_buffer.items, _buffer.capacity)
  70                 if nb <= 0 then
  71                         end_reached = true
  72                         nb = 0
  73                 end
  74                 _buffer.length = nb
  75                 _buffer_pos = 0
  76         end
  77
  78         # End of file?
  79         redef var end_reached: Bool = false
  80
  81         # Open the file at `path` for reading.
  82         init open(path: String)
  83         do
  84                 self.path = path
  85                 prepare_buffer(10)
  86                 _file = new NativeFile.io_open_read(path.to_cstring)
  87                 assert not _file.address_is_null else
  88                         print "Error: Opening file at '{path}' failed with '{sys.errno.strerror}'"
  89                 end
  90         end
  91
  92         private init do end
  93         private init without_file do end
  94 end
  95
  96 # File output stream
  97 class OFStream
  98         super FStream
  99         super OStream
 100
 101         redef fun write(s)
 102         do
 103                 assert _writable
 104                 if s isa FlatText then
 105                         write_native(s.to_cstring, s.length)
 106                 else
 107                         for i in s.substrings do write_native(i.to_cstring, i.length)
 108                 end
 109         end
 110
 111         redef fun is_writable do return _writable
 112
 113         redef fun close
 114         do
 115                 var i = _file.io_close
 116                 _writable = false
 117         end
 118
 119         # Is the file open in write mode
 120         var _writable: Bool
 121
 122         # Write `len` bytes from `native`.
 123         private fun write_native(native: NativeString, len: Int)
 124         do
 125                 assert _writable
 126                 var err = _file.io_write(native, len)
 127                 if err != len then
 128                         # Big problem
 129                         printn("Problem in writing : ", err, " ", len, "\n")
 130                 end
 131         end
 132
 133         # Open the file at `path` for writing.
 134         init open(path: String)
 135         do
 136                 _file = new NativeFile.io_open_write(path.to_cstring)
 137                 assert not _file.address_is_null else
 138                         print "Error: Opening file at '{path}' failed with '{sys.errno.strerror}'"
 139                 end
 140                 self.path = path
 141                 _writable = true
 142         end
 143
 144         private init do end
 145         private init without_file do end
 146 end
 147
 148 ###############################################################################
 149
 150 class Stdin
 151         super IFStream
 152         super PollableIStream
 153
 154         private init do
 155                 _file = new NativeFile.native_stdin
 156                 path = "/dev/stdin"
 157                 prepare_buffer(1)
 158         end
 159
 160         redef fun poll_in: Bool is extern "file_stdin_poll_in"
 161 end
 162
 163 class Stdout
 164         super OFStream
 165         private init do
 166                 _file = new NativeFile.native_stdout
 167                 path = "/dev/stdout"
 168                 _writable = true
 169         end
 170 end
 171
 172 class Stderr
 173         super OFStream
 174         private init do
 175                 _file = new NativeFile.native_stderr
 176                 path = "/dev/stderr"
 177                 _writable = true
 178         end
 179 end
 180
 181 ###############################################################################
 182
 183 redef class Streamable
 184         # Like `write_to` but take care of creating the file
 185         fun write_to_file(filepath: String)
 186         do
 187                 var stream = new OFStream.open(filepath)
 188                 write_to(stream)
 189                 stream.close
 190         end
 191 end
 192
 193 redef class String
 194         # return true if a file with this names exists
 195         fun file_exists: Bool do return to_cstring.file_exists
 196
 197         # The status of a file. see POSIX stat(2).
 198         fun file_stat: FileStat do return to_cstring.file_stat
 199
 200         # The status of a file or of a symlink. see POSIX lstat(2).
 201         fun file_lstat: FileStat do return to_cstring.file_lstat
 202
 203         # Remove a file, return true if success
 204         fun file_delete: Bool do return to_cstring.file_delete
 205
 206         # Copy content of file at `self` to `dest`
 207         fun file_copy_to(dest: String)
 208         do
 209                 var input = new IFStream.open(self)
 210                 var output = new OFStream.open(dest)
 211
 212                 while not input.eof do
 213                         var buffer = input.read(1024)
 214                         output.write buffer
 215                 end
 216
 217                 input.close
 218                 output.close
 219         end
 220
 221         # Remove the trailing extension `ext`.
 222         #
 223         # `ext` usually starts with a dot but could be anything.
 224         #
 225         #     assert "file.txt".strip_extension(".txt")  == "file"
 226         #     assert "file.txt".strip_extension("le.txt")  == "fi"
 227         #     assert "file.txt".strip_extension("xt")  == "file.t"
 228         #
 229         # if `ext` is not present, `self` is returned unmodified.
 230         #
 231         #     assert "file.txt".strip_extension(".tar.gz")  == "file.txt"
 232         fun strip_extension(ext: String): String
 233         do
 234                 if has_suffix(ext) then
 235                         return substring(0, length - ext.length)
 236                 end
 237                 return self
 238         end
 239
 240         # Extract the basename of a path and remove the extension
 241         #
 242         #     assert "/path/to/a_file.ext".basename(".ext")         == "a_file"
 243         #     assert "path/to/a_file.ext".basename(".ext")          == "a_file"
 244         #     assert "path/to".basename(".ext")                     == "to"
 245         #     assert "path/to/".basename(".ext")                    == "to"
 246         #     assert "path".basename("")                        == "path"
 247         #     assert "/path".basename("")                       == "path"
 248         #     assert "/".basename("")                           == "/"
 249         #     assert "".basename("")                            == ""
 250         fun basename(ext: String): String
 251         do
 252                 var l = length - 1 # Index of the last char
 253                 while l > 0 and self.chars[l] == '/' do l -= 1 # remove all trailing `/`
 254                 if l == 0 then return "/"
 255                 var pos = chars.last_index_of_from('/', l)
 256                 var n = self
 257                 if pos >= 0 then
 258                         n = substring(pos+1, l-pos)
 259                 end
 260                 return n.strip_extension(ext)
 261         end
 262
 263         # Extract the dirname of a path
 264         #
 265         #     assert "/path/to/a_file.ext".dirname         == "/path/to"
 266         #     assert "path/to/a_file.ext".dirname          == "path/to"
 267         #     assert "path/to".dirname                     == "path"
 268         #     assert "path/to/".dirname                    == "path"
 269         #     assert "path".dirname                        == "."
 270         #     assert "/path".dirname                       == "/"
 271         #     assert "/".dirname                           == "/"
 272         #     assert "".dirname                            == "."
 273         fun dirname: String
 274         do
 275                 var l = length - 1 # Index of the last char
 276                 while l > 0 and self.chars[l] == '/' do l -= 1 # remove all trailing `/`
 277                 var pos = chars.last_index_of_from('/', l)
 278                 if pos > 0 then
 279                         return substring(0, pos)
 280                 else if pos == 0 then
 281                         return "/"
 282                 else
 283                         return "."
 284                 end
 285         end
 286
 287         # Return the canonicalized absolute pathname (see POSIX function `realpath`)
 288         fun realpath: String do
 289                 var cs = to_cstring.file_realpath
 290                 var res = cs.to_s_with_copy
 291                 # cs.free_malloc # FIXME memory leak
 292                 return res
 293         end
 294
 295         # Simplify a file path by remove useless ".", removing "//", and resolving ".."
 296         # ".." are not resolved if they start the path
 297         # starting "/" is not removed
 298         # trainling "/" is removed
 299         #
 300         # Note that the method only wonrk on the string:
 301         #  * no I/O access is performed
 302         #  * the validity of the path is not checked
 303         #
 304         #     assert "some/./complex/../../path/from/../to/a////file//".simplify_path        ==  "path/to/a/file"
 305         #     assert "../dir/file".simplify_path       ==  "../dir/file"
 306         #     assert "dir/../../".simplify_path        ==  ".."
 307         #     assert "dir/..".simplify_path            ==  "."
 308         #     assert "//absolute//path/".simplify_path ==  "/absolute/path"
 309         fun simplify_path: String
 310         do
 311                 var a = self.split_with("/")
 312                 var a2 = new Array[String]
 313                 for x in a do
 314                         if x == "." then continue
 315                         if x == "" and not a2.is_empty then continue
 316                         if x == ".." and not a2.is_empty and a2.last != ".." then
 317                                 a2.pop
 318                                 continue
 319                         end
 320                         a2.push(x)
 321                 end
 322                 if a2.is_empty then return "."
 323                 return a2.join("/")
 324         end
 325
 326         # Correctly join two path using the directory separator.
 327         #
 328         # Using a standard "{self}/{path}" does not work when `self` is the empty string.
 329         # This method ensure that the join is valid.
 330         #
 331         #     assert "hello".join_path("world")      ==  "hello/world"
 332         #     assert "hel/lo".join_path("wor/ld")      ==  "hel/lo/wor/ld"
 333         #     assert "".join_path("world")      ==  "world"
 334         #     assert "/hello".join_path("/world")      ==  "/world"
 335         #
 336         # Note: you may want to use `simplify_path` on the result
 337         #
 338         # Note: I you want to join a great number of path, you can write
 339         #
 340         #     [p1, p2, p3, p4].join("/")
 341         fun join_path(path: String): String
 342         do
 343                 if path.is_empty then return self
 344                 if self.is_empty then return path
 345                 if path.chars[0] == '/' then return path
 346                 return "{self}/{path}"
 347         end
 348
 349         # Create a directory (and all intermediate directories if needed)
 350         fun mkdir
 351         do
 352                 var dirs = self.split_with("/")
 353                 var path = new FlatBuffer
 354                 if dirs.is_empty then return
 355                 if dirs[0].is_empty then
 356                         # it was a starting /
 357                         path.add('/')
 358                 end
 359                 for d in dirs do
 360                         if d.is_empty then continue
 361                         path.append(d)
 362                         path.add('/')
 363                         path.to_s.to_cstring.file_mkdir
 364                 end
 365         end
 366
 367         # Delete a directory and all of its content, return `true` on success
 368         #
 369         # Does not go through symbolic links and may get stuck in a cycle if there
 370         # is a cycle in the filesystem.
 371         fun rmdir: Bool
 372         do
 373                 var ok = true
 374                 for file in self.files do
 375                         var file_path = self.join_path(file)
 376                         var stat = file_path.file_lstat
 377                         if stat.is_dir then
 378                                 ok = file_path.rmdir and ok
 379                         else
 380                                 ok = file_path.file_delete and ok
 381                         end
 382                         stat.free
 383                 end
 384
 385                 # Delete the directory itself
 386                 if ok then to_cstring.rmdir
 387
 388                 return ok
 389         end
 390
 391         # Change the current working directory
 392         #
 393         #     "/etc".chdir
 394         #     assert getcwd == "/etc"
 395         #     "..".chdir
 396         #     assert getcwd == "/"
 397         #
 398         # TODO: errno
 399         fun chdir do to_cstring.file_chdir
 400
 401         # Return right-most extension (without the dot)
 402         #
 403         # Only the last extension is returned.
 404         # There is no special case for combined extensions.
 405         #
 406         #     assert "file.txt".file_extension      == "txt"
 407         #     assert "file.tar.gz".file_extension   == "gz"
 408         #
 409         # For file without extension, `null` is returned.
 410         # Hoever, for trailing dot, `""` is returned.
 411         #
 412         #     assert "file".file_extension          == null
 413         #     assert "file.".file_extension         == ""
 414         #
 415         # The starting dot of hidden files is never considered.
 416         #
 417         #     assert ".file.txt".file_extension     == "txt"
 418         #     assert ".file".file_extension         == null
 419         fun file_extension: nullable String
 420         do
 421                 var last_slash = chars.last_index_of('.')
 422                 if last_slash > 0 then
 423                         return substring( last_slash+1, length )
 424                 else
 425                         return null
 426                 end
 427         end
 428
 429         # returns files contained within the directory represented by self
 430         fun files : Set[ String ] is extern import HashSet[String], HashSet[String].add, NativeString.to_s, String.to_cstring, HashSet[String].as(Set[String]) `{
 431                 char *dir_path;
 432                 DIR *dir;
 433
 434                 dir_path = String_to_cstring( recv );
 435                 if ((dir = opendir(dir_path)) == NULL)
 436                 {
 437                         perror( dir_path );
 438                         exit( 1 );
 439                 }
 440                 else
 441                 {
 442                         HashSet_of_String results;
 443                         String file_name;
 444                         struct dirent *de;
 445
 446                         results = new_HashSet_of_String();
 447
 448                         while ( ( de = readdir( dir ) ) != NULL )
 449                                 if ( strcmp( de->d_name, ".." ) != 0 &&
 450                                         strcmp( de->d_name, "." ) != 0 )
 451                                 {
 452                                         file_name = NativeString_to_s( strdup( de->d_name ) );
 453                                         HashSet_of_String_add( results, file_name );
 454                                 }
 455
 456                         closedir( dir );
 457                         return HashSet_of_String_as_Set_of_String( results );
 458                 }
 459         `}
 460 end
 461
 462 redef class NativeString
 463         private fun file_exists: Bool is extern "string_NativeString_NativeString_file_exists_0"
 464         private fun file_stat: FileStat is extern "string_NativeString_NativeString_file_stat_0"
 465         private fun file_lstat: FileStat `{
 466                 struct stat* stat_element;
 467                 int res;
 468                 stat_element = malloc(sizeof(struct stat));
 469                 res = lstat(recv, stat_element);
 470                 if (res == -1) return NULL;
 471                 return stat_element;
 472         `}
 473         private fun file_mkdir: Bool is extern "string_NativeString_NativeString_file_mkdir_0"
 474         private fun rmdir: Bool `{ return rmdir(recv); `}
 475         private fun file_delete: Bool is extern "string_NativeString_NativeString_file_delete_0"
 476         private fun file_chdir is extern "string_NativeString_NativeString_file_chdir_0"
 477         private fun file_realpath: NativeString is extern "file_NativeString_realpath"
 478 end
 479
 480 # This class is system dependent ... must reify the vfs
 481 extern class FileStat `{ struct stat * `}
 482         # Returns the permission bits of file
 483         fun mode: Int is extern "file_FileStat_FileStat_mode_0"
 484         # Returns the last access time
 485         fun atime: Int is extern "file_FileStat_FileStat_atime_0"
 486         # Returns the last status change time
 487         fun ctime: Int is extern "file_FileStat_FileStat_ctime_0"
 488         # Returns the last modification time
 489         fun mtime: Int is extern "file_FileStat_FileStat_mtime_0"
 490         # Returns the size
 491         fun size: Int is extern "file_FileStat_FileStat_size_0"
 492
 493         # Returns true if it is a regular file (not a device file, pipe, sockect, ...)
 494         fun is_reg: Bool `{ return S_ISREG(recv->st_mode); `}
 495         # Returns true if it is a directory
 496         fun is_dir: Bool `{ return S_ISDIR(recv->st_mode); `}
 497         # Returns true if it is a character device
 498         fun is_chr: Bool `{ return S_ISCHR(recv->st_mode); `}
 499         # Returns true if it is a block device
 500         fun is_blk: Bool `{ return S_ISBLK(recv->st_mode); `}
 501         # Returns true if the type is fifo
 502         fun is_fifo: Bool `{ return S_ISFIFO(recv->st_mode); `}
 503         # Returns true if the type is a link
 504         fun is_lnk: Bool `{ return S_ISLNK(recv->st_mode); `}
 505         # Returns true if the type is a socket
 506         fun is_sock: Bool `{ return S_ISSOCK(recv->st_mode); `}
 507 end
 508
 509 # Instance of this class are standard FILE * pointers
 510 private extern class NativeFile `{ FILE* `}
 511         fun io_read(buf: NativeString, len: Int): Int is extern "file_NativeFile_NativeFile_io_read_2"
 512         fun io_write(buf: NativeString, len: Int): Int is extern "file_NativeFile_NativeFile_io_write_2"
 513         fun io_close: Int is extern "file_NativeFile_NativeFile_io_close_0"
 514         fun file_stat: FileStat is extern "file_NativeFile_NativeFile_file_stat_0"
 515
 516         new io_open_read(path: NativeString) is extern "file_NativeFileCapable_NativeFileCapable_io_open_read_1"
 517         new io_open_write(path: NativeString) is extern "file_NativeFileCapable_NativeFileCapable_io_open_write_1"
 518         new native_stdin is extern "file_NativeFileCapable_NativeFileCapable_native_stdin_0"
 519         new native_stdout is extern "file_NativeFileCapable_NativeFileCapable_native_stdout_0"
 520         new native_stderr is extern "file_NativeFileCapable_NativeFileCapable_native_stderr_0"
 521 end
 522
 523 redef class Sys
 524
 525         # Standard input
 526         var stdin: PollableIStream protected writable = new Stdin
 527
 528         # Standard output
 529         var stdout: OStream protected writable = new Stdout
 530
 531         # Standard output for errors
 532         var stderr: OStream protected writable = new Stderr
 533
 534 end
 535
 536 # Print `objects` on the standard output (`stdout`).
 537 protected fun printn(objects: Object...)
 538 do
 539         sys.stdout.write(objects.to_s)
 540 end
 541
 542 # Print an `object` on the standard output (`stdout`) and add a newline.
 543 protected fun print(object: Object)
 544 do
 545         sys.stdout.write(object.to_s)
 546         sys.stdout.write("\n")
 547 end
 548
 549 # Read a character from the standard input (`stdin`).
 550 protected fun getc: Char
 551 do
 552         return sys.stdin.read_char.ascii
 553 end
 554
 555 # Read a line from the standard input (`stdin`).
 556 protected fun gets: String
 557 do
 558         return sys.stdin.read_line
 559 end
 560
 561 # Return the working (current) directory
 562 protected fun getcwd: String do return file_getcwd.to_s
 563 private fun file_getcwd: NativeString is extern "string_NativeString_NativeString_file_getcwd_0"