contrib/benitlux/src/benitlux_daily.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Daily program to fetch and parse the Web site, update the database and email subscribers
  18 module benitlux_daily
  19
  20 import curl
  21 import sendmail
  22 import opts
  23
  24 import benitlux_model
  25 import benitlux_db
  26
  27 redef class Text
  28         # Return a `String` without any HTML tags (such as `<br />`) from `recv`
  29         fun strip_tags: String
  30         do
  31                 var str = to_s
  32                 var new_str = ""
  33
  34                 var from = 0
  35                 loop
  36                         var at = str.index_of_from('<', from)
  37                         if at == -1 then break
  38
  39                         new_str += str.substring(from, at-from)
  40
  41                         at = str.index_of_from('>', at)
  42                         assert at != -1
  43
  44                         from = at+1
  45                 end
  46
  47                 return new_str
  48         end
  49
  50         # Return an `Array` of the non-empty lines in `self`
  51         #
  52         #     assert ["a", "asdf", "", "  ", "&nbsp;", "b"].join("\n").to_clean_lines == ["a", "asdf", "b"]
  53         fun to_clean_lines: Array[String]
  54         do
  55                 var orig_lines = split_with("\n")
  56                 var new_lines = new Array[String]
  57
  58                 for line in orig_lines do
  59                         line = line.trim
  60
  61                         # remove empty lines
  62                         if line == "&nbsp;" then continue
  63                         if line.is_empty then continue
  64
  65                         new_lines.add line.to_s
  66                 end
  67
  68                 return new_lines
  69         end
  70 end
  71
  72 # Main logic of the program to be executed daily
  73 class Benitlux
  74         # The street on which is the Benelux
  75         var street: String
  76
  77         # The url of this precise Benelux
  78         var url = "www.brasseriebenelux.com/{street}" is lazy
  79
  80         # Path to the database
  81         var db_path = "benitlux_{street}.db" is lazy
  82
  83         # Where to save the sample email
  84         var sample_email_path = "benitlux_{street}.email" is lazy
  85
  86         # Execute the main program logic
  87         fun run(send_emails: Bool)
  88         do
  89                 # Get the web page
  90                 var body = download_html_page
  91
  92                 if opts.verbose.value > 1 then
  93                         print " # Body"
  94                         print body
  95                 end
  96
  97                 # Parse the Web page and get the available beers
  98                 var beers = parse_beers_from_html(body)
  99
 100                 if opts.verbose.value > 0 then
 101                         print " # Beers"
 102                         print beers
 103                 end
 104
 105                 var db = new DB.open(db_path)
 106
 107                 # Update the database with the beers of the day
 108                 db.insert_beers_of_the_day beers
 109
 110                 # Query the beer-related events of today
 111                 var beer_events = db.beer_events_today
 112
 113                 # Generate the email title and content, store them in attributes
 114                 generate_email(beer_events)
 115
 116                 # Save as sample email to file
 117                 var f = new FileWriter.open(sample_email_path)
 118                 f.write email_title + "\n"
 119                 for line in email_content do f.write line + "\n"
 120                 f.close
 121
 122                 # Set the email if desired
 123                 if send_emails then
 124                         var subs = db.subscribers
 125                         if opts.verbose.value > 0 then
 126                                 print " # Subscribers"
 127                                 print subs
 128                         end
 129                         send_emails_to subs
 130                 end
 131
 132                 db.close
 133         end
 134
 135         # Fetch the Web page at `url`
 136         fun download_html_page: String
 137         do
 138                 var request = new CurlHTTPRequest(url)
 139                 var response = request.execute
 140
 141                 if response isa CurlResponseSuccess then
 142                         var body = response.body_str
 143                         return body
 144                 else if response isa CurlResponseFailed then
 145                         print "Failed downloading URL '{url}' with: {response.error_msg} ({response.error_code})"
 146                         exit 1
 147                 end
 148                 abort
 149         end
 150
 151         # Extract the beers of the day information from the HTML if `body`
 152         fun parse_beers_from_html(body: String): HashSet[Beer]
 153         do
 154                 # Parts of the HTML page expected to encapsulate the interesting section
 155                 var header = "<h1>Bières<br /></h1>"
 156                 var ender = "</div></div></div>"
 157
 158                 var match = body.search(header)
 159                 assert match != null else print body
 160                 var start = match.after
 161
 162                 match = body.search_from(ender, start)
 163                 assert match != null
 164                 var finish = match.from
 165
 166                 var of_interest = body.substring(start, finish-start)
 167                 var lines = of_interest.strip_tags.to_clean_lines
 168
 169                 if opts.verbose.value > 0 then
 170                         print " # Lines"
 171                         print lines
 172                 end
 173
 174                 var beers = new HashSet[Beer]
 175                 for line in lines do
 176                         var parts = line.split(" - ")
 177                         if parts.length >= 2 then
 178                                 beers.add new Beer(parts[0].trim, parts[1].trim)
 179                         end
 180                 end
 181                 return beers
 182         end
 183
 184         # Content lines of the email
 185         var email_content: Array[String] is noautoinit
 186
 187         # Title of the email
 188         var email_title: String is noautoinit
 189
 190         # Generate email and fill the attributes `email_content` and `email_title`
 191         fun generate_email(beer_events: BeerEvents)
 192         do
 193                 email_title = "Benitlux {street.capitalized}{beer_events.to_email_title}"
 194                 email_content = beer_events.to_email_content
 195         end
 196
 197         # Send the email to all the addresses in `subs`
 198         fun send_emails_to(subs: Array[String])
 199         do
 200                 for email in subs do
 201                         var unsub_link = "http://benitlux.xymus.net/?unsub=&email={email}"
 202                         var content = """
 203 {{{email_content.join("<br />\n")}}}
 204 <br /><br />
 205 To unsubscribe, go to <a href="{{{unsub_link}}}">{{{unsub_link}}}</a>
 206 """
 207
 208                         var mail = new Mail("Benitlux <benitlux@xymus.net>", email_title, content)
 209                         mail.to.add email
 210                         mail.header["Content-Type"] = "text/html; charset=\"UTF-8\""
 211                         mail.header["List-Unsubscribe"] = unsub_link
 212                         mail.header["Precedence"] = "bulk"
 213                         mail.encrypt_with_base64
 214
 215                         mail.send
 216                 end
 217         end
 218 end
 219
 220 redef class OptionContext
 221         # Shall we mail the mailing list?
 222         var send_emails = new OptionBool("Send emails to subscribers", "-e", "--email")
 223
 224         # Display more debug messages
 225         var verbose = new OptionCount("Display extra debug messages", "-v")
 226
 227         # Print the usage message
 228         var help = new OptionBool("Print this help message", "-h", "--help")
 229
 230         redef init do add_option(send_emails, verbose, help)
 231 end
 232
 233 redef class Sys
 234         # Command line options
 235         var opts = new OptionContext
 236 end
 237
 238 # Avoid executing when running tests
 239 if "NIT_TESTING".environ == "true" then exit 0
 240
 241 opts.parse args
 242 if not opts.errors.is_empty or opts.help.value == true then
 243         print opts.errors.join("\n")
 244         print "Usage: benitlux_daily [Options]"
 245         opts.usage
 246         exit 1
 247 end
 248
 249 var ben = new Benitlux("sherbrooke")
 250 ben.run(opts.send_emails.value)
 251
 252 # The parsing logic for the wellington location is active (to gather data)
 253 # but the web interface do not allow to subscribe to its mailing list.
 254 #
 255 # TODO revamp mailing list Web interface
 256 ben = new Benitlux("wellington")
 257 ben.run(opts.send_emails.value)