src/platform.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Platform system, used to customize the behavior of the compiler according
  16 # to the target platform. Also detects conflicts between targetted platforms.
  17 module platform
  18
  19 import parser_util
  20 import modelbuilder
  21 import modelize
  22 private import annotation
  23
  24 redef class ToolContext
  25         var platform_phase: Phase = new PlatformPhase(self, [modelize_property_phase])
  26
  27         protected fun platform_from_name(name: String): nullable Platform
  28         do
  29                 return null
  30         end
  31 end
  32
  33 private class PlatformPhase
  34         super Phase
  35
  36         redef fun process_annotated_node(nmoduledecl, nat)
  37         do
  38                 var annotation_name = "platform"
  39
  40                 # Skip if we are not interested
  41                 if nat.name != annotation_name then return
  42
  43                 # Do some validity checks and print errors if the annotation is used incorrectly
  44                 var modelbuilder = toolcontext.modelbuilder
  45                 if not nmoduledecl isa AModuledecl then
  46                         modelbuilder.error(nat, "Syntax error: only the declaration of modules may use \"{annotation_name}\".")
  47                         return
  48                 end
  49
  50                 var args = nat.n_args
  51                 var platform_name
  52                 if args.length > 1 then
  53                         modelbuilder.error(nat, "Syntax error: \"{annotation_name}\" expects at most a single argument.")
  54                         return
  55                 else if args.is_empty then
  56                         platform_name = nmoduledecl.n_name.collect_text
  57                 else
  58                         platform_name = args.first.as_string
  59                         if platform_name == null then
  60                                 var format_error = "Syntax error: \"{annotation_name}\" expects its argument to be the name of the target platform as a String literal."
  61                                 modelbuilder.error(nat, format_error)
  62                                 return
  63                         end
  64                 end
  65
  66                 var nmodule = nmoduledecl.parent.as(AModule)
  67                 var mmodule = nmodule.mmodule
  68
  69                 var platform = toolcontext.platform_from_name(platform_name)
  70                 if platform == null then
  71                         toolcontext.error(nat.location, "Error: target platform \"{platform_name}\" unknown")
  72                         return
  73                 end
  74
  75                 var previous_target_platform = mmodule.target_platform
  76                 if previous_target_platform != null and previous_target_platform != platform then
  77                         modelbuilder.error(nat, "Syntax error: a target platform has already been defined as \"{previous_target_platform}\".")
  78                 end
  79
  80                 mmodule.local_target_platform = platform
  81         end
  82 end
  83
  84 redef class MModule
  85         private var local_target_platform: nullable Platform = null
  86
  87         # Recusively get the platform targetted by this module or imported modules
  88         fun target_platform: nullable Platform
  89         do
  90                 var ltp = local_target_platform
  91                 if ltp != null then return ltp
  92
  93                 for mmodule in in_importation.greaters do
  94                         ltp = mmodule.local_target_platform
  95                         if ltp != null then return ltp
  96                 end
  97
  98                 return null
  99         end
 100 end
 101
 102 # Sub-classes of `Platform` represent the target platform of a compilation
 103 #
 104 # Services will be added to this class in other modules.
 105 abstract class Platform
 106         fun supports_libunwind: Bool do return true
 107
 108         fun supports_libgc: Bool do return true
 109
 110         # Does this platform declare its own main function? If so, we won't generate one in Nit.
 111         fun no_main: Bool do return false
 112 end