lib/standard/file.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2004-2008 Jean Privat <jean@pryen.org>
   4 # Copyright 2008 Floréal Morandat <morandat@lirmm.fr>
   5 # Copyright 2008 Jean-Sébastien Gélinas <calestar@gmail.com>
   6 #
   7 # This file is free software, which comes along with NIT.  This software is
   8 # distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
   9 # without  even  the implied warranty of  MERCHANTABILITY or  FITNESS FOR A
  10 # PARTICULAR PURPOSE.  You can modify it is you want,  provided this header
  11 # is kept unaltered, and a notification of the changes is added.
  12 # You  are  allowed  to  redistribute it and sell it, alone or is a part of
  13 # another product.
  14
  15 # File manipulations (create, read, write, etc.)
  16 module file
  17
  18 intrude import stream
  19 intrude import string
  20 import string_search
  21 import time
  22
  23 redef class Object
  24 # Simple I/O
  25
  26         # Print `objects` on the standard output (`stdout`).
  27         protected fun printn(objects: Object...)
  28         do
  29                 stdout.write(objects.to_s)
  30         end
  31
  32         # Print an `object` on the standard output (`stdout`) and add a newline.
  33         protected fun print(object: Object)
  34         do
  35                 stdout.write(object.to_s)
  36                 stdout.write("\n")
  37         end
  38
  39         # Read a character from the standard input (`stdin`).
  40         protected fun getc: Char
  41         do
  42                 return stdin.read_char.ascii
  43         end
  44
  45         # Read a line from the standard input (`stdin`).
  46         protected fun gets: String
  47         do
  48                 return stdin.read_line
  49         end
  50
  51         # Return the working (current) directory
  52         protected fun getcwd: String do return file_getcwd.to_s
  53         private fun file_getcwd: NativeString is extern "string_NativeString_NativeString_file_getcwd_0"
  54 end
  55
  56 # File Abstract Stream
  57 abstract class FStream
  58         super IOS
  59         # The path of the file.
  60         readable var _path: nullable String = null
  61
  62         # The FILE *.
  63         var _file: nullable NativeFile = null
  64
  65         fun file_stat: FileStat
  66         do return _file.file_stat end
  67 end
  68
  69 # File input stream
  70 class IFStream
  71         super FStream
  72         super BufferedIStream
  73         # Misc
  74
  75         # Open the same file again.
  76         # The original path is reused, therefore the reopened file can be a different file.
  77         fun reopen
  78         do
  79                 if not eof then close
  80                 _file = new NativeFile.io_open_read(_path.to_cstring)
  81                 _end_reached = false
  82                 _buffer_pos = 0
  83                 _buffer.clear
  84         end
  85
  86         redef fun close
  87         do
  88                 var i = _file.io_close
  89                 _end_reached = true
  90         end
  91
  92         redef fun fill_buffer
  93         do
  94                 var nb = _file.io_read(_buffer._items, _buffer._capacity)
  95                 if nb <= 0 then
  96                         _end_reached = true
  97                         nb = 0
  98                 end
  99                 _buffer._length = nb
 100                 _buffer_pos = 0
 101         end
 102
 103         # End of file?
 104         redef readable var _end_reached: Bool = false
 105
 106         # Open the file at `path` for reading.
 107         init open(path: String)
 108         do
 109                 _path = path
 110                 prepare_buffer(10)
 111                 _file = new NativeFile.io_open_read(_path.to_cstring)
 112                 assert cant_open_file: _file != null
 113         end
 114
 115         private init do end
 116         private init without_file do end
 117 end
 118
 119 # File output stream
 120 class OFStream
 121         super FStream
 122         super OStream
 123
 124         redef fun write(s)
 125         do
 126                 assert _writable
 127                 write_native(s.to_cstring, s.length)
 128         end
 129
 130         redef fun is_writable do return _writable
 131
 132         redef fun close
 133         do
 134                 var i = _file.io_close
 135                 _writable = false
 136         end
 137
 138         # Is the file open in write mode
 139         var _writable: Bool
 140
 141         # Write `len` bytes from `native`.
 142         private fun write_native(native: NativeString, len: Int)
 143         do
 144                 assert _writable
 145                 var err = _file.io_write(native, len)
 146                 if err != len then
 147                         # Big problem
 148                         printn("Problem in writing : ", err, " ", len, "\n")
 149                 end
 150         end
 151
 152         # Open the file at `path` for writing.
 153         init open(path: String)
 154         do
 155                 _file = new NativeFile.io_open_write(path.to_cstring)
 156                 assert cant_open_file: _file != null
 157                 _path = path
 158                 _writable = true
 159         end
 160
 161         private init do end
 162         private init without_file do end
 163 end
 164
 165 ###############################################################################
 166
 167 class Stdin
 168         super IFStream
 169         private init do
 170                 _file = new NativeFile.native_stdin
 171                 _path = "/dev/stdin"
 172                 prepare_buffer(1)
 173         end
 174
 175         # Is these something to read? (non blocking)
 176         # FIXME: should be generalized
 177         fun poll_in: Bool is extern "file_stdin_poll_in"
 178 end
 179
 180 class Stdout
 181         super OFStream
 182         private init do
 183                 _file = new NativeFile.native_stdout
 184                 _path = "/dev/stdout"
 185                 _writable = true
 186         end
 187 end
 188
 189 class Stderr
 190         super OFStream
 191         private init do
 192                 _file = new NativeFile.native_stderr
 193                 _path = "/dev/stderr"
 194                 _writable = true
 195         end
 196 end
 197
 198 ###############################################################################
 199
 200 redef class String
 201         # return true if a file with this names exists
 202         fun file_exists: Bool do return to_cstring.file_exists
 203
 204         fun file_stat: FileStat do return to_cstring.file_stat
 205         fun file_lstat: FileStat do return to_cstring.file_lstat
 206
 207         # Remove a file, return true if success
 208         fun file_delete: Bool do return to_cstring.file_delete
 209
 210         # remove the trailing extension "ext"
 211         fun strip_extension(ext: String): String
 212         do
 213                 if has_suffix(ext) then
 214                         return substring(0, length - ext.length)
 215                 end
 216                 return self
 217         end
 218
 219         # Extract the basename of a path and remove the extension
 220         fun basename(ext: String): String
 221         do
 222                 var pos = last_index_of_from('/', _length - 1)
 223                 var n = self
 224                 if pos >= 0 then
 225                         n = substring_from(pos+1)
 226                 end
 227                 return n.strip_extension(ext)
 228         end
 229
 230         # Extract the dirname of a path
 231         #
 232         #     assert "/path/to/a_file.ext".dirname         == "/path/to"
 233         #     assert "path/to/a_file.ext".dirname          == "path/to"
 234         #     assert "path/to".dirname                     == "path"
 235         #     assert "path/to/".dirname                    == "path"
 236         #     assert "path".dirname                        == "."
 237         #     assert "/path".dirname                       == "/"
 238         #     assert "/".dirname                           == "/"
 239         #     assert "".dirname                            == "."
 240         fun dirname: String
 241         do
 242                 var l = _length - 1 # Index of the last char
 243                 if l > 0 and self.chars[l] == '/' then l -= 1 # remove trailing `/`
 244                 var pos = last_index_of_from('/', l)
 245                 if pos > 0 then
 246                         return substring(0, pos)
 247                 else if pos == 0 then
 248                         return "/"
 249                 else
 250                         return "."
 251                 end
 252         end
 253
 254         # Return the canonicalized absolute pathname (see POSIX function `realpath`)
 255         fun realpath: String do
 256                 var cs = to_cstring.file_realpath
 257                 var res = cs.to_s_with_copy
 258                 # cs.free_malloc # FIXME memory leak
 259                 return res
 260         end
 261
 262         # Simplify a file path by remove useless ".", removing "//", and resolving ".."
 263         # ".." are not resolved if they start the path
 264         # starting "/" is not removed
 265         # trainling "/" is removed
 266         #
 267         # Note that the method only wonrk on the string:
 268         #  * no I/O access is performed
 269         #  * the validity of the path is not checked
 270         #
 271         #     assert "some/./complex/../../path/from/../to/a////file//".simplify_path        ==  "path/to/a/file"
 272         #     assert "../dir/file".simplify_path       ==  "../dir/file"
 273         #     assert "dir/../../".simplify_path        ==  ".."
 274         #     assert "dir/..".simplify_path            ==  "."
 275         #     assert "//absolute//path/".simplify_path ==  "/absolute/path"
 276         fun simplify_path: String
 277         do
 278                 var a = self.split_with("/")
 279                 var a2 = new Array[String]
 280                 for x in a do
 281                         if x == "." then continue
 282                         if x == "" and not a2.is_empty then continue
 283                         if x == ".." and not a2.is_empty and a2.last != ".." then
 284                                 a2.pop
 285                                 continue
 286                         end
 287                         a2.push(x)
 288                 end
 289                 if a2.is_empty then return "."
 290                 return a2.join("/")
 291         end
 292
 293         # Correctly join two path using the directory separator.
 294         #
 295         # Using a standard "{self}/{path}" does not work when `self` is the empty string.
 296         # This method ensure that the join is valid.
 297         #
 298         #     assert "hello".join_path("world")      ==  "hello/world"
 299         #     assert "hel/lo".join_path("wor/ld")      ==  "hel/lo/wor/ld"
 300         #     assert "".join_path("world")      ==  "world"
 301         #     assert "/hello".join_path("/world")      ==  "/world"
 302         #
 303         # Note: you may want to use `simplify_path` on the result
 304         #
 305         # Note: I you want to join a great number of path, you can write
 306         #
 307         #     [p1, p2, p3, p4].join("/")
 308         fun join_path(path: String): String
 309         do
 310                 if path.is_empty then return self
 311                 if self.is_empty then return path
 312                 if path.chars[0] == '/' then return path
 313                 return "{self}/{path}"
 314         end
 315
 316         # Create a directory (and all intermediate directories if needed)
 317         fun mkdir
 318         do
 319                 var dirs = self.split_with("/")
 320                 var path = new Buffer
 321                 if dirs.is_empty then return
 322                 if dirs[0].is_empty then
 323                         # it was a starting /
 324                         path.add('/')
 325                 end
 326                 for d in dirs do
 327                         if d.is_empty then continue
 328                         path.append(d)
 329                         path.add('/')
 330                         path.to_s.to_cstring.file_mkdir
 331                 end
 332         end
 333
 334         # Change the current working directory
 335         #
 336         #     "/etc".chdir
 337         #     assert getcwd == "/etc"
 338         #     "..".chdir
 339         #     assert getcwd == "/"
 340         #
 341         # TODO: errno
 342         fun chdir do to_cstring.file_chdir
 343
 344         # Return right-most extension (without the dot)
 345         fun file_extension : nullable String
 346         do
 347                 var last_slash = last_index_of('.')
 348                 if last_slash >= 0 then
 349                         return substring( last_slash+1, length )
 350                 else
 351                         return null
 352                 end
 353         end
 354
 355         # returns files contained within the directory represented by self
 356         fun files : Set[ String ] is extern import HashSet, HashSet::add, NativeString::to_s, String::to_cstring, HashSet[String] as( Set[String] ), String as( Object )
 357 end
 358
 359 redef class NativeString
 360         private fun file_exists: Bool is extern "string_NativeString_NativeString_file_exists_0"
 361         private fun file_stat: FileStat is extern "string_NativeString_NativeString_file_stat_0"
 362         private fun file_lstat: FileStat `{
 363                 struct stat* stat_element;
 364                 int res;
 365                 stat_element = malloc(sizeof(struct stat));
 366                 res = lstat(recv, stat_element);
 367                 if (res == -1) return NULL;
 368                 return stat_element;
 369         `}
 370         private fun file_mkdir: Bool is extern "string_NativeString_NativeString_file_mkdir_0"
 371         private fun file_delete: Bool is extern "string_NativeString_NativeString_file_delete_0"
 372         private fun file_chdir is extern "string_NativeString_NativeString_file_chdir_0"
 373         private fun file_realpath: NativeString is extern "file_NativeString_realpath"
 374 end
 375
 376 extern FileStat `{ struct stat * `}
 377 # This class is system dependent ... must reify the vfs
 378         fun mode: Int is extern "file_FileStat_FileStat_mode_0"
 379         fun atime: Int is extern "file_FileStat_FileStat_atime_0"
 380         fun ctime: Int is extern "file_FileStat_FileStat_ctime_0"
 381         fun mtime: Int is extern "file_FileStat_FileStat_mtime_0"
 382         fun size: Int is extern "file_FileStat_FileStat_size_0"
 383
 384         fun is_reg: Bool `{ return S_ISREG(recv->st_mode); `}
 385         fun is_dir: Bool `{ return S_ISDIR(recv->st_mode); `}
 386         fun is_chr: Bool `{ return S_ISCHR(recv->st_mode); `}
 387         fun is_blk: Bool `{ return S_ISBLK(recv->st_mode); `}
 388         fun is_fifo: Bool `{ return S_ISFIFO(recv->st_mode); `}
 389         fun is_lnk: Bool `{ return S_ISLNK(recv->st_mode); `}
 390         fun is_sock: Bool `{ return S_ISSOCK(recv->st_mode); `}
 391 end
 392
 393 # Instance of this class are standard FILE * pointers
 394 private extern NativeFile
 395         fun io_read(buf: NativeString, len: Int): Int is extern "file_NativeFile_NativeFile_io_read_2"
 396         fun io_write(buf: NativeString, len: Int): Int is extern "file_NativeFile_NativeFile_io_write_2"
 397         fun io_close: Int is extern "file_NativeFile_NativeFile_io_close_0"
 398         fun file_stat: FileStat is extern "file_NativeFile_NativeFile_file_stat_0"
 399
 400         new io_open_read(path: NativeString) is extern "file_NativeFileCapable_NativeFileCapable_io_open_read_1"
 401         new io_open_write(path: NativeString) is extern "file_NativeFileCapable_NativeFileCapable_io_open_write_1"
 402         new native_stdin is extern "file_NativeFileCapable_NativeFileCapable_native_stdin_0"
 403         new native_stdout is extern "file_NativeFileCapable_NativeFileCapable_native_stdout_0"
 404         new native_stderr is extern "file_NativeFileCapable_NativeFileCapable_native_stderr_0"
 405 end
 406
 407 # Standard input.
 408 fun stdin: Stdin do return once new Stdin
 409
 410 # Standard output.
 411 fun stdout: OFStream do return once new Stdout
 412
 413 # Standard output for error.
 414 fun stderr: OFStream do return once new Stderr