contrib/benitlux/src/benitlux_daily.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Daily program to fetch and parse the Web site, update the database and email subscribers
  18 module benitlux_daily
  19
  20 import curl
  21 import sendmail
  22 import opts
  23
  24 import benitlux_model
  25 import benitlux_db
  26
  27 redef class Text
  28         # Return a `String` without any HTML tags (such as `<br />`) from `recv`
  29         fun strip_tags: String
  30         do
  31                 var str = to_s
  32                 var new_str = ""
  33
  34                 var from = 0
  35                 loop
  36                         var at = str.index_of_from('<', from)
  37                         if at == -1 then break
  38
  39                         new_str += str.substring(from, at-from)
  40
  41                         at = str.index_of_from('>', at)
  42                         assert at != -1
  43
  44                         from = at+1
  45                 end
  46
  47                 return new_str
  48         end
  49
  50         # Return an `Array` of the non-empty lines in `self`
  51         #
  52         #     assert ["a", "asdf", "", "  ", "&nbsp;", "b"].join("\n").to_clean_lines == ["a", "asdf", "b"]
  53         fun to_clean_lines: Array[String]
  54         do
  55                 var orig_lines = split_with("\n")
  56                 var new_lines = new Array[String]
  57
  58                 for line in orig_lines do
  59                         line = line.trim
  60
  61                         # remove empty lines
  62                         if line == "&nbsp;" then continue
  63                         if line.is_empty then continue
  64
  65                         new_lines.add line.to_s
  66                 end
  67
  68                 return new_lines
  69         end
  70 end
  71
  72 # Main logic of the program to be executed daily
  73 class Benitlux
  74         # The street on which is the Benelux
  75         var street: String
  76
  77         # The url of this precise Benelux
  78         var url: String
  79
  80         # Path to the database
  81         var db_path: String
  82
  83         # Where to save the sample email
  84         var sample_email_path: String
  85
  86         init(street: String)
  87         do
  88                 self.street = street
  89                 self.url = "www.brasseriebenelux.com/{street}"
  90                 self.db_path = "benitlux_{street}.db"
  91                 self.sample_email_path = "benitlux_{street}.email"
  92         end
  93
  94         # Execute the main program logic
  95         fun run(send_emails: Bool)
  96         do
  97                 # Get the web page
  98                 var body = download_html_page
  99
 100                 # Parse the Web page and get the available beers
 101                 var beers = parse_beers_from_html(body)
 102
 103                 var db = new DB.open(db_path)
 104
 105                 # Update the database with the beers of the day
 106                 db.insert_beers_of_the_day beers
 107
 108                 # Query the beer-related events of today
 109                 var beer_events = db.beer_events_today
 110
 111                 # Generate the email title and content, store them in attributes
 112                 generate_email(beer_events)
 113
 114                 # Save as sample email to file
 115                 var f = new FileWriter.open(sample_email_path)
 116                 f.write email_title + "\n"
 117                 for line in email_content do f.write line + "\n"
 118                 f.close
 119
 120                 # Set the email if desired
 121                 if send_emails then
 122                         var subs = db.subscribers
 123                         send_emails_to subs
 124                 end
 125
 126                 db.close
 127         end
 128
 129         # Fetch the Web page at `url`
 130         fun download_html_page: String
 131         do
 132                 var request = new CurlHTTPRequest(url)
 133                 var response = request.execute
 134
 135                 if response isa CurlResponseSuccess then
 136                         var body = response.body_str
 137                         return body
 138                 else if response isa CurlResponseFailed then
 139                         print "Failed downloading URL '{url}' with: {response.error_msg} ({response.error_code})"
 140                         exit 1
 141                 end
 142                 abort
 143         end
 144
 145         # Extract the beers of the day information from the HTML if `body`
 146         fun parse_beers_from_html(body: String): HashSet[Beer]
 147         do
 148                 # Parts of the HTML page expected to encapsulate the interesting section
 149                 var header = "<h1>Bières<br /></h1>"
 150                 var ender = "</div></div></div>"
 151
 152                 var match = body.search(header)
 153                 assert match != null else print body
 154                 var start = match.after
 155
 156                 match = body.search_from(ender, start)
 157                 assert match != null
 158                 var finish = match.from
 159
 160                 var of_interest = body.substring(start, finish-start)
 161                 var lines = of_interest.strip_tags.to_clean_lines
 162
 163                 var beers = new HashSet[Beer]
 164                 for line in lines do
 165                         var parts = line.split(" - ")
 166                         if parts.length >= 2 then
 167                                 beers.add new Beer(parts[0].trim, parts[1].trim)
 168                         end
 169                 end
 170                 return beers
 171         end
 172
 173         # Content lines of the email
 174         var email_content: Array[String]
 175
 176         # Title of the email
 177         var email_title: String
 178
 179         # Generate email and fill the attributes `email_content` and `email_title`
 180         fun generate_email(beer_events: BeerEvents)
 181         do
 182                 email_title = beer_events.to_email_title
 183                 email_content = beer_events.to_email_content
 184         end
 185
 186         # Send the email to all the addresses in `subs`
 187         fun send_emails_to(subs: Array[String])
 188         do
 189                 for email in subs do
 190                         var unsub_link = "http://benitlux.xymus.net/?unsub=&email={email}"
 191                         var content = """
 192 {{{email_content.join("<br />\n")}}}
 193 <br /><br />
 194 To unsubscribe, go to <a href="{{{unsub_link}}}">{{{unsub_link}}}</a>
 195 """
 196
 197                         var mail = new Mail("Benitlux <benitlux@xymus.net>", email_title, content)
 198                         mail.to.add email
 199                         mail.header["Content-Type"] = "text/html; charset=\"UTF-8\""
 200                         mail.encrypt_with_base64
 201
 202                         mail.send
 203                 end
 204         end
 205 end
 206
 207 redef class OptionContext
 208         # Shall we mail the mailing list?
 209         var send_emails = new OptionBool("Send emails to subscribers", "-e", "--email")
 210
 211         # Print the usage message
 212         var help = new OptionBool("Print this help message", "-h", "--help")
 213
 214         redef init do add_option(send_emails, help)
 215 end
 216
 217 # Avoid executing when running tests
 218 if "NIT_TESTING".environ == "true" then exit 0
 219
 220 var opts = new OptionContext
 221 opts.parse args
 222 if not opts.errors.is_empty or opts.help.value == true then
 223         print opts.errors.join("\n")
 224         print "Usage: benitlux_daily [Options]"
 225         opts.usage
 226         exit 1
 227 end
 228
 229 var ben = new Benitlux("sherbrooke")
 230 ben.run(opts.send_emails.value)
 231
 232 # The parsing logic for the wellington locaiton is active (to gather data)
 233 # but the web interface do not allow to subscribe to its mailing list.
 234 #
 235 # TODO revamp mailing list Web interface
 236 ben = new Benitlux("wellington")
 237 ben.run(opts.send_emails.value)