src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20 Package org.nitlanguage.gen;
  21
  22 /*****************************************************************************/
  23 Helpers
  24 /*****************************************************************************/
  25
  26 all = [0 .. 0xFF];
  27 lowercase = ['a' .. 'z'];
  28 uppercase = ['A' .. 'Z'];
  29 digit = ['0' .. '9'];
  30 hexdigit = ['0'..'9'] | ['a'..'f'] | ['A'..'F'];
  31 letter = lowercase | uppercase | digit | '_';
  32
  33 tab = 9;
  34 cr = 13;
  35 lf = 10;
  36 any = [all - [cr + lf]];
  37 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  38
  39 // characers inside strings and super-strings (atomaton powaa)
  40 str_char
  41         = [any - [['"' + '{'] + '\']]
  42         | '\' any
  43         ;
  44 str_body = str_char*;
  45
  46 sstr_char
  47         = [any - [''' + '\']]
  48         | '\' any
  49         ;
  50
  51 sstr_body = sstr_char*;
  52
  53 long_str_char = str_char | cr | lf;
  54
  55 // because no substraction in sablecc3, complex long strings are difficult to express
  56 ls1 = '"' '"'? ;
  57 ls2 = '{' '{'? ;
  58 ls12 = ls1? (ls2 ls1)* ls2?;
  59
  60 long_str_part
  61         = ls12 long_str_char
  62         ;
  63
  64 long_str_body = long_str_part*;
  65 lsend1 = ls2? (ls1 ls2)* '"""' '"'*;
  66 lsend2 = ls1? (ls2 ls1)* '{{{' '{'*;
  67
  68 long_sstr_char = sstr_char | cr | lf;
  69 long_sstr_part
  70         = long_sstr_char
  71         | ''' long_sstr_char
  72         | ''' ''' long_sstr_char
  73         ;
  74
  75 long_sstr_body = long_sstr_part*;
  76
  77
  78 extern_code_char
  79         = [all - ['`' + '\']]
  80         | '\' all
  81         | '`' [all - '}']
  82         ;
  83 extern_code_body = extern_code_char*;
  84
  85 /*****************************************************************************/
  86 States
  87 /*****************************************************************************/
  88 initial;
  89
  90
  91 /*****************************************************************************/
  92 Tokens
  93 /*****************************************************************************/
  94
  95 blank = (' ' | tab)+;
  96
  97 eol = eol_helper;
  98 comment = '#' any* eol_helper?;
  99
 100 kwpackage = 'package';
 101 kwmodule = 'module';
 102 kwimport = 'import';
 103 kwclass = 'class';
 104 kwabstract = 'abstract';
 105 kwinterface = 'interface';
 106 kwenum = 'universal'|'enum';
 107 kwend = 'end';
 108 kwmeth = 'fun';
 109 kwtype = 'type';
 110 kwinit = 'init';
 111 kwredef = 'redef';
 112 kwis = 'is';
 113 kwdo = 'do';
 114 kwvar = 'var';
 115 kwextern = 'extern';
 116 kwpublic = 'public';
 117 kwprotected = 'protected';
 118 kwprivate = 'private';
 119 kwintrude = 'intrude';
 120 kwif = 'if';
 121 kwthen = 'then';
 122 kwelse = 'else';
 123 kwwhile = 'while';
 124 kwloop = 'loop';
 125 kwfor = 'for';
 126 kwin = 'in';
 127 kwand = 'and';
 128 kwor = 'or';
 129 kwnot = 'not';
 130 kwimplies = 'implies';
 131 kwreturn = 'return';
 132 kwcontinue = 'continue';
 133 kwbreak = 'break';
 134 kwabort = 'abort';
 135 kwassert = 'assert';
 136 kwnew = 'new';
 137 kwisa = 'isa';
 138 kwonce = 'once';
 139 kwsuper = 'super';
 140 kwself = 'self';
 141 kwtrue = 'true';
 142 kwfalse = 'false';
 143 kwnull = 'null';
 144 kwas = 'as';
 145 kwnullable = 'nullable';
 146 kwisset = 'isset';
 147 kwlabel = 'label';
 148 kwdebug = '__debug__';
 149
 150 opar = '(';
 151 cpar = ')';
 152 obra = '[';
 153 cbra = ']';
 154 comma = ',';
 155 column = ':';
 156 quad = '::';
 157 assign = '=';
 158 pluseq = '+=';
 159 minuseq = '-=';
 160 dotdotdot = '...';
 161 dotdot = '..';
 162 dot = '.';
 163 plus = '+';
 164 minus = '-';
 165 star = '*';
 166 starstar = '**';
 167 slash = '/';
 168 percent = '%';
 169 eq = '==';
 170 ne = '!=';
 171 lt = '<';
 172 le = '<=';
 173 ll = '<<';
 174 gt = '>';
 175 ge = '>=';
 176 gg = '>>';
 177 starship = '<=>';
 178 bang='!';
 179 at='@';
 180
 181 classid = uppercase letter*;
 182 id = lowercase letter*;
 183 attrid = '_' lowercase letter*;
 184
 185 number = digit+;
 186 hex_number = ('0x' | '0X') hexdigit+;
 187 float = digit* '.' digit+;
 188 string = '"' str_body '"' | '"' '"' '"' long_str_body lsend1 | ''' ''' ''' long_sstr_body ''' ''' ''';
 189 start_string = '"' str_body '{' | '"' '"' '"' long_str_body lsend2;
 190 mid_string = '}' str_body '{' | '}' '}' '}' long_str_body lsend2;
 191 end_string = '}' str_body '"' | '}' '}' '}' long_str_body lsend1;
 192 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 193 bad_string = ('"'|'}') str_body | '"' '"' '"' long_str_body | ''' ''' ''' long_sstr_body;
 194 bad_char = ''' '\'? any;
 195
 196 extern_code_segment = '`' '{' extern_code_body '`' '}';
 197
 198 /*****************************************************************************/
 199 Ignored Tokens
 200 /*****************************************************************************/
 201
 202 blank;
 203
 204 /*****************************************************************************/
 205 Productions
 206 /*****************************************************************************/
 207
 208 /* MODULES *******************************************************************/
 209 module
 210         = moduledecl? [imports]:import* [extern_bodies]:extern_code_body* [classdefs]:topdef* implicit_main_class {-> New module(moduledecl, [imports.import], [extern_bodies.extern_code_block], [classdefs.classdef,implicit_main_class.classdef])};
 211
 212 moduledecl
 213         = [doc]:no redef visibility kwmodule no module_name annotation_withend [n2]:n1 {-> New moduledecl(doc.doc, redef.kwredef, visibility, kwmodule, module_name, annotation_withend.annotations)};
 214
 215 import
 216         = {std} [doc]:no redef visibility kwimport no module_name annotation_withend [n2]:n1 {-> New import.std(visibility, kwimport, module_name, annotation_withend.annotations)}
 217         | {no} [doc]:no redef visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 218         ;
 219
 220 topdef {-> classdef}
 221         = {classdef} classdef {-> classdef}
 222         | propdefs_toplevel {-> New classdef.top([propdefs_toplevel.propdef])}
 223         ;
 224
 225 implicit_main_class {-> classdef?}
 226         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 227         | {null} n? {-> Null}
 228         ;
 229 implicit_main_meth {-> propdef}
 230         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 231         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 232         ;
 233
 234 /* CLASSES *******************************************************************/
 235 classdef
 236         = [doc]:no redef visibility classkind no qclassid formaldefs line_annotations_forclass? extern_code_block? [superclasses]:superclass* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, qclassid.classid, [formaldefs.formaldef], line_annotations_forclass.annotations, extern_code_block, [superclasses.superclass], [propdefs.propdef], kwend)};
 237 redef {-> kwredef?}
 238         = kwredef? {-> kwredef};
 239 classkind
 240         = {concrete} kwclass
 241         | {abstract} kwabstract kwclass
 242         | {interface} kwinterface
 243         | {enum} kwenum
 244         | {extern} kwextern kwclass
 245         ;
 246
 247 formaldefs {-> formaldef*}
 248         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]}
 249         | {null} {-> []}
 250         ;
 251 formaldefs_tail {-> formaldef}
 252         = comma no formaldef {-> formaldef};
 253 formaldef
 254         = classid annotations? typing_o {-> New formaldef(classid, typing_o.type, annotations)};
 255
 256 superclass {-> superclass}
 257         = {super} no kwsuper [n2]:no type annotation_withend {-> New superclass(kwsuper, type, annotation_withend.annotations)}
 258         ;
 259
 260 propdefs~toplevel {-> propdef}
 261         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 262         ;
 263 propdef~toplevel {-> propdef}
 264         = {meth} [doc]:no redef visibility kwmeth qmethid signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 265         | {nobody} [doc]:no redef visibility kwmeth qmethid signature annotation_withend_nonull {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature.signature, annotation_withend_nonull.annotations, Null, Null, Null)}
 266 !toplevel| {intern_new} [doc]:no redef visibility kwnew qmethid? signature annotation_withend_nonull {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_withend_nonull.annotations, Null, Null, Null)}
 267 !toplevel| {new} [doc]:no redef visibility kwnew qmethid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 268         | {extern_implicit} [doc]:no redef visibility kwmeth qmethid signature annotation_noend? extern_calls extern_code_block {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature.signature, annotation_noend.annotations, extern_calls, extern_code_block, Null)}
 269 !toplevel| {var3} [doc]:no redef visibility kwvar id typing_o annotation_withend {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, Null, annotation_withend.annotations, Null)}
 270 !toplevel| {var4} [doc]:no redef visibility kwvar id typing_o assign [n2]:no expr annotation_withend {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, expr.expr, annotation_withend.annotations, Null)}
 271 !toplevel| {var5} [doc]:no redef visibility kwvar id typing_o annotation_noend? kwdo stmtso kwend? {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, Null, annotation_noend.annotations, stmtso.expr)}
 272 !toplevel| {init} [doc]:no redef visibility kwinit qmethid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, kwinit, Null, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 273 !toplevel| {type} [doc]:no redef visibility kwtype classid typing annotation_withend {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type, annotation_withend.annotations)}
 274 !toplevel| {extern_init_implicit} [doc]:no redef visibility kwnew qmethid? signature annotation_noend? extern_calls extern_code_block {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_noend.annotations, extern_calls, extern_code_block, Null)}
 275         ;
 276 annotation_withend~nonull {-> annotations?}
 277         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 278         | {more} kwis n1 line_annotations kwend {-> line_annotations.annotations}
 279 !nonull | {null} {-> Null}
 280         ;
 281 annotation_noend {-> annotations}
 282         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 283         | {more} kwis n1 line_annotations {-> line_annotations.annotations}
 284         ;
 285
 286 visibility
 287         = {public} {-> New visibility.public(Null)}
 288         | {public2} kwpublic no {-> New visibility.public(kwpublic)}
 289         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 290         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 291         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 292         ;
 293
 294 methid~noid {-> methid}
 295         = {plus} plus {-> New methid.plus(plus)}
 296         | {minus} minus {-> New methid.minus(minus)}
 297         | {star} star {-> New methid.star(star)}
 298         | {starstar} starstar {-> New methid.starstar(starstar)}
 299         | {slash} slash {-> New methid.slash(slash)}
 300         | {percent} percent {-> New methid.percent(percent)}
 301         | {eq} eq {-> New methid.eq(eq)}
 302         | {ne} ne {-> New methid.ne(ne)}
 303         | {le} le {-> New methid.le(le)}
 304         | {ge} ge {-> New methid.ge(ge)}
 305         | {lt} lt {-> New methid.lt(lt)}
 306         | {gt} gt {-> New methid.gt(gt)}
 307         | {ll} ll {-> New methid.ll(ll)}
 308         | {gg} gg {-> New methid.gg(gg)}
 309         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 310         | {starship} starship {-> New methid.starship(starship)}
 311         | {assign} id assign {-> New methid.assign(id, assign)}
 312         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 313 !noid   | {id} id {-> New methid.id(id)}
 314         ;
 315
 316 signature {-> signature}
 317         = opar no params cpar typing [no2]:no {-> New signature(opar, [params.param], cpar, typing.type)}
 318         | {noret} opar no params cpar [no2]:no {-> New signature(opar, [params.param], cpar, Null)}
 319         | {nopar} typing no {-> New signature(Null, [], Null, typing.type)}
 320         | {noparnoret} no {-> New signature(Null, [], Null, Null)}
 321         ;
 322
 323 params {-> param*}
 324         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 325         | {null} {-> []}
 326         ;
 327 params_tail {-> param}
 328         = comma no param {-> param};
 329 param
 330         = {untyped} id annotations_o {-> New param(id, Null, Null, annotations_o.annotations)}
 331         | id annotations? typing dotdotdot? {-> New param(id, typing.type, dotdotdot, annotations)}
 332         ;
 333
 334 extern_calls {-> extern_calls?}
 335         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 336         | {null} {-> Null}
 337         ;
 338 extern_call_tail {-> extern_call}
 339         = comma no extern_call {-> extern_call};
 340 extern_call {-> extern_call}
 341         = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 342         | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 343         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 344         ;
 345 extern_call_prop {-> extern_call}
 346         = {local} qmethid {-> New extern_call.local_prop( qmethid.methid )}
 347         | {full} type dot qmethid {-> New extern_call.full_prop( type, dot, qmethid.methid )}
 348         | {init} type {-> New extern_call.init_prop( type )}
 349         ;
 350 extern_call_cast {-> extern_call}
 351         = {as_cast} [from_type]:type dot kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 352         | {as_cast2}[from_type]:type dot kwas [n2]:no [to_type]:type {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 353         | {as_nullable} type dot kwas [n2]:no opar [n3]:no kwnullable [n4]:no cpar {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 354         | {as_nullable2}type dot kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 355         | {as_not_nullable} type dot kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnullable [n5]:no cpar {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 356         | {as_not_nullable2}type dot kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 357         ;
 358
 359 string_o {->string?} = string? {-> string};
 360
 361 in_language = kwin no string [n1]:no {-> New in_language(kwin, string)};
 362 extern_code_block = in_language? extern_code_segment;
 363 extern_code_block_o {-> extern_code_block?}
 364         = extern_code_block {-> extern_code_block}
 365         | {null} {-> Null}
 366         ;
 367 extern_code_body {-> extern_code_block} = no extern_code_block {-> extern_code_block};
 368
 369 /* TYPES *********************************************************************/
 370 type~nobra~nopar {-> type}
 371         = {simple} kwnullable? classid annotations_o~nopar {-> New type(kwnullable, classid, [], annotations_o~nopar.annotations)}
 372 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra annotations_o~nopar {-> New type(kwnullable, classid, [types.type], annotations_o~nopar.annotations)}
 373         ;
 374 types {-> type*}
 375         = type types_tail* {-> [type, types_tail.type]};
 376 types_tail {-> type}
 377         = comma no type {-> type};
 378 typing {-> type}
 379         = column no type {-> type};
 380 typing_o {-> type?}
 381         = column no type {-> type}
 382         | {null} {-> Null}
 383         ;
 384
 385 /* STATMENTS *****************************************************************/
 386 stmtso~withelse~withend {-> expr?}
 387         = {block} n stmtsnend {-> stmtsnend.expr}
 388         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 389         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 390 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 391         ;
 392 stmts {-> expr}
 393         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 394 stmtsn {-> expr}
 395         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 396 stmtsnend {-> expr}
 397         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 398 stmts_tail {-> expr}
 399         = n stmt {-> stmt.expr};
 400 stmt~withelse~noexpr~nopar {-> expr}
 401         = {vardecl} vardecl {-> vardecl.expr}
 402         | {assign} assignment~nopar {-> assignment~nopar.expr}
 403         | {return} kwreturn expr? {-> New expr.return(kwreturn, expr)}
 404         | {break} kwbreak label? {-> New expr.break(kwbreak, label)}
 405         | {abort} kwabort {-> New expr.abort(kwabort)}
 406         | {continue} kwcontinue label? {-> New expr.continue(kwcontinue, label)}
 407         | {do} do~withelse {-> do~withelse.expr}
 408 !noexpr | {if} if~withelse {-> if~withelse.expr}
 409         | {while} while~withelse {-> while~withelse.expr}
 410         | {loop} loop~withelse {-> loop~withelse.expr}
 411         | {for} for~withelse {-> for~withelse.expr}
 412         | {assert} assert~withelse {-> assert~withelse.expr}
 413 !noexpr | {call} recv qid args_nopar {-> New expr.call(recv.expr, qid.id, args_nopar.exprs)}
 414 !noexpr | {super} qualified_o kwsuper args_nopar {-> New expr.super(qualified_o.qualified, kwsuper, args_nopar.exprs)}
 415 !noexpr | {init} recv qualified? kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 416         | {debug_type_is} kwdebug kwtype type column expr {-> New expr.debug_type(kwdebug, kwtype, expr.expr, type) }
 417         ;
 418
 419 label= kwlabel id?;
 420
 421 vardecl{-> expr}
 422         = kwvar id annotations? typing_o {-> New expr.vardecl(kwvar, id, typing_o.type, Null, Null, annotations)}
 423         | {assign} kwvar id annotations? typing_o assign no expr {-> New expr.vardecl(kwvar, id, typing_o.type, assign, expr.expr, annotations)}
 424         ;
 425
 426 assignment~nopar {-> expr}
 427         = {attr} recv~nopar qualified_o attrid assign expr {-> New expr.attr_assign(recv~nopar.expr, attrid, assign, expr)}
 428         | {call} recv~nopar qid args assign expr {-> New expr.call_assign(recv~nopar.expr, qid.id, args.exprs, assign,  expr)}
 429         | {bra} expr_atom~nopar braargs assign expr {-> New expr.bra_assign(expr_atom~nopar.expr, braargs.exprs, assign,  expr)}
 430         | {attr_re} recv~nopar qualified_o attrid assign_op expr {-> New expr.attr_reassign(recv~nopar.expr, attrid, assign_op,  expr)}
 431         | {call_re} recv~nopar qid args assign_op expr {-> New expr.call_reassign(recv~nopar.expr, qid.id, args.exprs, assign_op,  expr)}
 432         | {bra_re} expr_atom~nopar braargs assign_op expr {-> New expr.bra_reassign(expr_atom~nopar.expr, braargs.exprs, assign_op,  expr)}
 433         ;
 434 assign_op
 435         = {plus} pluseq
 436         | {minus} minuseq
 437         ;
 438
 439 do~withelse {-> expr}
 440         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 441         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 442         ;
 443
 444 if~withelse {-> expr}
 445         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 446 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 447 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 448 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 449         ;
 450 elsepartblock {-> expr?}
 451         = {else} kwelse stmtso {-> stmtso.expr}
 452         | {empty} kwend {-> New expr.block([], kwend)}
 453         ;
 454
 455 loop~withelse {-> expr}
 456         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 457         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 458         ;
 459
 460 while~withelse {-> expr}
 461         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 462         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 463         ;
 464
 465 for~withelse {-> expr}
 466         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 467         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 468         ;
 469
 470 assert~withelse {-> expr}
 471         = {else} kwassert assertid? expr kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr, stmtso~withelse.expr)}
 472 !withelse| {noelse} kwassert assertid? expr {-> New expr.assert(kwassert, assertid.id, expr, Null)}
 473         ;
 474 assertid {-> id}
 475         = id column {-> id};
 476
 477 /* EXPRESSIONS ***************************************************************/
 478 expr~nopar~nobra {-> expr}
 479         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 480         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 481         ;
 482
 483 expr_and~nopar~nobra {-> expr}
 484         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 485         | {:or} expr_and~nopar~nobra :kwor :no expr_not~nopar~nobra
 486         | {:and} expr_and~nopar~nobra :kwand :no expr_not~nopar~nobra
 487         | {:or_else} expr_and~nopar~nobra :kwor :kwelse :no expr_not~nopar~nobra
 488         | {:implies} expr_and~nopar~nobra :kwimplies :no expr_not~nopar~nobra
 489         ;
 490
 491 expr_not~nopar~nobra {-> expr}
 492         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 493         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 494         ;
 495
 496 expr_eq~nopar~nobra {-> expr}
 497         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 498         | {:eq} expr_add~nopar~nobra :eq :no [expr2]:expr_add~nopar~nobra
 499         | {:ne} expr_add~nopar~nobra :ne :no [expr2]:expr_add~nopar~nobra
 500         | {:lt} expr_add~nopar~nobra :lt :no [expr2]:expr_add~nopar~nobra
 501         | {:le} expr_add~nopar~nobra :le :no [expr2]:expr_add~nopar~nobra
 502         | {:ll} expr_eq~nopar~nobra :ll :no [expr2]:expr_add~nopar~nobra
 503         | {:gt} expr_add~nopar~nobra :gt :no [expr2]:expr_add~nopar~nobra
 504         | {:ge} expr_add~nopar~nobra :ge :no [expr2]:expr_add~nopar~nobra
 505         | {:gg} expr_eq~nopar~nobra :gg :no [expr2]:expr_add~nopar~nobra
 506         | {:starship} expr_add~nopar~nobra :starship :no [expr2]:expr_add~nopar~nobra
 507         | {:isa} expr_add~nopar~nobra :kwisa :no type~nobra
 508         ;
 509
 510 expr_add~nopar~nobra {-> expr}
 511         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 512         | {:plus} expr_add~nopar~nobra :plus :no [expr2]:expr_mul~nopar~nobra
 513         | {:minus} expr_add~nopar~nobra :minus :no [expr2]:expr_mul~nopar~nobra
 514         ;
 515
 516 expr_mul~nopar~nobra {-> expr}
 517         = expr_pow~nopar~nobra {-> expr_pow~nopar~nobra.expr}
 518         | {:star} expr_mul~nopar~nobra :star :no [expr2]:expr_pow~nopar~nobra
 519         | {:slash} expr_mul~nopar~nobra :slash :no [expr2]:expr_pow~nopar~nobra
 520         | {:percent} expr_mul~nopar~nobra :percent :no [expr2]:expr_pow~nopar~nobra
 521         ;
 522
 523 expr_pow~nopar~nobra {-> expr}
 524         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 525         | {:starstar} expr_minus~nopar~nobra :starstar :no [expr2]:expr_pow~nopar~nobra
 526         ;
 527
 528 expr_minus~nopar~nobra {-> expr}
 529         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 530         | {:uminus} minus expr_minus~nobra
 531         | {:once} kwonce :no expr_minus~nobra
 532         ;
 533
 534 expr_new~nopar~nobra {-> expr}
 535         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 536         | {new} kwnew no type~nobra_nopar args {-> New expr.new(kwnew, type~nobra_nopar.type, Null, args.exprs)}
 537         | {isset_attr} kwisset recv~nopar~nobra qualified_o attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 538         ;
 539
 540 expr_atom~nopar~nobra {-> expr}
 541         = expr_single~nopar~nobra {-> expr_single~nopar~nobra.expr}
 542         | {attr} recv~nopar~nobra qualified_o attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 543         | {call} recv~nopar~nobra qid args {-> New expr.call(recv~nopar~nobra.expr, qid.id, args.exprs)}
 544         | {super} qualified_o kwsuper args {-> New expr.super(qualified_o.qualified, kwsuper, args.exprs)}
 545         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 546 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs)}
 547         | {new} kwnew no type~nobra_nopar dot [n2]:no qid args {-> New expr.new(kwnew, type~nobra_nopar.type, qid.id, args.exprs)}
 548         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 549         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 550         | {as_notnull2}expr_atom~nopar~nobra dot no kwas [n2]:no kwnot [n4]:no kwnull {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, Null, kwnot, kwnull, Null)}
 551         | {vararg} [expr]:expr_atom~nopar~nobra dotdotdot {-> New expr.vararg(expr.expr, dotdotdot)}
 552         ;
 553
 554 expr_single~nopar~nobra {-> expr}
 555         = {self} kwself annotations_o {-> New expr.self(kwself, annotations_o.annotations)}
 556         | {true} kwtrue annotations_o {-> New expr.true(kwtrue, annotations_o.annotations)}
 557         | {false} kwfalse annotations_o {-> New expr.false(kwfalse, annotations_o.annotations)}
 558         | {null} kwnull annotations_o {-> New expr.null(kwnull, annotations_o.annotations)}
 559         | {int} number annotations_o {-> New expr.dec_int(number, annotations_o.annotations)}
 560         | {hex_int} hex_number annotations_o {-> New expr.hex_int(hex_number, annotations_o.annotations)}
 561         | {float} float annotations_o {-> New expr.float(float, annotations_o.annotations)}
 562         | {char} char annotations_o {-> New expr.char(char, annotations_o.annotations)}
 563         | {string} string annotations_o {-> New expr.string(string, annotations_o.annotations)}
 564         | {superstring} superstring  {-> superstring.expr}
 565 !nopar  | {par} expr_par {-> expr_par.expr}
 566 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 567 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra annotations_o {-> New expr.crange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 568 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra annotations_o {-> New expr.orange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 569 !nobra!nopar    | {array} obra no array_items typing_o cbra annotations_o {-> New expr.array(obra, [array_items.expr], typing_o.type, cbra, annotations_o.annotations)}
 570         ;
 571
 572 expr_par {-> expr}
 573         = {par} opar no any_expr [n2]:no cpar annotations_o {-> New expr.par(opar, any_expr.expr, cpar, annotations_o.annotations)}
 574         | {tuple} opar no many_expr [n2]:no cpar annotations_o {-> New expr.par(opar, many_expr.expr, cpar, annotations_o.annotations)}
 575         ;
 576
 577 many_expr {->expr}
 578         = any_expr many_expr_tail+ {-> New expr.many([any_expr.expr, many_expr_tail.expr])}
 579         ;
 580
 581 many_expr_tail {->expr}
 582         = comma no any_expr {-> any_expr.expr}
 583         ;
 584
 585 array_items {-> expr*}
 586         = array_item array_items_tail* {-> [array_item.expr, array_items_tail.expr]}
 587         ;
 588 array_items_tail {-> expr}
 589         = comma no array_item {-> array_item.expr}
 590         ;
 591 array_item {-> expr}
 592         = expr no {-> expr}
 593         | {for} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo [block]:array_item {-> New expr.for(kwfor, [ids.id], expr, kwdo, block.expr, Null)}
 594         | {if} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:array_item {-> New expr.if(kwif, expr, then.expr, Null)}
 595         ;
 596
 597 superstring {-> expr}
 598         = superstring_start superstring_middle* superstring_end annotations_o {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr], annotations_o.annotations)};
 599 superstring_start {-> expr*}
 600         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]}
 601         | {noexpr} start_string_p no {-> [start_string_p.expr]}
 602         ;
 603 start_string_p {-> expr}
 604         = start_string {-> New expr.start_string(start_string)};
 605 superstring_middle {-> expr*}
 606         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]}
 607         | {noexpr} mid_string_p no {-> [mid_string_p.expr]}
 608         ;
 609 mid_string_p {-> expr}
 610         = mid_string {-> New expr.mid_string(mid_string)};
 611 superstring_end {-> expr}
 612         = end_string {-> New expr.end_string(end_string)};
 613
 614 /* ANNOTATIONS *******************************************************************/
 615
 616 annotations~nopar {-> annotations}
 617         = {one} at one_annotation~nopar {-> New annotations(at, Null, [one_annotation~nopar.annotation], Null)}
 618         | {many} at opar no annotation_list [n2]:no cpar {-> New annotations(at, opar, [annotation_list.annotation], cpar)}
 619         ;
 620 annotations_o~nopar {-> annotations?}
 621         = annotations~nopar {-> annotations~nopar.annotations}
 622         | {null} {-> Null}
 623         ;
 624
 625 one_annotation~nopar {-> annotation}
 626         = {alone} redef visibility atid annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [], Null, annotations_o~nopar.annotations)}
 627 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 628 !nopar  | {args} redef visibility atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, opar, [at_args.expr], cpar, annotations_o~nopar.annotations)}
 629         ;
 630
 631 many_annotations {-> annotations}
 632         = {many} annotation_list {-> New annotations(Null, Null, [annotation_list.annotation], Null)}
 633         ;
 634
 635 annotation_list {-> annotation*}
 636         = {many} one_annotation_list annotations_tail* {-> [one_annotation_list.annotation, annotations_tail.annotation] }
 637         ;
 638
 639 one_annotation_list~nopar {-> annotation}
 640         = {alone} redef visibility atid annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [], Null, annotations_o~nopar.annotations)}
 641 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 642 !nopar  | {args} redef visibility atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, opar, [at_args.expr], cpar, annotations_o~nopar.annotations)}
 643 !nopar  | {nopar} redef visibility atid at_arg_single {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [at_arg_single.expr], Null, Null)}
 644         ;
 645 at_arg_single {-> expr}
 646 // FIXME: why expr_single but not expr_atom is not clear :(
 647         = {expr} [expr]:expr_single_nopar {-> expr.expr}
 648         ;
 649
 650 annotations_tail {-> annotation}
 651         = comma no one_annotation_list {-> one_annotation_list.annotation}
 652         ;
 653
 654 line_annotations {-> annotations}
 655         = line_annotation+ {-> New annotations(Null, Null, [line_annotation.annotation], Null) }
 656         ;
 657 line_annotation {-> annotation}
 658         = [doc]:no redef visibility atid annotations? n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, Null, [], Null, annotations)}
 659         | {args} [doc]:no redef visibility atid opar no at_args cpar annotations? n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, opar, [at_args.expr], cpar, annotations)}
 660         | {nopar} [doc]:no redef visibility atid at_args_nopar n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, Null, [at_args_nopar.expr], Null, Null)}
 661         ;
 662 line_annotations_forclass {-> annotations}
 663         = line_annotation_forclass+ {-> New annotations(Null, Null, [line_annotation_forclass.annotation], Null) }
 664         ;
 665 line_annotation_forclass {-> annotation}
 666         = [doc]:no atid_forclass annotations? n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, Null, [], Null, annotations)}
 667         | {args} [doc]:no atid_forclass opar no at_args cpar annotations? n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, opar, [at_args.expr], cpar, annotations)}
 668         | {nopar} [doc]:no atid_forclass at_args_nopar n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, Null, [at_args_nopar.expr], Null, Null)}
 669         ;
 670
 671 at_args~nopar {-> expr* }
 672         = {many} any_expr~nopar at_args_tail* {-> [any_expr~nopar.expr, at_args_tail.expr]}
 673         ;
 674
 675 at_args_tail {-> expr}
 676         = comma no any_expr {-> any_expr.expr}
 677         ;
 678
 679 any_expr~nopar {-> expr}
 680         = {type} type {-> New expr.type(type)}
 681         | {expr} expr~nopar {-> expr~nopar.expr}
 682         | {stmt} stmt_noexpr~nopar {-> stmt_noexpr~nopar.expr}
 683         | {methid} recv~nopar qmethid_noid {-> New expr.methid(recv~nopar.expr, qmethid_noid.methid)}
 684 !nopar  | {at} annotations {-> New expr.at(annotations.annotations)}
 685         ;
 686
 687 atid~forclass {-> atid}
 688         = {id}  id {-> New atid.id(id)}
 689 !forclass       | {kwextern} kwextern {-> New atid.kwextern(kwextern)}
 690 //      | {kwimport} kwimport {-> New atid.kwimport(kwimport)}
 691         | {kwabstract} kwabstract {-> New atid.kwabstract(kwabstract)}
 692         ;
 693
 694 /* MISC **********************************************************************/
 695
 696 recv~nopar~nobra {-> expr}
 697         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 698         | {implicit} {-> New expr.implicit_self()}
 699         ;
 700
 701 args {-> exprs}
 702         = args_n {-> args_n.exprs}
 703         | {empty} {-> New exprs.list([])}
 704         ;
 705 args_n {-> exprs}
 706         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 707         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 708         ;
 709 args_nopar {-> exprs}
 710         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 711         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 712         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 713         | {empty} {-> New exprs.list([])}
 714         ;
 715 braargs {-> exprs}
 716         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 717 args_list {-> exprs}
 718         = expr_list {-> New exprs.list([expr_list.expr])};
 719 expr_list {-> expr*}
 720         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 721 expr_tail {-> expr}
 722         = comma no expr [n2]:no {-> expr};
 723 idlist {-> id*}
 724         = opar no idlist_nopar [n2]:no cpar {-> [idlist_nopar.id]}
 725         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 726         ;
 727 idlist_nopar {-> id*}
 728         = {single} id {-> [id]}
 729         | {more} idlist_nopar comma [n2]:no id {-> [idlist_nopar.id, id]}
 730         ;
 731
 732 module_name {-> module_name}
 733         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 734         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 735         ;
 736
 737 qualified
 738         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 739         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 740         ;
 741 qualified_o {-> qualified?}
 742         = qualified {-> qualified}
 743         | {null} {-> Null}
 744         ;
 745 qid {-> id}
 746         = qualified? id {-> id}
 747         ;
 748 qclassid {-> classid}
 749         = qualified? classid {-> classid}
 750         ;
 751 qmethid~noid {-> methid}
 752         = qualified? methid~noid {-> methid~noid.methid}
 753         ;
 754 modquad {-> id}
 755         = id quad no {-> id};
 756 classquad {-> classid}
 757         = classid quad no {-> classid};
 758
 759 kwend_o {-> kwend?}
 760         = kwend? {-> kwend}
 761         ;
 762
 763 n1      = {a} comment | {b} eol;
 764 n {-> doc?}
 765         = {a} n2? comment+ {-> New doc([comment])}
 766         | {b} n2 {-> Null}
 767         ;
 768 no {-> doc?}
 769         = {empty} {-> Null}
 770         | n {-> n.doc}
 771         ;
 772
 773 n2
 774         = {a} n2? comment+ eol+
 775         | {b} eol+
 776         ;
 777
 778 /*****************************************************************************/
 779 Abstract Syntax Tree
 780 /*****************************************************************************/
 781
 782 module  = moduledecl? [imports]:import* [extern_code_blocks]:extern_code_block* [classdefs]:classdef*;
 783
 784 moduledecl
 785         = doc? kwredef? visibility kwmodule [name]:module_name annotations?;
 786
 787 import  = {std} visibility kwimport [name]:module_name annotations?
 788         | {no} visibility kwimport kwend
 789         ;
 790
 791 visibility
 792         = {public} kwpublic?
 793         | {private} kwprivate
 794         | {protected} kwprotected
 795         | {intrude} kwintrude
 796         ;
 797
 798 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* annotations? extern_code_block? [superclasses]:superclass* [propdefs]:propdef* kwend
 799         | {top} [propdefs]:propdef*
 800         | {main} [propdefs]:propdef*
 801         ;
 802 classkind
 803         = {concrete} kwclass
 804         | {abstract} kwabstract kwclass
 805         | {interface} kwinterface
 806         | {enum} kwenum
 807         | {extern} kwextern kwclass?
 808         ;
 809 formaldef = [id]:classid type? annotations?;
 810 superclass = kwsuper type annotations?;
 811
 812
 813 propdef = {attr} doc? kwredef? visibility kwvar [id2]:id type? expr? annotations? [block]:expr?
 814         | {main_meth} kwredef? [block]:expr?
 815         | {type} doc? kwredef? visibility kwtype [id]:classid type annotations?
 816         | {meth} doc? kwredef? visibility kwmeth? kwinit? kwnew? methid? signature annotations? extern_calls? extern_code_block? [block]:expr?
 817         ;
 818
 819 methid = {id} id | {plus} plus | {minus} minus | {star} star | {starstar} starstar | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 820
 821 signature = opar? [params]:param* cpar? type?;
 822
 823 param   = id type? dotdotdot? annotations?
 824         ;
 825
 826 type    = kwnullable? [id]:classid [types]:type* annotations?;
 827
 828 label = kwlabel id?;
 829
 830 expr    = {block} expr* kwend?
 831         | {vardecl} kwvar id type? assign? expr? annotations?
 832         | {return} kwreturn? expr?
 833         | {break} kwbreak label?
 834         | {abort} kwabort
 835         | {continue} kwcontinue? label?
 836         | {do} kwdo [block]:expr? label?
 837         | {if} kwif expr [then]:expr? [else]:expr?
 838         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 839         | {while} kwwhile expr kwdo [block]:expr? label?
 840         | {loop} kwloop [block]:expr? label?
 841         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 842         | {assert} kwassert id? expr [else]:expr?
 843         | {once} kwonce expr
 844         | {send} expr
 845         | {binop} expr [expr2]:expr
 846         | {or} expr [expr2]:expr
 847         | {and} expr [expr2]:expr
 848         | {or_else} expr [expr2]:expr
 849         | {implies} expr [expr2]:expr
 850         | {not} kwnot expr
 851         | {eq} expr [expr2]:expr
 852         | {ne} expr [expr2]:expr
 853         | {lt} expr [expr2]:expr
 854         | {le} expr [expr2]:expr
 855         | {ll} expr [expr2]:expr
 856         | {gt} expr [expr2]:expr
 857         | {ge} expr [expr2]:expr
 858         | {gg} expr [expr2]:expr
 859         | {isa} expr type
 860         | {plus} expr [expr2]:expr
 861         | {minus} expr [expr2]:expr
 862         | {starship} expr [expr2]:expr
 863         | {star} expr [expr2]:expr
 864         | {starstar} expr [expr2]:expr
 865         | {slash} expr [expr2]:expr
 866         | {percent} expr [expr2]:expr
 867         | {uminus} minus expr
 868         | {new} kwnew type id? [args]:exprs
 869         | {attr} expr [id]:attrid
 870         | {attr_assign} expr [id]:attrid assign [value]:expr
 871         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 872         | {call} expr id [args]:exprs
 873         | {call_assign} expr id [args]:exprs assign [value]:expr
 874         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 875         | {super} qualified? kwsuper [args]:exprs
 876         | {init} expr kwinit [args]:exprs
 877         | {bra} expr [args]:exprs
 878         | {bra_assign} expr [args]:exprs assign [value]:expr
 879         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 880         | {var} id
 881         | {var_assign} id assign [value]:expr
 882         | {var_reassign} id assign_op [value]:expr
 883         | {range} expr [expr2]:expr annotations?
 884         | {crange} obra expr [expr2]:expr cbra annotations?
 885         | {orange} obra expr [expr2]:expr [cbra]:obra annotations?
 886         | {array} obra [exprs]:expr* type? cbra annotations?
 887         | {self} kwself annotations?
 888         | {implicit_self}
 889         | {true} kwtrue annotations?
 890         | {false} kwfalse annotations?
 891         | {null} kwnull annotations?
 892         | {dec_int} number annotations?
 893         | {hex_int} hex_number annotations?
 894         | {float} float annotations?
 895         | {char} char annotations?
 896         | {string} string annotations?
 897         | {start_string} [string]:start_string
 898         | {mid_string} [string]:mid_string
 899         | {end_string} [string]:end_string
 900         | {superstring} [exprs]:expr* annotations?
 901         | {par} opar expr cpar annotations?
 902         | {as_cast} expr kwas opar? type cpar?
 903         | {as_notnull} expr kwas opar? kwnot kwnull cpar?
 904         | {isset_attr} kwisset expr [id]:attrid
 905         | {debug_type} kwdebug kwtype expr type
 906         | {vararg} expr dotdotdot
 907         | {type} type
 908         | {methid} expr [id]:methid
 909         | {at} annotations
 910         | {many} [exprs]:expr*
 911         ;
 912 exprs
 913         = {list} [exprs]:expr*
 914         | {par} opar [exprs]:expr* cpar
 915         | {bra} obra [exprs]:expr* cbra
 916         ;
 917 assign_op
 918         = {plus} pluseq
 919         | {minus} minuseq
 920         ;
 921
 922 module_name = quad? [path]:id* id;
 923 extern_calls = kwimport [extern_calls]:extern_call*
 924         ;
 925 extern_call =
 926         | {super} kwsuper
 927         | {local_prop} methid
 928         | {full_prop} type dot? methid
 929         | {init_prop} type
 930         | {cast_as} [from_type]:type dot? kwas [to_type]:type
 931         | {as_nullable} type kwas kwnullable
 932         | {as_not_nullable} type kwas kwnot kwnullable
 933         ;
 934 in_language = kwin string;
 935 extern_code_block = in_language? extern_code_segment;
 936
 937 qualified = id* classid? ;
 938
 939 doc = comment+;
 940
 941 annotations = at? opar? [items]:annotation* cpar?;
 942
 943 annotation = doc? kwredef? visibility? atid opar? [args]:expr* cpar? annotations?;
 944
 945 atid = {id} id | {kwextern} [id]:kwextern | {kwabstract} [id]:kwabstract | {kwimport} [id]:kwimport;
 946
 947 /*****************************************************************************/
 948