src/doc/doc_base.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 # http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Base entities shared by all the nitdoc code.
  16 module doc_base
  17
  18 import toolcontext
  19 import model_utils
  20 import model_ext
  21
  22 # The model of a Nitdoc documentation.
  23 #
  24 # `DocModel` contains the list of the `DocPage` to be generated.
  25 #
  26 # The model is populated through `DocPhase` to be constructed.
  27 # It is a placeholder to share data between each phase.
  28 class DocModel
  29
  30         # `DocPage` composing the documentation.
  31         #
  32         # This is where `DocPhase` store and access pages to produce documentation.
  33         var pages = new Array[DocPage]
  34
  35         # Nit `Model` from which we extract the documentation.
  36         var model: Model is writable
  37
  38         # The entry point of the `model`.
  39         var mainmodule: MModule is writable
  40 end
  41
  42 # A documentation page abstraction.
  43 #
  44 # The page contains a link to the `root` of the `DocComposite` that compose the
  45 # the page.
  46 class DocPage
  47
  48         # Title of this page.
  49         var title: String is writable
  50
  51         # Root element of the page.
  52         #
  53         # `DocPhase` access the structure of the page from the `DocRoot`.
  54         var root = new DocRoot
  55
  56         redef fun to_s do return title
  57 end
  58
  59 # `DocPage` elements that can be nested in another.
  60 #
  61 # `DocComposite` is an abstraction for everything that go in a `DocPage` like
  62 # sections, articles, images, lists, graphs...
  63 #
  64 # It provides base services for nesting mechanisms following the
  65 # *Composite pattern*.
  66 # The composed structure is a tree from a `DocRoot` that can be manipulated
  67 # recursively.
  68 abstract class DocComposite
  69
  70         # Parent element.
  71         var parent: nullable DocComposite = null is writable
  72
  73         # Does `self` have a `parent`?
  74         fun is_root: Bool do return parent == null
  75
  76         # Children elements contained in `self`.
  77         #
  78         # Children are ordered, this order can be changed by the `DocPhase`.
  79         var children = new Array[DocComposite]
  80
  81         # Does `self` have `children`?
  82         fun is_empty: Bool do return children.is_empty
  83
  84         # Add a `child` to `self`.
  85         #
  86         # Shortcut for `children.add`.
  87         fun add_child(child: DocComposite) do
  88                 child.parent = self
  89                 children.add child
  90         end
  91 end
  92
  93 # The `DocComposite` element that contains all the other.
  94 #
  95 # The root uses a specific subclass to provide different a different behavior
  96 # than other `DocComposite` elements.
  97 class DocRoot
  98         super DocComposite
  99
 100         # No op for `RootSection`.
 101         redef fun parent=(p) do end
 102 end
 103
 104 # Base page elements.
 105
 106 # `DocSection` are used to break the documentation page into meaningfull parts.
 107 #
 108 # The content of the documentation summary is based on the section structure
 109 # contained in the DocComposite tree.
 110 class DocSection
 111         super DocComposite
 112 end
 113
 114 # `DocArticle` are pieces of documentation.
 115 #
 116 # They maintains the content (text, list, image...) of a documentation page.
 117 class DocArticle
 118         super DocComposite
 119 end
 120
 121 # A DocPhase is a step in the production of a Nitdoc documentation.
 122 #
 123 # Phases work from a `DocModel`.
 124 # Specific phases are used to populate, organize, enhance and render the content
 125 # of the documentation pages.
 126 #
 127 # See `doc_phases` for available DocPhase.
 128 class DocPhase
 129
 130         # Link to the ToolContext to access Nitdoc tool options.
 131         var ctx: ToolContext
 132
 133         # `DocModel` used by this phase to work.
 134         var doc: DocModel
 135
 136         # Starting point of a `DocPhase`.
 137         #
 138         # This is where the behavior of the phase is implemented.
 139         # Phases can populate, edit or render the `doc` from here.
 140         fun apply is abstract
 141 end
 142
 143 redef class ToolContext
 144
 145         # Directory where the Nitdoc is rendered.
 146         var opt_dir = new OptionString("output directory", "-d", "--dir")
 147
 148         # Shortcut for `opt_dir.value` with default "doc".
 149         var output_dir: String is lazy do return opt_dir.value or else "doc"
 150
 151         redef init do
 152                 super
 153                 option_context.add_option(opt_dir)
 154         end
 155 end
 156
 157 # Catalog properties by kind.
 158 class PropertiesByKind
 159         # The virtual types.
 160         var virtual_types = new PropertyGroup[MVirtualTypeProp]("Virtual types")
 161
 162         # The constructors.
 163         var constructors = new PropertyGroup[MMethod]("Contructors")
 164
 165         # The attributes.
 166         var attributes = new PropertyGroup[MAttribute]("Attributes")
 167
 168         # The methods.
 169         var methods = new PropertyGroup[MMethod]("Methods")
 170
 171         # The inner classes.
 172         var inner_classes = new PropertyGroup[MInnerClass]("Inner classes")
 173
 174         # All the groups.
 175         #
 176         # Sorted in the order they are displayed to the user.
 177         var groups: SequenceRead[PropertyGroup[MProperty]] = [
 178                         virtual_types,
 179                         constructors,
 180                         attributes,
 181                         methods,
 182                         inner_classes: PropertyGroup[MProperty]]
 183
 184         # Add each the specified property to the appropriate list.
 185         init with_elements(properties: Collection[MProperty]) do add_all(properties)
 186
 187         # Add the specified property to the appropriate list.
 188         fun add(property: MProperty) do
 189                 if property isa MMethod then
 190                         if property.is_init then
 191                                 constructors.add property
 192                         else
 193                                 methods.add property
 194                         end
 195                 else if property isa MVirtualTypeProp then
 196                         virtual_types.add property
 197                 else if property isa MAttribute then
 198                         attributes.add property
 199                 else if property isa MInnerClass then
 200                         inner_classes.add property
 201                 else
 202                         abort
 203                 end
 204         end
 205
 206         # Add each the specified property to the appropriate list.
 207         fun add_all(properties: Collection[MProperty]) do
 208                 for p in properties do add(p)
 209         end
 210
 211         # Sort each group with the specified comparator.
 212         fun sort_groups(comparator: Comparator) do
 213                 for g in groups do comparator.sort(g)
 214         end
 215 end
 216
 217 # An ordered list of properties of the same kind.
 218 class PropertyGroup[E: MProperty]
 219         super Array[E]
 220
 221         # The title of the group, as displayed to the user.
 222         var title: String
 223 end
 224
 225 redef class MEntity
 226         # Name displayed in console for debug and tests.
 227         fun nitdoc_name: String do return name.html_escape
 228 end
 229
 230 redef class MClassDef
 231         redef fun nitdoc_name do return mclass.nitdoc_name
 232 end
 233
 234 redef class MPropDef
 235         redef fun nitdoc_name do return mproperty.nitdoc_name
 236 end