lib/serialization/serialization.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Abstract services to serialize Nit objects to different formats
  18 #
  19 # This module declares the `auto_serializable` annotation to mark Nit classes as serializable.
  20 # For an introduction to this service, refer to the documentation of the `serialization` group.
  21 # This documentation provides more technical information on interesting entitie of this module.
  22 #
  23 # Interesting entities for end users of serializable classes:
  24 #
  25 # * Serialize an instance subclass of `Serializable` with either
  26 #   `Serializer::serializable` and `Serializable::serialize`.
  27 # * Deserialize an object using `Deserializer::deserialize`.
  28 #   The object type must the be checked with an `assert` or otherwise.
  29 #
  30 # Interesting entities to create custom serializable classes:
  31 #
  32 # * Subclass `Serializable` to declare a class as serializable and to customize
  33 #   the serialization and deserialization behavior.
  34 # * Redefine `Serializable::core_serialize_to` to customize the serialization
  35 #   of the receiver class.
  36 # * Redefine `Deserializer::deserialize_class` to customize the deserialization
  37 #   of a specific class by name.
  38 #
  39 # Interesting entities for serialization format:
  40 #
  41 # * Subclass `Serializer` and `Deserializer` with custom serices.
  42 # * In `Serializer`, `serialize` and `serialize_reference` must be redefined.
  43 # * In `Deserializer`; `deserialize`, `deserialize_attribute and
  44 #   `notify_of_creation` must be redefined.
  45 module serialization is
  46         new_annotation auto_serializable
  47         new_annotation serialize
  48         new_annotation noserialize
  49 end
  50
  51 # Abstract serialization service to be sub-classed by specialized services.
  52 interface Serializer
  53         # Entry point method of this service, serialize the `object`
  54         #
  55         # This method, and refinements, should handle `null` and probably
  56         # use double dispatch to customize the bahavior per serializable objects.
  57         fun serialize(object: nullable Serializable) is abstract
  58
  59         # Serialize an object, with full serialization or a simple reference
  60         protected fun serialize_reference(object: Serializable) is abstract
  61
  62         # Serialize an attribute to compose a serializable object
  63         #
  64         # This method should be called from `Serializable::core_serialize_to`.
  65         fun serialize_attribute(name: String, value: nullable Object)
  66         do
  67                 if not try_to_serialize(value) then
  68                         warn("argument {name} of type {value.class_name} is not serializable.")
  69                 end
  70         end
  71
  72         # Serialize `value` is possie, i.e. it is `Serializable` or `null`
  73         fun try_to_serialize(value: nullable Object): Bool
  74         do
  75                 if value isa Serializable then
  76                         value.serialize_to_or_delay(self)
  77                 else if value == null then
  78                         serialize value
  79                 else return false
  80                 return true
  81         end
  82
  83         # Warn of problems and potential errors (such as if an attribute
  84         # is not serializable)
  85         fun warn(msg: String) do print "Serialization warning: {msg}"
  86 end
  87
  88 # Abstract deserialization service
  89 #
  90 # After initialization of one of its sub-classes, call `deserialize`
  91 interface Deserializer
  92         # Main method of this class, returns a Nit object
  93         fun deserialize: nullable Object is abstract
  94
  95         # Internal method to be implemented by sub-classes
  96         fun deserialize_attribute(name: String): nullable Object is abstract
  97
  98         # Internal method called by objects in creation,
  99         # to be implemented by sub-classes
 100         fun notify_of_creation(new_object: Object) is abstract
 101
 102         # Deserialize the next available object as an instance of `class_name`
 103         #
 104         # Returns the deserialized object on success, aborts on error.
 105         #
 106         # This method should be redefined for each custom subclass of `Serializable`.
 107         # All refinement should look for a precise `class_name` and call super
 108         # on unsupported classes.
 109         fun deserialize_class(class_name: String): Object do
 110                 print "Error: doesn't know how to deserialize class \"{class_name}\""
 111                 abort
 112         end
 113 end
 114
 115 # Instances of this class can be passed to `Serializer::serialize`
 116 interface Serializable
 117         # Serialize `self` to `serializer`
 118         #
 119         # This is a shortcut to `Serializer::serialize`.
 120         fun serialize_to(serializer: Serializer) do serializer.serialize(self)
 121
 122         # Actual serialization of `self` to `serializer`
 123         #
 124         # This writes the full data of `self` to `serializer`.
 125         #
 126         # This method can be redefined in sub classes and refinements.
 127         # It should use `Serializer::serialize_attribute` to to register real or
 128         # logical attributes.
 129         #
 130         # Any refinement should have its equivalent refinement of
 131         # `Deserializer::deserialize_class` to support this custom deserialization.
 132         fun core_serialize_to(serializer: Serializer) do end
 133
 134         # Accept references or force direct serialization (using `serialize_to`)
 135         #
 136         # The subclass change the default behavior, which will accept references,
 137         # to force to always serialize copies of `self`.
 138         private fun serialize_to_or_delay(v: Serializer) do v.serialize_reference(self)
 139
 140         # Create an instance of this class from the `deserializer`
 141         #
 142         # This constructor is refined by subclasses to correctly build their instances.
 143         init from_deserializer(deserializer: Deserializer) do end
 144 end
 145
 146 redef interface Object
 147         # Is `self` the same as `other` in a serialization context?
 148         #
 149         # Used to determine if an object has already been serialized.
 150         fun is_same_serialized(other: nullable Object): Bool do return is_same_instance(other)
 151
 152         # Hash value use for serialization
 153         #
 154         # Used in combination with `is_same_serialized`. If two objects are the same
 155         # in a serialization context, they must have the same `serialization_hash`.
 156         fun serialization_hash: Int do return object_id
 157 end
 158
 159 # Instances of this class are not delayed and instead serialized immediately
 160 # This applies mainly to `universal` types
 161 interface DirectSerializable
 162         super Serializable
 163
 164         redef fun serialize_to_or_delay(v) do serialize_to(v)
 165 end
 166
 167 redef class Bool super DirectSerializable end
 168 redef class Char super DirectSerializable end
 169 redef class Int super DirectSerializable end
 170 redef class Float super DirectSerializable end
 171 redef class NativeString super DirectSerializable end
 172 redef class String super DirectSerializable end
 173 redef class SimpleCollection[E] super Serializable end
 174 redef class Map[K, V] super Serializable end
 175
 176 redef class Couple[F, S]
 177         super Serializable
 178
 179         redef init from_deserializer(v)
 180         do
 181                 v.notify_of_creation self
 182                 var first = v.deserialize_attribute("first")
 183                 var second = v.deserialize_attribute("second")
 184                 init(first, second)
 185         end
 186
 187         redef fun core_serialize_to(v)
 188         do
 189                 v.serialize_attribute("first", first)
 190                 v.serialize_attribute("second", second)
 191         end
 192 end
 193
 194 redef class Container[E]
 195         super Serializable
 196
 197         redef init from_deserializer(v)
 198         do
 199                 v.notify_of_creation self
 200                 var item = v.deserialize_attribute("item")
 201                 init item
 202         end
 203
 204         redef fun core_serialize_to(v)
 205         do
 206                 v.serialize_attribute("item", first)
 207         end
 208 end