lib/standard/file.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2004-2008 Jean Privat <jean@pryen.org>
   4 # Copyright 2008 Floréal Morandat <morandat@lirmm.fr>
   5 # Copyright 2008 Jean-Sébastien Gélinas <calestar@gmail.com>
   6 #
   7 # This file is free software, which comes along with NIT.  This software is
   8 # distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
   9 # without  even  the implied warranty of  MERCHANTABILITY or  FITNESS FOR A
  10 # PARTICULAR PURPOSE.  You can modify it is you want,  provided this header
  11 # is kept unaltered, and a notification of the changes is added.
  12 # You  are  allowed  to  redistribute it and sell it, alone or is a part of
  13 # another product.
  14
  15 # File manipulations (create, read, write, etc.)
  16 module file
  17
  18 intrude import stream
  19 intrude import string
  20 import string_search
  21 import time
  22
  23 in "C Header" `{
  24         #include <dirent.h>
  25         #include <string.h>
  26         #include <sys/types.h>
  27         #include <sys/stat.h>
  28         #include <unistd.h>
  29 `}
  30
  31 redef class Object
  32 # Simple I/O
  33
  34         # Print `objects` on the standard output (`stdout`).
  35         protected fun printn(objects: Object...)
  36         do
  37                 sys.stdout.write(objects.to_s)
  38         end
  39
  40         # Print an `object` on the standard output (`stdout`) and add a newline.
  41         protected fun print(object: Object)
  42         do
  43                 sys.stdout.write(object.to_s)
  44                 sys.stdout.write("\n")
  45         end
  46
  47         # Read a character from the standard input (`stdin`).
  48         protected fun getc: Char
  49         do
  50                 return sys.stdin.read_char.ascii
  51         end
  52
  53         # Read a line from the standard input (`stdin`).
  54         protected fun gets: String
  55         do
  56                 return sys.stdin.read_line
  57         end
  58
  59         # Return the working (current) directory
  60         protected fun getcwd: String do return file_getcwd.to_s
  61         private fun file_getcwd: NativeString is extern "string_NativeString_NativeString_file_getcwd_0"
  62 end
  63
  64 # File Abstract Stream
  65 abstract class FStream
  66         super IOS
  67         # The path of the file.
  68         var path: nullable String = null
  69
  70         # The FILE *.
  71         var _file: nullable NativeFile = null
  72
  73         fun file_stat: FileStat
  74         do return _file.file_stat end
  75 end
  76
  77 # File input stream
  78 class IFStream
  79         super FStream
  80         super BufferedIStream
  81         # Misc
  82
  83         # Open the same file again.
  84         # The original path is reused, therefore the reopened file can be a different file.
  85         fun reopen
  86         do
  87                 if not eof then close
  88                 _file = new NativeFile.io_open_read(path.to_cstring)
  89                 end_reached = false
  90                 _buffer_pos = 0
  91                 _buffer.clear
  92         end
  93
  94         redef fun close
  95         do
  96                 var i = _file.io_close
  97                 end_reached = true
  98         end
  99
 100         redef fun fill_buffer
 101         do
 102                 var nb = _file.io_read(_buffer.items, _buffer.capacity)
 103                 if nb <= 0 then
 104                         end_reached = true
 105                         nb = 0
 106                 end
 107                 _buffer.length = nb
 108                 _buffer_pos = 0
 109         end
 110
 111         # End of file?
 112         redef var end_reached: Bool = false
 113
 114         # Open the file at `path` for reading.
 115         init open(path: String)
 116         do
 117                 self.path = path
 118                 prepare_buffer(10)
 119                 _file = new NativeFile.io_open_read(path.to_cstring)
 120                 assert not _file.address_is_null else
 121                         print "Error: Opening file at '{path}' failed with '{sys.errno.strerror}'"
 122                 end
 123         end
 124
 125         private init do end
 126         private init without_file do end
 127 end
 128
 129 # File output stream
 130 class OFStream
 131         super FStream
 132         super OStream
 133
 134         redef fun write(s)
 135         do
 136                 assert _writable
 137                 write_native(s.to_cstring, s.length)
 138         end
 139
 140         redef fun is_writable do return _writable
 141
 142         redef fun close
 143         do
 144                 var i = _file.io_close
 145                 _writable = false
 146         end
 147
 148         # Is the file open in write mode
 149         var _writable: Bool
 150
 151         # Write `len` bytes from `native`.
 152         private fun write_native(native: NativeString, len: Int)
 153         do
 154                 assert _writable
 155                 var err = _file.io_write(native, len)
 156                 if err != len then
 157                         # Big problem
 158                         printn("Problem in writing : ", err, " ", len, "\n")
 159                 end
 160         end
 161
 162         # Open the file at `path` for writing.
 163         init open(path: String)
 164         do
 165                 _file = new NativeFile.io_open_write(path.to_cstring)
 166                 assert not _file.address_is_null else
 167                         print "Error: Opening file at '{path}' failed with '{sys.errno.strerror}'"
 168                 end
 169                 self.path = path
 170                 _writable = true
 171         end
 172
 173         private init do end
 174         private init without_file do end
 175 end
 176
 177 ###############################################################################
 178
 179 class Stdin
 180         super IFStream
 181         super PollableIStream
 182
 183         private init do
 184                 _file = new NativeFile.native_stdin
 185                 path = "/dev/stdin"
 186                 prepare_buffer(1)
 187         end
 188
 189         redef fun poll_in: Bool is extern "file_stdin_poll_in"
 190 end
 191
 192 class Stdout
 193         super OFStream
 194         private init do
 195                 _file = new NativeFile.native_stdout
 196                 path = "/dev/stdout"
 197                 _writable = true
 198         end
 199 end
 200
 201 class Stderr
 202         super OFStream
 203         private init do
 204                 _file = new NativeFile.native_stderr
 205                 path = "/dev/stderr"
 206                 _writable = true
 207         end
 208 end
 209
 210 ###############################################################################
 211
 212 redef class Streamable
 213         # Like `write_to` but take care of creating the file
 214         fun write_to_file(filepath: String)
 215         do
 216                 var stream = new OFStream.open(filepath)
 217                 write_to(stream)
 218                 stream.close
 219         end
 220 end
 221
 222 redef class String
 223         # return true if a file with this names exists
 224         fun file_exists: Bool do return to_cstring.file_exists
 225
 226         # The status of a file. see POSIX stat(2).
 227         fun file_stat: FileStat do return to_cstring.file_stat
 228
 229         # The status of a file or of a symlink. see POSIX lstat(2).
 230         fun file_lstat: FileStat do return to_cstring.file_lstat
 231
 232         # Remove a file, return true if success
 233         fun file_delete: Bool do return to_cstring.file_delete
 234
 235         # Copy content of file at `self` to `dest`
 236         fun file_copy_to(dest: String)
 237         do
 238                 var input = new IFStream.open(self)
 239                 var output = new OFStream.open(dest)
 240
 241                 while not input.eof do
 242                         var buffer = input.read(1024)
 243                         output.write buffer
 244                 end
 245
 246                 input.close
 247                 output.close
 248         end
 249
 250         # Remove the trailing extension `ext`.
 251         #
 252         # `ext` usually starts with a dot but could be anything.
 253         #
 254         #     assert "file.txt".strip_extension(".txt")  == "file"
 255         #     assert "file.txt".strip_extension("le.txt")  == "fi"
 256         #     assert "file.txt".strip_extension("xt")  == "file.t"
 257         #
 258         # if `ext` is not present, `self` is returned unmodified.
 259         #
 260         #     assert "file.txt".strip_extension(".tar.gz")  == "file.txt"
 261         fun strip_extension(ext: String): String
 262         do
 263                 if has_suffix(ext) then
 264                         return substring(0, length - ext.length)
 265                 end
 266                 return self
 267         end
 268
 269         # Extract the basename of a path and remove the extension
 270         #
 271         #     assert "/path/to/a_file.ext".basename(".ext")         == "a_file"
 272         #     assert "path/to/a_file.ext".basename(".ext")          == "a_file"
 273         #     assert "path/to".basename(".ext")                     == "to"
 274         #     assert "path/to/".basename(".ext")                    == "to"
 275         #     assert "path".basename("")                        == "path"
 276         #     assert "/path".basename("")                       == "path"
 277         #     assert "/".basename("")                           == "/"
 278         #     assert "".basename("")                            == ""
 279         fun basename(ext: String): String
 280         do
 281                 var l = length - 1 # Index of the last char
 282                 while l > 0 and self.chars[l] == '/' do l -= 1 # remove all trailing `/`
 283                 if l == 0 then return "/"
 284                 var pos = chars.last_index_of_from('/', l)
 285                 var n = self
 286                 if pos >= 0 then
 287                         n = substring(pos+1, l-pos)
 288                 end
 289                 return n.strip_extension(ext)
 290         end
 291
 292         # Extract the dirname of a path
 293         #
 294         #     assert "/path/to/a_file.ext".dirname         == "/path/to"
 295         #     assert "path/to/a_file.ext".dirname          == "path/to"
 296         #     assert "path/to".dirname                     == "path"
 297         #     assert "path/to/".dirname                    == "path"
 298         #     assert "path".dirname                        == "."
 299         #     assert "/path".dirname                       == "/"
 300         #     assert "/".dirname                           == "/"
 301         #     assert "".dirname                            == "."
 302         fun dirname: String
 303         do
 304                 var l = length - 1 # Index of the last char
 305                 while l > 0 and self.chars[l] == '/' do l -= 1 # remove all trailing `/`
 306                 var pos = chars.last_index_of_from('/', l)
 307                 if pos > 0 then
 308                         return substring(0, pos)
 309                 else if pos == 0 then
 310                         return "/"
 311                 else
 312                         return "."
 313                 end
 314         end
 315
 316         # Return the canonicalized absolute pathname (see POSIX function `realpath`)
 317         fun realpath: String do
 318                 var cs = to_cstring.file_realpath
 319                 var res = cs.to_s_with_copy
 320                 # cs.free_malloc # FIXME memory leak
 321                 return res
 322         end
 323
 324         # Simplify a file path by remove useless ".", removing "//", and resolving ".."
 325         # ".." are not resolved if they start the path
 326         # starting "/" is not removed
 327         # trainling "/" is removed
 328         #
 329         # Note that the method only wonrk on the string:
 330         #  * no I/O access is performed
 331         #  * the validity of the path is not checked
 332         #
 333         #     assert "some/./complex/../../path/from/../to/a////file//".simplify_path        ==  "path/to/a/file"
 334         #     assert "../dir/file".simplify_path       ==  "../dir/file"
 335         #     assert "dir/../../".simplify_path        ==  ".."
 336         #     assert "dir/..".simplify_path            ==  "."
 337         #     assert "//absolute//path/".simplify_path ==  "/absolute/path"
 338         fun simplify_path: String
 339         do
 340                 var a = self.split_with("/")
 341                 var a2 = new Array[String]
 342                 for x in a do
 343                         if x == "." then continue
 344                         if x == "" and not a2.is_empty then continue
 345                         if x == ".." and not a2.is_empty and a2.last != ".." then
 346                                 a2.pop
 347                                 continue
 348                         end
 349                         a2.push(x)
 350                 end
 351                 if a2.is_empty then return "."
 352                 return a2.join("/")
 353         end
 354
 355         # Correctly join two path using the directory separator.
 356         #
 357         # Using a standard "{self}/{path}" does not work when `self` is the empty string.
 358         # This method ensure that the join is valid.
 359         #
 360         #     assert "hello".join_path("world")      ==  "hello/world"
 361         #     assert "hel/lo".join_path("wor/ld")      ==  "hel/lo/wor/ld"
 362         #     assert "".join_path("world")      ==  "world"
 363         #     assert "/hello".join_path("/world")      ==  "/world"
 364         #
 365         # Note: you may want to use `simplify_path` on the result
 366         #
 367         # Note: I you want to join a great number of path, you can write
 368         #
 369         #     [p1, p2, p3, p4].join("/")
 370         fun join_path(path: String): String
 371         do
 372                 if path.is_empty then return self
 373                 if self.is_empty then return path
 374                 if path.chars[0] == '/' then return path
 375                 return "{self}/{path}"
 376         end
 377
 378         # Create a directory (and all intermediate directories if needed)
 379         fun mkdir
 380         do
 381                 var dirs = self.split_with("/")
 382                 var path = new FlatBuffer
 383                 if dirs.is_empty then return
 384                 if dirs[0].is_empty then
 385                         # it was a starting /
 386                         path.add('/')
 387                 end
 388                 for d in dirs do
 389                         if d.is_empty then continue
 390                         path.append(d)
 391                         path.add('/')
 392                         path.to_s.to_cstring.file_mkdir
 393                 end
 394         end
 395
 396         # Change the current working directory
 397         #
 398         #     "/etc".chdir
 399         #     assert getcwd == "/etc"
 400         #     "..".chdir
 401         #     assert getcwd == "/"
 402         #
 403         # TODO: errno
 404         fun chdir do to_cstring.file_chdir
 405
 406         # Return right-most extension (without the dot)
 407         #
 408         # Only the last extension is returned.
 409         # There is no special case for combined extensions.
 410         #
 411         #     assert "file.txt".file_extension      == "txt"
 412         #     assert "file.tar.gz".file_extension   == "gz"
 413         #
 414         # For file without extension, `null` is returned.
 415         # Hoever, for trailing dot, `""` is returned.
 416         #
 417         #     assert "file".file_extension          == null
 418         #     assert "file.".file_extension         == ""
 419         #
 420         # The starting dot of hidden files is never considered.
 421         #
 422         #     assert ".file.txt".file_extension     == "txt"
 423         #     assert ".file".file_extension         == null
 424         fun file_extension: nullable String
 425         do
 426                 var last_slash = chars.last_index_of('.')
 427                 if last_slash > 0 then
 428                         return substring( last_slash+1, length )
 429                 else
 430                         return null
 431                 end
 432         end
 433
 434         # returns files contained within the directory represented by self
 435         fun files : Set[ String ] is extern import HashSet[String], HashSet[String].add, NativeString.to_s, String.to_cstring, HashSet[String].as(Set[String]) `{
 436                 char *dir_path;
 437                 DIR *dir;
 438
 439                 dir_path = String_to_cstring( recv );
 440                 if ((dir = opendir(dir_path)) == NULL)
 441                 {
 442                         perror( dir_path );
 443                         exit( 1 );
 444                 }
 445                 else
 446                 {
 447                         HashSet_of_String results;
 448                         String file_name;
 449                         struct dirent *de;
 450
 451                         results = new_HashSet_of_String();
 452
 453                         while ( ( de = readdir( dir ) ) != NULL )
 454                                 if ( strcmp( de->d_name, ".." ) != 0 &&
 455                                         strcmp( de->d_name, "." ) != 0 )
 456                                 {
 457                                         file_name = NativeString_to_s( strdup( de->d_name ) );
 458                                         HashSet_of_String_add( results, file_name );
 459                                 }
 460
 461                         closedir( dir );
 462                         return HashSet_of_String_as_Set_of_String( results );
 463                 }
 464         `}
 465 end
 466
 467 redef class NativeString
 468         private fun file_exists: Bool is extern "string_NativeString_NativeString_file_exists_0"
 469         private fun file_stat: FileStat is extern "string_NativeString_NativeString_file_stat_0"
 470         private fun file_lstat: FileStat `{
 471                 struct stat* stat_element;
 472                 int res;
 473                 stat_element = malloc(sizeof(struct stat));
 474                 res = lstat(recv, stat_element);
 475                 if (res == -1) return NULL;
 476                 return stat_element;
 477         `}
 478         private fun file_mkdir: Bool is extern "string_NativeString_NativeString_file_mkdir_0"
 479         private fun file_delete: Bool is extern "string_NativeString_NativeString_file_delete_0"
 480         private fun file_chdir is extern "string_NativeString_NativeString_file_chdir_0"
 481         private fun file_realpath: NativeString is extern "file_NativeString_realpath"
 482 end
 483
 484 # This class is system dependent ... must reify the vfs
 485 extern class FileStat `{ struct stat * `}
 486         # Returns the permission bits of file
 487         fun mode: Int is extern "file_FileStat_FileStat_mode_0"
 488         # Returns the last access time
 489         fun atime: Int is extern "file_FileStat_FileStat_atime_0"
 490         # Returns the last status change time
 491         fun ctime: Int is extern "file_FileStat_FileStat_ctime_0"
 492         # Returns the last modification time
 493         fun mtime: Int is extern "file_FileStat_FileStat_mtime_0"
 494         # Returns the size
 495         fun size: Int is extern "file_FileStat_FileStat_size_0"
 496
 497         # Returns true if it is a regular file (not a device file, pipe, sockect, ...)
 498         fun is_reg: Bool `{ return S_ISREG(recv->st_mode); `}
 499         # Returns true if it is a directory
 500         fun is_dir: Bool `{ return S_ISDIR(recv->st_mode); `}
 501         # Returns true if it is a character device
 502         fun is_chr: Bool `{ return S_ISCHR(recv->st_mode); `}
 503         # Returns true if it is a block device
 504         fun is_blk: Bool `{ return S_ISBLK(recv->st_mode); `}
 505         # Returns true if the type is fifo
 506         fun is_fifo: Bool `{ return S_ISFIFO(recv->st_mode); `}
 507         # Returns true if the type is a link
 508         fun is_lnk: Bool `{ return S_ISLNK(recv->st_mode); `}
 509         # Returns true if the type is a socket
 510         fun is_sock: Bool `{ return S_ISSOCK(recv->st_mode); `}
 511 end
 512
 513 # Instance of this class are standard FILE * pointers
 514 private extern class NativeFile `{ FILE* `}
 515         fun io_read(buf: NativeString, len: Int): Int is extern "file_NativeFile_NativeFile_io_read_2"
 516         fun io_write(buf: NativeString, len: Int): Int is extern "file_NativeFile_NativeFile_io_write_2"
 517         fun io_close: Int is extern "file_NativeFile_NativeFile_io_close_0"
 518         fun file_stat: FileStat is extern "file_NativeFile_NativeFile_file_stat_0"
 519
 520         new io_open_read(path: NativeString) is extern "file_NativeFileCapable_NativeFileCapable_io_open_read_1"
 521         new io_open_write(path: NativeString) is extern "file_NativeFileCapable_NativeFileCapable_io_open_write_1"
 522         new native_stdin is extern "file_NativeFileCapable_NativeFileCapable_native_stdin_0"
 523         new native_stdout is extern "file_NativeFileCapable_NativeFileCapable_native_stdout_0"
 524         new native_stderr is extern "file_NativeFileCapable_NativeFileCapable_native_stderr_0"
 525 end
 526
 527 redef class Sys
 528
 529         # Standard input
 530         var stdin: PollableIStream protected writable = new Stdin
 531
 532         # Standard output
 533         var stdout: OStream protected writable = new Stdout
 534
 535         # Standard output for errors
 536         var stderr: OStream protected writable = new Stderr
 537
 538 end