lib/ios/data_store.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Implements `app::data_store` using `NSUserDefaults`
  16 module data_store
  17
  18 import app::data_store
  19 import cocoa::foundation
  20 private import json
  21
  22 redef class App
  23         redef var data_store = new UserDefaultView
  24 end
  25
  26 private class UserDefaultView
  27         super DataStore
  28
  29         # The `NSUserDefaults` used to implement `DataStore`
  30         var user_defaults = new NSUserDefaults.standard_user_defaults is lazy
  31
  32         redef fun [](key)
  33         do
  34                 var nsstr = user_defaults.string_for_key(key.to_nsstring)
  35
  36                 if nsstr.address_is_null then return null
  37
  38                 # TODO report errors
  39                 var deserializer = new JsonDeserializer(nsstr.to_s)
  40                 return deserializer.deserialize
  41         end
  42
  43         redef fun []=(key, value)
  44         do
  45                 var nsobject: NSString
  46
  47                 if value == null then
  48                         nsobject = new NSString.nil
  49                 else
  50                         var serialized_string = new StringWriter
  51                         var serializer = new JsonSerializer(serialized_string)
  52                         serializer.serialize(value)
  53
  54                         # TODO report errors
  55                         nsobject = serialized_string.to_s.to_nsstring
  56                 end
  57
  58                 user_defaults.set_object(nsobject, key.to_nsstring)
  59         end
  60 end