contrib/nitiwiki/src/wiki_html.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # HTML wiki rendering
  16 module wiki_html
  17
  18 import wiki_links
  19 import markdown::decorators
  20
  21 redef class Nitiwiki
  22
  23         # Render HTML output looking for changes in the markdown sources.
  24         redef fun render do
  25                 super
  26                 if not root_section.is_dirty and not force_render then return
  27                 var out_dir = expand_path(config.root_dir, config.out_dir)
  28                 out_dir.mkdir
  29                 copy_assets
  30                 root_section.add_child make_sitemap
  31                 root_section.render
  32         end
  33
  34         # Copy the asset directory to the (public) output directory.
  35         private fun copy_assets do
  36                 var src = expand_path(config.root_dir, config.assets_dir)
  37                 var out = expand_path(config.root_dir, config.out_dir)
  38                 if need_render(src, expand_path(out, config.assets_dir)) then
  39                         if src.file_exists then sys.system "cp -R {src} {out}"
  40                 end
  41         end
  42
  43         # Build the wiki sitemap page.
  44         private fun make_sitemap: WikiSitemap do
  45                 var sitemap = new WikiSitemap(self, "sitemap")
  46                 sitemap.is_dirty = true
  47                 return sitemap
  48         end
  49
  50         # Markdown processor used for inline element such as titles in TOC.
  51         private var inline_processor: MarkdownProcessor is lazy do
  52                 var proc = new MarkdownProcessor
  53                 proc.emitter.decorator = new InlineDecorator
  54                 return proc
  55         end
  56
  57         # Inline markdown (remove h1, p, ... elements).
  58         private fun inline_md(md: Writable): Writable do
  59                 return inline_processor.process(md.write_to_string)
  60         end
  61 end
  62
  63 redef class WikiEntry
  64         # Get a `<a>` template link to `self`
  65         fun tpl_link: Writable do
  66                 return "<a href=\"{url}\">{title}</a>"
  67         end
  68 end
  69
  70 redef class WikiSection
  71
  72         # Output directory (where to ouput the HTML pages for this section).
  73         redef fun out_path: String do
  74                 if parent == null then
  75                         return wiki.config.out_dir
  76                 else
  77                         return wiki.expand_path(parent.out_path, name)
  78                 end
  79         end
  80
  81         redef fun render do
  82                 if not is_dirty and not wiki.force_render then return
  83                 if is_new then
  84                         out_full_path.mkdir
  85                 else
  86                         sys.system "touch {out_full_path}"
  87                 end
  88                 if has_source then
  89                         wiki.message("Render section {out_path}", 1)
  90                         copy_files
  91                 end
  92                 var index = self.index
  93                 if index isa WikiSectionIndex then
  94                         wiki.message("Render auto-index for section {out_path}", 1)
  95                         index.is_dirty = true
  96                         add_child index
  97                 end
  98                 super
  99         end
 100
 101         # Copy attached files from `src_path` to `out_path`.
 102         private fun copy_files do
 103                 assert has_source
 104                 var dir = src_full_path.to_s
 105                 for name in dir.files do
 106                         if name == wiki.config_filename then continue
 107                         if name.has_suffix(".md") then continue
 108                         if has_child(name) then continue
 109                         var src = wiki.expand_path(dir, name)
 110                         var out = wiki.expand_path(out_full_path, name)
 111                         if not wiki.need_render(src, out) then continue
 112                         sys.system "cp -R {src} {out_full_path}"
 113                 end
 114         end
 115
 116         redef fun tpl_link do return index.tpl_link
 117
 118         # Render the section hierarchy as a html tree.
 119         #
 120         # `limit` is used to specify the max-depth of the tree.
 121         #
 122         # The generated tree will be something like this:
 123         #
 124         # ~~~html
 125         # <ul>
 126         #  <li>section 1</li>
 127         #  <li>section 2
 128         #   <ul>
 129         #    <li>section 2.1</li>
 130         #    <li>section 2.2</li>
 131         #   </ul>
 132         #  </li>
 133         # </ul>
 134         # ~~~
 135         fun tpl_tree(limit: Int): Template do
 136                 return tpl_tree_intern(limit, 1)
 137         end
 138
 139         # Build the template tree for this section recursively.
 140         protected fun tpl_tree_intern(limit, count: Int): Template do
 141                 var out = new Template
 142                 var index = index
 143                 out.add "<li>"
 144                 out.add tpl_link
 145                 if (limit < 0 or count < limit) and
 146                    (children.length > 1 or (children.length == 1)) then
 147                         out.add " <ul>"
 148                         for child in children.values do
 149                                 if child == index then continue
 150                                 if child isa WikiArticle then
 151                                         out.add "<li>"
 152                                         out.add child.tpl_link
 153                                         out.add "</li>"
 154                                 else if child isa WikiSection and not child.is_hidden then
 155                                         out.add child.tpl_tree_intern(limit, count + 1)
 156                                 end
 157                         end
 158                         out.add " </ul>"
 159                 end
 160                 out.add "</li>"
 161                 return out
 162         end
 163 end
 164
 165 redef class WikiArticle
 166
 167         redef fun out_path: String do
 168                 if parent == null then
 169                         return wiki.expand_path(wiki.config.out_dir, "{name}.html")
 170                 else
 171                         return wiki.expand_path(parent.out_path, "{name}.html")
 172                 end
 173         end
 174
 175         redef fun render do
 176                 super
 177                 if not is_dirty and not wiki.force_render then return
 178                 wiki.message("Render article {name}", 2)
 179                 var file = out_full_path
 180                 file.dirname.mkdir
 181                 tpl_page.write_to_file file
 182         end
 183
 184
 185         # Replace macros in the template by wiki data.
 186         private fun tpl_page: TemplateString do
 187                 var tpl = wiki.load_template(template_file)
 188                 if tpl.has_macro("TOP_MENU") then
 189                         tpl.replace("TOP_MENU", tpl_menu)
 190                 end
 191                 if tpl.has_macro("HEADER") then
 192                         tpl.replace("HEADER", tpl_header)
 193                 end
 194                 if tpl.has_macro("BODY") then
 195                         tpl.replace("BODY", tpl_article)
 196                 end
 197                 if tpl.has_macro("FOOTER") then
 198                         tpl.replace("FOOTER", tpl_footer)
 199                 end
 200                 return tpl
 201         end
 202
 203         # Generate the HTML header for this article.
 204         fun tpl_header: Writable do
 205                 var file = header_file
 206                 if not wiki.has_template(file) then return ""
 207                 return wiki.load_template(file)
 208         end
 209
 210         # Generate the HTML page for this article.
 211         fun tpl_article: TplArticle do
 212                 var article = new TplArticle
 213                 article.body = content
 214                 article.breadcrumbs = new TplBreadcrumbs(self)
 215                 tpl_sidebar.blocks.add tpl_summary
 216                 article.sidebar = tpl_sidebar
 217                 article.sidebar_pos = wiki.config.sidebar
 218                 return article
 219         end
 220
 221         # Sidebar for this page.
 222         var tpl_sidebar = new TplSidebar
 223
 224         # Generate the HTML summary for this article.
 225         #
 226         # Based on `headlines`
 227         fun tpl_summary: Writable do
 228                 var headlines = self.headlines
 229                 var tpl = new Template
 230                 tpl.add "<ul class=\"summary list-unstyled\">"
 231                 var iter = headlines.iterator
 232                 while iter.is_ok do
 233                         var hl = iter.item
 234                         # parse title as markdown
 235                         var title = wiki.inline_md(hl.title)
 236                         tpl.add "<li><a href=\"#{hl.id}\">{title}</a>"
 237                         iter.next
 238                         if iter.is_ok then
 239                                 if iter.item.level > hl.level then
 240                                         tpl.add "<ul class=\"list-unstyled\">"
 241                                 else if iter.item.level < hl.level then
 242                                         tpl.add "</li>"
 243                                         tpl.add "</ul>"
 244                                 end
 245                         else
 246                                 tpl.add "</li>"
 247                         end
 248                 end
 249                 tpl.add "</ul>"
 250                 return tpl
 251         end
 252
 253         # Generate the HTML menu for this article.
 254         fun tpl_menu: Writable do
 255                 var file = menu_file
 256                 if not wiki.has_template(file) then return ""
 257                 var tpl = wiki.load_template(file)
 258                 if tpl.has_macro("MENUS") then
 259                         var items = new Template
 260                         for child in wiki.root_section.children.values do
 261                                 if child isa WikiArticle and child.is_index then continue
 262                                 if child isa WikiSection and child.is_hidden then continue
 263                                 items.add "<li"
 264                                 if self == child or self.breadcrumbs.has(child) then
 265                                         items.add " class=\"active\""
 266                                 end
 267                                 items.add ">"
 268                                 items.add child.tpl_link
 269                                 items.add "</li>"
 270                         end
 271                         tpl.replace("MENUS", items)
 272                 end
 273                 return tpl
 274         end
 275
 276         # Generate the HTML footer for this article.
 277         fun tpl_footer: Writable do
 278                 var file = footer_file
 279                 if not wiki.has_template(file) then return ""
 280                 var tpl = wiki.load_template(file)
 281                 var time = new Tm.gmtime
 282                 if tpl.has_macro("YEAR") then
 283                         tpl.replace("YEAR", (time.year + 1900).to_s)
 284                 end
 285                 if tpl.has_macro("GEN_TIME") then
 286                         tpl.replace("GEN_TIME", time.to_s)
 287                 end
 288                 return tpl
 289         end
 290 end
 291
 292 # A `WikiArticle` that contains the sitemap tree.
 293 class WikiSitemap
 294         super WikiArticle
 295
 296         redef fun tpl_article do
 297                 var article = new TplArticle.with_title("Sitemap")
 298                 article.body = new TplPageTree(wiki.root_section, -1)
 299                 return article
 300         end
 301
 302         redef var is_dirty = false
 303 end
 304
 305 # A `WikiArticle` that contains the section index tree.
 306 redef class WikiSectionIndex
 307
 308         redef var is_dirty = false
 309
 310         redef fun tpl_article do
 311                 var article = new TplArticle.with_title(section.title)
 312                 article.body = new TplPageTree(section, -1)
 313                 article.breadcrumbs = new TplBreadcrumbs(self)
 314                 return article
 315         end
 316 end
 317
 318 # Article HTML output.
 319 class TplArticle
 320         super Template
 321
 322         # Article title.
 323         var title: nullable Writable = null
 324
 325         # Article HTML body.
 326         var body: nullable Writable = null
 327
 328         # Sidebar of this article (if any).
 329         var sidebar: nullable TplSidebar = null
 330
 331         # Position of the sidebar.
 332         #
 333         # See `WikiConfig::sidebar`.
 334         var sidebar_pos: String = "left"
 335
 336         # Breadcrumbs from wiki root to this article.
 337         var breadcrumbs: nullable TplBreadcrumbs = null
 338
 339         # Init `self` with a `title`.
 340         init with_title(title: Writable) do
 341                 self.title = title
 342         end
 343
 344         redef fun rendering do
 345                 if sidebar_pos == "left" then render_sidebar
 346                 if sidebar == null then
 347                         add "<div class=\"col-sm-12 content\">"
 348                 else
 349                         add "<div class=\"col-sm-9 content\">"
 350                 end
 351                 if body != null then
 352                         add "<article>"
 353                         if breadcrumbs != null then
 354                                 add breadcrumbs.as(not null)
 355                         end
 356                         if title != null then
 357                                 add "<h1>"
 358                                 add title.as(not null)
 359                                 add "</h1>"
 360                         end
 361                         add     body.as(not null)
 362                         add " </article>"
 363                 end
 364                 add "</div>"
 365                 if sidebar_pos == "right" then render_sidebar
 366         end
 367
 368         private fun render_sidebar do
 369                 if sidebar == null then return
 370                 add "<div class=\"col-sm-3 sidebar\">"
 371                 add sidebar.as(not null)
 372                 add "</div>"
 373         end
 374 end
 375
 376 # A collection of HTML blocks displayed on the side of a page.
 377 class TplSidebar
 378         super Template
 379
 380         # Blocks are `Stremable` pieces that will be rendered in the sidebar.
 381         var blocks = new Array[Writable]
 382
 383         redef fun rendering do
 384                 for block in blocks do
 385                         add "<div class=\"sideblock\">"
 386                         add block
 387                         add "</div>"
 388                 end
 389         end
 390 end
 391
 392 # An HTML breadcrumbs that show the path from a `WikiArticle` to the `Nitiwiki` root.
 393 class TplBreadcrumbs
 394         super Template
 395
 396         # Bread crumb article.
 397         var article: WikiArticle
 398
 399         redef fun rendering do
 400                 var path = article.breadcrumbs
 401                 if path.is_empty or path.length <= 2 and article.is_index then return
 402                 add "<ol class=\"breadcrumb\">"
 403                 for entry in path do
 404                         if entry == path.last then
 405                                 add "<li class=\"active\">"
 406                                 add entry.title
 407                                 add "</li>"
 408                         else
 409                                 if article.parent == entry and article.is_index then continue
 410                                 add "<li>"
 411                                 add entry.tpl_link
 412                                 add "</li>"
 413                         end
 414                 end
 415                 add "</ol>"
 416         end
 417 end
 418
 419 # An HTML tree that show the section pages structure.
 420 class TplPageTree
 421         super Template
 422
 423         # Builds the page tree from `root`.
 424         var root: WikiSection
 425
 426         # Limits the tree depth to `max_depth` levels.
 427         var max_depth: Int
 428
 429         redef fun rendering do
 430                 add "<ul>"
 431                 add root.tpl_tree(-1)
 432                 add "</ul>"
 433         end
 434 end