nitlanguage / nit.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
syntax: new class AAbsAbsSendExpr
[nit.git] / src / compiling / compiling_methods.nit
1 # This file is part of NIT ( http://www.nitlanguage.org ).
2 #
3 # Copyright 2008 Jean Privat <jean@pryen.org>
4 #
5 # Licensed under the Apache License, Version 2.0 (the "License");
6 # you may not use this file except in compliance with the License.
7 # You may obtain a copy of the License at
8 #
9 # http://www.apache.org/licenses/LICENSE-2.0
10 #
11 # Unless required by applicable law or agreed to in writing, software
12 # distributed under the License is distributed on an "AS IS" BASIS,
13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
14 # See the License for the specific language governing permissions and
15 # limitations under the License.
16
17 # Compile method bodies, statments and expressions to C.
18 package compiling_methods
19
20 import compiling_base
21 private import syntax
22
23 redef class CompilerVisitor
24 # Compile a statment node
25 meth compile_stmt(n: PExpr)
26 do
27 if n == null then return
28 add_instr("/* Compile stmt {n.locate} */")
29 n.prepare_compile_stmt(self)
30 var i = cfc._variable_index
31 n.compile_stmt(self)
32 cfc._variable_index = i
33 end
34
35 # Compile is expression node
36 meth compile_expr(n: PExpr): String
37 do
38 add_instr("/* Compile expr {n.locate} */")
39 var i = cfc._variable_index
40 var s = n.compile_expr(self)
41 cfc._variable_index = i
42 if s[0] == ' ' or cfc.is_valid_variable(s) then
43 return s
44 end
45 var v = cfc.get_var("Result for expr {n.locate}")
46 add_assignment(v, s)
47 return v
48 end
49
50 # Ensure that a c expression is a var
51 meth ensure_var(s: String, comment: String): String
52 do
53 if cfc.is_valid_variable(s) then
54 add_instr("/* Ensure var {s}: {comment}*/")
55 return s
56 end
57 var v = cfc.get_var(null)
58 add_assignment(v, "{s} /* Ensure var: {comment}*/")
59 return v
60 end
61
62 # Add a assignment between a variable and an expression
63 meth add_assignment(v: String, s: String)
64 do
65 if v != s then
66 add_instr("{v} = {s};")
67 end
68 end
69
70 readable writable attr _cfc: CFunctionContext
71
72 readable writable attr _nmc: NitMethodContext
73
74 # C outputs written outside the current C function.
75 readable writable attr _out_contexts: Array[CContext] = new Array[CContext]
76
77 # Generate an fprintf to display an error location
78 meth printf_locate_error(node: PNode): String
79 do
80 var s = new Buffer.from("fprintf(stderr, \"")
81 if nmc != null then s.append(" in %s")
82 s.append(" (%s:%d)\\n\", ")
83 if nmc != null then s.append("LOCATE_{nmc.method.cname}, ")
84 s.append("LOCATE_{module.name}, {node.line_number});")
85 return s.to_s
86 end
87
88 meth invoke_super_init_calls_after(start_prop: MMMethod)
89 do
90 var n = nmc.method.node
91 assert n isa AConcreteInitPropdef
92
93 if n.super_init_calls.is_empty then return
94 var i = 0
95 var j = 0
96 #var s = ""
97 if start_prop != null then
98 while n.super_init_calls[i] != start_prop do
99 #s.append(" {n.super_init_calls[i]}")
100 i += 1
101 end
102 i += 1
103 #s.append(" {start_prop}")
104
105 while n.explicit_super_init_calls[j] != start_prop do
106 j += 1
107 end
108 j += 1
109 end
110 var stop_prop: MMMethod = null
111 if j < n.explicit_super_init_calls.length then
112 stop_prop = n.explicit_super_init_calls[j]
113 end
114 var l = n.super_init_calls.length
115 #s.append(" [")
116 while i < l do
117 var p = n.super_init_calls[i]
118 if p == stop_prop then break
119 var cargs = new Array[String]
120 if p.signature.arity == 0 then
121 cargs.add(cfc.varname(nmc.method_params[0]))
122 else
123 for va in nmc.method_params do
124 cargs.add(cfc.varname(va))
125 end
126 end
127 #s.append(" {p}")
128 p.compile_stmt_call(self, cargs)
129 i += 1
130 end
131 #s.append(" ]")
132 #while i < l do
133 # s.append(" {n.super_init_calls[i]}")
134 # i += 1
135 #end
136 #if stop_prop != null then s.append(" (stop at {stop_prop})")
137 #n.printl("implicit calls in {n.method}: {s}")
138 end
139 end
140
141 # A C function currently written
142 class CFunctionContext
143 readable attr _visitor: CompilerVisitor
144
145 # Next available variable number
146 attr _variable_index: Int = 0
147
148 # Total number of variable
149 attr _variable_index_max: Int = 0
150
151 # Association between nit variable and the corrsponding c variable index
152 attr _varindexes: Map[Variable, Int] = new HashMap[Variable, Int]
153
154 # Are we currenlty in a closure definition?
155 readable writable attr _closure: NitMethodContext = null
156
157 # Return the cvariable of a Nit variable
158 meth varname(v: Variable): String
159 do
160 if v isa ClosureVariable then
161 return closure_variable(_varindexes[v])
162 else
163 return variable(_varindexes[v])
164 end
165 end
166
167 # Return the next available variable
168 meth get_var(comment: String): String
169 do
170 var v = variable(_variable_index)
171 _variable_index = _variable_index + 1
172 if _variable_index > _variable_index_max then
173 _variable_index_max = _variable_index
174 end
175 if comment != null then
176 visitor.add_instr("/* Register {v}: {comment} */")
177 end
178 return v
179 end
180
181 meth register_variable(v: Variable): String
182 do
183 _varindexes[v] = _variable_index
184 var s = get_var("Local variable")
185 return s
186 end
187
188 # Next available closure variable number
189 attr _closurevariable_index: Int = 0
190
191 meth register_closurevariable(v: ClosureVariable): String
192 do
193 var s = "closurevariable[{_closurevariable_index}]"
194 _varindexes[v] = _closurevariable_index
195 _closurevariable_index += 1
196 if _closure != null then
197 return "(closctx->{s})"
198 else
199 return s
200 end
201 end
202
203 # Return the ith cvariable
204 protected meth variable(i: Int): String
205 do
206 if closure != null then
207 var vn = once new Array[String]
208 if vn.length <= i then
209 for j in [vn.length..i] do
210 vn[j] = "(closctx->variable[{j}])"
211 end
212 end
213 return vn[i]
214 else
215 var vn = once new Array[String]
216 if vn.length <= i then
217 for j in [vn.length..i] do
218 vn[j] = "variable[{j}]"
219 end
220 end
221 return vn[i]
222 end
223 end
224
225 # Return the ith closurevariable
226 protected meth closure_variable(i: Int): String
227 do
228 if closure != null then
229 return "(closctx->closurevariable[{i}])"
230 else
231 return "closurevariable[{i}]"
232 end
233 end
234
235 # Is s a valid variable
236 protected meth is_valid_variable(s: String): Bool
237 do
238 for i in [0.._variable_index[ do
239 if s == variable(i) then return true
240 end
241 return false
242 end
243
244 # Mark the variable available
245 meth free_var(v: String)
246 do
247 # FIXME: So ugly..
248 if v == variable(_variable_index-1) then
249 _variable_index = _variable_index - 1
250 end
251 end
252
253 # Generate the local variable declarations
254 # To use at the end of the C function once all variables are known
255 meth generate_var_decls
256 do
257 if _variable_index_max > 0 then
258 visitor.add_decl("val_t variable[{_variable_index_max}];")
259 else
260 visitor.add_decl("val_t *variable = NULL;")
261 end
262 if _closurevariable_index > 0 then
263 visitor.add_decl("struct WBT_ *closurevariable[{_closurevariable_index}];")
264 else
265 visitor.add_decl("struct WBT_ **closurevariable = NULL;")
266 end
267 end
268
269 init(v: CompilerVisitor) do _visitor = v
270 end
271
272 # A Nit method currenlty compiled
273 class NitMethodContext
274 # Current method compiled
275 readable attr _method: MMSrcMethod
276
277 # Association between parameters and the corresponding variables
278 readable writable attr _method_params: Array[ParamVariable]
279
280 # Where a nit return must branch
281 readable writable attr _return_label: String
282
283 # Where a nit break must branch
284 readable writable attr _break_label: String
285
286 # Where a nit continue must branch
287 readable writable attr _continue_label: String
288
289 # Variable where a functionnal nit return must store its value
290 readable writable attr _return_value: String
291
292 # Variable where a functionnal nit break must store its value
293 readable writable attr _break_value: String
294
295 # Variable where a functionnal nit continue must store its value
296 readable writable attr _continue_value: String
297
298 init(method: MMSrcMethod)
299 do
300 _method = method
301 end
302 end
303
304 ###############################################################################
305
306 redef class ClosureVariable
307 readable writable attr _ctypename: String
308 end
309
310 redef class MMMethod
311 # Compile as an expression.
312 # require that signature.return_type != null
313 meth compile_expr_call(v: CompilerVisitor, cargs: Array[String]): String
314 do
315 assert signature.return_type != null
316 var s = intern_compile_call(v, cargs)
317 assert s != null
318 return s
319 end
320
321 # Compile as a statement.
322 # require that signature.return_type == null
323 meth compile_stmt_call(v: CompilerVisitor, cargs: Array[String])
324 do
325 assert signature.return_type == null
326 var s = intern_compile_call(v, cargs)
327 assert s == null
328 end
329
330 # Compile a call on self for given arguments
331 # Most calls are compiled with a table access,
332 # primitive calles are inlined
333 # == and != are guarded and possibly inlined
334 private meth intern_compile_call(v: CompilerVisitor, cargs: Array[String]): String
335 do
336 var i = self
337 if i isa MMSrcMethod then
338 if i isa MMMethSrcMethod and i.node isa AInternMethPropdef or
339 (i.local_class.name == (once "Array".to_symbol) and name == (once "[]".to_symbol))
340 then
341 var e = i.do_compile_inside(v, cargs)
342 return e
343 end
344 end
345 var ee = once "==".to_symbol
346 var ne = once "!=".to_symbol
347 if name == ne then
348 var eqp = signature.recv.local_class.select_method(ee)
349 var eqcall = eqp.compile_expr_call(v, cargs)
350 return "TAG_Bool(!UNTAG_Bool({eqcall}))"
351 end
352 if global.is_init then
353 cargs = cargs.to_a
354 cargs.add("init_table /*YYY*/")
355 end
356
357 var m = "{global.meth_call}({cargs[0]})"
358 var vcall = "{m}({cargs.join(", ")}) /*{local_class}::{name}*/"
359 if name == ee then
360 vcall = "UNTAG_Bool({vcall})"
361 var obj = once "Object".to_symbol
362 if i.local_class.name == obj then
363 vcall = "(({m}=={i.cname})?(IS_EQUAL_NN({cargs[0]},{cargs[1]})):({vcall}))"
364 end
365 vcall = "TAG_Bool(({cargs.first} == {cargs[1]}) || (({cargs.first} != NIT_NULL) && {vcall}))"
366 end
367 if signature.return_type != null then
368 return vcall
369 else
370 v.add_instr(vcall + ";")
371 return null
372 end
373 end
374
375 # Compile a call on self for given arguments and given closures
376 meth compile_call_and_closures(v: CompilerVisitor, cargs: Array[String], clos_defs: Array[PClosureDef]): String
377 do
378 var ve: String = null
379 var arity = 0
380 if clos_defs != null then arity = clos_defs.length
381
382 # Prepare result value.
383 # In case of procedure, the return value is still used to intercept breaks
384 var old_bv = v.nmc.break_value
385 ve = v.cfc.get_var("Closure return value and escape marker")
386 v.nmc.break_value = ve
387
388 # Compile closure to c function
389 var realcargs = new Array[String] # Args to pass to the C function call
390 var closcns = new Array[String] # Closure C structure names
391 realcargs.add_all(cargs)
392 for i in [0..arity[ do
393 var cn = clos_defs[i].compile_closure(v, closure_cname(i))
394 closcns.add(cn)
395 realcargs.add(cn)
396 end
397 for i in [arity..signature.closures.length[ do
398 realcargs.add("NULL")
399 end
400
401 v.nmc.break_value = old_bv
402
403 # Call
404 var e = intern_compile_call(v, realcargs)
405 if e != null then
406 v.add_assignment(ve, e)
407 e = ve
408 end
409
410 # Intercept returns and breaks
411 for i in [0..arity[ do
412 # A break or a return is intercepted
413 v.add_instr("if ({closcns[i]}->has_broke != NULL) \{")
414 v.indent
415 # A passtrought break or a return is intercepted: go the the next closure
416 v.add_instr("if ({closcns[i]}->has_broke != &({ve})) \{")
417 v.indent
418 if v.cfc.closure == v.nmc then v.add_instr("closctx->has_broke = {closcns[i]}->has_broke; closctx->broke_value = {closcns[i]}->broke_value;")
419 v.add_instr("goto {v.nmc.return_label};")
420 v.unindent
421 # A direct break is interpected
422 if e != null then
423 # overwrite the returned value in a function
424 v.add_instr("\} else {ve} = {closcns[i]}->broke_value;")
425 else
426 # Do nothing in a procedure
427 v.add_instr("\}")
428 end
429 v.unindent
430 v.add_instr("\}")
431 end
432 return e
433 end
434
435 # Compile a call as constructor with given args
436 meth compile_constructor_call(v: CompilerVisitor, recvtype: MMType, cargs: Array[String]): String
437 do
438 return "NEW_{recvtype.local_class}_{global.intro.cname}({cargs.join(", ")}) /*new {recvtype}*/"
439 end
440
441 # Compile a call as call-next-method on self with given args
442 meth compile_super_call(v: CompilerVisitor, cargs: Array[String]): String
443 do
444 var m = "{super_meth_call}({cargs[0]})"
445 var vcall = "{m}({cargs.join(", ")}) /*super {local_class}::{name}*/"
446 return vcall
447 end
448
449 # Cname of the i-th closure C struct type
450 protected meth closure_cname(i: Int): String
451 do
452 return "FWBT_{cname}_{i}"
453 end
454 end
455
456 redef class MMAttribute
457 # Compile an acces on selffor a given reciever.
458 # Result is a valid C left-value for assigment
459 meth compile_access(v: CompilerVisitor, recv: String): String
460 do
461 return "{global.attr_access}({recv}) /*{local_class}::{name}*/"
462 end
463 end
464
465 redef class MMLocalProperty
466 # Compile the property as a C property
467 meth compile_property_to_c(v: CompilerVisitor) do end
468 end
469
470 redef class MMSrcMethod
471
472 # Compile and declare the signature to C
473 protected meth decl_csignature(v: CompilerVisitor, args: Array[String]): String
474 do
475 var params = new Array[String]
476 params.add("val_t {args[0]}")
477 for i in [0..signature.arity[ do
478 var p = "val_t {args[i+1]}"
479 params.add(p)
480 end
481
482 var first_closure_index = signature.arity + 1 # Wich parameter is the first closure
483 for i in [0..signature.closures.length[ do
484 var closcn = closure_cname(i)
485 var cs = signature.closures[i].signature # Closure signature
486 var subparams = new Array[String] # Parameters of the closure
487 subparams.add("struct WBT_ *")
488 for j in [0..cs.arity[ do
489 var p = "val_t"
490 subparams.add(p)
491 end
492 var r = "void"
493 if cs.return_type != null then r = "val_t"
494 params.add("struct WBT_ *{args[first_closure_index+i]}")
495 v.add_decl("typedef {r} (*{closcn})({subparams.join(", ")});")
496 end
497
498 if global.is_init then
499 params.add("int* init_table")
500 end
501
502 var ret: String
503 if signature.return_type != null then
504 ret = "val_t"
505 else
506 ret = "void"
507 end
508
509 var p = params.join(", ")
510 var s = "{ret} {cname}({p})"
511 v.add_decl("typedef {ret} (* {cname}_t)({p});")
512 v.add_decl(s + ";")
513 return s
514 end
515
516 redef meth compile_property_to_c(v)
517 do
518 v.cfc = new CFunctionContext(v)
519
520 var args = new Array[String]
521 args.add(" self")
522 for i in [0..signature.arity[ do
523 args.add(" param{i}")
524 end
525 for i in [0..signature.closures.length[ do
526 args.add(" wd{i}")
527 end
528 var cs = decl_csignature(v, args)
529 v.add_decl("#define LOCATE_{cname} \"{full_name}\"")
530
531 v.add_instr("{cs} \{")
532 v.indent
533 var ctx_old = v.ctx
534 v.ctx = new CContext
535
536 v.out_contexts.clear
537
538 var ln = 0
539 var s = self
540 if s.node != null then ln = s.node.line_number
541 v.add_decl("struct trace_t trace = \{NULL, NULL, {ln}, LOCATE_{cname}};")
542 v.add_instr("trace.prev = tracehead; tracehead = &trace;")
543 v.add_instr("trace.file = LOCATE_{module.name};")
544 var s = do_compile_inside(v, args)
545 v.add_instr("tracehead = trace.prev;")
546 if s == null then
547 v.add_instr("return;")
548 else
549 v.add_instr("return {s};")
550 end
551
552 v.cfc.generate_var_decls
553
554 ctx_old.append(v.ctx)
555 v.ctx = ctx_old
556 v.unindent
557 v.add_instr("}")
558
559 for ctx in v.out_contexts do v.ctx.merge(ctx)
560 end
561
562 # Compile the method body inline
563 meth do_compile_inside(v: CompilerVisitor, params: Array[String]): String is abstract
564 end
565
566 redef class MMReadImplementationMethod
567 redef meth do_compile_inside(v, params)
568 do
569 return node.prop.compile_access(v, params[0])
570 end
571 end
572
573 redef class MMWriteImplementationMethod
574 redef meth do_compile_inside(v, params)
575 do
576 v.add_assignment(node.prop.compile_access(v, params[0]), params[1])
577 return null
578 end
579 end
580
581 redef class MMMethSrcMethod
582 redef meth do_compile_inside(v, params)
583 do
584 return node.do_compile_inside(v, self, params)
585 end
586 end
587
588 redef class MMImplicitInit
589 redef meth do_compile_inside(v, params)
590 do
591 var f = params.length - unassigned_attributes.length
592 var recv = params.first
593 for sp in super_inits do
594 assert sp isa MMMethod
595 var args_recv = [recv]
596 if sp == super_init then
597 var args = new Array[String].with_capacity(f)
598 args.add(recv)
599 for i in [1..f[ do
600 args.add(params[i])
601 end
602 sp.compile_stmt_call(v, args)
603 else
604 sp.compile_stmt_call(v, args_recv)
605 end
606 end
607 for i in [f..params.length[ do
608 var attribute = unassigned_attributes[i-f]
609 v.add_assignment(attribute.compile_access(v, recv), params[i])
610 end
611 return null
612 end
613 end
614
615 redef class MMType
616 # Compile a subtype check to self
617 # Return a NIT Bool
618 meth compile_cast(v: CompilerVisitor, recv: String): String
619 do
620 # Fixme: handle formaltypes
621 var g = local_class.global
622 return "TAG_Bool(({recv}==NIT_NULL) || VAL_ISA({recv}, {g.color_id}, {g.id_id})) /*cast {self}*/"
623 end
624
625 # Compile a cast assertion
626 meth compile_type_check(v: CompilerVisitor, recv: String, n: PNode)
627 do
628 # Fixme: handle formaltypes
629 var g = local_class.global
630 v.add_instr("if (({recv}!=NIT_NULL) && !VAL_ISA({recv}, {g.color_id}, {g.id_id})) \{ fprintf(stderr, \"Cast failled\"); {v.printf_locate_error(n)} nit_exit(1); } /*cast {self}*/;")
631 end
632 end
633
634 ###############################################################################
635
636 redef class AMethPropdef
637 # Compile the method body
638 meth do_compile_inside(v: CompilerVisitor, method: MMSrcMethod, params: Array[String]): String is abstract
639 end
640
641 redef class PSignature
642 meth compile_parameters(v: CompilerVisitor, orig_sig: MMSignature, params: Array[String]) is abstract
643 end
644
645 redef class ASignature
646 redef meth compile_parameters(v: CompilerVisitor, orig_sig: MMSignature, params: Array[String])
647 do
648 for ap in n_params do
649 var cname = v.cfc.register_variable(ap.variable)
650 v.nmc.method_params.add(ap.variable)
651 var orig_type = orig_sig[ap.position]
652 if not orig_type < ap.variable.stype then
653 # FIXME: do not test always
654 # FIXME: handle formal types
655 v.add_instr("/* check if p<{ap.variable.stype} with p:{orig_type} */")
656 ap.variable.stype.compile_type_check(v, params[ap.position], ap)
657 end
658 v.add_assignment(cname, params[ap.position])
659 end
660 for i in [0..n_closure_decls.length[ do
661 var wd = n_closure_decls[i]
662 var cname = v.cfc.register_closurevariable(wd.variable)
663 wd.variable.ctypename = v.nmc.method.closure_cname(i)
664 v.add_assignment(cname, "{params[orig_sig.arity + i]}")
665 end
666 end
667 end
668
669 redef class AConcreteMethPropdef
670 redef meth do_compile_inside(v, method, params)
671 do
672 var old_nmc = v.nmc
673 v.nmc = new NitMethodContext(method)
674
675 var selfcname = v.cfc.register_variable(self_var)
676 v.add_assignment(selfcname, params[0])
677 params.shift
678 v.nmc.method_params = [self_var]
679
680 if n_signature != null then
681 var orig_meth: MMLocalProperty = method.global.intro
682 var orig_sig = orig_meth.signature_for(method.signature.recv)
683 n_signature.compile_parameters(v, orig_sig, params)
684 end
685
686 var itpos: String = null
687 if self isa AConcreteInitPropdef then
688 itpos = "VAL2OBJ({selfcname})->vft[{method.local_class.global.init_table_pos_id}].i"
689 # v.add_instr("printf(\"{method.full_name}: inittable[%d] = %d\\n\", {itpos}, init_table[{itpos}]);")
690 v.add_instr("if (init_table[{itpos}]) return;")
691 end
692
693 v.nmc.return_label = "return_label{v.new_number}"
694 v.nmc.return_value = v.cfc.get_var("Method return value and escape marker")
695 if self isa AConcreteInitPropdef then
696 v.invoke_super_init_calls_after(null)
697 end
698 v.compile_stmt(n_block)
699 v.add_instr("{v.nmc.return_label}: while(false);")
700 if self isa AConcreteInitPropdef then
701 v.add_instr("init_table[{itpos}] = 1;")
702 end
703
704 var ret: String = null
705 if method.signature.return_type != null then
706 ret = v.nmc.return_value
707 end
708
709 v.nmc = old_nmc
710 return ret
711 end
712 end
713
714 redef class ADeferredMethPropdef
715 redef meth do_compile_inside(v, method, params)
716 do
717 v.add_instr("fprintf(stderr, \"Deferred method called\");")
718 v.add_instr(v.printf_locate_error(self))
719 v.add_instr("nit_exit(1);")
720 if method.signature.return_type != null then
721 return("NIT_NULL")
722 else
723 return null
724 end
725 end
726 end
727
728 redef class AExternMethPropdef
729 redef meth do_compile_inside(v, method, params)
730 do
731 var ename = "{method.module.name}_{method.local_class.name}_{method.local_class.name}_{method.name}_{method.signature.arity}"
732 if n_extern != null then
733 ename = n_extern.text
734 ename = ename.substring(1, ename.length-2)
735 end
736 var sig = method.signature
737 if params.length != sig.arity + 1 then
738 printl("par:{params.length} sig:{sig.arity}")
739 end
740 var args = new Array[String]
741 args.add(sig.recv.unboxtype(params[0]))
742 for i in [0..sig.arity[ do
743 args.add(sig[i].unboxtype(params[i+1]))
744 end
745 var s = "{ename}({args.join(", ")})"
746 if sig.return_type != null then
747 return sig.return_type.boxtype(s)
748 else
749 v.add_instr("{s};")
750 return null
751 end
752 end
753 end
754
755 redef class AInternMethPropdef
756 redef meth do_compile_inside(v, method, p)
757 do
758 var c = method.local_class.name
759 var n = method.name
760 var s: String = null
761 if c == once "Int".to_symbol then
762 if n == once "object_id".to_symbol then
763 s = "{p[0]}"
764 else if n == once "unary -".to_symbol then
765 s = "TAG_Int(-UNTAG_Int({p[0]}))"
766 else if n == once "output".to_symbol then
767 v.add_instr("printf(\"%ld\\n\", UNTAG_Int({p[0]}));")
768 else if n == once "ascii".to_symbol then
769 s = "TAG_Char(UNTAG_Int({p[0]}))"
770 else if n == once "succ".to_symbol then
771 s = "TAG_Int(UNTAG_Int({p[0]})+1)"
772 else if n == once "prec".to_symbol then
773 s = "TAG_Int(UNTAG_Int({p[0]})-1)"
774 else if n == once "to_f".to_symbol then
775 s = "BOX_Float((float)UNTAG_Int({p[0]}))"
776 else if n == once "+".to_symbol then
777 s = "TAG_Int(UNTAG_Int({p[0]})+UNTAG_Int({p[1]}))"
778 else if n == once "-".to_symbol then
779 s = "TAG_Int(UNTAG_Int({p[0]})-UNTAG_Int({p[1]}))"
780 else if n == once "*".to_symbol then
781 s = "TAG_Int(UNTAG_Int({p[0]})*UNTAG_Int({p[1]}))"
782 else if n == once "/".to_symbol then
783 s = "TAG_Int(UNTAG_Int({p[0]})/UNTAG_Int({p[1]}))"
784 else if n == once "%".to_symbol then
785 s = "TAG_Int(UNTAG_Int({p[0]})%UNTAG_Int({p[1]}))"
786 else if n == once "<".to_symbol then
787 s = "TAG_Bool(UNTAG_Int({p[0]})<UNTAG_Int({p[1]}))"
788 else if n == once ">".to_symbol then
789 s = "TAG_Bool(UNTAG_Int({p[0]})>UNTAG_Int({p[1]}))"
790 else if n == once "<=".to_symbol then
791 s = "TAG_Bool(UNTAG_Int({p[0]})<=UNTAG_Int({p[1]}))"
792 else if n == once ">=".to_symbol then
793 s = "TAG_Bool(UNTAG_Int({p[0]})>=UNTAG_Int({p[1]}))"
794 else if n == once "lshift".to_symbol then
795 s = "TAG_Int(UNTAG_Int({p[0]})<<UNTAG_Int({p[1]}))"
796 else if n == once "rshift".to_symbol then
797 s = "TAG_Int(UNTAG_Int({p[0]})>>UNTAG_Int({p[1]}))"
798 else if n == once "==".to_symbol then
799 s = "TAG_Bool(({p[0]})==({p[1]}))"
800 else if n == once "!=".to_symbol then
801 s = "TAG_Bool(({p[0]})!=({p[1]}))"
802 end
803 else if c == once "Float".to_symbol then
804 if n == once "object_id".to_symbol then
805 s = "TAG_Int((bigint)UNBOX_Float({p[0]}))"
806 else if n == once "unary -".to_symbol then
807 s = "BOX_Float(-UNBOX_Float({p[0]}))"
808 else if n == once "output".to_symbol then
809 v.add_instr("printf(\"%f\\n\", UNBOX_Float({p[0]}));")
810 else if n == once "to_i".to_symbol then
811 s = "TAG_Int((bigint)UNBOX_Float({p[0]}))"
812 else if n == once "+".to_symbol then
813 s = "BOX_Float(UNBOX_Float({p[0]})+UNBOX_Float({p[1]}))"
814 else if n == once "-".to_symbol then
815 s = "BOX_Float(UNBOX_Float({p[0]})-UNBOX_Float({p[1]}))"
816 else if n == once "*".to_symbol then
817 s = "BOX_Float(UNBOX_Float({p[0]})*UNBOX_Float({p[1]}))"
818 else if n == once "/".to_symbol then
819 s = "BOX_Float(UNBOX_Float({p[0]})/UNBOX_Float({p[1]}))"
820 else if n == once "<".to_symbol then
821 s = "TAG_Bool(UNBOX_Float({p[0]})<UNBOX_Float({p[1]}))"
822 else if n == once ">".to_symbol then
823 s = "TAG_Bool(UNBOX_Float({p[0]})>UNBOX_Float({p[1]}))"
824 else if n == once "<=".to_symbol then
825 s = "TAG_Bool(UNBOX_Float({p[0]})<=UNBOX_Float({p[1]}))"
826 else if n == once ">=".to_symbol then
827 s = "TAG_Bool(UNBOX_Float({p[0]})>=UNBOX_Float({p[1]}))"
828 end
829 else if c == once "Char".to_symbol then
830 if n == once "object_id".to_symbol then
831 s = "TAG_Int(UNTAG_Char({p[0]}))"
832 else if n == once "unary -".to_symbol then
833 s = "TAG_Char(-UNTAG_Char({p[0]}))"
834 else if n == once "output".to_symbol then
835 v.add_instr("printf(\"%c\", (unsigned char)UNTAG_Char({p[0]}));")
836 else if n == once "ascii".to_symbol then
837 s = "TAG_Int((unsigned char)UNTAG_Char({p[0]}))"
838 else if n == once "succ".to_symbol then
839 s = "TAG_Char(UNTAG_Char({p[0]})+1)"
840 else if n == once "prec".to_symbol then
841 s = "TAG_Char(UNTAG_Char({p[0]})-1)"
842 else if n == once "to_i".to_symbol then
843 s = "TAG_Int(UNTAG_Char({p[0]})-'0')"
844 else if n == once "+".to_symbol then
845 s = "TAG_Char(UNTAG_Char({p[0]})+UNTAG_Char({p[1]}))"
846 else if n == once "-".to_symbol then
847 s = "TAG_Char(UNTAG_Char({p[0]})-UNTAG_Char({p[1]}))"
848 else if n == once "*".to_symbol then
849 s = "TAG_Char(UNTAG_Char({p[0]})*UNTAG_Char({p[1]}))"
850 else if n == once "/".to_symbol then
851 s = "TAG_Char(UNTAG_Char({p[0]})/UNTAG_Char({p[1]}))"
852 else if n == once "%".to_symbol then
853 s = "TAG_Char(UNTAG_Char({p[0]})%UNTAG_Char({p[1]}))"
854 else if n == once "<".to_symbol then
855 s = "TAG_Bool(UNTAG_Char({p[0]})<UNTAG_Char({p[1]}))"
856 else if n == once ">".to_symbol then
857 s = "TAG_Bool(UNTAG_Char({p[0]})>UNTAG_Char({p[1]}))"
858 else if n == once "<=".to_symbol then
859 s = "TAG_Bool(UNTAG_Char({p[0]})<=UNTAG_Char({p[1]}))"
860 else if n == once ">=".to_symbol then
861 s = "TAG_Bool(UNTAG_Char({p[0]})>=UNTAG_Char({p[1]}))"
862 else if n == once "==".to_symbol then
863 s = "TAG_Bool(({p[0]})==({p[1]}))"
864 else if n == once "!=".to_symbol then
865 s = "TAG_Bool(({p[0]})!=({p[1]}))"
866 end
867 else if c == once "Bool".to_symbol then
868 if n == once "object_id".to_symbol then
869 s = "TAG_Int(UNTAG_Bool({p[0]}))"
870 else if n == once "unary -".to_symbol then
871 s = "TAG_Bool(-UNTAG_Bool({p[0]}))"
872 else if n == once "output".to_symbol then
873 v.add_instr("(void)printf(UNTAG_Bool({p[0]})?\"true\\n\":\"false\\n\");")
874 else if n == once "ascii".to_symbol then
875 s = "TAG_Bool(UNTAG_Bool({p[0]}))"
876 else if n == once "to_i".to_symbol then
877 s = "TAG_Int(UNTAG_Bool({p[0]}))"
878 else if n == once "==".to_symbol then
879 s = "TAG_Bool(({p[0]})==({p[1]}))"
880 else if n == once "!=".to_symbol then
881 s = "TAG_Bool(({p[0]})!=({p[1]}))"
882 end
883 else if c == once "NativeArray".to_symbol then
884 if n == once "object_id".to_symbol then
885 s = "TAG_Int(UNBOX_NativeArray({p[0]}))"
886 else if n == once "[]".to_symbol then
887 s = "UNBOX_NativeArray({p[0]})[UNTAG_Int({p[1]})]"
888 else if n == once "[]=".to_symbol then
889 v.add_instr("UNBOX_NativeArray({p[0]})[UNTAG_Int({p[1]})]={p[2]};")
890 else if n == once "copy_to".to_symbol then
891 v.add_instr("(void)memcpy(UNBOX_NativeArray({p[1]}), UNBOX_NativeArray({p[0]}), UNTAG_Int({p[2]})*sizeof(val_t));")
892 end
893 else if c == once "NativeString".to_symbol then
894 if n == once "object_id".to_symbol then
895 s = "TAG_Int(UNBOX_NativeString({p[0]}))"
896 else if n == once "atoi".to_symbol then
897 s = "TAG_Int(atoi(UNBOX_NativeString({p[0]})))"
898 else if n == once "[]".to_symbol then
899 s = "TAG_Char(UNBOX_NativeString({p[0]})[UNTAG_Int({p[1]})])"
900 else if n == once "[]=".to_symbol then
901 v.add_instr("UNBOX_NativeString({p[0]})[UNTAG_Int({p[1]})]=UNTAG_Char({p[2]});")
902 else if n == once "copy_to".to_symbol then
903 v.add_instr("(void)memcpy(UNBOX_NativeString({p[1]})+UNTAG_Int({p[4]}), UNBOX_NativeString({p[0]})+UNTAG_Int({p[3]}), UNTAG_Int({p[2]}));")
904 end
905 else if n == once "object_id".to_symbol then
906 s = "TAG_Int((bigint){p[0]})"
907 else if n == once "sys".to_symbol then
908 s = "(G_sys)"
909 else if n == once "is_same_type".to_symbol then
910 s = "TAG_Bool((VAL2VFT({p[0]})==VAL2VFT({p[1]})))"
911 else if n == once "exit".to_symbol then
912 v.add_instr("exit(UNTAG_Int({p[1]}));")
913 else if n == once "calloc_array".to_symbol then
914 s = "BOX_NativeArray((val_t*)malloc((UNTAG_Int({p[1]}) * sizeof(val_t))))"
915 else if n == once "calloc_string".to_symbol then
916 s = "BOX_NativeString((char*)malloc((UNTAG_Int({p[1]}) * sizeof(char))))"
917
918 else
919 v.add_instr("fprintf(stderr, \"Intern {n}\\n\"); nit_exit(1);")
920 end
921 if method.signature.return_type != null and s == null then
922 s = "NIT_NULL /*stub*/"
923 end
924 return s
925 end
926 end
927
928 ###############################################################################
929
930 redef class PExpr
931 # Compile the node as an expression
932 # Only the visitor should call it
933 meth compile_expr(v: CompilerVisitor): String is abstract
934
935 # Prepare a call of node as a statement
936 # Only the visitor should call it
937 # It's used for local variable managment
938 meth prepare_compile_stmt(v: CompilerVisitor) do end
939
940 # Compile the node as a statement
941 # Only the visitor should call it
942 meth compile_stmt(v: CompilerVisitor) do printl("Error!")
943 end
944
945 redef class ABlockExpr
946 redef meth compile_stmt(v)
947 do
948 for n in n_expr do
949 v.compile_stmt(n)
950 end
951 end
952 end
953
954 redef class AVardeclExpr
955 redef meth prepare_compile_stmt(v)
956 do
957 v.cfc.register_variable(variable)
958 end
959
960 redef meth compile_stmt(v)
961 do
962 var cname = v.cfc.varname(variable)
963 if n_expr == null then
964 v.add_instr("/*{cname} is variable {variable.name}*/")
965 else
966 var e = v.compile_expr(n_expr)
967 v.add_assignment(cname, e)
968 end
969 end
970 end
971
972 redef class AReturnExpr
973 redef meth compile_stmt(v)
974 do
975 if n_expr != null then
976 var e = v.compile_expr(n_expr)
977 v.add_assignment(v.nmc.return_value, e)
978 end
979 if v.cfc.closure == v.nmc then v.add_instr("closctx->has_broke = &({v.nmc.return_value});")
980 v.add_instr("goto {v.nmc.return_label};")
981 end
982 end
983
984 redef class ABreakExpr
985 redef meth compile_stmt(v)
986 do
987 if n_expr != null then
988 var e = v.compile_expr(n_expr)
989 v.add_assignment(v.nmc.break_value, e)
990 end
991 if v.cfc.closure == v.nmc then v.add_instr("closctx->has_broke = &({v.nmc.break_value}); closctx->broke_value = *closctx->has_broke;")
992 v.add_instr("goto {v.nmc.break_label};")
993 end
994 end
995
996 redef class AContinueExpr
997 redef meth compile_stmt(v)
998 do
999 if n_expr != null then
1000 var e = v.compile_expr(n_expr)
1001 v.add_assignment(v.nmc.continue_value, e)
1002 end
1003 v.add_instr("goto {v.nmc.continue_label};")
1004 end
1005 end
1006
1007 redef class AAbortExpr
1008 redef meth compile_stmt(v)
1009 do
1010 v.add_instr("fprintf(stderr, \"Aborted\"); {v.printf_locate_error(self)} nit_exit(1);")
1011 end
1012 end
1013
1014 redef class ADoExpr
1015 redef meth compile_stmt(v)
1016 do
1017 v.compile_stmt(n_block)
1018 end
1019 end
1020
1021 redef class AIfExpr
1022 redef meth compile_stmt(v)
1023 do
1024 var e = v.compile_expr(n_expr)
1025 v.add_instr("if (UNTAG_Bool({e})) \{ /*if*/")
1026 v.cfc.free_var(e)
1027 if n_then != null then
1028 v.indent
1029 v.compile_stmt(n_then)
1030 v.unindent
1031 end
1032 if n_else != null then
1033 v.add_instr("} else \{ /*if*/")
1034 v.indent
1035 v.compile_stmt(n_else)
1036 v.unindent
1037 end
1038 v.add_instr("}")
1039 end
1040 end
1041
1042 redef class AIfexprExpr
1043 redef meth compile_expr(v)
1044 do
1045 var e = v.compile_expr(n_expr)
1046 v.add_instr("if (UNTAG_Bool({e})) \{ /*if*/")
1047 v.cfc.free_var(e)
1048 v.indent
1049 var e = v.ensure_var(v.compile_expr(n_then), "Then value")
1050 v.unindent
1051 v.add_instr("} else \{ /*if*/")
1052 v.cfc.free_var(e)
1053 v.indent
1054 var e2 = v.ensure_var(v.compile_expr(n_else), "Else value")
1055 v.add_assignment(e, e2)
1056 v.unindent
1057 v.add_instr("}")
1058 return e
1059 end
1060 end
1061
1062 redef class AControlableBlock
1063 meth compile_inside_block(v: CompilerVisitor) is abstract
1064 redef meth compile_stmt(v)
1065 do
1066 var old_break_label = v.nmc.break_label
1067 var old_continue_label = v.nmc.continue_label
1068 var id = v.new_number
1069 v.nmc.break_label = "break_{id}"
1070 v.nmc.continue_label = "continue_{id}"
1071
1072 compile_inside_block(v)
1073
1074
1075 v.nmc.break_label = old_break_label
1076 v.nmc.continue_label = old_continue_label
1077 end
1078 end
1079
1080 redef class AWhileExpr
1081 redef meth compile_inside_block(v)
1082 do
1083 v.add_instr("while (true) \{ /*while*/")
1084 v.indent
1085 var e = v.compile_expr(n_expr)
1086 v.add_instr("if (!UNTAG_Bool({e})) break; /* while*/")
1087 v.cfc.free_var(e)
1088 v.compile_stmt(n_block)
1089 v.add_instr("{v.nmc.continue_label}: while(0);")
1090 v.unindent
1091 v.add_instr("}")
1092 v.add_instr("{v.nmc.break_label}: while(0);")
1093 end
1094 end
1095
1096 redef class AForExpr
1097 redef meth compile_inside_block(v)
1098 do
1099 var e = v.compile_expr(n_expr)
1100 var ittype = meth_iterator.signature.return_type
1101 v.cfc.free_var(e)
1102 var iter = v.cfc.get_var("For iterator")
1103 v.add_assignment(iter, meth_iterator.compile_expr_call(v, [e]))
1104 v.add_instr("while (true) \{ /*for*/")
1105 v.indent
1106 var ok = v.cfc.get_var("For 'is_ok' result")
1107 v.add_assignment(ok, meth_is_ok.compile_expr_call(v, [iter]))
1108 v.add_instr("if (!UNTAG_Bool({ok})) break; /*for*/")
1109 v.cfc.free_var(ok)
1110 var e = meth_item.compile_expr_call(v, [iter])
1111 e = v.ensure_var(e, "For item")
1112 var cname = v.cfc.register_variable(variable)
1113 v.add_assignment(cname, e)
1114 v.compile_stmt(n_block)
1115 v.add_instr("{v.nmc.continue_label}: while(0);")
1116 meth_next.compile_stmt_call(v, [iter])
1117 v.unindent
1118 v.add_instr("}")
1119 v.add_instr("{v.nmc.break_label}: while(0);")
1120 end
1121 end
1122
1123 redef class AAssertExpr
1124 redef meth compile_stmt(v)
1125 do
1126 var e = v.compile_expr(n_expr)
1127 var s = ""
1128 if n_id != null then
1129 s = " '{n_id.text}' "
1130 end
1131 v.add_instr("if (!UNTAG_Bool({e})) \{ fprintf(stderr, \"Assert%s failed\", \"{s}\"); {v.printf_locate_error(self)} nit_exit(1);}")
1132 end
1133 end
1134
1135 redef class AVarExpr
1136 redef meth compile_expr(v)
1137 do
1138 return " {v.cfc.varname(variable)} /*{variable.name}*/"
1139 end
1140 end
1141
1142 redef class AVarAssignExpr
1143 redef meth compile_stmt(v)
1144 do
1145 var e = v.compile_expr(n_value)
1146 v.add_assignment(v.cfc.varname(variable), "{e} /*{variable.name}=*/")
1147 end
1148 end
1149
1150 redef class AVarReassignExpr
1151 redef meth compile_stmt(v)
1152 do
1153 var e1 = v.cfc.varname(variable)
1154 var e2 = v.compile_expr(n_value)
1155 var e3 = assign_method.compile_expr_call(v, [e1, e2])
1156 v.add_assignment(v.cfc.varname(variable), "{e3} /*{variable.name}*/")
1157 end
1158 end
1159
1160 redef class ASelfExpr
1161 redef meth compile_expr(v)
1162 do
1163 return v.cfc.varname(v.nmc.method_params[0])
1164 end
1165 end
1166
1167 redef class AOrExpr
1168 redef meth compile_expr(v)
1169 do
1170 var e = v.ensure_var(v.compile_expr(n_expr), "Left 'or' operand")
1171 v.add_instr("if (!UNTAG_Bool({e})) \{ /* or */")
1172 v.cfc.free_var(e)
1173 v.indent
1174 var e2 = v.compile_expr(n_expr2)
1175 v.add_assignment(e, e2)
1176 v.unindent
1177 v.add_instr("}")
1178 return e
1179 end
1180 end
1181
1182 redef class AAndExpr
1183 redef meth compile_expr(v)
1184 do
1185 var e = v.ensure_var(v.compile_expr(n_expr), "Left 'and' operand")
1186 v.add_instr("if (UNTAG_Bool({e})) \{ /* and */")
1187 v.cfc.free_var(e)
1188 v.indent
1189 var e2 = v.compile_expr(n_expr2)
1190 v.add_assignment(e, e2)
1191 v.unindent
1192 v.add_instr("}")
1193 return e
1194 end
1195 end
1196
1197 redef class ANotExpr
1198 redef meth compile_expr(v)
1199 do
1200 return " TAG_Bool(!UNTAG_Bool({v.compile_expr(n_expr)}))"
1201 end
1202 end
1203
1204 redef class AEeExpr
1205 redef meth compile_expr(v)
1206 do
1207 var e = v.compile_expr(n_expr)
1208 var e2 = v.compile_expr(n_expr2)
1209 return "TAG_Bool(IS_EQUAL_NN({e},{e2}))"
1210 end
1211 end
1212
1213 redef class AIsaExpr
1214 redef meth compile_expr(v)
1215 do
1216 var e = v.compile_expr(n_expr)
1217 return n_type.stype.compile_cast(v, e)
1218 end
1219 end
1220
1221 redef class AAsCastExpr
1222 redef meth compile_expr(v)
1223 do
1224 var e = v.compile_expr(n_expr)
1225 n_type.stype.compile_type_check(v, e, self)
1226 return e
1227 end
1228 end
1229
1230 redef class ATrueExpr
1231 redef meth compile_expr(v)
1232 do
1233 return " TAG_Bool(true)"
1234 end
1235 end
1236
1237 redef class AFalseExpr
1238 redef meth compile_expr(v)
1239 do
1240 return " TAG_Bool(false)"
1241 end
1242 end
1243
1244 redef class AIntExpr
1245 redef meth compile_expr(v)
1246 do
1247 return " TAG_Int({n_number.text})"
1248 end
1249 end
1250
1251 redef class AFloatExpr
1252 redef meth compile_expr(v)
1253 do
1254 return "BOX_Float({n_float.text})"
1255 end
1256 end
1257
1258 redef class ACharExpr
1259 redef meth compile_expr(v)
1260 do
1261 return " TAG_Char({n_char.text})"
1262 end
1263 end
1264
1265 redef class AStringFormExpr
1266 redef meth compile_expr(v)
1267 do
1268 compute_string_info
1269 var i = v.new_number
1270 var cvar = v.cfc.get_var("Once String constant")
1271 v.add_decl("static val_t once_value_{i} = NIT_NULL; /* Once value for string {cvar}*/")
1272 v.add_instr("if (once_value_{i} != NIT_NULL) {cvar} = once_value_{i};")
1273 v.add_instr("else \{")
1274 v.indent
1275 v.cfc.free_var(cvar)
1276 var e = meth_with_native.compile_constructor_call(v, stype , ["BOX_NativeString(\"{_cstring}\")", "TAG_Int({_cstring_length})"])
1277 v.add_assignment(cvar, e)
1278 v.add_instr("once_value_{i} = {cvar};")
1279 v.unindent
1280 v.add_instr("}")
1281 return cvar
1282 end
1283
1284 # The raw string value
1285 protected meth string_text: String is abstract
1286
1287 # The string in a C native format
1288 protected attr _cstring: String
1289
1290 # The string length in bytes
1291 protected attr _cstring_length: Int
1292
1293 # Compute _cstring and _cstring_length using string_text
1294 protected meth compute_string_info
1295 do
1296 var len = 0
1297 var str = string_text
1298 var res = new Buffer
1299 var i = 0
1300 while i < str.length do
1301 var c = str[i]
1302 if c == '\\' then
1303 i = i + 1
1304 var c2 = str[i]
1305 if c2 != '{' and c2 != '}' then
1306 res.add(c)
1307 end
1308 c = c2
1309 end
1310 len = len + 1
1311 res.add(c)
1312 i = i + 1
1313 end
1314 _cstring = res.to_s
1315 _cstring_length = len
1316 end
1317 end
1318
1319 redef class AStringExpr
1320 redef meth string_text do return n_string.text.substring(1, n_string.text.length - 2)
1321 end
1322 redef class AStartStringExpr
1323 redef meth string_text do return n_string.text.substring(1, n_string.text.length - 2)
1324 end
1325 redef class AMidStringExpr
1326 redef meth string_text do return n_string.text.substring(1, n_string.text.length - 2)
1327 end
1328 redef class AEndStringExpr
1329 redef meth string_text do return n_string.text.substring(1, n_string.text.length - 2)
1330 end
1331
1332 redef class ASuperstringExpr
1333 redef meth compile_expr(v)
1334 do
1335 var array = meth_with_capacity.compile_constructor_call(v, atype, ["TAG_Int({n_exprs.length})"])
1336 array = v.ensure_var(array, "Array (for super-string)")
1337
1338 for ne in n_exprs do
1339 var e = v.ensure_var(v.compile_expr(ne), "super-string element")
1340 if ne.stype != stype then
1341 v.cfc.free_var(e)
1342 e = meth_to_s.compile_expr_call(v, [e])
1343 end
1344 v.cfc.free_var(e)
1345 meth_add.compile_stmt_call(v, [array, e])
1346 end
1347
1348 return meth_to_s.compile_expr_call(v, [array])
1349 end
1350 end
1351
1352 redef class ANullExpr
1353 redef meth compile_expr(v)
1354 do
1355 return " NIT_NULL /*null*/"
1356 end
1357 end
1358
1359 redef class AArrayExpr
1360 redef meth compile_expr(v)
1361 do
1362 var recv = meth_with_capacity.compile_constructor_call(v, stype, ["TAG_Int({n_exprs.length})"])
1363 recv = v.ensure_var(recv, "Literal array")
1364
1365 for ne in n_exprs do
1366 var e = v.compile_expr(ne)
1367 meth_add.compile_stmt_call(v, [recv, e])
1368 end
1369 return recv
1370 end
1371 end
1372
1373 redef class ARangeExpr
1374 redef meth compile_expr(v)
1375 do
1376 var e = v.compile_expr(n_expr)
1377 var e2 = v.compile_expr(n_expr2)
1378 return meth_init.compile_constructor_call(v, stype, [e, e2])
1379 end
1380 end
1381
1382 redef class ASuperExpr
1383 redef meth compile_stmt(v)
1384 do
1385 var e = intern_compile_call(v)
1386 if e != null then
1387 v.add_instr(e + ";")
1388 end
1389 end
1390
1391 redef meth compile_expr(v)
1392 do
1393 var e = intern_compile_call(v)
1394 assert e != null
1395 return e
1396 end
1397
1398 private meth intern_compile_call(v: CompilerVisitor): String
1399 do
1400 var arity = v.nmc.method_params.length - 1
1401 if init_in_superclass != null then
1402 arity = init_in_superclass.signature.arity
1403 end
1404 var args = new Array[String].with_capacity(arity + 1)
1405 args.add(v.cfc.varname(v.nmc.method_params[0]))
1406 if n_args.length != arity then
1407 for i in [0..arity[ do
1408 args.add(v.cfc.varname(v.nmc.method_params[i + 1]))
1409 end
1410 else
1411 for na in n_args do
1412 args.add(v.compile_expr(na))
1413 end
1414 end
1415 #return "{prop.cname}({args.join(", ")}) /*super {prop.local_class}::{prop.name}*/"
1416 if init_in_superclass != null then
1417 return init_in_superclass.intern_compile_call(v, args)
1418 else
1419 if prop.global.is_init then args.add("init_table")
1420 return prop.compile_super_call(v, args)
1421 end
1422 end
1423 end
1424
1425 redef class AAttrExpr
1426 redef meth compile_expr(v)
1427 do
1428 var e = v.compile_expr(n_expr)
1429 return prop.compile_access(v, e)
1430 end
1431 end
1432
1433 redef class AAttrAssignExpr
1434 redef meth compile_stmt(v)
1435 do
1436 var e = v.compile_expr(n_expr)
1437 var e2 = v.compile_expr(n_value)
1438 v.add_assignment(prop.compile_access(v, e), e2)
1439 end
1440 end
1441 redef class AAttrReassignExpr
1442 redef meth compile_stmt(v)
1443 do
1444 var e1 = v.compile_expr(n_expr)
1445 var e2 = prop.compile_access(v, e1)
1446 var e3 = v.compile_expr(n_value)
1447 var e4 = assign_method.compile_expr_call(v, [e2, e3])
1448 v.add_assignment(e2, e4)
1449 end
1450 end
1451
1452 redef class AAbsAbsSendExpr
1453 # Compile each argument and add them to the array
1454 meth compile_arguments_in(v: CompilerVisitor, cargs: Array[String])
1455 do
1456 for a in arguments do
1457 cargs.add(v.compile_expr(a))
1458 end
1459 end
1460
1461 end
1462
1463 redef class ASendExpr
1464 private meth intern_compile_call(v: CompilerVisitor): String
1465 do
1466 var recv = v.compile_expr(n_expr)
1467 var cargs = new Array[String]
1468 cargs.add(recv)
1469 compile_arguments_in(v, cargs)
1470
1471 var e: String
1472 if prop_signature.closures.is_empty then
1473 e = prop.intern_compile_call(v, cargs)
1474 else
1475 e = prop.compile_call_and_closures(v, cargs, closure_defs)
1476 end
1477
1478 if prop.global.is_init then
1479 v.invoke_super_init_calls_after(prop)
1480 end
1481 return e
1482 end
1483
1484 redef meth compile_expr(v)
1485 do
1486 var e = intern_compile_call(v)
1487 assert e != null
1488 return e
1489 end
1490
1491 redef meth compile_stmt(v)
1492 do
1493 var e = intern_compile_call(v)
1494 if e != null then
1495 v.add_instr(e + ";")
1496 end
1497 end
1498 end
1499
1500 redef class ASendReassignExpr
1501 redef meth compile_expr(v) do abort
1502
1503 redef meth compile_stmt(v)
1504 do
1505 var recv = v.compile_expr(n_expr)
1506 var cargs = new Array[String]
1507 cargs.add(recv)
1508 compile_arguments_in(v, cargs)
1509
1510 var e2 = read_prop.compile_expr_call(v, cargs)
1511 var e3 = v.compile_expr(n_value)
1512 var e4 = assign_method.compile_expr_call(v, [e2, e3])
1513 cargs.add(e4)
1514 prop.compile_stmt_call(v, cargs)
1515 end
1516 end
1517
1518 redef class ANewExpr
1519 redef meth compile_expr(v)
1520 do
1521 var cargs = new Array[String]
1522 compile_arguments_in(v, cargs)
1523 return prop.compile_constructor_call(v, stype, cargs)
1524 end
1525
1526 redef meth compile_stmt(v) do abort
1527 end
1528
1529 redef class PClosureDef
1530 # Compile the closure definition as a function in v.out_contexts
1531 # Return the cname of the function
1532 meth compile_closure(v: CompilerVisitor, closcn: String): String is abstract
1533
1534 # Compile the closure definition inside the current C function.
1535 meth do_compile_inside(v: CompilerVisitor, params: Array[String]): String is abstract
1536 end
1537
1538 redef class AClosureDef
1539 # The cname of the function
1540 readable attr _cname: String
1541
1542 redef meth compile_closure(v, closcn)
1543 do
1544 var ctx_old = v.ctx
1545 v.ctx = new CContext
1546 v.out_contexts.add(v.ctx)
1547
1548 var cfc_old = v.cfc.closure
1549 v.cfc.closure = v.nmc
1550
1551 var old_rv = v.nmc.return_value
1552 var old_bv = v.nmc.break_value
1553 if cfc_old == null then
1554 v.nmc.return_value = "closctx->{old_rv}"
1555 v.nmc.break_value = "closctx->{old_bv}"
1556 end
1557
1558 var cname = "OC_{v.nmc.method.cname}_{v.out_contexts.length}"
1559 _cname = cname
1560 var args = new Array[String]
1561 for i in [0..closure.signature.arity[ do
1562 args.add(" param{i}")
1563 end
1564
1565 var cs = decl_csignature(v, args, closcn)
1566
1567 v.add_instr("{cs} \{")
1568 v.indent
1569 var ctx_old2 = v.ctx
1570 v.ctx = new CContext
1571
1572 v.add_decl("struct trace_t trace = \{NULL, NULL, {line_number}, LOCATE_{v.nmc.method.cname}};")
1573 v.add_instr("trace.prev = tracehead; tracehead = &trace;")
1574
1575 v.add_instr("trace.file = LOCATE_{v.module.name};")
1576 var s = do_compile_inside(v, args)
1577
1578 v.add_instr("{v.nmc.return_label}:")
1579 v.add_instr("tracehead = trace.prev;")
1580 if s == null then
1581 v.add_instr("return;")
1582 else
1583 v.add_instr("return {s};")
1584 end
1585
1586 ctx_old2.append(v.ctx)
1587 v.ctx = ctx_old2
1588 v.unindent
1589 v.add_instr("}")
1590 v.ctx = ctx_old
1591
1592 v.cfc.closure = cfc_old
1593 v.nmc.return_value = old_rv
1594 v.nmc.break_value = old_bv
1595
1596 # Build closure
1597 var closcnv = "wbclos{v.new_number}"
1598 v.add_decl("struct WBT_ {closcnv};")
1599 v.add_instr("{closcnv}.fun = (fun_t){cname};")
1600 v.add_instr("{closcnv}.has_broke = NULL;")
1601 if cfc_old != null then
1602 v.add_instr("{closcnv}.variable = closctx->variable;")
1603 v.add_instr("{closcnv}.closurevariable = closctx->closurevariable;")
1604 else
1605 v.add_instr("{closcnv}.variable = variable;")
1606 v.add_instr("{closcnv}.closurevariable = closurevariable;")
1607 end
1608
1609 return "(&{closcnv})"
1610 end
1611
1612 protected meth decl_csignature(v: CompilerVisitor, args: Array[String], closcn: String): String
1613 do
1614 var params = new Array[String]
1615 params.add("struct WBT_ *closctx")
1616 for i in [0..closure.signature.arity[ do
1617 var p = "val_t {args[i]}"
1618 params.add(p)
1619 end
1620 var ret: String
1621 if closure.signature.return_type != null then
1622 ret = "val_t"
1623 else
1624 ret = "void"
1625 end
1626 var p = params.join(", ")
1627 var s = "{ret} {cname}({p})"
1628 v.add_decl("typedef {ret} (* {cname}_t)({p});")
1629 v.add_decl(s + ";")
1630 return s
1631 end
1632
1633 redef meth do_compile_inside(v, params)
1634 do
1635 for i in [0..variables.length[ do
1636 var vacname = v.cfc.register_variable(variables[i])
1637 v.add_assignment(vacname, params[i])
1638 end
1639
1640 var old_cv = v.nmc.continue_value
1641 var old_cl = v.nmc.continue_label
1642 var old_bl = v.nmc.break_label
1643
1644 v.nmc.continue_value = v.cfc.get_var("Continue value and escape marker")
1645 v.nmc.continue_label = "continue_label{v.new_number}"
1646 v.nmc.break_label = v.nmc.return_label
1647
1648 v.compile_stmt(n_expr)
1649
1650 v.add_instr("{v.nmc.continue_label}: while(false);")
1651
1652 var ret: String = null
1653 if closure.signature.return_type != null then ret = v.nmc.continue_value
1654
1655 v.nmc.continue_value = old_cv
1656 v.nmc.continue_label = old_cl
1657 v.nmc.break_label = old_bl
1658
1659 return ret
1660 end
1661 end
1662
1663 redef class PClosureDecl
1664 meth do_compile_inside(v: CompilerVisitor, params: Array[String]): String is abstract
1665 end
1666 redef class AClosureDecl
1667 redef meth do_compile_inside(v, params)
1668 do
1669 if n_signature != null then n_signature.compile_parameters(v, variable.closure.signature, params)
1670
1671 var old_cv = v.nmc.continue_value
1672 var old_cl = v.nmc.continue_label
1673 var old_bl = v.nmc.break_label
1674
1675 v.nmc.continue_value = v.cfc.get_var("Continue value and escape marker")
1676 v.nmc.continue_label = "continue_label{v.new_number}"
1677 v.nmc.break_label = v.nmc.return_label
1678
1679 v.compile_stmt(n_expr)
1680
1681 v.add_instr("{v.nmc.continue_label}: while(false);")
1682
1683 var ret: String = null
1684 if variable.closure.signature.return_type != null then ret = v.nmc.continue_value
1685
1686 v.nmc.continue_value = old_cv
1687 v.nmc.continue_label = old_cl
1688 v.nmc.break_label = old_bl
1689
1690 return ret
1691 end
1692 end
1693
1694 redef class AClosureCallExpr
1695 redef meth intern_compile_call(v)
1696 do
1697 var cargs = new Array[String]
1698 compile_arguments_in(v, cargs)
1699 var va: String = null
1700 if variable.closure.signature.return_type != null then va = v.cfc.get_var("Closure call result value")
1701
1702 if variable.closure.is_optional then
1703 v.add_instr("if({v.cfc.varname(variable)}==NULL) \{")
1704 v.indent
1705 var n = variable.decl
1706 assert n isa AClosureDecl
1707 var s = n.do_compile_inside(v, cargs)
1708 if s != null then v.add_assignment(va, s)
1709 v.unindent
1710 v.add_instr("} else \{")
1711 v.indent
1712 end
1713
1714 var ivar = v.cfc.varname(variable)
1715 var cargs2 = [ivar]
1716 cargs2.append(cargs)
1717 var s = "(({variable.ctypename})({ivar}->fun))({cargs2.join(", ")}) /* Invoke closure {variable} */"
1718 if va != null then
1719 v.add_assignment(va, s)
1720 else
1721 v.add_instr("{s};")
1722 end
1723 v.add_instr("if ({ivar}->has_broke) \{")
1724 v.indent
1725 if n_closure_defs != null and n_closure_defs.length == 1 then do
1726 n_closure_defs.first.do_compile_inside(v, null)
1727 end
1728 if v.cfc.closure == v.nmc then v.add_instr("if ({ivar}->has_broke) \{ closctx->has_broke = {ivar}->has_broke; closctx->broke_value = {ivar}->broke_value;\}")
1729 v.add_instr("goto {v.nmc.return_label};")
1730 v.unindent
1731 v.add_instr("\}")
1732
1733 if variable.closure.is_optional then
1734 v.unindent
1735 v.add_instr("\}")
1736 end
1737 return va
1738 end
1739 end
1740
1741 redef class AProxyExpr
1742 redef meth compile_expr(v)
1743 do
1744 return v.compile_expr(n_expr)
1745 end
1746 end
1747
1748 redef class AOnceExpr
1749 redef meth compile_expr(v)
1750 do
1751 var i = v.new_number
1752 var cvar = v.cfc.get_var("Once expression result")
1753 v.add_decl("static val_t once_value_{i}; static int once_bool_{i}; /* Once value for {cvar}*/")
1754 v.add_instr("if (once_bool_{i}) {cvar} = once_value_{i};")
1755 v.add_instr("else \{")
1756 v.indent
1757 v.cfc.free_var(cvar)
1758 var e = v.compile_expr(n_expr)
1759 v.add_assignment(cvar, e)
1760 v.add_instr("once_value_{i} = {cvar};")
1761 v.add_instr("once_bool_{i} = true;")
1762 v.unindent
1763 v.add_instr("}")
1764 return cvar
1765 end
1766 end
Nit language project; an oo programing language and its tool suite.