src/nitni/nitni_base.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Native interface related services (used underneath the FFI)
  18 #
  19 # All nitni properties may not be visible to the user but they are
  20 # shared between engines
  21 module nitni_base
  22
  23 import parser
  24 import modelbuilder # builder only for externcalls
  25
  26 redef class MMethod
  27         # Short name of this method in C (without the class name)
  28         fun short_cname: String do
  29                 var nit_name = name
  30
  31                 if nit_name == "+" then return "_plus"
  32                 if nit_name == "-" then return "_minus"
  33                 if nit_name == "unary -" then return "_unary_minus"
  34                 if nit_name == "*" then return "_star"
  35                 if nit_name == "/" then return "_slash"
  36                 if nit_name == "%" then return "_percent"
  37                 if nit_name == "[]" then return "_index"
  38                 if nit_name == "[]=" then return "_index_assign"
  39                 if nit_name == "==" then return "_equal"
  40                 if nit_name == "<" then return "_less"
  41                 if nit_name == ">" then return "_geater"
  42                 if nit_name == "<=" then return "_less_or_equal"
  43                 if nit_name == ">=" then return "_greater_or_equal"
  44                 if nit_name == "!=" then return "_not_equal"
  45                 if nit_name == "<<" then return "_left"
  46                 if nit_name == ">>" then return "_right"
  47                 if nit_name == "<=>" then return "_starship"
  48
  49                 if nit_name.chars.last == '=' then return "{nit_name.substring(0, nit_name.length-1)}__assign"
  50                 return nit_name
  51         end
  52 end
  53
  54 redef class MMethodDef
  55         # Name of the function to callback this method from C,
  56         # also used in other functions names used for this method.
  57         fun cname: String do return "{mclassdef.mclass.name}_{mproperty.short_cname}"
  58 end
  59
  60 redef class MType
  61         # Representation of this type in pure C on the FFI extern side
  62         #   Object -> Object
  63         #   Pointer -> void*
  64         fun cname: String is abstract
  65
  66         # Representation of this type in C for the internal of the system
  67         # Hides extern types.
  68         fun cname_blind: String is abstract
  69
  70         # Representation of this type in mangled C
  71         #   Object -> Object
  72         #   Pointer -> Pointer
  73         fun mangled_cname: String is abstract
  74
  75         # Does this types has a primitive reprensentation
  76         #   type Object is_primitive? false
  77         #   type Pointer is_primitive? true
  78         fun is_cprimitive: Bool is abstract
  79 end
  80
  81 redef class MClassType
  82         redef fun cname
  83         do
  84                 var name = mclass.name
  85                 if name == "Bool" then return "int"
  86                 if name == "Char" then return "char"
  87                 if name == "Float" then return "double"
  88                 if name == "Int" then return "long"
  89                 if name == "NativeString" then return "char*"
  90                 if mclass.kind == extern_kind then
  91                         var ctype = mclass.ctype
  92                         assert ctype != null
  93                         return ctype
  94                 end
  95                 return mangled_cname
  96         end
  97
  98         redef fun cname_blind do
  99                 var name = mclass.name
 100                 if name == "Bool" then return "int"
 101                 if name == "Char" then return "char"
 102                 if name == "Float" then return "double"
 103                 if name == "Int" then return "long"
 104                 if name == "NativeString" then return "char*"
 105                 if mclass.kind == extern_kind then return "void*"
 106                 return "struct nitni_instance *"
 107         end
 108
 109         redef fun mangled_cname do return mclass.name
 110
 111         redef fun is_cprimitive do return mclass.kind == extern_kind or
 112                         (once ["Bool", "Char", "Float", "Int", "NativeString"]).has(mclass.name)
 113 end
 114
 115 redef class MNullableType
 116         redef fun cname do return mangled_cname
 117         redef fun cname_blind do return "struct nitni_instance *"
 118         redef fun mangled_cname do return "nullable_{mtype.mangled_cname}"
 119         redef fun is_cprimitive do return false
 120 end
 121
 122 redef class MVirtualType
 123         redef fun mangled_cname: String do return to_s
 124 end
 125
 126 redef class MGenericType
 127         redef fun cname do return mangled_cname
 128         redef fun mangled_cname
 129         do
 130                 var base = super
 131
 132                 var params = new Array[String]
 133                 for arg in arguments do params.add(arg.mangled_cname)
 134
 135                 return "{base}_of_{params.join("_")}"
 136         end
 137 end
 138
 139 redef class MClass
 140         fun ctype: nullable String
 141         do
 142                 assert kind == extern_kind
 143                 return "void*"
 144         end
 145 end