src/model/model_base.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # The abstract concept of model and related common things
  18 module model_base
  19 import location
  20
  21 # The container class of a Nit object-oriented model.
  22 # A model knows modules, classes and properties and can retrieve them.
  23 class Model
  24         super MEntity
  25
  26         redef fun model do return self
  27
  28         # Place-holder object that means no-location
  29         #
  30         # See `MEntity::location`
  31         var no_location = new Location(null, 0, 0, 0, 0)
  32 end
  33
  34 # A named and possibly documented entity in the model.
  35 # This class is useful to generalize presentation of entities to the human.
  36 abstract class MEntity
  37         # The short (unqualified) name of this model entity.
  38         #
  39         # The short-name is based from the identifiers used to declare or denote the entity.
  40         # It is usually globally ambiguous but is often enough in a precise local context.
  41         #
  42         # It is suitable to use the short-name in message to the user.
  43         # However, special care must be used in case of potential ambiguities or name conflict.
  44         fun name: String is abstract
  45
  46         # A fully-qualified name of this model entity.
  47         #
  48         # The full-name is based on the short name and is usually prefixed by the name of an outer entity.
  49         # Usually the quad (`::`) is used to separate the different names.
  50         #
  51         # The full-name is expected to be unique and unambiguous in lawful Nit models for the same kind of entity.
  52         #
  53         # It is often suitable to use it in message to the user.
  54         # However, some full-name could be long and verbose,
  55         #
  56         # See the specific implementation in subclasses for details.
  57         fun full_name: String is abstract
  58
  59         # A fully-qualified C-like identifier of this model entity.
  60         #
  61         # The C-name is a name that respects the rule of identifiers in the C language:
  62         # it is only made of alphanumeric characters and starts with a letter (or a underscore).
  63         #
  64         # The C-name can be seen as a mangled version of the `full_name`.
  65         # Therefore, it is expected to be unique and unambiguous in lawful Nit models for the same kind of entity.
  66         #
  67         # The C-name is used by tools that need some identifiers in generated files to designate the
  68         # entity.
  69         #
  70         # Is is not suitable to use it directly with the user (e.g. in message) and
  71         # indirect use should be restricted (e.g. to name a web-page)
  72         fun c_name: String is abstract
  73
  74         # The origin of the definition.
  75         #
  76         # Most model entities are defined in a specific place in the source base.
  77         #
  78         # Because most model entities have one,
  79         # it is simpler for the client to have a non-nullable return value.
  80         # For entities that lack a location, mock-up special locations are used instead.
  81         # By default it is `model.no_location`.
  82         fun location: Location do return model.no_location
  83
  84         # A Model Entity has a direct link to its model
  85         fun model: Model is abstract
  86
  87         # The indication that the entity did not pass some semantic verifications.
  88         #
  89         # This simple flag is set by a given analysis to say that the entity is broken and unusable in
  90         # an execution.
  91         # When an entity status is set to broken, it is usually associated with a error message.
  92         #
  93         # If it is safe to do so, clients of the model SHOULD just skip broken entities in their processing.
  94         # Clients that do not care about the executability (e.g. metrics) MAY still process the entity or
  95         # perform specific checks to determinate the validity of the entity.
  96         #
  97         # Note that the broken status is not propagated to enclosing and enclosed entities.
  98         # e.g. a broken method does not make the whole module broken.
  99         var is_broken = false is writable
 100
 101         # Is `self` created for internal purpose?
 102         #
 103         # Fictive entities are used internally but they should not be
 104         # exposed to the final user.
 105         var is_fictive: Bool = false is writable
 106 end
 107
 108 # Something that represents a concern
 109 abstract class MConcern
 110         super MEntity
 111         # The concern that contains `self` or null if `self` is the root of the concern hierarchy
 112         fun parent_concern: nullable MConcern is abstract
 113 end
 114
 115 # A visibility (for modules, class and properties)
 116 # Valid visibility are:
 117 #
 118 #  * `intrude_visibility`
 119 #  * `public_visibility`
 120 #  * `protected_visibility`
 121 #  * `none_visibility`
 122 #  * `private_visiblity`
 123 #
 124 # Note this class is basically an enum.
 125 # FIXME: use a real enum once user-defined enums are available
 126 class MVisibility
 127         super Comparable
 128         redef type OTHER: MVisibility
 129
 130         redef var to_s: String
 131
 132         private var level: Int
 133
 134         # TODO: private init because enumeration.
 135
 136         # Is self give less visibility than other
 137         # none < private < protected < public < intrude
 138         redef fun <(other)
 139         do
 140                 return self.level < other.level
 141         end
 142 end
 143
 144 # A `Comparator` to sort mentities by their names.
 145 class MEntityNameSorter
 146         super Comparator
 147
 148         redef type COMPARED: MEntity
 149
 150         # Returns `a.name <=> b.name`.
 151         redef fun compare(a, b) do return a.name <=> b.name
 152 end
 153
 154 # The visibility level `intrude`
 155 fun intrude_visibility: MVisibility do return once new MVisibility("intrude", 5)
 156 # The visibility level `public`
 157 fun public_visibility: MVisibility do return once new MVisibility("public", 4)
 158 # The visibility level `protected`
 159 fun protected_visibility: MVisibility do return once new MVisibility("protected", 3)
 160 # The visibility level `private`
 161 fun private_visibility: MVisibility do return once new MVisibility("private", 2)
 162 # The visibility level `none` (no visibility)
 163 fun none_visibility: MVisibility do return once new MVisibility("none", 1)