lib/standard/math.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2004-2008 Jean Privat <jean@pryen.org>
   4 #
   5 # This file is free software, which comes along with NIT.  This software is
   6 # distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
   7 # without  even  the implied warranty of  MERCHANTABILITY or  FITNESS FOR A
   8 # PARTICULAR PURPOSE.  You can modify it is you want,  provided this header
   9 # is kept unaltered, and a notification of the changes is added.
  10 # You  are  allowed  to  redistribute it and sell it, alone or is a part of
  11 # another product.
  12
  13 # Mathematical operations
  14 module math
  15
  16 import kernel
  17 import collection
  18
  19 in "C header" `{
  20 #include <math.h>
  21 `}
  22
  23 redef class Int
  24         # Returns a random `Int` in `[0 .. self[`.
  25         fun rand: Int is extern "kernel_Int_Int_rand_0"
  26
  27         # Returns the result of a binary AND operation on `self` and `i`
  28         #
  29         #     assert 0x10.bin_and(0x01) == 0
  30         fun bin_and(i: Int): Int is extern "kernel_Int_Int_binand_0"
  31
  32         # Returns the result of a binary OR operation on `self` and `i`
  33         #
  34         #     assert 0x10.bin_or(0x01) == 0x11
  35         fun bin_or(i: Int): Int is extern "kernel_Int_Int_binor_0"
  36
  37         # Returns the result of a binary XOR operation on `self` and `i`
  38         #
  39         #     assert 0x101.bin_xor(0x110) == 0x11
  40         fun bin_xor(i: Int): Int is extern "kernel_Int_Int_binxor_0"
  41
  42         # Returns the 1's complement of `self`
  43         #
  44         #     assert 0x2F.bin_not == -48
  45         fun bin_not: Int is extern "kernel_Int_Int_binnot_0"
  46
  47         # Returns the square root of `self`
  48         #
  49         #     assert 16.sqrt == 4
  50         fun sqrt: Int `{ return sqrt(recv); `}
  51
  52         # Returns the greatest common divisor of `self` and `o`
  53         #
  54         #     assert 54.gcd(24)   == 6
  55         #     assert -54.gcd(-24) == 6
  56         #     assert 54.gcd(-24)  == -6
  57         #     assert -54.gcd(24)  == -6
  58         #     assert 12.gcd(6)    == 6
  59         fun gcd(o: Int): Int
  60         do
  61                 if self < 0 then return -(-self).gcd(o)
  62                 if o < 0 then return -(self.gcd(-o))
  63                 if self == 0 or o == self then return o
  64                 if o == 0 then return self
  65                 if self.bin_and(1) == 0 then
  66                         if o.bin_and(1) == 1 then
  67                                 return self.rshift(1).gcd(o)
  68                         else
  69                                 return self.rshift(1).gcd(o.rshift(1)).lshift(1)
  70                         end
  71                 end
  72                 if o.bin_and(1) == 0 then return self.gcd(o.rshift(1))
  73                 if self > o then return (self - o).rshift(1).gcd(o)
  74                 return (o - self).rshift(1).gcd(self)
  75         end
  76
  77         # Is `self` even ?
  78         #
  79         #     assert 12.is_even
  80         fun is_even: Bool do return self % 2 == 0
  81
  82         # Is `self` odd ?
  83         #
  84         #     assert not 13.is_even
  85         fun is_odd: Bool do return not is_even
  86
  87         # Returns the `self` raised to the power of `e`.
  88         #
  89         #     assert 2 ** 3 == 8
  90         fun **(e: Int): Int
  91         do
  92                 return self.to_f.pow(e.to_f).to_i
  93         end
  94
  95         # The factorial of `self` (aka `self!`)
  96         #
  97         # Returns `1 * 2 * 3 * ... * self-1 * self`
  98         #
  99         #     assert 0.factorial == 1  # by convention for an empty product
 100         #     assert 1.factorial == 1
 101         #     assert 4.factorial == 24
 102         #     assert 9.factorial == 362880
 103         fun factorial: Int
 104         do
 105                 assert self >= 0
 106                 var res = 1
 107                 var n = self
 108                 while n > 0 do
 109                         res = res * n
 110                         n -= 1
 111                 end
 112                 return res
 113         end
 114 end
 115
 116 redef class Float
 117
 118         # Returns the non-negative square root of `self`.
 119         #
 120         #     assert 9.0.sqrt == 3.0
 121         #     #assert 3.0.sqrt == 1.732
 122         #     assert 1.0.sqrt == 1.0
 123         #     assert 0.0.sqrt == 0.0
 124         fun sqrt: Float is extern "kernel_Float_Float_sqrt_0"
 125
 126         # Computes the cosine of `self` (expressed in radians).
 127         #
 128         #     #assert pi.cos == -1.0
 129         fun cos: Float is extern "kernel_Float_Float_cos_0"
 130
 131         # Computes the sine of `self` (expressed in radians).
 132         #
 133         #     #assert pi.sin == 0.0
 134         fun sin: Float is extern "kernel_Float_Float_sin_0"
 135
 136         # Computes the cosine of x (expressed in radians).
 137         #
 138         #     #assert 0.0.tan == 0.0
 139         fun tan: Float is extern "kernel_Float_Float_tan_0"
 140
 141         # Computes the arc cosine of `self`.
 142         #
 143         #     #assert 0.0.acos == pi / 2.0
 144         fun acos: Float is extern "kernel_Float_Float_acos_0"
 145
 146         # Computes the arc sine of `self`.
 147         #
 148         #     #assert 1.0.asin == pi / 2.0
 149         fun asin: Float is extern "kernel_Float_Float_asin_0"
 150
 151         # Computes the arc tangent of `self`.
 152         #
 153         #     #assert 0.0.tan == 0.0
 154         fun atan: Float is extern "kernel_Float_Float_atan_0"
 155
 156         # Returns the absolute value of `self`.
 157         #
 158         #     assert 12.0.abs == 12.0
 159         #     assert (-34.56).abs == 34.56
 160         #     assert -34.56.abs == -34.56
 161         fun abs: Float `{ return fabs(recv); `}
 162
 163         # Returns `self` raised at `e` power.
 164         #
 165         #     #assert 2.0.pow(0.0) == 1.0
 166         #     #assert 2.0.pow(3.0) == 8.0
 167         #     #assert 0.0.pow(9.0) == 0.0
 168         fun pow(e: Float): Float is extern "kernel_Float_Float_pow_1"
 169
 170         # Returns the logarithm of `self`.
 171         #
 172         #     assert 0.0.log.is_inf == -1
 173         #     #assert 1.0.log == 0.0
 174         fun log: Float is extern "kernel_Float_Float_log_0"
 175
 176         # Returns *e* raised to `self`.
 177         fun exp: Float is extern "kernel_Float_Float_exp_0"
 178
 179         #     assert 1.1.ceil == 2.0
 180         #     assert 1.9.ceil == 2.0
 181         #     assert 2.0.ceil == 2.0
 182         #     assert (-1.5).ceil == -1.0
 183         fun ceil: Float `{ return ceil(recv); `}
 184
 185         #     assert 1.1.floor == 1.0
 186         #     assert 1.9.floor == 1.0
 187         #     assert 2.0.floor == 2.0
 188         #     assert (-1.5).floor == -2.0
 189         fun floor: Float `{ return floor(recv); `}
 190
 191         # Rounds the value of a float to its nearest integer value
 192         #
 193         #     assert 1.67.round == 2.0
 194         #     assert 1.34.round == 1.0
 195         #     assert -1.34.round == -1.0
 196         #     assert -1.67.round == -2.0
 197         fun round: Float is extern "round"
 198
 199         # Returns a random `Float` in `[0.0 .. self[`.
 200         fun rand: Float is extern "kernel_Float_Float_rand_0"
 201
 202         # Returns the euclidean distance from `b`.
 203         fun hypot_with(b : Float): Float is extern "hypotf"
 204
 205         # Returns true is self is not a number.
 206         fun is_nan: Bool is extern "isnan"
 207
 208         # Is the float an infinite value
 209         # this function returns:
 210         #
 211         #  * 1 if self is positive infinity
 212         #  * -1 if self is negative infinity
 213         #  * 0 otherwise
 214         fun is_inf: Int do
 215                 if is_inf_extern then
 216                         if self < 0.0 then return -1
 217                         return 1
 218                 end
 219                 return 0
 220         end
 221
 222         private fun is_inf_extern: Bool is extern "isinf"
 223 end
 224
 225 redef class Collection[ E ]
 226         # Return a random element form the collection
 227         # There must be at least one element in the collection
 228         fun rand: E
 229         do
 230                 if is_empty then abort
 231                 var rand_index = length.rand
 232
 233                 for e in self do
 234                         if rand_index == 0 then return e
 235                         rand_index -= 1
 236                 end
 237                 abort
 238         end
 239 end
 240
 241 redef class SequenceRead[E]
 242         # Optimized for large collections using `[]`
 243         redef fun rand
 244         do
 245                 assert not is_empty
 246                 return self[length.rand]
 247         end
 248 end
 249
 250 redef class Sys
 251         init
 252         do
 253                 srand
 254         end
 255 end
 256
 257 # Computes the arc tangent given `x` and `y`.
 258 #
 259 #     assert atan2(-0.0, 1.0) == -0.0
 260 #     assert atan2(0.0, 1.0) == 0.0
 261 fun atan2(x: Float, y: Float): Float is extern "kernel_Any_Any_atan2_2"
 262
 263 # Approximate value of **pi**.
 264 fun pi: Float is extern "kernel_Any_Any_pi_0"
 265
 266 # Initialize the pseudo-random generator with the given seed.
 267 # The pseudo-random generator is used by the method `rand` and other to generate sequence of numbers.
 268 # These sequences are repeatable by calling `srand_from` with a same seed value.
 269 #
 270 # ~~~~
 271 # srand_from(0)
 272 # var a = 10.rand
 273 # var b = 100.rand
 274 # srand_from(0)
 275 # assert 10.rand == a
 276 # assert 100.rand == b
 277 # ~~~~
 278 fun srand_from(x: Int) is extern "kernel_Any_Any_srand_from_1"
 279
 280 # Reinitialize the pseudo-random generator used by the method `rand` and other.
 281 # This method is automatically invoked at the begin of the program, so usually, there is no need to manually invoke it.
 282 # The only exception is in conjunction with `srand_from` to reset the pseudo-random generator.
 283 fun srand is extern "kernel_Any_Any_srand_0"