src/nitunit.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Program to extract and execute unit tests from nit source files
  16 module nitunit
  17
  18 import modelize_property
  19 intrude import markdown
  20 import parser_util
  21
  22 # Extractor, Executor an Reporter for the tests in a module
  23 class NitUnitExecutor
  24         super Doc2Mdwn
  25
  26         # The name of the module to import
  27         var modname: String
  28
  29         # The prefix of the generated Nit source-file
  30         var prefix: String
  31
  32         # The XML node associated to the module
  33         var testsuite: HTMLTag
  34
  35         # Initialize a new e
  36         init(toolcontext: ToolContext, prefix: String, modname: String, testsuite: HTMLTag)
  37         do
  38                 super(toolcontext)
  39                 self.prefix = prefix
  40                 self.modname = modname
  41                 self.testsuite = testsuite
  42         end
  43
  44         # All blocks of code from a same `ADoc`
  45         var block = new Array[String]
  46
  47         redef fun process_code(n: HTMLTag, text: String)
  48         do
  49                 # Try to parse it
  50                 var ast = toolcontext.parse_something(text)
  51
  52                 # We want executable code
  53                 if not (ast isa AModule or ast isa ABlockExpr or ast isa AExpr) then return
  54
  55                 # Search `assert` in the AST
  56                 var v = new SearchAssertVisitor
  57                 v.enter_visit(ast)
  58                 if not v.foundit then return
  59
  60                 # Add it to the file
  61                 block.add(text)
  62         end
  63
  64         # used to generate distinct names
  65         var cpt = 0
  66
  67         # The entry point for a new `ndoc` node
  68         # Fill the prepated `tc` (testcase) XTM node
  69         fun extract(ndoc: ADoc, tc: HTMLTag)
  70         do
  71                 block.clear
  72
  73                 work(ndoc.to_mdoc)
  74
  75                 if block.is_empty then return
  76
  77                 toolcontext.modelbuilder.unit_entities += 1
  78
  79                 cpt += 1
  80                 var file = "{prefix}{cpt}.nit"
  81
  82                 toolcontext.info("Execute {tc.attrs["classname"]}.{tc.attrs["name"]} in {file}", 2)
  83
  84                 var dir = file.dirname
  85                 if dir != "" then dir.mkdir
  86                 var f
  87                 f = new OFStream.open(file)
  88                 f.write("# GENERATED FILE\n")
  89                 f.write("# Example extracted from a documentation\n")
  90                 var modname = self.modname
  91                 f.write("import {modname}\n")
  92                 f.write("\n")
  93                 for text in block do
  94                         f.write(text)
  95                 end
  96                 f.close
  97
  98                 var nit_dir = toolcontext.nit_dir
  99                 var nitg = "{nit_dir}/bin/nitg"
 100                 if nit_dir == null or not nitg.file_exists then
 101                         toolcontext.error(null, "Cannot find nitg. Set envvar NIT_DIR.")
 102                         toolcontext.check_errors
 103                 end
 104                 var cmd = "{nitg} --ignore-visibility --no-color '{file}' -I . >'{file}.out1' 2>&1 </dev/null -o '{file}.bin'"
 105                 var res = sys.system(cmd)
 106                 var res2 = 0
 107                 if res == 0 then
 108                         res2 = sys.system("./{file}.bin >>'{file}.out1' 2>&1 </dev/null")
 109                 end
 110
 111                 var msg
 112                 f = new IFStream.open("{file}.out1")
 113                 var n2
 114                 n2 = new HTMLTag("system-err")
 115                 tc.add n2
 116                 msg = f.read_all
 117                 f.close
 118
 119                 n2 = new HTMLTag("system-out")
 120                 tc.add n2
 121                 for text in block do n2.append(text)
 122
 123
 124                 if res != 0 then
 125                         var ne = new HTMLTag("failure")
 126                         ne.attr("message", msg)
 127                         tc.add ne
 128                         toolcontext.warning(ndoc.location, "FAILURE: {tc.attrs["classname"]}.{tc.attrs["name"]} (in {file}): {msg}")
 129                         toolcontext.modelbuilder.failed_entities += 1
 130                 else if res2 != 0 then
 131                         var ne = new HTMLTag("error")
 132                         ne.attr("message", msg)
 133                         tc.add ne
 134                         toolcontext.warning(ndoc.location, "ERROR: {tc.attrs["classname"]}.{tc.attrs["name"]} (in {file}): {msg}")
 135                         toolcontext.modelbuilder.failed_entities += 1
 136                 end
 137                 toolcontext.check_errors
 138
 139                 testsuite.add(tc)
 140         end
 141 end
 142
 143 class SearchAssertVisitor
 144         super Visitor
 145         var foundit = false
 146         redef fun visit(node)
 147         do
 148                 if foundit then
 149                         return
 150                 else if node isa AAssertExpr then
 151                         foundit = true
 152                         return
 153                 else
 154                         node.visit_all(self)
 155                 end
 156         end
 157 end
 158
 159 redef class ModelBuilder
 160         var total_entities = 0
 161         var doc_entities = 0
 162         var unit_entities = 0
 163         var failed_entities = 0
 164
 165         fun test_markdown(mmodule: MModule): HTMLTag
 166         do
 167                 var ts = new HTMLTag("testsuite")
 168                 toolcontext.info("nitunit: {mmodule}", 2)
 169                 if not mmodule2nmodule.has_key(mmodule) then return ts
 170
 171                 var nmodule = mmodule2nmodule[mmodule]
 172                 assert nmodule != null
 173
 174                 # what module to import in the unit test.
 175                 # try to detect the main module of the project
 176                 # TODO do things correctly once the importation of arbitraty nested module is legal
 177                 var o = mmodule
 178                 var g = o.mgroup
 179                 if g != null then
 180                         o = get_mmodule_by_name(nmodule, g, g.mproject.name).as(not null)
 181                 end
 182
 183                 ts.attr("package", mmodule.full_name)
 184
 185                 var prefix = toolcontext.opt_dir.value
 186                 if prefix == null then prefix = ".nitunit"
 187                 prefix = prefix.join_path(mmodule.to_s)
 188                 var d2m = new NitUnitExecutor(toolcontext, prefix, o.name, ts)
 189
 190                 var tc
 191
 192                 do
 193                         total_entities += 1
 194                         var nmoduledecl = nmodule.n_moduledecl
 195                         if nmoduledecl == null then break label x
 196                         var ndoc = nmoduledecl.n_doc
 197                         if ndoc == null then break label x
 198                         doc_entities += 1
 199                         tc = new HTMLTag("testcase")
 200                         # NOTE: jenkins expects a '.' in the classname attr
 201                         tc.attr("classname", mmodule.full_name + ".<module>")
 202                         tc.attr("name", "<module>")
 203                         d2m.extract(ndoc, tc)
 204                 end label x
 205                 for nclassdef in nmodule.n_classdefs do
 206                         var mclassdef = nclassdef.mclassdef.as(not null)
 207                         if nclassdef isa AStdClassdef then
 208                                 total_entities += 1
 209                                 var ndoc = nclassdef.n_doc
 210                                 if ndoc != null then
 211                                         doc_entities += 1
 212                                         tc = new HTMLTag("testcase")
 213                                         tc.attr("classname", mmodule.full_name + "." + mclassdef.mclass.full_name)
 214                                         tc.attr("name", "<class>")
 215                                         d2m.extract(ndoc, tc)
 216                                 end
 217                         end
 218                         for npropdef in nclassdef.n_propdefs do
 219                                 var mpropdef = npropdef.mpropdef.as(not null)
 220                                 total_entities += 1
 221                                 var ndoc = npropdef.n_doc
 222                                 if ndoc != null then
 223                                         doc_entities += 1
 224                                         tc = new HTMLTag("testcase")
 225                                         tc.attr("classname", mmodule.full_name + "." + mclassdef.mclass.full_name)
 226                                         tc.attr("name", mpropdef.mproperty.full_name)
 227                                         d2m.extract(ndoc, tc)
 228                                 end
 229                         end
 230                 end
 231
 232                 return ts
 233         end
 234 end
 235
 236 redef class ToolContext
 237         var opt_full = new OptionBool("Process also imported modules", "--full")
 238         var opt_output = new OptionString("Output name (default is 'nitunit.xml')", "-o", "--output")
 239         var opt_dir = new OptionString("Working directory (default is '.nitunit')", "--dir")
 240 end
 241
 242 var toolcontext = new ToolContext
 243
 244 toolcontext.option_context.add_option(toolcontext.opt_full, toolcontext.opt_output, toolcontext.opt_dir)
 245 toolcontext.tooldescription = "Usage: nitunit [OPTION]... <file.nit>...\nExecutes the unit tests from Nit source files."
 246
 247 toolcontext.process_options(args)
 248 var args = toolcontext.option_context.rest
 249
 250 var model = new Model
 251 var modelbuilder = new ModelBuilder(model, toolcontext)
 252
 253 var mmodules = modelbuilder.parse(args)
 254 modelbuilder.run_phases
 255
 256 var page = new HTMLTag("testsuites")
 257
 258 if toolcontext.opt_full.value then mmodules = model.mmodules
 259
 260 for m in mmodules do
 261         page.add modelbuilder.test_markdown(m)
 262 end
 263
 264 var file = toolcontext.opt_output.value
 265 if file == null then file = "nitunit.xml"
 266 page.write_to_file(file)
 267 print "Results saved in {file}"
 268
 269 if modelbuilder.unit_entities == 0 then
 270         print "No nitunits found"
 271 else if modelbuilder.failed_entities == 0 then
 272         print "Success"
 273 end
 274 print "Entities: {modelbuilder.total_entities}; Documented ones: {modelbuilder.doc_entities}; With nitunits: {modelbuilder.unit_entities}; Failures: {modelbuilder.failed_entities}"