lib/nitcc_runtime.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Runtime library required by parsers and lexers generated by nitcc
  16 module nitcc_runtime
  17
  18 # A abstract parser engine generated by nitcc
  19 abstract class Parser
  20         # The list of tokens
  21         # FIXME: provide something better, like a lexer?
  22         var tokens = new List[NToken]
  23
  24         # Look at the next token
  25         # Used by generated parsers
  26         fun peek_token: NToken do return tokens.first
  27
  28         # Consume the next token
  29         # Used by generated parsers
  30         fun get_token: NToken do return tokens.shift
  31
  32         # Consume the next token and shift to the state `dest`.
  33         # Used by generated parsers
  34         fun shift(dest: LRState)
  35         do
  36                 var t = get_token
  37                 #print "shift {t} -> {dest}"
  38                 node_stack.push t
  39                 state_stack.push state
  40                 state = dest
  41         end
  42
  43         # After a reduction on `goto` go to the next state
  44         # Used by generated parsers
  45         fun goto(goto: LRGoto)
  46         do
  47                 #print "reduce from {state} -> {prod}"
  48                 state.goto(self, goto)
  49         end
  50
  51         # push a new state on the stack of states (
  52         # Used by generated parsers
  53         fun push(dest: LRState)
  54         do
  55                 #print "push prod {prod} -> {dest}"
  56                 state_stack.push state
  57                 state = dest
  58         end
  59
  60         # Pop and return the last node
  61         # Also pop (and discard) the associated state
  62         # Used by generated parsers
  63         fun pop: Node
  64         do
  65                 var res = node_stack.pop
  66                 state = state_stack.pop
  67                 return res
  68         end
  69
  70         # Produce a parse error and stop the parsing
  71         # Used by generated parsers
  72         fun parse_error
  73         do
  74                 var token = peek_token
  75                 #print "* parse error in state {state} on token {token}"
  76                 #print "  expected: {state.error_msg}"
  77                 #print "  node_stack={node_stack.join(", ")}"
  78                 #print "  state_stack={state_stack.join(", ")}"
  79                 node_stack.add(token)
  80                 var error: NError
  81                 if token isa NLexerError then
  82                         error = token
  83                 else
  84                         error = new NParserError
  85                         error.position = token.position
  86                         error.text = token.text
  87                         error.token = token
  88                 end
  89                 error.error_tree.children.add_all(node_stack)
  90                 error.expected = state.error_msg
  91                 node_stack.clear
  92                 node_stack.add error
  93                 stop = true
  94         end
  95
  96         # The stating state for parsing
  97         # Used by generated parsers
  98         protected fun start_state: LRState is abstract
  99
 100         # The current state
 101         # Used by generated parsers
 102         var state: LRState
 103
 104         init
 105         do
 106                 state = start_state
 107         end
 108
 109         # The stack of nodes
 110         # Used by generated parsers
 111         var node_stack = new Array[Node]
 112
 113         # The stack of states
 114         # Used by generated parsers
 115         var state_stack = new Array[LRState]
 116
 117         # Should the parser stop
 118         # Used by generated parsers
 119         var stop writable = true
 120
 121         # Parse a full sequence of tokens and return a complete syntactic tree
 122         fun parse: Node
 123         do
 124                 state = start_state
 125                 state_stack.clear
 126                 node_stack.clear
 127                 stop = false
 128                 while not stop do
 129                         #print "* current state {state}"
 130                         #print "  tokens={tokens.join(" ")}"
 131                         #print "  node_stack={node_stack.join(" ")}"
 132                         #print "  state_stack={state_stack.join(" ")}"
 133                         state.action(self)
 134                 end
 135                 #print "* over"
 136                 return node_stack.first
 137         end
 138 end
 139
 140 # A state in a parser LR automaton generated by nitcc
 141 # Used by generated parsers
 142 abstract class LRState
 143         fun action(parser: Parser) is abstract
 144         fun goto(parser: Parser, goto: LRGoto) is abstract
 145         fun error_msg: String do return "FIXME"
 146 end
 147
 148 # A concrete production in a parser LR automation generated by nitcc
 149 # Used by generated parsers
 150 abstract class LRGoto
 151 end
 152
 153 ###
 154
 155 # A abstract lexer engine generated by nitcc
 156 abstract class Lexer
 157         # The input stream of characters
 158         var stream: String
 159
 160         # The stating state for lexing
 161         # Used by generated parsers
 162         protected fun start_state: DFAState is abstract
 163
 164         # Lexize a stream of characters and return a sequence of tokens
 165         fun lex: List[NToken]
 166         do
 167                 var res = new List[NToken]
 168                 var state = start_state
 169                 var pos = 0
 170                 var pos_start = 0
 171                 var pos_end = 0
 172                 var line = 1
 173                 var line_start = 1
 174                 var line_end = 0
 175                 var col = 1
 176                 var col_start = 1
 177                 var col_end = 0
 178                 var last_state: nullable DFAState = null
 179                 var text = stream
 180                 var length = text.length
 181                 loop
 182                         if state.is_accept then
 183                                 pos_end = pos - 1
 184                                 line_end = line
 185                                 col_end = col
 186                                 last_state = state
 187                         end
 188                         var c
 189                         if pos >= length then
 190                                 c = '\0'
 191                         else
 192                                 c = text[pos]
 193                         end
 194                         var next = state.trans(c)
 195                         if next == null then
 196                                 if pos_start < length then
 197                                         if last_state == null then
 198                                                 var token = new NLexerError
 199                                                 var position = new Position(pos_start, pos, line_start, line, col_start, col)
 200                                                 token.position = position
 201                                                 token.text = text.substring(pos_start, pos-pos_start+1)
 202                                                 res.add token
 203                                                 break
 204                                         end
 205                                         var position = new Position(pos_start, pos_end, line_start, line_end, col_start, col_end)
 206                                         var token = last_state.make_token(position, text.substring(pos_start, pos_end-pos_start+1))
 207                                         if token != null then res.add(token)
 208                                 end
 209                                 if pos >= length then
 210                                         var token = new NEof
 211                                         var position = new Position(pos, pos, line, line, col, col)
 212                                         token.position = position
 213                                         token.text = ""
 214                                         res.add token
 215                                         break
 216                                 end
 217                                 state = start_state
 218                                 pos_start = pos_end + 1
 219                                 pos = pos_start
 220                                 line_start = line_end
 221                                 line = line_start
 222                                 col_start = col_end
 223                                 col = col_start
 224
 225                                 last_state = null
 226                                 continue
 227                         end
 228                         state = next
 229                         pos += 1
 230                         col += 1
 231                         if c == '\n' then
 232                                 line += 1
 233                                 col = 1
 234                         end
 235                 end
 236                 return res
 237         end
 238 end
 239
 240 # A state in a lexer automaton generated by nitcc
 241 # Used by generated lexers
 242 interface DFAState
 243         fun is_accept: Bool do return false
 244         fun trans(c: Char): nullable DFAState do return null
 245         fun make_token(position: Position, text: String): nullable NToken is abstract
 246 end
 247
 248 ###
 249
 250 # A abstract visitor on syntactic trees generated by nitcc
 251 abstract class Visitor
 252         # The main entry point to visit a node `n`
 253         # Should not be redefined
 254         fun enter_visit(n: Node)
 255         do
 256                 visit(n)
 257         end
 258
 259         # The specific implementation of a visit
 260         #
 261         # Should be redefined by concrete visitors
 262         #
 263         # Should not be called directly (use `enter_visit` instead)
 264         #
 265         # By default, the visitor just rescursively visit the children of `n`
 266         protected fun visit(n: Node)
 267         do
 268                 n.visit_children(self)
 269         end
 270 end
 271
 272 # Print a node (using to_s) on a line and recustively each children indented (with two spaces)
 273 class TreePrinterVisitor
 274         super Visitor
 275         var writer: OStream
 276         private var indent = 0
 277         init(writer: OStream) do self.writer = writer
 278         redef fun visit(n)
 279         do
 280                 for i in [0..indent[ do writer.write("  ")
 281                 writer.write(n.to_s)
 282                 writer.write("\n")
 283                 indent += 1
 284                 super
 285                 indent -= 1
 286         end
 287 end
 288
 289 # A position into a input stream
 290 # Used to give position to tokens
 291 class Position
 292         var pos_start: Int
 293         var pos_end: Int
 294         var line_start: Int
 295         var line_end: Int
 296         var col_start: Int
 297         var col_end: Int
 298         redef fun to_s do return "{line_start}:{col_start}-{line_end}:{col_end}"
 299 end
 300
 301 # A node of a syntactic tree
 302 abstract class Node
 303         # The name of the node (as used in the grammar file)
 304         fun node_name: String do return class_name
 305
 306         # A point of view on the direct children of the node
 307         fun children: SequenceRead[nullable Node] is abstract
 308
 309         # Visit all the children of the node with the visitor `v`
 310         protected fun visit_children(v: Visitor)
 311         do
 312                 for c in children do if c != null then v.enter_visit(c)
 313         end
 314
 315         # The position of the node in the input stream
 316         var position: nullable Position writable = null
 317
 318         # Produce a graphiz file for the syntaxtic tree rooted at `self`.
 319         fun to_dot(filepath: String)
 320         do
 321                 var f = new OFStream.open(filepath)
 322                 f.write("digraph g \{\n")
 323                 f.write("rankdir=BT;\n")
 324
 325                 var a = new Array[NToken]
 326                 to_dot_visitor(f, a)
 327
 328                 f.write("\{ rank=same\n")
 329                 var first = true
 330                 for n in a do
 331                         if first then
 332                                 first = false
 333                         else
 334                                 f.write("->")
 335                         end
 336                         f.write("n{n.object_id}")
 337                 end
 338                 f.write("[style=invis];\n")
 339                 f.write("\}\n")
 340
 341                 f.write("\}\n")
 342                 f.close
 343         end
 344
 345         private fun to_dot_visitor(f: OStream, a: Array[NToken])
 346         do
 347                 f.write("n{object_id} [label=\"{node_name}\"];\n")
 348                 for x in children do
 349                         if x == null then continue
 350                         f.write("n{x.object_id} -> n{object_id};\n")
 351                         x.to_dot_visitor(f,a )
 352                 end
 353         end
 354
 355         redef fun to_s do
 356                 var pos = position
 357                 if pos == null then
 358                         return "{node_name}"
 359                 else
 360                         return "{node_name}@({pos})"
 361                 end
 362         end
 363 end
 364
 365 # A token produced by the lexer and used in a syntactic tree
 366 abstract class NToken
 367         super Node
 368
 369         redef fun children do return once new Array[Node]
 370
 371         redef fun to_dot_visitor(f, a)
 372         do
 373                 var labe = "{node_name}"
 374                 var pos = position
 375                 if pos != null then labe += "\\n{pos}"
 376                 var text = self.text
 377                 if node_name != "'{text}'" then
 378                         labe += "\\n'{text.escape_to_c}'"
 379                 end
 380                 f.write("n{object_id} [label=\"{labe}\",shape=box];\n")
 381                 a.add(self)
 382         end
 383
 384         # The text associated with the token
 385         var text: String writable = ""
 386
 387         redef fun to_s do
 388                 var res = super
 389                 var text = self.text
 390                 if node_name != "'{text}'" then
 391                         res += "='{text.escape_to_c}'"
 392                 end
 393                 return res
 394         end
 395 end
 396
 397 # The special token for the end of stream
 398 class NEof
 399         super NToken
 400 end
 401
 402 # A special token used to represent a parser or lexer error
 403 abstract class NError
 404         super NToken
 405
 406         # All the partially built tree during parsing (aka the node_stack)
 407         var error_tree = new Nodes[Node]
 408
 409         # The things unexpected
 410         fun unexpected: String is abstract
 411
 412         # The things expected (if any)
 413         var expected: nullable String = null
 414
 415         # The error message,using `expected` and `unexpected`
 416         fun message: String
 417         do
 418                 var exp = expected
 419                 var res = "Unexpected {unexpected}"
 420                 if exp != null then res += "; is acceptable instead: {exp}"
 421                 return res
 422         end
 423 end
 424
 425 # A lexer error as a token for the unexpected characted
 426 class NLexerError
 427         super NError
 428
 429         redef fun unexpected do return "character '{text.first}'"
 430 end
 431
 432 # A parser error linked to a unexpected token
 433 class NParserError
 434         super NError
 435         # The unexpected token
 436         var token: nullable NToken
 437
 438         redef fun unexpected
 439         do
 440                 var res = token.node_name
 441                 var text = token.text
 442                 if not text.is_empty and res != "'{text}'" then
 443                         res += " '{text.escape_to_c}'"
 444                 end
 445                 return res
 446         end
 447 end
 448
 449 # A hogeneous sequence of node, used to represent unbounded lists (and + modifier)
 450 class Nodes[T: Node]
 451         super Node
 452         redef var children = new Array[T]
 453 end
 454
 455 # A production with a specific, named and statically typed children
 456 class NProd
 457         super Node
 458         redef var children: SequenceRead[nullable Node] = new NProdChildren(self)
 459
 460         # The exact number of direct children
 461         # Used to implement `children` by generated parsers
 462         fun number_of_children: Int is abstract
 463
 464         # The specific children got by its index
 465         # Used to implement `children` by generated parsers
 466         fun child(x: Int): nullable Node is abstract
 467 end
 468
 469
 470 private class NProdChildren
 471         super SequenceRead[nullable Node]
 472         var prod: NProd
 473         redef fun iterator do return new NProdIterator(prod)
 474         redef fun length do return prod.number_of_children
 475         redef fun is_empty do return prod.number_of_children == 0
 476         redef fun [](i) do return prod.child(i)
 477 end
 478
 479 private class NProdIterator
 480         super IndexedIterator[nullable Node]
 481         var prod: NProd
 482         redef var index = 0
 483         redef fun is_ok do return index < prod.number_of_children
 484         redef fun next do index += 1
 485         redef fun item do return prod.child(index)
 486 end
 487
 488 # All-in-one abstract class to test generated parsers on a given
 489 abstract class TestParser
 490         # How to get a new lexer on a given stream of character
 491         fun new_lexer(text: String): Lexer is abstract
 492
 493         # How to get a new parser
 494         fun new_parser: Parser is abstract
 495
 496         # The name of the language (used for generated files)
 497         fun name: String is abstract
 498
 499         # Use the class as the main enrty point of the program
 500         # - parse arguments and options of the command
 501         # - test the parser (see `work`)
 502         fun main: Node
 503         do
 504                 if args.is_empty then
 505                         print "usage {name}_test <filepath> | - | -e <text>"
 506                         exit 0
 507                 end
 508
 509                 var filepath = args.shift
 510                 var text
 511                 if filepath == "-" then
 512                         text = stdin.read_all
 513                 else if filepath == "-e" then
 514                         if args.is_empty then
 515                                 print "Error: -e need a text"
 516                                 exit 1
 517                         end
 518                         text = args.shift
 519                 else
 520                         var f = new IFStream.open(filepath)
 521                         text = f.read_all
 522                         f.close
 523                 end
 524
 525                 if not args.is_empty then
 526                         print "Error: superfluous arguments."
 527                         exit 1
 528                 end
 529
 530                 return work(text)
 531         end
 532
 533         # Produce a full syntactic tree for a given stream of character
 534         # Produce also statistics and output files
 535         fun work(text: String): Node
 536         do
 537                 print "INPUT: {text.length} chars"
 538                 var l = new_lexer(text)
 539                 var tokens = l.lex
 540
 541                 var tokout = "{name}.tokens.out"
 542                 print "TOKEN: {tokens.length} tokens (see {tokout})"
 543
 544                 var f = new OFStream.open(tokout)
 545                 for t in tokens do
 546                         f.write "{t.to_s}\n"
 547                 end
 548                 f.close
 549
 550                 var p = new_parser
 551                 p.tokens.add_all(tokens)
 552
 553                 var n = p.parse
 554
 555                 var astout = "{name}.ast.out"
 556                 f = new OFStream.open(astout)
 557                 var tpv = new TreePrinterVisitor(f)
 558                 var astdotout = "{name}.ast.dot"
 559                 if n isa NError then
 560                         print "Syntax error: {n.message}"
 561                         print "ERROR: {n} (see {astout} and {astdotout})"
 562                         tpv.enter_visit(n)
 563                         n = n.error_tree
 564                 else
 565                         print "ROOT: {n} (see {astout} and {astdotout})"
 566                 end
 567                 tpv.enter_visit(n)
 568                 n.to_dot(astdotout)
 569                 f.close
 570
 571                 return n
 572         end
 573 end