src/model/mmodule.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # modules and module hierarchies in the metamodel
  18 module mmodule
  19
  20 import mpackage
  21 private import more_collections
  22
  23 # The container class of a Nit object-oriented model.
  24 #
  25 # A model knows modules, classes and properties and can retrieve them.
  26 #
  27 # However, a model is not a program or a library as it can contains modules
  28 # found by the system (including broken ones) but not used.
  29 redef class Model
  30         # All known modules
  31         var mmodules = new Array[MModule]
  32
  33         # Full module importation hierarchy including private or nested links.
  34         var mmodule_importation_hierarchy = new POSet[MModule]
  35
  36         # Collections of modules grouped by their short names
  37         private var mmodules_by_name = new MultiHashMap[String, MModule]
  38
  39         # Return all module named `name`
  40         # If such a module does not exist, null is returned (instead of an empty array)
  41         #
  42         # Visibility or modules are not considered
  43         fun get_mmodules_by_name(name: String): nullable Array[MModule]
  44         do
  45                 if mmodules_by_name.has_key(name) then
  46                         return mmodules_by_name[name]
  47                 else
  48                         return null
  49                 end
  50         end
  51 end
  52
  53 redef class MGroup
  54         # The loaded modules of this group
  55         var mmodules = new Array[MModule]
  56
  57         # The default module of a group (if any, and if loaded)
  58         #
  59         # The default module of a group is the one that has the same name.
  60         # Return `null` if the group has no default module or if the default
  61         # module is not loaded.
  62         var default_mmodule: nullable MModule = null
  63
  64         redef fun mdoc_or_fallback
  65         do
  66                 if mdoc != null then return mdoc
  67                 var default_mmodule = self.default_mmodule
  68                 if default_mmodule == null then return null
  69                 return default_mmodule.mdoc_or_fallback
  70         end
  71 end
  72
  73 # A Nit module is usually associated with a Nit source file.
  74 class MModule
  75         super MConcern
  76
  77         # The model considered
  78         redef var model: Model
  79
  80         # The group of module in the package if any
  81         var mgroup: nullable MGroup
  82
  83         # The path of the module source, if any
  84         var filepath: nullable String = null is writable
  85
  86         # The package of the module if any
  87         # Safe alias for `mgroup.mpackage`
  88         fun mpackage: nullable MPackage
  89         do
  90                 var g = mgroup
  91                 if g == null then return null else return g.mpackage
  92         end
  93
  94         # The short name of the module
  95         redef var name: String
  96
  97         redef var location: Location is writable
  98
  99         # Alias for `name`
 100         redef fun to_s do return self.name
 101
 102         # The view of the module in the `model.mmodule_importation_hierarchy`
 103         var in_importation: POSetElement[MModule] is noinit
 104
 105         # The canonical name of the module.
 106         #
 107         # It is usually the `name` prefixed by the package's name.
 108         # Example: `"package::name"`
 109         #
 110         # Default modules use a doubled name to distinguish them from the package name.
 111         # E.g.: `"core::core"`
 112         #
 113         # If the module is package-less, then the short-name is used alone.
 114         redef var full_name is lazy do
 115                 var mgroup = self.mgroup
 116                 if mgroup == null then
 117                         return self.name
 118                 else
 119                         return "{mgroup.mpackage.name}::{self.name}"
 120                 end
 121         end
 122
 123         # The namespace used for entities according to their visibility `v`.
 124         #
 125         # Public entities use only the package as a namespace.
 126         # Private entities use the `full_name` (i.e. "package::module")
 127         #
 128         # This method is used by entities to implement their `full_name`.
 129         fun namespace_for(v: MVisibility): String do
 130                 if v <= private_visibility then return full_name
 131                 var mgroup = self.mgroup
 132                 if mgroup == null then
 133                         return full_name
 134                 else
 135                         return mgroup.mpackage.full_name
 136                 end
 137         end
 138
 139         # Return the name of the global C identifier associated to `self`.
 140         # This name is used to prefix files and other C identifiers associated with `self`.
 141         redef var c_name: String is lazy do
 142                 var g = mgroup
 143                 var res
 144                 if g != null and g.mpackage.name != name then
 145                         res = g.mpackage.name.to_cmangle + "__" + name.to_cmangle
 146                 else
 147                         res = name.to_cmangle
 148                 end
 149                 return res
 150         end
 151
 152         # C identifier version of `namespace_for`.
 153         # See `c_name`
 154         #
 155         # This method is used by entities to implement their `c_name`.
 156         fun c_namespace_for(v: MVisibility): String do
 157                 if v <= private_visibility then return c_name
 158                 var mgroup = self.mgroup
 159                 if mgroup == null then
 160                         return c_name
 161                 else
 162                         return mgroup.mpackage.c_name
 163                 end
 164         end
 165
 166         # Create a new empty module and register it to a model
 167         init
 168         do
 169                 model.mmodules_by_name.add_one(name, self)
 170                 model.mmodules.add(self)
 171                 var mgroup = self.mgroup
 172                 if mgroup != null then
 173                         mgroup.mmodules.add(self)
 174                         if mgroup.name == name then
 175                                 assert mgroup.default_mmodule == null
 176                                 mgroup.default_mmodule = self
 177                         end
 178                 end
 179                 self.in_importation = model.mmodule_importation_hierarchy.add_node(self)
 180         end
 181
 182         # Register the imported modules (ie "import some_module")
 183         # The visibility must be set with `set_visibility_for`.
 184         fun set_imported_mmodules(imported_mmodules: Array[MModule])
 185         do
 186                 for m in imported_mmodules do
 187                         self.model.mmodule_importation_hierarchy.add_edge(self, m)
 188                 end
 189         end
 190
 191         private var intrude_mmodules = new HashSet[MModule]
 192         private var public_mmodules = new HashSet[MModule]
 193         private var private_mmodules = new HashSet[MModule]
 194
 195         # Return the visibility level of an imported module `m`
 196         fun visibility_for(m: MModule): MVisibility
 197         do
 198                 if m == self then return intrude_visibility
 199                 if self.intrude_mmodules.has(m) then return intrude_visibility
 200                 if self.public_mmodules.has(m) then return public_visibility
 201                 if self.private_mmodules.has(m) then return private_visibility
 202                 return none_visibility
 203         end
 204
 205         # Set the visibility of an imported module
 206         # REQUIRE: the visibility of the modules imported by `m` are already set for `m`
 207         fun set_visibility_for(m: MModule, v: MVisibility)
 208         do
 209                 if v == intrude_visibility then
 210                         self.intrude_mmodules.add(m)
 211                         self.intrude_mmodules.add_all(m.intrude_mmodules)
 212                         self.public_mmodules.add_all(m.public_mmodules)
 213                         self.private_mmodules.add_all(m.private_mmodules)
 214                 else if v == public_visibility then
 215                         self.public_mmodules.add(m)
 216                         self.public_mmodules.add_all(m.intrude_mmodules)
 217                         self.public_mmodules.add_all(m.public_mmodules)
 218                 else if v == private_visibility then
 219                         self.private_mmodules.add(m)
 220                         self.private_mmodules.add_all(m.intrude_mmodules)
 221                         self.private_mmodules.add_all(m.public_mmodules)
 222                 else
 223                         print "{self} visibility for {m} = {v}"
 224                         abort # invalid visibility
 225                 end
 226         end
 227
 228         # Return true if a class or a property introduced in `intro_mmodule` with a visibility of `visibility` is visible in self.
 229         fun is_visible(intro_mmodule: MModule, visibility: MVisibility): Bool
 230         do
 231                 var v = visibility_for(intro_mmodule)
 232                 if v == intrude_visibility then
 233                         return visibility >= private_visibility
 234                 else if v == public_visibility then
 235                         return visibility > private_visibility
 236                 else if v == private_visibility then
 237                         return visibility > private_visibility
 238                 else if v == none_visibility then
 239                         return false
 240                 else
 241                         abort
 242                 end
 243         end
 244
 245         # Is `self` a unit test module used by `nitunit`?
 246         var is_test_suite: Bool = false is writable
 247
 248         # Get the first non `is_fictive` module greater than self
 249         fun first_real_mmodule: MModule
 250         do
 251                 var mmodule = self
 252                 while mmodule.is_fictive do
 253                         mmodule = mmodule.in_importation.direct_greaters.first
 254                 end
 255                 return mmodule
 256         end
 257
 258         redef fun parent_concern do return mgroup
 259 end