src/nitc.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2008 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Nit compiler main module
  18 package nitc
  19
  20 import abstracttool
  21 import analysis
  22 import program
  23 private import compiling
  24 private import syntax
  25
  26 # The main class of the nitcompiler program
  27 class NitCompiler
  28 special AbstractCompiler
  29         readable var _opt_output: OptionString = new OptionString("Output file", "-o", "--output")
  30         readable var _opt_boost: OptionBool = new OptionBool("Optimize compilation", "-O", "--boost")
  31         readable var _opt_no_cc: OptionBool = new OptionBool("Do not invoke C compiler", "--no_cc")
  32         readable var _opt_global: OptionBool = new OptionBool("Use global compilation", "--global")
  33         readable var _opt_global_no_STF_opt: OptionBool = new OptionBool("Do not use SFT optimization", "--no-global-SFT-optimization")
  34         readable var _opt_clibdir: OptionString = new OptionString("NIT C library directory", "--clibdir")
  35         readable var _opt_bindir: OptionString = new OptionString("NIT tools directory", "--bindir")
  36         readable var _opt_compdir: OptionString = new OptionString("Intermediate compilation directory", "--compdir")
  37         readable var _opt_extension_prefix: OptionString = new OptionString("Append prefix to file extension", "-p", "--extension-prefix")
  38         readable var _opt_dump: OptionBool = new OptionBool("Dump intermediate code", "--dump")
  39
  40         init
  41         do
  42                 super("nitc")
  43                 option_context.add_option(opt_output, opt_boost, opt_no_cc, opt_global, opt_clibdir, opt_bindir, opt_compdir, opt_extension_prefix, opt_dump, opt_global_no_STF_opt)
  44         end
  45
  46         redef fun process_options
  47         do
  48                 super
  49                 output_file = opt_output.value
  50                 boost = opt_boost.value
  51                 no_cc = opt_no_cc.value
  52                 var ext = opt_extension_prefix.value
  53                 if ext != null then ext_prefix = ext else ext_prefix = ""
  54                 global = opt_global.value
  55                 use_SFT_optimization = not opt_global_no_STF_opt.value
  56                 compdir = opt_compdir.value
  57                 if compdir == null then
  58                         var dir = once ("NIT_COMPDIR".to_symbol).environ
  59                         if not dir.is_empty then
  60                                 compdir = dir
  61                         end
  62                         if compdir == null then
  63                                 compdir = ".nit_compile"
  64                         end
  65                 end
  66                 compdir += ext_prefix
  67
  68                 clibdir = opt_clibdir.value
  69                 if clibdir == null then
  70                         var dir = once ("NIT_DIR".to_symbol).environ
  71                         if dir.is_empty then
  72                                 dir = "{sys.program_name.dirname}/../clib"
  73                                 if dir.file_exists then clibdir = dir
  74                         else
  75                                 dir = "{dir}/clib"
  76                                 if dir.file_exists then clibdir = dir
  77                         end
  78                         if clibdir == null then
  79                                 fatal_error(null, "Error: Cannot locate NIT C library directory. Uses --clibdir or envvar NIT_DIR.")
  80                         end
  81                 end
  82                 bindir = opt_bindir.value
  83
  84                 if bindir == null then
  85                         var dir = once ("NIT_DIR".to_symbol).environ
  86                         if dir.is_empty then
  87                                 dir = "{sys.program_name.dirname}/../bin"
  88                                 if dir.file_exists then bindir = dir
  89                         else
  90                                 dir = "{dir}/bin"
  91                                 if dir.file_exists then bindir = dir
  92                         end
  93                         if bindir == null then
  94                                 fatal_error(null, "Error: Cannot locate NIT tools directory. Uses --bindir or envvar NIT_DIR.")
  95                         end
  96                 end
  97         end
  98
  99         fun dump_intermediate_code(mods: Collection[MMModule])
 100         do
 101                 for mod in mods do
 102                         for c in mod.local_classes do
 103                                 if not c isa MMConcreteClass then continue
 104                                 for p in c.local_local_properties do
 105                                         var routine: nullable IRoutine = null
 106                                         if p isa MMAttribute then
 107                                                 routine = p.iroutine
 108                                         else if p isa MMMethod then
 109                                                 routine = p.iroutine
 110                                         end
 111                                         if routine == null then continue
 112                                         print "**** Property {p.full_name} ****"
 113                                         var icd = new ICodeDumper
 114                                         routine.dump(icd)
 115                                         print "**** OPTIMIZE {p.full_name} ****"
 116                                         routine.optimize(mod)
 117                                         icd = new ICodeDumper
 118                                         routine.dump(icd)
 119                                 end
 120                         end
 121                 end
 122         end
 123
 124         redef fun perform_work(mods)
 125         do
 126                 if opt_dump.value then
 127                         dump_intermediate_code(mods)
 128                 end
 129                 for mod in mods do
 130                         var p = new Program(mod, self)
 131                         p.compute_main_method
 132                         p.do_table_computation
 133                         p.generate_allocation_iroutines
 134                         p.compile_prog_to_c
 135                 end
 136         end
 137 end
 138
 139 var c = new NitCompiler
 140 c.exec_cmd_line