tests/test_deserialization.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 import serialization
  18
  19 # Simple class
  20 class A
  21         auto_serializable
  22
  23         var b = false
  24         var c: Char
  25         var f: Float
  26         var i = 123
  27         var s = "asdf"
  28         var n: nullable Int
  29         var password = "p4ssw0rd" is lazy, noserialize
  30
  31         init(b: Bool, c: Char, f: Float, i: Int, s: String, n: nullable Int)
  32         do
  33                 self.b = b
  34                 self.c = c
  35                 self.f = f
  36                 self.i = i
  37                 self.s = s
  38         end
  39
  40         redef fun to_s do return "<A: {b} {c} {f} {i} {s} {n != null} {password}>"
  41 end
  42
  43 # Sub-class of A
  44 class B
  45         auto_serializable
  46         super A
  47
  48         var ii: Int
  49         var ss: String
  50
  51         init(b: Bool, c: Char, f: Float, i: Int, s: String, n: nullable Int, ii: Int, ss: String)
  52         do
  53                 super(b, c, f, i, s, n)
  54
  55                 self.ii = ii
  56                 self.ss = ss
  57         end
  58
  59         redef fun to_s do return "<B: {super} {ii} {ss}>"
  60 end
  61
  62 # Composed of an A and a B
  63 class C
  64         auto_serializable
  65
  66         var a: A
  67         var b = new B(false, 'b', 123.123, 2345, "hjkl", 12, 1111, "qwer")
  68         var aa: A
  69
  70         init(a: A, b: B)
  71         do
  72                 self.a = a
  73                 self.b = b
  74                 self.aa = a
  75         end
  76
  77         redef fun to_s do return "<C: {a} {b}>"
  78 end
  79
  80 # Class with cyclic reference
  81 class D
  82         auto_serializable
  83         super B
  84
  85         var d: nullable D = null
  86
  87         redef fun to_s do return "<D: {super} {d != null}>"
  88 end
  89
  90 # Class with generics
  91 class E
  92         auto_serializable
  93
  94         var a = new Array[Object].with_items("hello", 1234, 123.4)
  95         var b = new Array[nullable Serializable].with_items("hella", 2345, 234.5)
  96
  97         redef fun to_s do return "<E: a: {a.join(", ")}; b: {b.join(", ")}>"
  98 end
  99
 100 # Parameterized class
 101 class F[N: Numeric]
 102         auto_serializable
 103
 104         var n: N
 105
 106         redef fun to_s do return "<E: {n}>"
 107 end
 108
 109 # Other collections
 110 class G
 111         auto_serializable
 112
 113         var hs = new HashSet[Int]
 114         var s: Set[String] = new ArraySet[String]
 115         var hm = new HashMap[String, Int]
 116         var am = new ArrayMap[String, String]
 117
 118         init
 119         do
 120                 hs.add -1
 121                 hs.add 0
 122                 s.add "one"
 123                 s.add "two"
 124                 hm["one"] = 1
 125                 hm["two"] = 2
 126                 am["three"] = 3.to_s
 127                 am["four"] = 4.to_s
 128         end
 129
 130         redef fun to_s do return "<G: hs: {hs.join(", ")}; s: {s.join(", ")}; "+
 131                 "hm: {hm.join(", ", ". ")}; am: {am.join(", ", ". ")}>"
 132 end
 133
 134 class TestEntities
 135         var a = new A(true, 'a', 0.1234, 1234, "asdf", null)
 136         var b = new B(false, 'b', 123.123, 2345, "hjkl", 12, 1111, "qwer")
 137         var c = new C(a, b)
 138         var d = new D(false, 'b', 123.123, 2345, "new line ->\n<-", null, 1111, "\t\f\"\r\\/")
 139         init do d.d = d
 140         var e = new E
 141         var fi = new F[Int](2222)
 142         var ff = new F[Float](33.33)
 143         var g = new G
 144
 145         # should work without nitserial
 146         var without_generics: Array[Serializable] = [a, b, c, d: Serializable]
 147
 148         # Default works only with Nit serial
 149         var with_generics: Array[Serializable] = [a, b, c, d, e, fi, ff, g: Serializable]
 150 end
 151
 152 # We instanciate it here so that `nitserial` detects generic types as being alive
 153 var entities = new TestEntities