lib/ordered_tree.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Manipulation and presentation of ordered trees.
  18 module ordered_tree
  19
  20 # Generic structure to manage and display an ordered tree
  21 #
  22 # Ordered tree are tree where the elements of a same parent are in a specific order
  23 #
  24 # Elements of the trees are added with the `add` method that takes a parent and
  25 # a sub-element.
  26 # If the parent is `null`, then the element is considered a root.
  27 #
  28 # ~~~~
  29 # var t = new OrderedTree[String]
  30 # t.add(null, "root")
  31 # t.add("root", "child1")
  32 # t.add("root", "child2")
  33 # t.add("child1", "grand-child")
  34 # assert t.length == 4
  35 # ~~~~
  36 #
  37 # By default, the elements with a same parent
  38 # are visited in the order they are added.
  39 #
  40 # ~~~
  41 # assert t.to_a == ["root", "child1", "grand-child", "child2"]
  42 # assert t.write_to_string == """
  43 # root
  44 # |--child1
  45 # |  `--grand-child
  46 # `--child2
  47 # """
  48 # ~~~
  49 #
  50 # The `sort_with` method can be used reorder elements
  51 #
  52 # ~~~
  53 # t.add("root", "aaa")
  54 # assert t.to_a == ["root", "child1", "grand-child", "child2", "aaa"]
  55 # t.sort_with(alpha_comparator)
  56 # assert t.to_a == ["root", "aaa", "child1", "grand-child", "child2"]
  57 # ~~~
  58 #
  59 # This class can be used as it to work with generic trees but can also be specialized to provide more specific
  60 # behavior or display. It is why the internal attributes are mutable.
  61 class OrderedTree[E: Object]
  62         super Writable
  63         super Collection[E]
  64
  65         # The roots of the tree (in sequence)
  66         var roots = new Array[E]
  67
  68         # The branches of the trees.
  69         # For each element, the ordered array of its direct sub-elements.
  70         var sub = new HashMap[E, Array[E]]
  71
  72         # Add a new element `e` in the tree.
  73         # `p` is the parent of `e`.
  74         # if `p` is null, then `e` is a root element.
  75         fun add(p: nullable E, e: E)
  76         do
  77                 if p == null then
  78                         roots.add(e)
  79                 else if sub.has_key(p) then
  80                         sub[p].add(e)
  81                 else
  82                         sub[p] = [e]
  83                 end
  84         end
  85
  86         # Append all nodes `es` as children of `p`.
  87         fun add_all(p: nullable E, es: Collection[E])
  88         do
  89                 for e in es do add(p, e)
  90         end
  91
  92         # print the full tree on `o`
  93         # Write a ASCII-style tree and use the `display` method to label elements
  94         redef fun write_to(stream: Writer)
  95         do
  96                 for r in roots do
  97                         stream.write display(r)
  98                         stream.write "\n"
  99                         sub_write_to(stream, r, "")
 100                 end
 101         end
 102
 103         private fun sub_write_to(o: Writer, e: E, prefix: String)
 104         do
 105                 if not sub.has_key(e) then return
 106                 var subs = sub[e]
 107                 var last = subs.last
 108                 for e2 in subs do
 109                         if e2 != last then
 110                                 o.write "{prefix}|--{display(e2)}\n"
 111                                 sub_write_to(o, e2, prefix+"|  ")
 112                         else
 113                                 o.write "{prefix}`--{display(e2)}\n"
 114                                 sub_write_to(o, e2, prefix+"   ")
 115                         end
 116                 end
 117         end
 118
 119         # Sort roots and other elements using a comparator method
 120         # This method basically sorts roots then each group of children
 121         fun sort_with(comparator: Comparator)
 122         do
 123                 comparator.sort(roots)
 124                 for a in sub.values do
 125                         comparator.sort(a)
 126                 end
 127         end
 128
 129         # How to display a specific element of the tree
 130         # By defaut, uses `to_s`
 131         #
 132         # Subclasses should redefine this method to provide a specific output
 133         fun display(e: E): String do return e.to_s
 134
 135         # Get an array of the contained elements
 136         # Order is preserved
 137         #
 138         #     var tree = new OrderedTree[Int]
 139         #     tree.add_all(null, [1, 2])
 140         #     tree.add_all(1, [11, 12])
 141         #     tree.add_all(11, [111, 112])
 142         #     tree.add_all(12, [121, 122])
 143         #     tree.add_all(2, [21, 22])
 144         #     assert tree.to_a == [1, 11, 111, 112, 12, 121, 122, 2, 21, 22]
 145         redef fun to_a: Array[E] do
 146                 var res = new Array[E]
 147                 for r in roots do sub_to_a(r, res)
 148                 return res
 149         end
 150
 151         private fun sub_to_a(e: E, res: Array[E]) do
 152                 res.add e
 153                 if sub.has_key(e) then for e2 in sub[e] do sub_to_a(e2, res)
 154         end
 155
 156         #     var tree = new OrderedTree[Int]
 157         #     assert tree.is_empty
 158         #     tree.add(null, 1)
 159         #     assert not tree.is_empty
 160         redef fun is_empty: Bool do return roots.is_empty
 161
 162         #     var tree = new OrderedTree[Int]
 163         #     tree.add(null, 1)
 164         #     tree.add(1, 11)
 165         #     assert tree.first == 1
 166         redef fun first do return roots.first
 167
 168         #     var tree = new OrderedTree[Int]
 169         #     tree.add_all(null, [1, 2])
 170         #     tree.add_all(1, [11, 12])
 171         #     tree.add_all(11, [111, 112])
 172         #     tree.add_all(12, [121, 122])
 173         #     tree.add_all(2, [21, 22])
 174         #     var order = [1, 11, 111, 112, 12, 121, 122, 2, 21, 22]
 175         #     assert tree.iterator.to_a == order
 176         redef fun iterator do return new OrderedTreeIterator[E](self)
 177 end
 178
 179 # An Iterator over an OrderedTree
 180 private class OrderedTreeIterator[E: Object]
 181         super Iterator[E]
 182
 183         var tree: OrderedTree[E]
 184
 185         var iterators = new Array[Iterator[E]]
 186
 187         init do
 188                 if not tree.is_empty then
 189                         iterators.add tree.roots.iterator
 190                 end
 191         end
 192
 193         redef fun is_ok do return not iterators.is_empty
 194
 195         redef fun item do
 196                 assert is_ok
 197                 return iterators.last.item
 198         end
 199
 200         redef fun next do
 201                 assert is_ok
 202                 if tree.sub.has_key(item) then
 203                         iterators.add tree.sub[item].iterator
 204                 else
 205                         iterators.last.next
 206                         while is_ok and not iterators.last.is_ok do
 207                                 iterators.pop
 208                                 if is_ok and iterators.last.is_ok then
 209                                         iterators.last.next
 210                                 end
 211                         end
 212                 end
 213         end
 214
 215         redef fun iterator do return new OrderedTreeIterator[E](tree)
 216 end