src/compiling/compiling.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2008 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Compute and generate tables for classes and modules.
  18 package compiling
  19
  20 import table_computation
  21 import compiling_base
  22 private import compiling_global
  23 private import compiling_icode
  24
  25 redef class Program
  26         # Generate icode for allocation/construction/validation of classes
  27         fun generate_classes_init_to_icode
  28         do
  29                 for c in module.local_classes do
  30                         c.generate_allocation_iroutines(self)
  31                 end
  32         end
  33
  34         # Compile the program
  35         # Generate all sep files (_sep.[ch]), the main file (_table.c) and the build file (_build.sh)
  36         # Then execute the build.sh
  37         fun compile_prog_to_c(tc: ToolContext)
  38         do
  39                 tc.compdir.mkdir
  40
  41                 var files = new Array[String]
  42                 var includes = new ArraySet[String]
  43                 files.add("$CLIBDIR/nit_main.c")
  44                 files.add("$CLIBDIR/gc.c")
  45                 files.add("$CLIBDIR/gc_static_objects_list.c")
  46                 tc.info("Generating C code",1)
  47                 for m in module.mhe.greaters_and_self do
  48                         files.add("{tc.compdir}/{m.name}._sep.c")
  49                         tc.info("Generating C code for module: {m.name}",2)
  50                         m.compile_separate_module(tc, self)
  51                         var native_name = m.location.file.strip_extension(".nit")
  52                         if (native_name + "_nit.h").file_exists then
  53                                 includes.add("-I {native_name.dirname}")
  54                         end
  55                         native_name += "_nit.c"
  56                         if native_name.file_exists then files.add(native_name)
  57                 end
  58
  59                 tc.info("Generating main, tables and makefile ...",1)
  60                 files.add("{tc.compdir}/{module.name}._tables.c")
  61                 compile_main(tc)
  62
  63                 var fn = "{tc.compdir}/{module.name}._build.sh"
  64                 var f = new OFStream.open(fn)
  65                 var verbose = ""
  66
  67                 if tc.verbose_level > 0 then
  68                         verbose = "-"
  69                         for i in [1..tc.verbose_level] do verbose = verbose + "v"
  70                 end
  71
  72                 f.write("#!/bin/sh\n")
  73                 f.write("# This shell script is generated by NIT to compile the program {module.name}.\n")
  74                 f.write("CLIBDIR=\"{tc.clibdir}\"\n")
  75                 f.write("{tc.bindir}/gccx {verbose} -d {tc.compdir} -I $CLIBDIR {includes.join(" ")}")
  76                 if tc.output_file != null then
  77                         f.write(" -o {tc.output_file}")
  78                 else if tc.ext_prefix.is_empty then
  79                         f.write(" -o {module.name}")
  80                 else
  81                         f.write(" -o {module.name}_{tc.ext_prefix}")
  82                 end
  83                 if tc.boost then f.write(" -O")
  84                 f.write(" \"$@\" \\\n  {files.join("\\\n  ")}\n")
  85                 f.close
  86
  87                 if not tc.no_cc then
  88                         tc.info("Building",1)
  89                         sys.system("sh {fn}")
  90                 end
  91         end
  92
  93         # Compile the main file
  94         private fun compile_main(tc: ToolContext)
  95         do
  96                 var v = new GlobalCompilerVisitor(module, tc, self)
  97                 v.add_decl("#include <nit_common.h>")
  98                 compile_tables_to_c(v)
  99                 compile_main_part(v)
 100                 var f = new OFStream.open("{tc.compdir}/{module.name}._tables.c")
 101                 f.write("/* This C file is generated by NIT to compile program {module.name}. */\n")
 102                 for m in module.mhe.greaters_and_self do
 103                         f.write("#include \"{m.name}._sep.h\"\n")
 104                 end
 105                 f.write(v.to_s)
 106                 f.close
 107         end
 108 end
 109
 110 redef class MMModule
 111         # Compile the sep files (of the current module only)
 112         private fun compile_separate_module(tc: ToolContext, program: Program)
 113         do
 114                 var v = new GlobalCompilerVisitor(self, tc, program)
 115                 v.add_decl("#include <nit_common.h>")
 116                 var native_name = location.file.strip_extension(".nit")
 117                 native_name += ("_nit.h")
 118                 if native_name.file_exists then v.add_decl("#include <{native_name.basename("")}>")
 119                 declare_class_tables_to_c(v)
 120                 compile_mod_to_c(v)
 121                 var f = new OFStream.open("{tc.compdir}/{name}._sep.h")
 122                 f.write("/* This C header file is generated by NIT to compile modules and programs that requires {name}. */\n")
 123                 f.write("#ifndef {name}_sep\n")
 124                 f.write("#define {name}_sep\n")
 125                 for m in mhe.direct_greaters do f.write("#include \"{m.name}._sep.h\"\n")
 126                 for s in v.ctx.decls do
 127                         f.write(s)
 128                 end
 129                 f.write("#endif\n")
 130                 f.close
 131
 132                 f = new OFStream.open("{tc.compdir}/{name}._sep.c")
 133                 f.write("/* This C file is generated by NIT to compile module {name}. */\n")
 134                 f.write("#include \"{name}._sep.h\"\n")
 135                 for s in v.ctx.instrs do
 136                         f.write(s)
 137                 end
 138                 f.close
 139         end
 140 end
 141