src/metamodel/static_type.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2004-2008 Jean Privat <jean@pryen.org>
   4 # Copyright 2006-2008 Floréal Morandat <morandat@lirmm.fr>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17
  18 # Static types and property signatures
  19 package static_type
  20
  21 intrude import abstractmetamodel
  22
  23 redef class MMLocalClass
  24         # Cached result of get_type
  25         attr _base_type_cache: MMType
  26
  27         # Return the type of self for this class
  28         meth get_type: MMType
  29         do
  30                 if _base_type_cache == null then _base_type_cache = new MMTypeSimpleClass(self)
  31                 return _base_type_cache
  32         end
  33
  34         # Register a new ancestor
  35         protected meth add_ancestor(a: MMAncestor)
  36         do
  37                 assert not _ancestors.has_key(a.local_class)
  38                 assert a.local_class != self
  39                 _ancestors[a.local_class] = a
  40         end
  41
  42         # Array of ancestor that associate each superclass with the corresponding ancestor
  43         readable attr _ancestors: Map[MMLocalClass, MMAncestor]
  44
  45         # The ancestor type for a given superclass
  46         meth ancestor(c: MMLocalClass): MMType
  47         do
  48                 assert _ancestors != null
  49                 if _ancestors.has_key(c) then
  50                         return _ancestors[c].stype
  51                 end
  52                 return null
  53         end
  54 end
  55
  56 redef class MMLocalProperty
  57         # The signature of the property (where it is declared)
  58         readable writable attr _signature: MMSignature
  59
  60         attr _signatures_cache: HashMap[MMType, MMSignature] = new HashMap[MMType, MMSignature]
  61
  62         # Return the adapted signature of self for a receiver of type t
  63         meth signature_for(t: MMType): MMSignature do
  64                 if t == local_class.get_type then return signature
  65
  66                 if _signatures_cache.has_key(t) then return _signatures_cache[t]
  67
  68                 var res = signature.adaptation_to(t)
  69                 _signatures_cache[t] = res
  70                 return res
  71         end
  72 end
  73
  74 # Signature for local properties
  75 class MMSignature
  76         # The type of the reveiver
  77         readable attr _recv: MMType
  78
  79         # The parameter types
  80         attr _params: Array[MMType]
  81
  82         # The return type
  83         readable attr _return_type: MMType
  84
  85         # The closure parameters
  86         readable attr _closures: Array[MMClosure] = new Array[MMClosure]
  87
  88         # Number of parameters
  89         meth arity: Int
  90         do
  91                 assert _params != null
  92                 return _params.length
  93         end
  94
  95         # Is self a valid subtype of an other signature
  96         meth <(s: MMSignature): Bool
  97         do
  98                 assert s != null
  99                 if self == s then
 100                         return true
 101                 end
 102                 assert _recv.module == s.recv.module
 103                 if arity != s.arity or (_return_type == null) != (s.return_type == null) then return false
 104                 if _return_type != null and not _return_type < s.return_type then
 105                         return false
 106                 end
 107
 108                 for i in [0..arity[ do
 109                         if not s[i] < self[i] then
 110                                 return false
 111                         end
 112                 end
 113                 return true
 114         end
 115
 116         # The type of the i-th parameter
 117         meth [](i: Int): MMType
 118         do
 119                 assert _params.length > i
 120                 return _params[i]
 121         end
 122
 123         redef meth to_s
 124         do
 125                 var s = new Buffer
 126                 if _params != null and _params.length > 0 then
 127                         var tmp: String
 128                         var a = new Array[String].with_capacity(_params.length)
 129                         for i in [0.._params.length[ do
 130                                 #var pn = _params_name[i]
 131                                 var p = _params[i]
 132                                 #a.add("{pn}: {p}")
 133                                 a.add(p.to_s)
 134                         end
 135                         s.append("({a.join(",")})")
 136                 end
 137                 if _return_type != null then
 138                         s.append(": {_return_type}")
 139                 end
 140                 return s.to_s
 141         end
 142
 143         # Adapt the signature to a different receiver
 144         meth adaptation_to(r: MMType): MMSignature
 145         do
 146                 if _recv == r then
 147                         return self
 148                 end
 149                 var mod = r.module
 150                 var p = _params
 151                 if p != null then
 152                         p = new Array[MMType]
 153                         for i in _params do
 154                                 p.add(i.for_module(mod).adapt_to(r))
 155                         end
 156                 end
 157                 var rv = _return_type
 158                 if rv != null then
 159                         rv = rv.for_module(mod).adapt_to(r)
 160                 end
 161                 var res = new MMSignature(p,rv,r)
 162                 for clos in _closures do
 163                         res.closures.add(clos.adaptation_to(r))
 164                 end
 165                 return res
 166         end
 167
 168         attr _not_for_self_cache: MMSignature = null
 169
 170         # Return a type approximation if the reveiver is not self
 171         # Useful for virtual types
 172         meth not_for_self: MMSignature
 173         do
 174                 var res = _not_for_self_cache
 175                 if res != null then return res
 176
 177                 var need_for_self = false
 178                 var p = _params
 179                 if p != null then
 180                         p = new Array[MMType]
 181                         for i in _params do
 182                                 var i2 = i.not_for_self
 183                                 if i != i2 then need_for_self = true
 184                                 p.add(i2)
 185                         end
 186                 end
 187
 188                 var rv = _return_type
 189                 if rv != null then
 190                         rv = rv.not_for_self
 191                         if rv != _return_type then need_for_self = true
 192                 end
 193
 194                 var clos = _closures
 195                 if clos != null then
 196                         clos = new Array[MMClosure]
 197                         for c in _closures do
 198                                 var c2 = c.not_for_self
 199                                 if c2 != c then need_for_self = true
 200                                 clos.add(c2)
 201                         end
 202                 end
 203
 204                 if need_for_self then
 205                         res = new MMSignature(p, rv, _recv)
 206                         res.closures.add_all(clos)
 207                 else
 208                         res = self
 209                 end
 210
 211                 _not_for_self_cache = res
 212                 return res
 213         end
 214
 215         init(params: Array[MMType], return_type: MMType, r: MMType)
 216         do
 217                 assert params != null
 218                 _params = params
 219                 _return_type = return_type
 220                 _recv = r
 221         end
 222 end
 223
 224 # A closure in a signature
 225 class MMClosure
 226         # The signature of the closure
 227         readable attr _signature: MMSignature
 228
 229         # Is the closure a brek one
 230         # aka is defined with the break keyword thus does not return
 231         readable attr _is_break: Bool
 232
 233         # Is the closure optional?
 234         # ie is there a default definition
 235         readable attr _is_optional: Bool
 236
 237         # Adapt the signature to a different receiver
 238         meth adaptation_to(r: MMType): MMClosure
 239         do
 240                 return new MMClosure(_signature.adaptation_to(r), _is_break, _is_optional)
 241         end
 242
 243         init(s: MMSignature, is_break: Bool, is_optional: Bool)
 244         do
 245                 _signature = s
 246                 _is_break = is_break
 247                 _is_optional = is_optional
 248         end
 249
 250         meth not_for_self: MMClosure
 251         do
 252                 var sig = _signature.not_for_self
 253                 if sig != _signature then
 254                         return new MMClosure(sig, _is_break, _is_optional)
 255                 else
 256                         return self
 257                 end
 258         end
 259 end
 260
 261 # Inheritance relation between two types
 262 abstract class MMAncestor
 263         # The inherited type
 264         readable writable attr _stype: MMType = null
 265
 266         # The inheriter (heir) type
 267         readable writable attr _inheriter: MMType  = null
 268
 269         meth is_reffinement: Bool do
 270                 return stype.module != stype.module
 271         end
 272
 273         meth is_specialisation: Bool do
 274                 return stype.local_class.global != inheriter.local_class.global
 275         end
 276
 277         # The inherited class
 278         meth local_class: MMLocalClass is abstract
 279
 280         redef meth to_s
 281         do
 282                 if stype == null then
 283                         return local_class.to_s
 284                 else
 285                         return stype.to_s
 286                 end
 287         end
 288 end
 289
 290 # A static type
 291 # Note that static type a related to a specific module
 292 abstract class MMType
 293         # The module where self makes sence
 294         meth module: MMModule is abstract
 295
 296         # The local class that self direclty or indirectly refers to
 297         meth local_class: MMLocalClass is abstract
 298
 299         # Is self a valid subtype of t
 300         meth <(t : MMType): Bool is abstract
 301
 302         # Is self a valid supertype of t
 303         # This method must be only called within definition of < if
 304         # a double dispatch is needed
 305         meth is_supertype(t: MMType): Bool is abstract
 306
 307         # Adapt self to another module
 308         meth for_module(mod: MMModule): MMType is abstract
 309
 310         # Get the type adapted to another receiver type
 311         # Useful for formal types
 312         meth adapt_to(recv: MMType): MMType is abstract
 313
 314         # Adapt self to another local class context
 315         # Useful for genericity
 316         meth upcast_for(c: MMLocalClass): MMType is abstract
 317
 318         # Return a type approximation if the reveiver is not self
 319         # Useful for virtual types
 320         meth not_for_self: MMType do return self
 321 end
 322
 323 class MMTypeClass
 324 special MMType
 325         redef readable attr _local_class: MMLocalClass
 326         redef meth module do return _local_class.module end
 327         redef meth <(t) do return t != null and t.is_supertype(self)
 328
 329         redef meth to_s
 330         do
 331                 return _local_class.to_s
 332         end
 333
 334         redef meth upcast_for(c)
 335         do
 336                 assert _local_class != null
 337                 assert c != null
 338
 339                 var t: MMType = self
 340                 if _local_class != c then
 341                         t = _local_class.ancestor(c)
 342                 end
 343                 assert t != null
 344                 return t
 345         end
 346
 347         init(c : MMLocalClass)
 348         do
 349                 _local_class = c
 350         end
 351 end
 352
 353 class MMTypeSimpleClass
 354 special MMTypeClass
 355         redef meth is_supertype(t)
 356         do
 357                 return  t.local_class.cshe <= _local_class
 358         end
 359
 360         redef meth for_module(mod)
 361         do
 362                 var t: MMType = self
 363                 if module != mod then
 364                         t = _local_class.for_module(mod).get_type
 365                 end
 366                 assert t != null
 367                 return t
 368         end
 369
 370         redef meth adapt_to(recv) do return self
 371
 372         init(c: MMLocalClass)
 373         do
 374                 super(c)
 375         end
 376 end
 377
 378 # The type of null
 379 class MMTypeNone
 380 special MMType
 381         redef readable attr _module: MMModule
 382         redef meth <(t) do return true
 383         redef meth is_supertype(t) do return false
 384         redef meth local_class do abort
 385         redef meth upcast_for(c) do return self
 386
 387         private init(m: MMModule) do _module = m
 388 end
 389
 390 redef class MMModule
 391         # The type of null
 392         readable attr _type_none: MMTypeNone = new MMTypeNone(self)
 393 end