src/separate_erasure_compiler.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Separate compilation of a Nit program with generic type erasure
  16 module separate_erasure_compiler
  17
  18 intrude import separate_compiler
  19
  20 # Add separate erased compiler specific options
  21 redef class ToolContext
  22         # --erasure
  23         var opt_erasure: OptionBool = new OptionBool("Erase generic types", "--erasure")
  24         # --no-check-erasure-cast
  25         var opt_no_check_erasure_cast: OptionBool = new OptionBool("Disable implicit casts on unsafe return with erasure-typing policy (dangerous)", "--no-check-erasure-cast")
  26
  27         redef init
  28         do
  29                 super
  30                 self.option_context.add_option(self.opt_erasure, self.opt_no_check_erasure_cast)
  31         end
  32 end
  33
  34 redef class ModelBuilder
  35         fun run_separate_erasure_compiler(mainmodule: MModule, runtime_type_analysis: nullable RapidTypeAnalysis)
  36         do
  37                 var time0 = get_time
  38                 self.toolcontext.info("*** GENERATING C ***", 1)
  39
  40                 var compiler = new SeparateErasureCompiler(mainmodule, self, runtime_type_analysis)
  41                 compiler.compile_header
  42
  43                 # compile class structures
  44                 self.toolcontext.info("Property coloring", 2)
  45                 compiler.new_file("{mainmodule.name}.tables")
  46                 compiler.do_property_coloring
  47                 for m in mainmodule.in_importation.greaters do
  48                         for mclass in m.intro_mclasses do
  49                                 compiler.compile_class_to_c(mclass)
  50                         end
  51                 end
  52                 compiler.compile_color_consts(compiler.vt_layout.pos)
  53
  54                 # The main function of the C
  55                 compiler.new_file("{mainmodule.name}.main")
  56                 compiler.compile_main_function
  57
  58                 # compile methods
  59                 for m in mainmodule.in_importation.greaters do
  60                         self.toolcontext.info("Generate C for module {m}", 2)
  61                         compiler.new_file("{m.name}.sep")
  62                         compiler.compile_module_to_c(m)
  63                 end
  64
  65                 compiler.display_stats
  66
  67                 var time1 = get_time
  68                 self.toolcontext.info("*** END GENERATING C: {time1-time0} ***", 2)
  69                 write_and_make(compiler)
  70         end
  71 end
  72
  73 class SeparateErasureCompiler
  74         super SeparateCompiler
  75
  76         private var class_layout: nullable Layout[MClass]
  77         protected var vt_layout: nullable Layout[MVirtualTypeProp]
  78
  79         init(mainmodule: MModule, mmbuilder: ModelBuilder, runtime_type_analysis: nullable RapidTypeAnalysis) do
  80                 super
  81
  82                 var mclasses = new HashSet[MClass].from(mmbuilder.model.mclasses)
  83
  84                 var layout_builder: TypingLayoutBuilder[MClass]
  85                 var class_colorer = new MClassColorer(mainmodule)
  86                 if modelbuilder.toolcontext.opt_phmod_typing.value then
  87                         layout_builder = new MClassHasher(new PHModOperator, mainmodule)
  88                         class_colorer.build_layout(mclasses)
  89                 else if modelbuilder.toolcontext.opt_phand_typing.value then
  90                         layout_builder = new MClassHasher(new PHAndOperator, mainmodule)
  91                         class_colorer.build_layout(mclasses)
  92                 else if modelbuilder.toolcontext.opt_bm_typing.value then
  93                         layout_builder = new MClassBMizer(mainmodule)
  94                         class_colorer.build_layout(mclasses)
  95                 else
  96                         layout_builder = class_colorer
  97                 end
  98                 self.class_layout = layout_builder.build_layout(mclasses)
  99                 self.class_tables = self.build_class_typing_tables(mclasses)
 100
 101                 # lookup vt to build layout with
 102                 var vts = new HashMap[MClass, Set[MVirtualTypeProp]]
 103                 for mclass in mclasses do
 104                         vts[mclass] = new HashSet[MVirtualTypeProp]
 105                         for mprop in self.mainmodule.properties(mclass) do
 106                                 if mprop isa MVirtualTypeProp then
 107                                         vts[mclass].add(mprop)
 108                                 end
 109                         end
 110                 end
 111
 112                 # vt coloration
 113                 var vt_coloring = new MPropertyColorer[MVirtualTypeProp](mainmodule, class_colorer)
 114                 var vt_layout = vt_coloring.build_layout(vts)
 115                 self.vt_tables = build_vt_tables(mclasses, vt_layout)
 116                 self.vt_layout = vt_layout
 117         end
 118
 119         fun build_vt_tables(mclasses: Set[MClass], layout: Layout[MProperty]): Map[MClass, Array[nullable MPropDef]] do
 120                 var tables = new HashMap[MClass, Array[nullable MPropDef]]
 121                 for mclass in mclasses do
 122                         var table = new Array[nullable MPropDef]
 123                         # first, fill table from parents by reverse linearization order
 124                         var parents = new Array[MClass]
 125                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 126                                 parents = mclass.in_hierarchy(mainmodule).greaters.to_a
 127                                 self.mainmodule.linearize_mclasses(parents)
 128                         end
 129                         for parent in parents do
 130                                 if parent == mclass then continue
 131                                 for mproperty in self.mainmodule.properties(parent) do
 132                                         if not mproperty isa MVirtualTypeProp then continue
 133                                         var color = layout.pos[mproperty]
 134                                         if table.length <= color then
 135                                                 for i in [table.length .. color[ do
 136                                                         table[i] = null
 137                                                 end
 138                                         end
 139                                         for mpropdef in mproperty.mpropdefs do
 140                                                 if mpropdef.mclassdef.mclass == parent then
 141                                                         table[color] = mpropdef
 142                                                 end
 143                                         end
 144                                 end
 145                         end
 146
 147                         # then override with local properties
 148                         for mproperty in self.mainmodule.properties(mclass) do
 149                                 if not mproperty isa MVirtualTypeProp then continue
 150                                 var color = layout.pos[mproperty]
 151                                 if table.length <= color then
 152                                         for i in [table.length .. color[ do
 153                                                 table[i] = null
 154                                         end
 155                                 end
 156                                 for mpropdef in mproperty.mpropdefs do
 157                                         if mpropdef.mclassdef.mclass == mclass then
 158                                                 table[color] = mpropdef
 159                                         end
 160                                 end
 161                         end
 162                         tables[mclass] = table
 163                 end
 164                 return tables
 165         end
 166
 167         # Build class tables
 168         fun build_class_typing_tables(mclasses: Set[MClass]): Map[MClass, Array[nullable MClass]] do
 169                 var tables = new HashMap[MClass, Array[nullable MClass]]
 170                 var layout = self.class_layout
 171                 for mclass in mclasses do
 172                         var table = new Array[nullable MClass]
 173                         var supers = new Array[MClass]
 174                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 175                                 supers = mclass.in_hierarchy(mainmodule).greaters.to_a
 176                         end
 177                         for sup in supers do
 178                                 var color: Int
 179                                 if layout isa PHLayout[MClass, MClass] then
 180                                         color = layout.hashes[mclass][sup]
 181                                 else
 182                                         color = layout.pos[sup]
 183                                 end
 184                                 if table.length <= color then
 185                                         for i in [table.length .. color[ do
 186                                                 table[i] = null
 187                                         end
 188                                 end
 189                                 table[color] = sup
 190                         end
 191                         tables[mclass] = table
 192                 end
 193                 return tables
 194         end
 195
 196         redef fun compile_header_structs do
 197                 self.header.add_decl("typedef void(*nitmethod_t)(void); /* general C type representing a Nit method. */")
 198                 self.compile_header_attribute_structs
 199                 self.header.add_decl("struct class \{ int id; const char *name; int box_kind; int color; const struct vts_table *vts_table; const struct type_table *type_table; nitmethod_t vft[]; \}; /* general C type representing a Nit class. */")
 200                 self.header.add_decl("struct type_table \{ int size; int table[]; \}; /* colorized type table. */")
 201                 self.header.add_decl("struct vts_entry \{ short int is_nullable; const struct class *class; \}; /* link (nullable or not) between the vts and is bound. */")
 202
 203                 if self.vt_layout isa PHLayout[MClass, MVirtualTypeProp] then
 204                         self.header.add_decl("struct vts_table \{ int mask; const struct vts_entry vts[]; \}; /* vts list of a C type representation. */")
 205                 else
 206                         self.header.add_decl("struct vts_table \{ int dummy; const struct vts_entry vts[]; \}; /* vts list of a C type representation. */")
 207                 end
 208
 209                 if modelbuilder.toolcontext.opt_phmod_typing.value then
 210                         self.header.add_decl("#define HASH(mask, id) ((mask)%(id))")
 211                 else if modelbuilder.toolcontext.opt_phand_typing.value then
 212                         self.header.add_decl("#define HASH(mask, id) ((mask)&(id))")
 213                 end
 214
 215                 self.header.add_decl("typedef struct instance \{ const struct class *class; nitattribute_t attrs[1]; \} val; /* general C type representing a Nit instance. */")
 216         end
 217
 218         redef fun compile_class_to_c(mclass: MClass)
 219         do
 220                 var mtype = mclass.intro.bound_mtype
 221                 var c_name = mclass.c_name
 222                 var c_instance_name = mclass.c_instance_name
 223
 224                 var vft = self.method_tables[mclass]
 225                 var attrs = self.attr_tables[mclass]
 226                 var class_table = self.class_tables[mclass]
 227                 var v = self.new_visitor
 228
 229                 v.add_decl("/* runtime class {c_name} */")
 230
 231                 self.provide_declaration("class_{c_name}", "extern const struct class class_{c_name};")
 232                 v.add_decl("extern const struct type_table type_table_{c_name};")
 233
 234                 # Build class vft
 235                 v.add_decl("const struct class class_{c_name} = \{")
 236                 v.add_decl("{self.class_layout.ids[mclass]},")
 237                 v.add_decl("\"{mclass.name}\", /* class_name_string */")
 238                 v.add_decl("{self.box_kind_of(mclass)}, /* box_kind */")
 239                 var layout = self.class_layout
 240                 if layout isa PHLayout[MClass, MClass] then
 241                         v.add_decl("{layout.masks[mclass]},")
 242                 else
 243                         v.add_decl("{layout.pos[mclass]},")
 244                 end
 245                 if build_class_vts_table(mclass) then
 246                         v.require_declaration("vts_table_{c_name}")
 247                         v.add_decl("&vts_table_{c_name},")
 248                 else
 249                         v.add_decl("NULL,")
 250                 end
 251                 v.add_decl("&type_table_{c_name},")
 252                 v.add_decl("\{")
 253                 for i in [0 .. vft.length[ do
 254                         var mpropdef = vft[i]
 255                         if mpropdef == null then
 256                                 v.add_decl("NULL, /* empty */")
 257                         else
 258                                 if true or mpropdef.mclassdef.bound_mtype.ctype != "val*" then
 259                                         v.require_declaration("VIRTUAL_{mpropdef.c_name}")
 260                                         v.add_decl("(nitmethod_t)VIRTUAL_{mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 261                                 else
 262                                         v.require_declaration("{mpropdef.c_name}")
 263                                         v.add_decl("(nitmethod_t){mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 264                                 end
 265                         end
 266                 end
 267                 v.add_decl("\}")
 268                 v.add_decl("\};")
 269
 270                 # Build class type table
 271
 272                 v.add_decl("const struct type_table type_table_{c_name} = \{")
 273                 v.add_decl("{class_table.length},")
 274                 v.add_decl("\{")
 275                 for msuper in class_table do
 276                         if msuper == null then
 277                                 v.add_decl("-1, /* empty */")
 278                         else
 279                                 v.add_decl("{self.class_layout.ids[msuper]}, /* {msuper} */")
 280                         end
 281                 end
 282                 v.add_decl("\}")
 283                 v.add_decl("\};")
 284
 285                 if mtype.ctype != "val*" then
 286                         if mtype.mclass.name == "Pointer" or mtype.mclass.kind != extern_kind then
 287                                 #Build instance struct
 288                                 self.header.add_decl("struct instance_{c_instance_name} \{")
 289                                 self.header.add_decl("const struct class *class;")
 290                                 self.header.add_decl("{mtype.ctype} value;")
 291                                 self.header.add_decl("\};")
 292                         end
 293
 294                         #Build BOX
 295                         self.provide_declaration("BOX_{c_name}", "val* BOX_{c_name}({mtype.ctype});")
 296                         v.add_decl("/* allocate {mtype} */")
 297                         v.add_decl("val* BOX_{mtype.c_name}({mtype.ctype} value) \{")
 298                         v.add("struct instance_{c_instance_name}*res = nit_alloc(sizeof(struct instance_{c_instance_name}));")
 299                         v.require_declaration("class_{c_name}")
 300                         v.add("res->class = &class_{c_name};")
 301                         v.add("res->value = value;")
 302                         v.add("return (val*)res;")
 303                         v.add("\}")
 304                         return
 305                 else if mclass.name == "NativeArray" then
 306                         #Build instance struct
 307                         self.header.add_decl("struct instance_{c_name} \{")
 308                         self.header.add_decl("const struct class *class;")
 309                         self.header.add_decl("int length;")
 310                         self.header.add_decl("val* values[];")
 311                         self.header.add_decl("\};")
 312
 313                         #Build NEW
 314                         self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(int length);")
 315                         v.add_decl("/* allocate {mtype} */")
 316                         v.add_decl("{mtype.ctype} NEW_{c_name}(int length) \{")
 317                         var res = v.get_name("self")
 318                         v.add_decl("struct instance_{c_name} *{res};")
 319                         var mtype_elt = mtype.arguments.first
 320                         v.add("{res} = nit_alloc(sizeof(struct instance_{c_name}) + length*sizeof({mtype_elt.ctype}));")
 321                         v.require_declaration("class_{c_name}")
 322                         v.add("{res}->class = &class_{c_name};")
 323                         v.add("{res}->length = length;")
 324                         v.add("return (val*){res};")
 325                         v.add("\}")
 326                         return
 327                 end
 328
 329                 #Build NEW
 330                 self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(void);")
 331                 v.add_decl("/* allocate {mtype} */")
 332                 v.add_decl("{mtype.ctype} NEW_{c_name}(void) \{")
 333                 var res = v.new_named_var(mtype, "self")
 334                 res.is_exact = true
 335                 v.add("{res} = nit_alloc(sizeof(struct instance) + {attrs.length}*sizeof(nitattribute_t));")
 336                 v.require_declaration("class_{c_name}")
 337                 v.add("{res}->class = &class_{c_name};")
 338                 self.generate_init_attr(v, res, mtype)
 339                 v.add("return {res};")
 340                 v.add("\}")
 341         end
 342
 343         private fun build_class_vts_table(mclass: MClass): Bool do
 344                 if self.vt_tables[mclass].is_empty then return false
 345
 346                 self.provide_declaration("vts_table_{mclass.c_name}", "extern const struct vts_table vts_table_{mclass.c_name};")
 347
 348                 var v = new_visitor
 349                 v.add_decl("const struct vts_table vts_table_{mclass.c_name} = \{")
 350                 if self.vt_layout isa PHLayout[MClass, MVirtualTypeProp] then
 351                         #TODO redo this when PHPropertyLayoutBuilder will be implemented
 352                         #v.add_decl("{vt_masks[mclass]},")
 353                 else
 354                         v.add_decl("0, /* dummy */")
 355                 end
 356                 v.add_decl("\{")
 357
 358                 for vt in self.vt_tables[mclass] do
 359                         if vt == null then
 360                                 v.add_decl("\{-1, NULL\}, /* empty */")
 361                         else
 362                                 var is_null = 0
 363                                 var bound = retrieve_vt_bound(mclass.intro.bound_mtype, vt.as(MVirtualTypeDef).bound)
 364                                 while bound isa MNullableType do
 365                                         bound = retrieve_vt_bound(mclass.intro.bound_mtype, bound.mtype)
 366                                         is_null = 1
 367                                 end
 368                                 var vtclass = bound.as(MClassType).mclass
 369                                 v.require_declaration("class_{vtclass.c_name}")
 370                                 v.add_decl("\{{is_null}, &class_{vtclass.c_name}\}, /* {vt} */")
 371                         end
 372                 end
 373                 v.add_decl("\},")
 374                 v.add_decl("\};")
 375                 return true
 376         end
 377
 378         private fun retrieve_vt_bound(anchor: MClassType, mtype: nullable MType): MType do
 379                 if mtype == null then
 380                         print "NOT YET IMPLEMENTED: retrieve_vt_bound on null"
 381                         abort
 382                 end
 383                 if mtype isa MVirtualType then
 384                         return mtype.anchor_to(mainmodule, anchor)
 385                 else if mtype isa MParameterType then
 386                         return mtype.anchor_to(mainmodule, anchor)
 387                 else
 388                         return mtype
 389                 end
 390         end
 391
 392         redef fun new_visitor do return new SeparateErasureCompilerVisitor(self)
 393
 394         # Stats
 395
 396         private var class_tables: Map[MClass, Array[nullable MClass]]
 397         private var vt_tables: Map[MClass, Array[nullable MPropDef]]
 398
 399         redef fun display_sizes
 400         do
 401                 print "# size of subtyping tables"
 402                 print "\ttotal \tholes"
 403                 var total = 0
 404                 var holes = 0
 405                 for t, table in class_tables do
 406                         total += table.length
 407                         for e in table do if e == null then holes += 1
 408                 end
 409                 print "\t{total}\t{holes}"
 410
 411                 print "# size of resolution tables"
 412                 print "\ttotal \tholes"
 413                 total = 0
 414                 holes = 0
 415                 for t, table in vt_tables do
 416                         total += table.length
 417                         for e in table do if e == null then holes += 1
 418                 end
 419                 print "\t{total}\t{holes}"
 420
 421                 print "# size of methods tables"
 422                 print "\ttotal \tholes"
 423                 total = 0
 424                 holes = 0
 425                 for t, table in method_tables do
 426                         total += table.length
 427                         for e in table do if e == null then holes += 1
 428                 end
 429                 print "\t{total}\t{holes}"
 430
 431                 print "# size of attributes tables"
 432                 print "\ttotal \tholes"
 433                 total = 0
 434                 holes = 0
 435                 for t, table in attr_tables do
 436                         total += table.length
 437                         for e in table do if e == null then holes += 1
 438                 end
 439                 print "\t{total}\t{holes}"
 440         end
 441 end
 442
 443 class SeparateErasureCompilerVisitor
 444         super SeparateCompilerVisitor
 445
 446         redef fun compile_callsite(callsite, arguments)
 447         do
 448                 var res = super
 449                 if callsite.erasure_cast and not self.compiler.as(SeparateErasureCompiler).modelbuilder.toolcontext.opt_no_check_erasure_cast.value then
 450                         assert res != null
 451                         var mtype = callsite.msignature.return_mtype
 452                         assert mtype != null
 453                         self.add("/* Erasure cast for return {res} isa {mtype} */")
 454                         var cond = self.type_test(res, mtype, "erasure")
 455                         self.add("if (!{cond}) \{")
 456                         #var x = self.class_name_string(res)
 457                         #var y = self.class_name_string(arguments.first)
 458                         #self.add("fprintf(stderr, \"Erasure cast: expected {mtype} (self is %s), got %s for {res}\\n\", {y}, {x});")
 459                         self.add_abort("Cast failed")
 460                         self.add("\}")
 461                 end
 462                 return res
 463         end
 464
 465         redef fun init_instance(mtype)
 466         do
 467                 self.require_declaration("NEW_{mtype.mclass.c_name}")
 468                 return self.new_expr("NEW_{mtype.mclass.c_name}()", mtype)
 469         end
 470
 471         redef fun type_test(value, mtype, tag)
 472         do
 473                 self.add("/* type test for {value.inspect} isa {mtype} */")
 474
 475                 var res = self.new_var(bool_type)
 476
 477                 var cltype = self.get_name("cltype")
 478                 self.add_decl("int {cltype};")
 479                 var idtype = self.get_name("idtype")
 480                 self.add_decl("int {idtype};")
 481
 482                 var maybe_null = self.maybe_null(value)
 483                 var accept_null = "0"
 484                 if mtype isa MNullableType then
 485                         mtype = mtype.mtype
 486                         accept_null = "1"
 487                 end
 488                 if mtype isa MParameterType then
 489                         # Here we get the bound of the the formal type (eh, erasure...)
 490                         mtype = mtype.resolve_for(self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.mmodule, false)
 491                         if mtype isa MNullableType then
 492                                 mtype = mtype.mtype
 493                                 accept_null = "1"
 494                         end
 495                 end
 496
 497                 if value.mcasttype.is_subtype(self.frame.mpropdef.mclassdef.mmodule, self.frame.mpropdef.mclassdef.bound_mtype, mtype) then
 498                         self.add("{res} = 1; /* easy {value.inspect} isa {mtype}*/")
 499                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 500                                 self.compiler.count_type_test_skipped[tag] += 1
 501                                 self.add("count_type_test_skipped_{tag}++;")
 502                         end
 503                         return res
 504                 end
 505
 506                 var class_ptr
 507                 var type_table
 508                 if value.mtype.ctype == "val*" then
 509                         class_ptr = "{value}->class->"
 510                 else
 511                         var mclass = value.mtype.as(MClassType).mclass
 512                         self.require_declaration("class_{mclass.c_name}")
 513                         class_ptr = "class_{mclass.c_name}."
 514                 end
 515
 516                 if mtype isa MClassType then
 517                         self.require_declaration("class_{mtype.mclass.c_name}")
 518                         self.add("{cltype} = class_{mtype.mclass.c_name}.color;")
 519                         self.add("{idtype} = class_{mtype.mclass.c_name}.id;")
 520                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 521                                 self.compiler.count_type_test_resolved[tag] += 1
 522                                 self.add("count_type_test_resolved_{tag}++;")
 523                         end
 524                 else if mtype isa MVirtualType then
 525                         var recv = self.frame.arguments.first
 526                         var recv_ptr
 527                         if recv.mtype.ctype == "val*" then
 528                                 recv_ptr = "{recv}->class->"
 529                         else
 530                                 var mclass = recv.mtype.as(MClassType).mclass
 531                                 self.require_declaration("class_{mclass.c_name}")
 532                                 recv_ptr = "class_{mclass.c_name}."
 533                         end
 534                         var entry = self.get_name("entry")
 535                         self.add("struct vts_entry {entry};")
 536                         self.require_declaration(mtype.mproperty.const_color)
 537                         if self.compiler.as(SeparateErasureCompiler).vt_layout isa PHLayout[MClass, MVirtualTypeProp] then
 538                                 self.add("{entry} = {recv_ptr}vts_table->vts[HASH({recv_ptr}vts_table->mask, {mtype.mproperty.const_color})];")
 539                         else
 540                                 self.add("{entry} = {recv_ptr}vts_table->vts[{mtype.mproperty.const_color}];")
 541                         end
 542                         self.add("{cltype} = {entry}.class->color;")
 543                         self.add("{idtype} = {entry}.class->id;")
 544                         if maybe_null and accept_null == "0" then
 545                                 var is_nullable = self.get_name("is_nullable")
 546                                 self.add_decl("short int {is_nullable};")
 547                                 self.add("{is_nullable} = {entry}.is_nullable;")
 548                                 accept_null = is_nullable.to_s
 549                         end
 550                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 551                                 self.compiler.count_type_test_unresolved[tag] += 1
 552                                 self.add("count_type_test_unresolved_{tag}++;")
 553                         end
 554                 else
 555                         self.debug("type_test({value.inspect}, {mtype})")
 556                         abort
 557                 end
 558
 559                 # check color is in table
 560                 if maybe_null then
 561                         self.add("if({value} == NULL) \{")
 562                         self.add("{res} = {accept_null};")
 563                         self.add("\} else \{")
 564                 end
 565                 if self.compiler.as(SeparateErasureCompiler).class_layout isa PHLayout[MClass, MClass] then
 566                         self.add("{cltype} = HASH({class_ptr}color, {idtype});")
 567                 end
 568                 self.add("if({cltype} >= {class_ptr}type_table->size) \{")
 569                 self.add("{res} = 0;")
 570                 self.add("\} else \{")
 571                 self.add("{res} = {class_ptr}type_table->table[{cltype}] == {idtype};")
 572                 self.add("\}")
 573                 if maybe_null then
 574                         self.add("\}")
 575                 end
 576
 577                 return res
 578         end
 579
 580         redef fun class_name_string(value)
 581         do
 582                 var res = self.get_name("var_class_name")
 583                 self.add_decl("const char* {res};")
 584                 if value.mtype.ctype == "val*" then
 585                         self.add "{res} = {value} == NULL ? \"null\" : {value}->class->name;"
 586                 else
 587                         self.require_declaration("class_{value.mtype.c_name}")
 588                         self.add "{res} = class_{value.mtype.c_name}.name;"
 589                 end
 590                 return res
 591         end
 592
 593         redef fun array_instance(array, elttype)
 594         do
 595                 var nclass = self.get_class("NativeArray")
 596                 elttype = self.anchor(elttype)
 597                 var arraytype = self.get_class("Array").get_mtype([elttype])
 598                 var res = self.init_instance(arraytype)
 599                 self.add("\{ /* {res} = array_instance Array[{elttype}] */")
 600                 var nat = self.new_var(self.get_class("NativeArray").get_mtype([elttype]))
 601                 nat.is_exact = true
 602                 self.require_declaration("NEW_{nclass.c_name}")
 603                 self.add("{nat} = NEW_{nclass.c_name}({array.length});")
 604                 for i in [0..array.length[ do
 605                         var r = self.autobox(array[i], self.object_type)
 606                         self.add("((struct instance_{nclass.c_instance_name}*){nat})->values[{i}] = (val*) {r};")
 607                 end
 608                 var length = self.int_instance(array.length)
 609                 self.send(self.get_property("with_native", arraytype), [res, nat, length])
 610                 self.add("\}")
 611                 return res
 612         end
 613
 614         redef fun calloc_array(ret_type, arguments)
 615         do
 616                 var ret = ret_type.as(MClassType)
 617                 self.require_declaration("NEW_{ret.mclass.c_name}")
 618                 self.ret(self.new_expr("NEW_{ret.mclass.c_name}({arguments[1]})", ret_type))
 619         end
 620 end