src/compiling/compiling_methods.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2008 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Compile method bodies, statments and expressions to C.
  18 package compiling_methods
  19
  20 import compiling_base
  21 private import syntax
  22
  23 redef class CompilerVisitor
  24         # Compile a statment node
  25         meth compile_stmt(n: PExpr)
  26         do
  27                 n.prepare_compile_stmt(self)
  28                 var i = cfc._variable_index
  29                 n.compile_stmt(self)
  30                 cfc._variable_index = i
  31         end
  32
  33         # Compile is expression node
  34         meth compile_expr(n: PExpr): String
  35         do
  36                 var i = cfc._variable_index
  37                 var s = n.compile_expr(self)
  38                 cfc._variable_index = i
  39                 if s[0] == ' ' then
  40                         return s
  41                 end
  42                 var v = cfc.get_var
  43                 add_assignment(v, s)
  44                 return v
  45         end
  46
  47         # Ensure that a c expression is a var
  48         meth ensure_var(s: String): String
  49         do
  50                 if s.substring(0,3) == "variable" then
  51                         return s
  52                 end
  53                 var v = cfc.get_var
  54                 add_assignment(v, s)
  55                 return v
  56         end
  57
  58         # Add a assignment between a variable and an expression
  59         meth add_assignment(v: String, s: String)
  60         do
  61                 if v != s then
  62                         add_instr("{v} = {s};")
  63                 end
  64         end
  65
  66         readable writable attr _cfc: CFunctionContext
  67
  68         readable writable attr _nmc: NitMethodContext
  69
  70         # C outputs written outside the current C function.
  71         readable writable attr _out_contexts: Array[CContext] = new Array[CContext]
  72
  73         # Generate an fprintf to display an error location
  74         meth printf_locate_error(node: PNode): String
  75         do
  76                 var s = new Buffer.from("fprintf(stderr, \"")
  77                 if nmc != null then s.append(" in %s")
  78                 s.append(" (%s:%d)\\n\", ")
  79                 if nmc != null then s.append("LOCATE_{nmc.method.cname}, ")
  80                 s.append("LOCATE_{module.name}, {node.line_number});")
  81                 return s.to_s
  82         end
  83
  84         redef init(module: MMSrcModule)
  85         do
  86                 super
  87         end
  88
  89         meth invoke_super_init_calls_after(start_prop: MMMethod)
  90         do
  91                 var n = nmc.method.node
  92                 assert n isa AConcreteInitPropdef
  93
  94                 if n.super_init_calls.is_empty then return
  95                 var i = 0
  96                 var j = 0
  97                 #var s = ""
  98                 if start_prop != null then
  99                         while n.super_init_calls[i] != start_prop do
 100                                 #s.append(" {n.super_init_calls[i]}")
 101                                 i += 1
 102                         end
 103                         i += 1
 104                         #s.append(" {start_prop}")
 105
 106                         while n.explicit_super_init_calls[j] != start_prop do
 107                                 j += 1
 108                         end
 109                         j += 1
 110                 end
 111                 var stop_prop: MMMethod = null
 112                 if j < n.explicit_super_init_calls.length then
 113                         stop_prop = n.explicit_super_init_calls[j]
 114                 end
 115                 var l = n.super_init_calls.length
 116                 #s.append(" [")
 117                 while i < l do
 118                         var p = n.super_init_calls[i]
 119                         if p == stop_prop then break
 120                         var cargs = new Array[String]
 121                         if p.signature.arity == 0 then
 122                                 cargs.add(cfc.varname(nmc.method_params[0]))
 123                         else
 124                                 for va in nmc.method_params do
 125                                         cargs.add(cfc.varname(va))
 126                                 end
 127                         end
 128                         #s.append(" {p}")
 129                         p.compile_call(self, cargs)
 130                         i += 1
 131                 end
 132                 #s.append(" ]")
 133                 #while i < l do
 134                 #       s.append(" {n.super_init_calls[i]}")
 135                 #       i += 1
 136                 #end
 137                 #if stop_prop != null then s.append(" (stop at {stop_prop})")
 138                 #n.printl("implicit calls in {n.method}: {s}")
 139         end
 140 end
 141
 142 # A C function currently written
 143 class CFunctionContext
 144         readable attr _visitor: CompilerVisitor
 145
 146         # Next available variable number
 147         attr _variable_index: Int = 0
 148
 149         # Total number of variable
 150         attr _variable_index_max: Int = 0
 151
 152         # Association between nit variable and the corrsponding c variable
 153         attr _varnames: Map[Variable, String] = new HashMap[Variable, String]
 154
 155         # Are we currenlty in a closure definition?
 156         readable writable attr _in_closure: Bool = false
 157
 158         meth varname(v: Variable): String
 159         do
 160                 if _in_closure then
 161                         return "closctx->{_varnames[v]}"
 162                 else
 163                         return _varnames[v]
 164                 end
 165         end
 166
 167         # Return the next available variable
 168         meth get_var: String
 169         do
 170                 var v = variable(_variable_index)
 171                 _variable_index = _variable_index + 1
 172                 if _variable_index > _variable_index_max then
 173                         #visitor.add_decl("val_t {v};")
 174                         _variable_index_max = _variable_index
 175                 end
 176                 return v
 177         end
 178
 179         meth register_variable(v: Variable): String
 180         do
 181                 var s = get_var
 182                 _varnames[v] = "variable[{_variable_index-1}]"
 183                 return s
 184         end
 185
 186         # Next available closure variable number
 187         attr _closurevariable_index: Int = 0
 188
 189         meth register_closurevariable(v: ClosureVariable): String
 190         do
 191                 var s = "closurevariable[{_closurevariable_index}]"
 192                 _closurevariable_index += 1
 193                 _varnames[v] = s
 194                 if _in_closure then
 195                         return "(closctx->{s})"
 196                 else
 197                         return s
 198                 end
 199         end
 200
 201         # Return the ith variable
 202         protected meth variable(i: Int): String
 203         do
 204                 if _in_closure then
 205                         return "(closctx->variable[{i}])"
 206                 else
 207                         return "variable[{i}]"
 208                 end
 209         end
 210
 211         # Mark the variable available
 212         meth free_var(v: String)
 213         do
 214                 # FIXME: So ugly..
 215                 if v == variable(_variable_index-1) then
 216                         _variable_index = _variable_index - 1
 217                 end
 218         end
 219
 220         # Generate the local variable declarations
 221         # To use at the end of the C function once all variables are known
 222         meth generate_var_decls
 223         do
 224                 if _variable_index_max > 0 then
 225                         visitor.add_decl("val_t variable[{_variable_index_max}];")
 226                 else
 227                         visitor.add_decl("val_t *variable = NULL;")
 228                 end
 229                 if _closurevariable_index > 0 then
 230                         visitor.add_decl("void *closurevariable[{_closurevariable_index}];")
 231                 else
 232                         visitor.add_decl("void **closurevariable = NULL;")
 233                 end
 234         end
 235
 236         init(v: CompilerVisitor) do _visitor = v
 237 end
 238
 239 # A Nit method currenlty compiled
 240 class NitMethodContext
 241         # Current method compiled
 242         readable attr _method: MMSrcMethod
 243
 244         # Association between parameters and the corresponding variables
 245         readable writable attr _method_params: Array[ParamVariable]
 246
 247         # Where a nit return must branch
 248         readable writable attr _return_label: String
 249
 250         # Where a nit break must branch
 251         readable writable attr _break_label: String
 252
 253         # Where a nit continue must branch
 254         readable writable attr _continue_label: String
 255
 256         # Variable where a functionnal nit return must store its value
 257         readable writable attr _return_value: String
 258
 259         # Variable where a functionnal nit break must store its value
 260         readable writable attr _break_value: String
 261
 262         # Variable where a functionnal nit continue must store its value
 263         readable writable attr _continue_value: String
 264
 265         init(method: MMSrcMethod)
 266         do
 267                 _method = method
 268         end
 269 end
 270
 271 ###############################################################################
 272
 273 redef class ClosureVariable
 274         readable writable attr _ctypename: String
 275 end
 276
 277 redef class MMMethod
 278         # Compile a call on self for given arguments
 279         # Most calls are compiled with a table access,
 280         # primitive calles are inlined
 281         # == and != are guarded and possibly inlined
 282         meth compile_call(v: CompilerVisitor, cargs: Array[String]): String
 283         do
 284                 var i = self
 285                 if i isa MMSrcMethod then
 286                         if i isa MMMethSrcMethod and i.node isa AInternMethPropdef or
 287                                 (i.local_class.name == (once "Array".to_symbol) and name == (once "[]".to_symbol))
 288                         then
 289                                 var e = i.do_compile_inside(v, cargs)
 290                                 return e
 291                         end
 292                 end
 293                 var ee = once "==".to_symbol
 294                 var ne = once "!=".to_symbol
 295                 if name == ne then
 296                         var eqp = signature.recv.local_class.select_method(ee)
 297                         var eqcall = eqp.compile_call(v, cargs)
 298                         return "TAG_Bool(!UNTAG_Bool({eqcall}))"
 299                 end
 300                 if global.is_init then
 301                         cargs = cargs.to_a
 302                         cargs.add("init_table /*YYY*/")
 303                 end
 304
 305                 var m = "{global.meth_call}({cargs[0]})"
 306                 var vcall = "{m}({cargs.join(", ")}) /*{local_class}::{name}*/"
 307                 if name == ee then
 308                         vcall = "UNTAG_Bool({vcall})"
 309                         var obj = once "Object".to_symbol
 310                         if i.local_class.name == obj then
 311                                 vcall = "(({m}=={i.cname})?(IS_EQUAL_NN({cargs[0]},{cargs[1]})):({vcall}))"
 312                         end
 313                         vcall = "TAG_Bool(({cargs.first} == {cargs[1]}) || (({cargs.first} != NIT_NULL) && {vcall}))"
 314                 end
 315                 if signature.return_type != null then
 316                         return vcall
 317                 else
 318                         v.add_instr(vcall + ";")
 319                         return null
 320                 end
 321         end
 322
 323         # Compile a call as constructor with given args
 324         meth compile_constructor_call(v: CompilerVisitor, recvtype: MMType, cargs: Array[String]): String
 325         do
 326                 var recv = v.cfc.get_var
 327                 v.add_instr("{recv} = NEW_{recvtype.local_class}_{global.intro.cname}({cargs.join(", ")}); /*new {recvtype}*/")
 328                 return recv
 329         end
 330
 331         # Compile a call as call-next-method on self with given args
 332         meth compile_super_call(v: CompilerVisitor, cargs: Array[String]): String
 333         do
 334                 var m = "{super_meth_call}({cargs[0]})"
 335                 var vcall = "{m}({cargs.join(", ")}) /*super {local_class}::{name}*/"
 336                 return vcall
 337         end
 338
 339         # Cname of the i-th closure C struct type
 340         protected meth closure_cname(i: Int): String
 341         do
 342                 return "WBT_{cname}_{i}"
 343         end
 344 end
 345
 346 redef class MMAttribute
 347         # Compile an acces on selffor a given reciever.
 348         # Result is a valid C left-value for assigment
 349         meth compile_access(v: CompilerVisitor, recv: String): String
 350         do
 351                 return "{global.attr_access}({recv}) /*{local_class}::{name}*/"
 352         end
 353 end
 354
 355 redef class MMLocalProperty
 356         # Compile the property as a C property
 357         meth compile_property_to_c(v: CompilerVisitor) do end
 358 end
 359
 360 redef class MMSrcMethod
 361
 362         # Compile and declare the signature to C
 363         protected meth decl_csignature(v: CompilerVisitor, args: Array[String]): String
 364         do
 365                 var params = new Array[String]
 366                 params.add("val_t {args[0]}")
 367                 for i in [0..signature.arity[ do
 368                         var p = "val_t {args[i+1]}"
 369                         params.add(p)
 370                 end
 371
 372                 var first_closure_index = signature.arity + 1 # Wich parameter is the first closure
 373                 for i in [0..signature.closures.length[ do
 374                         var closcn = closure_cname(i)
 375                         var cs = signature.closures[i].signature # Closure signature
 376                         var subparams = new Array[String] # Parameters of the closure
 377                         subparams.add("struct {closcn}*")
 378                         for j in [0..cs.arity[ do
 379                                 var p = "val_t"
 380                                 subparams.add(p)
 381                         end
 382                         var r = "void"
 383                         if cs.return_type != null then r = "val_t"
 384                         params.add("struct {closcn} *{args[first_closure_index+i]}")
 385                         v.add_decl("struct {closcn};")
 386                         v.add_decl("typedef {r} (*F{closcn})({subparams.join(", ")});")
 387                         v.add_decl("struct {closcn} \{F{closcn} fun; val_t *has_broke; val_t broke_value; val_t *variable; void **closurevariable;\};")
 388                 end
 389
 390                 if global.is_init then
 391                         params.add("int* init_table")
 392                 end
 393
 394                 var ret: String
 395                 if signature.return_type != null then
 396                         ret = "val_t"
 397                 else
 398                         ret = "void"
 399                 end
 400
 401                 var p = params.join(", ")
 402                 var s = "{ret} {cname}({p})"
 403                 v.add_decl("typedef {ret} (* {cname}_t)({p});")
 404                 v.add_decl(s + ";")
 405                 return s
 406         end
 407
 408         redef meth compile_property_to_c(v)
 409         do
 410                 v.cfc = new CFunctionContext(v)
 411
 412                 var args = new Array[String]
 413                 args.add(" self")
 414                 for i in [0..signature.arity[ do
 415                         args.add(" param{i}")
 416                 end
 417                 for i in [0..signature.closures.length[ do
 418                         args.add(" wd{i}")
 419                 end
 420                 var cs = decl_csignature(v, args)
 421                 v.add_decl("#define LOCATE_{cname} \"{full_name}\"")
 422
 423                 v.add_instr("{cs} \{")
 424                 v.indent
 425                 var ctx_old = v.ctx
 426                 v.ctx = new CContext
 427
 428                 v.out_contexts.clear
 429
 430                 var ln = 0
 431                 var s = self
 432                 if s.node != null then ln = s.node.line_number
 433                 v.add_decl("struct trace_t trace = \{NULL, NULL, {ln}, LOCATE_{cname}};")
 434                 v.add_instr("trace.prev = tracehead; tracehead = &trace;")
 435                 v.add_instr("trace.file = LOCATE_{module.name};")
 436                 var s = do_compile_inside(v, args)
 437                 v.add_instr("tracehead = trace.prev;")
 438                 if s == null then
 439                         v.add_instr("return;")
 440                 else
 441                         v.add_instr("return {s};")
 442                 end
 443
 444                 v.cfc.generate_var_decls
 445
 446                 ctx_old.append(v.ctx)
 447                 v.ctx = ctx_old
 448                 v.unindent
 449                 v.add_instr("}")
 450
 451                 for ctx in v.out_contexts do v.ctx.merge(ctx)
 452         end
 453
 454         # Compile the method body inline
 455         meth do_compile_inside(v: CompilerVisitor, params: Array[String]): String is abstract
 456 end
 457
 458 redef class MMReadImplementationMethod
 459         redef meth do_compile_inside(v, params)
 460         do
 461                 return node.prop.compile_access(v, params[0])
 462         end
 463 end
 464
 465 redef class MMWriteImplementationMethod
 466         redef meth do_compile_inside(v, params)
 467         do
 468                 v.add_assignment(node.prop.compile_access(v, params[0]), params[1])
 469                 return null
 470         end
 471 end
 472
 473 redef class MMMethSrcMethod
 474         redef meth do_compile_inside(v, params)
 475         do
 476                 return node.do_compile_inside(v, self, params)
 477         end
 478 end
 479
 480 redef class MMImplicitInit
 481         redef meth do_compile_inside(v, params)
 482         do
 483                 var f = params.length - unassigned_attributes.length
 484                 var recv = params.first
 485                 for sp in super_inits do
 486                         assert sp isa MMMethod
 487                         var args_recv = [recv]
 488                         if sp == super_init then
 489                                 var args = new Array[String].with_capacity(f)
 490                                 args.add(recv)
 491                                 for i in [1..f[ do
 492                                         args.add(params[i])
 493                                 end
 494                                 sp.compile_call(v, args)
 495                         else
 496                                 sp.compile_call(v, args_recv)
 497                         end
 498                 end
 499                 for i in [f..params.length[ do
 500                         var attribute = unassigned_attributes[i-f]
 501                         v.add_assignment(attribute.compile_access(v, recv), params[i])
 502                 end
 503                 return null
 504         end
 505 end
 506
 507 redef class MMType
 508         # Compile a subtype check to self
 509         # Return a NIT Bool
 510         meth compile_cast(v: CompilerVisitor, recv: String): String
 511         do
 512                 # Fixme: handle formaltypes
 513                 var g = local_class.global
 514                 return "TAG_Bool(({recv}==NIT_NULL) || VAL_ISA({recv}, {g.color_id}, {g.id_id})) /*cast {self}*/"
 515         end
 516
 517         # Compile a cast assertion
 518         meth compile_type_check(v: CompilerVisitor, recv: String, n: PNode)
 519         do
 520                 # Fixme: handle formaltypes
 521                 var g = local_class.global
 522                 v.add_instr("if (({recv}!=NIT_NULL) && !VAL_ISA({recv}, {g.color_id}, {g.id_id})) \{ fprintf(stderr, \"Cast failled\"); {v.printf_locate_error(n)} nit_exit(1); } /*cast {self}*/;")
 523         end
 524 end
 525
 526 ###############################################################################
 527
 528 redef class AMethPropdef
 529         # Compile the method body
 530         meth do_compile_inside(v: CompilerVisitor, method: MMSrcMethod, params: Array[String]): String is abstract
 531 end
 532
 533 redef class PSignature
 534         meth compile_parameters(v: CompilerVisitor, orig_sig: MMSignature, params: Array[String]) is abstract
 535 end
 536
 537 redef class ASignature
 538         redef meth compile_parameters(v: CompilerVisitor, orig_sig: MMSignature, params: Array[String])
 539         do
 540                 for ap in n_params do
 541                         var cname = v.cfc.register_variable(ap.variable)
 542                         v.nmc.method_params.add(ap.variable)
 543                         var orig_type = orig_sig[ap.position]
 544                         if not orig_type < ap.variable.stype then
 545                                 # FIXME: do not test always
 546                                 # FIXME: handle formal types
 547                                 v.add_instr("/* check if p<{ap.variable.stype} with p:{orig_type} */")
 548                                 ap.variable.stype.compile_type_check(v, params[ap.position], ap)
 549                         end
 550                         v.add_assignment(cname, params[ap.position])
 551                 end
 552                 for i in [0..n_closure_decls.length[ do
 553                         var wd = n_closure_decls[i]
 554                         var cname = v.cfc.register_closurevariable(wd.variable)
 555                         wd.variable.ctypename = "struct {v.nmc.method.closure_cname(i)} *"
 556                         v.add_assignment(cname, "{params[orig_sig.arity + i]}")
 557                 end
 558         end
 559 end
 560
 561 redef class AConcreteMethPropdef
 562         redef meth do_compile_inside(v, method, params)
 563         do
 564                 var old_nmc = v.nmc
 565                 v.nmc = new NitMethodContext(method)
 566
 567                 var selfcname = v.cfc.register_variable(self_var)
 568                 v.add_assignment(selfcname, params[0])
 569                 params.shift
 570                 v.nmc.method_params = [self_var]
 571
 572                 if n_signature != null then
 573                         var orig_meth: MMLocalProperty = method.global.intro
 574                         var orig_sig = orig_meth.signature_for(method.signature.recv)
 575                         n_signature.compile_parameters(v, orig_sig, params)
 576                 end
 577
 578                 var itpos: String = null
 579                 if self isa AConcreteInitPropdef then
 580                         itpos = "VAL2OBJ({selfcname})->vft[{method.local_class.global.init_table_pos_id}].i"
 581                         # v.add_instr("printf(\"{method.full_name}: inittable[%d] = %d\\n\", {itpos}, init_table[{itpos}]);")
 582                         v.add_instr("if (init_table[{itpos}]) return;")
 583                 end
 584
 585                 v.nmc.return_label = "return_label{v.new_number}"
 586                 v.nmc.return_value = v.cfc.get_var
 587                 if self isa AConcreteInitPropdef then
 588                         v.invoke_super_init_calls_after(null)
 589                 end
 590                 if n_block != null then
 591                         v.compile_stmt(n_block)
 592                 end
 593                 v.add_instr("{v.nmc.return_label}: while(false);")
 594                 if self isa AConcreteInitPropdef then
 595                         v.add_instr("init_table[{itpos}] = 1;")
 596                 end
 597
 598                 var ret: String = null
 599                 if method.signature.return_type != null then
 600                         ret = v.nmc.return_value
 601                 end
 602
 603                 v.nmc = old_nmc
 604                 return ret
 605         end
 606 end
 607
 608 redef class ADeferredMethPropdef
 609         redef meth do_compile_inside(v, method, params)
 610         do
 611                 v.add_instr("fprintf(stderr, \"Deferred method called\");")
 612                 v.add_instr(v.printf_locate_error(self))
 613                 v.add_instr("nit_exit(1);")
 614                 if method.signature.return_type != null then
 615                         return("NIT_NULL")
 616                 else
 617                         return null
 618                 end
 619         end
 620 end
 621
 622 redef class AExternMethPropdef
 623         redef meth do_compile_inside(v, method, params)
 624         do
 625                 var ename = "{method.module.name}_{method.local_class.name}_{method.local_class.name}_{method.name}_{method.signature.arity}"
 626                 if n_extern != null then
 627                         ename = n_extern.text
 628                         ename = ename.substring(1, ename.length-2)
 629                 end
 630                 var sig = method.signature
 631                 if params.length != sig.arity + 1 then
 632                         printl("par:{params.length} sig:{sig.arity}")
 633                 end
 634                 var args = new Array[String]
 635                 args.add(sig.recv.unboxtype(params[0]))
 636                 for i in [0..sig.arity[ do
 637                         args.add(sig[i].unboxtype(params[i+1]))
 638                 end
 639                 var s = "{ename}({args.join(", ")})"
 640                 if sig.return_type != null then
 641                         return sig.return_type.boxtype(s)
 642                 else
 643                         v.add_instr("{s};")
 644                         return null
 645                 end
 646         end
 647 end
 648
 649 redef class AInternMethPropdef
 650         redef meth do_compile_inside(v, method, p)
 651         do
 652                 var c = method.local_class.name
 653                 var n = method.name
 654                 var s: String = null
 655                 if c == once "Int".to_symbol then
 656                         if n == once "object_id".to_symbol then
 657                                 s = "{p[0]}"
 658                         else if n == once "unary -".to_symbol then
 659                                 s = "TAG_Int(-UNTAG_Int({p[0]}))"
 660                         else if n == once "output".to_symbol then
 661                                 v.add_instr("printf(\"%ld\\n\", UNTAG_Int({p[0]}));")
 662                         else if n == once "ascii".to_symbol then
 663                                 s = "TAG_Char(UNTAG_Int({p[0]}))"
 664                         else if n == once "succ".to_symbol then
 665                                 s = "TAG_Int(UNTAG_Int({p[0]})+1)"
 666                         else if n == once "prec".to_symbol then
 667                                 s = "TAG_Int(UNTAG_Int({p[0]})-1)"
 668                         else if n == once "to_f".to_symbol then
 669                                 s = "BOX_Float((float)UNTAG_Int({p[0]}))"
 670                         else if n == once "+".to_symbol then
 671                                 s = "TAG_Int(UNTAG_Int({p[0]})+UNTAG_Int({p[1]}))"
 672                         else if n == once "-".to_symbol then
 673                                 s = "TAG_Int(UNTAG_Int({p[0]})-UNTAG_Int({p[1]}))"
 674                         else if n == once "*".to_symbol then
 675                                 s = "TAG_Int(UNTAG_Int({p[0]})*UNTAG_Int({p[1]}))"
 676                         else if n == once "/".to_symbol then
 677                                 s = "TAG_Int(UNTAG_Int({p[0]})/UNTAG_Int({p[1]}))"
 678                         else if n == once "%".to_symbol then
 679                                 s = "TAG_Int(UNTAG_Int({p[0]})%UNTAG_Int({p[1]}))"
 680                         else if n == once "<".to_symbol then
 681                                 s = "TAG_Bool(UNTAG_Int({p[0]})<UNTAG_Int({p[1]}))"
 682                         else if n == once ">".to_symbol then
 683                                 s = "TAG_Bool(UNTAG_Int({p[0]})>UNTAG_Int({p[1]}))"
 684                         else if n == once "<=".to_symbol then
 685                                 s = "TAG_Bool(UNTAG_Int({p[0]})<=UNTAG_Int({p[1]}))"
 686                         else if n == once ">=".to_symbol then
 687                                 s = "TAG_Bool(UNTAG_Int({p[0]})>=UNTAG_Int({p[1]}))"
 688                         else if n == once "lshift".to_symbol then
 689                                 s = "TAG_Int(UNTAG_Int({p[0]})<<UNTAG_Int({p[1]}))"
 690                         else if n == once "rshift".to_symbol then
 691                                 s = "TAG_Int(UNTAG_Int({p[0]})>>UNTAG_Int({p[1]}))"
 692                         else if n == once "==".to_symbol then
 693                                 s = "TAG_Bool(({p[0]})==({p[1]}))"
 694                         else if n == once "!=".to_symbol then
 695                                 s = "TAG_Bool(({p[0]})!=({p[1]}))"
 696                         end
 697                 else if c == once "Float".to_symbol then
 698                         if n == once "object_id".to_symbol then
 699                                 s = "TAG_Int((bigint)UNBOX_Float({p[0]}))"
 700                         else if n == once "unary -".to_symbol then
 701                                 s = "BOX_Float(-UNBOX_Float({p[0]}))"
 702                         else if n == once "output".to_symbol then
 703                                 v.add_instr("printf(\"%f\\n\", UNBOX_Float({p[0]}));")
 704                         else if n == once "to_i".to_symbol then
 705                                 s = "TAG_Int((bigint)UNBOX_Float({p[0]}))"
 706                         else if n == once "+".to_symbol then
 707                                 s = "BOX_Float(UNBOX_Float({p[0]})+UNBOX_Float({p[1]}))"
 708                         else if n == once "-".to_symbol then
 709                                 s = "BOX_Float(UNBOX_Float({p[0]})-UNBOX_Float({p[1]}))"
 710                         else if n == once "*".to_symbol then
 711                                 s = "BOX_Float(UNBOX_Float({p[0]})*UNBOX_Float({p[1]}))"
 712                         else if n == once "/".to_symbol then
 713                                 s = "BOX_Float(UNBOX_Float({p[0]})/UNBOX_Float({p[1]}))"
 714                         else if n == once "<".to_symbol then
 715                                 s = "TAG_Bool(UNBOX_Float({p[0]})<UNBOX_Float({p[1]}))"
 716                         else if n == once ">".to_symbol then
 717                                 s = "TAG_Bool(UNBOX_Float({p[0]})>UNBOX_Float({p[1]}))"
 718                         else if n == once "<=".to_symbol then
 719                                 s = "TAG_Bool(UNBOX_Float({p[0]})<=UNBOX_Float({p[1]}))"
 720                         else if n == once ">=".to_symbol then
 721                                 s = "TAG_Bool(UNBOX_Float({p[0]})>=UNBOX_Float({p[1]}))"
 722                         end
 723                 else if c == once "Char".to_symbol then
 724                         if n == once "object_id".to_symbol then
 725                                 s = "TAG_Int(UNTAG_Char({p[0]}))"
 726                         else if n == once "unary -".to_symbol then
 727                                 s = "TAG_Char(-UNTAG_Char({p[0]}))"
 728                         else if n == once "output".to_symbol then
 729                                 v.add_instr("printf(\"%c\", (unsigned char)UNTAG_Char({p[0]}));")
 730                         else if n == once "ascii".to_symbol then
 731                                 s = "TAG_Int((unsigned char)UNTAG_Char({p[0]}))"
 732                         else if n == once "succ".to_symbol then
 733                                 s = "TAG_Char(UNTAG_Char({p[0]})+1)"
 734                         else if n == once "prec".to_symbol then
 735                                 s = "TAG_Char(UNTAG_Char({p[0]})-1)"
 736                         else if n == once "to_i".to_symbol then
 737                                 s = "TAG_Int(UNTAG_Char({p[0]})-'0')"
 738                         else if n == once "+".to_symbol then
 739                                 s = "TAG_Char(UNTAG_Char({p[0]})+UNTAG_Char({p[1]}))"
 740                         else if n == once "-".to_symbol then
 741                                 s = "TAG_Char(UNTAG_Char({p[0]})-UNTAG_Char({p[1]}))"
 742                         else if n == once "*".to_symbol then
 743                                 s = "TAG_Char(UNTAG_Char({p[0]})*UNTAG_Char({p[1]}))"
 744                         else if n == once "/".to_symbol then
 745                                 s = "TAG_Char(UNTAG_Char({p[0]})/UNTAG_Char({p[1]}))"
 746                         else if n == once "%".to_symbol then
 747                                 s = "TAG_Char(UNTAG_Char({p[0]})%UNTAG_Char({p[1]}))"
 748                         else if n == once "<".to_symbol then
 749                                 s = "TAG_Bool(UNTAG_Char({p[0]})<UNTAG_Char({p[1]}))"
 750                         else if n == once ">".to_symbol then
 751                                 s = "TAG_Bool(UNTAG_Char({p[0]})>UNTAG_Char({p[1]}))"
 752                         else if n == once "<=".to_symbol then
 753                                 s = "TAG_Bool(UNTAG_Char({p[0]})<=UNTAG_Char({p[1]}))"
 754                         else if n == once ">=".to_symbol then
 755                                 s = "TAG_Bool(UNTAG_Char({p[0]})>=UNTAG_Char({p[1]}))"
 756                         else if n == once "==".to_symbol then
 757                                 s = "TAG_Bool(({p[0]})==({p[1]}))"
 758                         else if n == once "!=".to_symbol then
 759                                 s = "TAG_Bool(({p[0]})!=({p[1]}))"
 760                         end
 761                 else if c == once "Bool".to_symbol then
 762                         if n == once "object_id".to_symbol then
 763                                 s = "TAG_Int(UNTAG_Bool({p[0]}))"
 764                         else if n == once "unary -".to_symbol then
 765                                 s = "TAG_Bool(-UNTAG_Bool({p[0]}))"
 766                         else if n == once "output".to_symbol then
 767                                 v.add_instr("(void)printf(UNTAG_Bool({p[0]})?\"true\\n\":\"false\\n\");")
 768                         else if n == once "ascii".to_symbol then
 769                                 s = "TAG_Bool(UNTAG_Bool({p[0]}))"
 770                         else if n == once "to_i".to_symbol then
 771                                 s = "TAG_Int(UNTAG_Bool({p[0]}))"
 772                         else if n == once "==".to_symbol then
 773                                 s = "TAG_Bool(({p[0]})==({p[1]}))"
 774                         else if n == once "!=".to_symbol then
 775                                 s = "TAG_Bool(({p[0]})!=({p[1]}))"
 776                         end
 777                 else if c == once "NativeArray".to_symbol then
 778                         if n == once "object_id".to_symbol then
 779                                 s = "TAG_Int(UNBOX_NativeArray({p[0]}))"
 780                         else if n == once "[]".to_symbol then
 781                                 s = "UNBOX_NativeArray({p[0]})[UNTAG_Int({p[1]})]"
 782                         else if n == once "[]=".to_symbol then
 783                                 v.add_instr("UNBOX_NativeArray({p[0]})[UNTAG_Int({p[1]})]={p[2]};")
 784                         else if n == once "copy_to".to_symbol then
 785                                 v.add_instr("(void)memcpy(UNBOX_NativeArray({p[1]}), UNBOX_NativeArray({p[0]}), UNTAG_Int({p[2]})*sizeof(val_t));")
 786                         end
 787                 else if c == once "NativeString".to_symbol then
 788                         if n == once "object_id".to_symbol then
 789                                 s = "TAG_Int(UNBOX_NativeString({p[0]}))"
 790                         else if n == once "atoi".to_symbol then
 791                                 s = "TAG_Int(atoi(UNBOX_NativeString({p[0]})))"
 792                         else if n == once "[]".to_symbol then
 793                                 s = "TAG_Char(UNBOX_NativeString({p[0]})[UNTAG_Int({p[1]})])"
 794                         else if n == once "[]=".to_symbol then
 795                                 v.add_instr("UNBOX_NativeString({p[0]})[UNTAG_Int({p[1]})]=UNTAG_Char({p[2]});")
 796                         else if n == once "copy_to".to_symbol then
 797                                 v.add_instr("(void)memcpy(UNBOX_NativeString({p[1]})+UNTAG_Int({p[4]}), UNBOX_NativeString({p[0]})+UNTAG_Int({p[3]}), UNTAG_Int({p[2]}));")
 798                         end
 799                 else if n == once "object_id".to_symbol then
 800                         s = "TAG_Int((bigint){p[0]})"
 801                 else if n == once "sys".to_symbol then
 802                         s = "(G_sys)"
 803                 else if n == once "is_same_type".to_symbol then
 804                         s = "TAG_Bool((VAL2VFT({p[0]})==VAL2VFT({p[1]})))"
 805                 else if n == once "exit".to_symbol then
 806                         v.add_instr("exit(UNTAG_Int({p[1]}));")
 807                 else if n == once "calloc_array".to_symbol then
 808                         s = "BOX_NativeArray((val_t*)malloc((UNTAG_Int({p[1]}) * sizeof(val_t))))"
 809                 else if n == once "calloc_string".to_symbol then
 810                         s = "BOX_NativeString((char*)malloc((UNTAG_Int({p[1]}) * sizeof(char))))"
 811
 812                 else
 813                         v.add_instr("fprintf(stderr, \"Intern {n}\\n\"); nit_exit(1);")
 814                 end
 815                 if method.signature.return_type != null and s == null then
 816                         s = "NIT_NULL /*stub*/"
 817                 end
 818                 return s
 819         end
 820 end
 821
 822 ###############################################################################
 823
 824 redef class PExpr
 825         # Compile the node as an expression
 826         # Only the visitor should call it
 827         meth compile_expr(v: CompilerVisitor): String is abstract
 828
 829         # Prepare a call of node as a statement
 830         # Only the visitor should call it
 831         # It's used for local variable managment
 832         meth prepare_compile_stmt(v: CompilerVisitor) do end
 833
 834         # Compile the node as a statement
 835         # Only the visitor should call it
 836         meth compile_stmt(v: CompilerVisitor) do printl("Error!")
 837 end
 838
 839 redef class ABlockExpr
 840         redef meth compile_stmt(v)
 841         do
 842                 for n in n_expr do
 843                         v.compile_stmt(n)
 844                 end
 845         end
 846 end
 847
 848 redef class AVardeclExpr
 849         redef meth prepare_compile_stmt(v)
 850         do
 851                 v.cfc.register_variable(variable)
 852         end
 853
 854         redef meth compile_stmt(v)
 855         do
 856                 var cname = v.cfc.varname(variable)
 857                 if n_expr == null then
 858                         v.add_instr("/*{cname} is variable {variable.name}*/")
 859                 else
 860                         var e = v.compile_expr(n_expr)
 861                         v.add_assignment(cname, e)
 862                 end
 863         end
 864 end
 865
 866 redef class AReturnExpr
 867         redef meth compile_stmt(v)
 868         do
 869                 if n_expr != null then
 870                         var e = v.compile_expr(n_expr)
 871                         v.add_assignment(v.nmc.return_value, e)
 872                 end
 873                 if v.cfc.in_closure then v.add_instr("closctx->has_broke = &({v.nmc.return_value});")
 874                 v.add_instr("goto {v.nmc.return_label};")
 875         end
 876 end
 877
 878 redef class ABreakExpr
 879         redef meth compile_stmt(v)
 880         do
 881                 if n_expr != null then
 882                         var e = v.compile_expr(n_expr)
 883                         v.add_assignment(v.nmc.break_value, e)
 884                 end
 885                 if v.cfc.in_closure then v.add_instr("closctx->has_broke = &({v.nmc.break_value}); closctx->broke_value = *closctx->has_broke;")
 886                 v.add_instr("goto {v.nmc.break_label};")
 887         end
 888 end
 889
 890 redef class AContinueExpr
 891         redef meth compile_stmt(v)
 892         do
 893                 if n_expr != null then
 894                         var e = v.compile_expr(n_expr)
 895                         v.add_assignment(v.nmc.continue_value, e)
 896                 end
 897                 v.add_instr("goto {v.nmc.continue_label};")
 898         end
 899 end
 900
 901 redef class AAbortExpr
 902         redef meth compile_stmt(v)
 903         do
 904                 v.add_instr("fprintf(stderr, \"Aborted\"); {v.printf_locate_error(self)} nit_exit(1);")
 905         end
 906 end
 907
 908 redef class ADoExpr
 909         redef meth compile_stmt(v)
 910         do
 911                  if n_block != null then
 912                          v.compile_stmt(n_block)
 913                  end
 914         end
 915 end
 916
 917 redef class AIfExpr
 918         redef meth compile_stmt(v)
 919         do
 920                 var e = v.compile_expr(n_expr)
 921                 v.add_instr("if (UNTAG_Bool({e})) \{ /*if*/")
 922                 v.cfc.free_var(e)
 923                 if n_then != null then
 924                         v.indent
 925                         v.compile_stmt(n_then)
 926                         v.unindent
 927                 end
 928                 if n_else != null then
 929                         v.add_instr("} else \{ /*if*/")
 930                         v.indent
 931                         v.compile_stmt(n_else)
 932                         v.unindent
 933                 end
 934                 v.add_instr("}")
 935         end
 936 end
 937
 938 redef class AIfexprExpr
 939         redef meth compile_expr(v)
 940         do
 941                 var e = v.compile_expr(n_expr)
 942                 v.add_instr("if (UNTAG_Bool({e})) \{ /*if*/")
 943                 v.cfc.free_var(e)
 944                 v.indent
 945                 var e = v.ensure_var(v.compile_expr(n_then))
 946                 v.unindent
 947                 v.add_instr("} else \{ /*if*/")
 948                 v.cfc.free_var(e)
 949                 v.indent
 950                 var e2 = v.ensure_var(v.compile_expr(n_else))
 951                 v.add_assignment(e, e2)
 952                 v.unindent
 953                 v.add_instr("}")
 954                 return e
 955         end
 956 end
 957
 958 redef class AControlableBlock
 959         meth compile_inside_block(v: CompilerVisitor) is abstract
 960         redef meth compile_stmt(v)
 961         do
 962                 var old_break_label = v.nmc.break_label
 963                 var old_continue_label = v.nmc.continue_label
 964                 var id = v.new_number
 965                 v.nmc.break_label = "break_{id}"
 966                 v.nmc.continue_label = "continue_{id}"
 967
 968                 compile_inside_block(v)
 969
 970
 971                 v.nmc.break_label = old_break_label
 972                 v.nmc.continue_label = old_continue_label
 973         end
 974 end
 975
 976 redef class AWhileExpr
 977         redef meth compile_inside_block(v)
 978         do
 979                 v.add_instr("while (true) \{ /*while*/")
 980                 v.indent
 981                 var e = v.compile_expr(n_expr)
 982                 v.add_instr("if (!UNTAG_Bool({e})) break; /* while*/")
 983                 v.cfc.free_var(e)
 984                 if n_block != null then
 985                         v.compile_stmt(n_block)
 986                 end
 987                 v.add_instr("{v.nmc.continue_label}: while(0);")
 988                 v.unindent
 989                 v.add_instr("}")
 990                 v.add_instr("{v.nmc.break_label}: while(0);")
 991         end
 992 end
 993
 994 redef class AForExpr
 995         redef meth compile_inside_block(v)
 996         do
 997                 v.compile_stmt(n_vardecl)
 998         end
 999 end
1000
1001 redef class AForVardeclExpr
1002         redef meth compile_stmt(v)
1003         do
1004                 var e = v.compile_expr(n_expr)
1005                 var ittype = meth_iterator.signature.return_type
1006                 v.cfc.free_var(e)
1007                 var iter = v.cfc.get_var
1008                 v.add_assignment(iter, meth_iterator.compile_call(v, [e]))
1009                 v.add_instr("while (true) \{ /*for*/")
1010                 v.indent
1011                 var ok = v.cfc.get_var
1012                 v.add_assignment(ok, meth_is_ok.compile_call(v, [iter]))
1013                 v.add_instr("if (!UNTAG_Bool({ok})) break; /*for*/")
1014                 v.cfc.free_var(ok)
1015                 var e = meth_item.compile_call(v, [iter])
1016                 e = v.ensure_var(e)
1017                 var cname = v.cfc.register_variable(variable)
1018                 v.add_assignment(cname, e)
1019                 var par = parent
1020                 assert par isa AForExpr
1021                 var n_block = par.n_block
1022                 if n_block != null then
1023                         v.compile_stmt(n_block)
1024                 end
1025                 v.add_instr("{v.nmc.continue_label}: while(0);")
1026                 e = meth_next.compile_call(v, [iter])
1027                 assert e == null
1028                 v.unindent
1029                 v.add_instr("}")
1030                 v.add_instr("{v.nmc.break_label}: while(0);")
1031         end
1032 end
1033
1034 redef class AAssertExpr
1035         redef meth compile_stmt(v)
1036         do
1037                 var e = v.compile_expr(n_expr)
1038                 var s = ""
1039                 if n_id != null then
1040                         s = " '{n_id.text}' "
1041                 end
1042                 v.add_instr("if (!UNTAG_Bool({e})) \{ fprintf(stderr, \"Assert%s failed\", \"{s}\"); {v.printf_locate_error(self)} nit_exit(1);}")
1043         end
1044 end
1045
1046 redef class AVarExpr
1047         redef meth compile_expr(v)
1048         do
1049                 return " {v.cfc.varname(variable)} /*{variable.name}*/"
1050         end
1051 end
1052
1053 redef class AVarAssignExpr
1054         redef meth compile_stmt(v)
1055         do
1056                 var e = v.compile_expr(n_value)
1057                 v.add_assignment(v.cfc.varname(variable), "{e} /*{variable.name}=*/")
1058         end
1059 end
1060
1061 redef class AVarReassignExpr
1062         redef meth compile_stmt(v)
1063         do
1064                 var e1 = v.cfc.varname(variable)
1065                 var e2 = v.compile_expr(n_value)
1066                 var e3 = assign_method.compile_call(v, [e1, e2])
1067                 v.add_assignment(v.cfc.varname(variable), "{e3} /*{variable.name}*/")
1068         end
1069 end
1070
1071 redef class ASelfExpr
1072         redef meth compile_expr(v)
1073         do
1074                 return v.cfc.varname(v.nmc.method_params[0])
1075         end
1076 end
1077
1078 redef class AOrExpr
1079         redef meth compile_expr(v)
1080         do
1081                 var e = v.ensure_var(v.compile_expr(n_expr))
1082                 v.add_instr("if (!UNTAG_Bool({e})) \{ /* or */")
1083                 v.cfc.free_var(e)
1084                 v.indent
1085                 var e2 = v.compile_expr(n_expr2)
1086                 v.add_assignment(e, e2)
1087                 v.unindent
1088                 v.add_instr("}")
1089                 return e
1090         end
1091 end
1092
1093 redef class AAndExpr
1094         redef meth compile_expr(v)
1095         do
1096                 var e = v.ensure_var(v.compile_expr(n_expr))
1097                 v.add_instr("if (UNTAG_Bool({e})) \{ /* and */")
1098                 v.cfc.free_var(e)
1099                 v.indent
1100                 var e2 = v.compile_expr(n_expr2)
1101                 v.add_assignment(e, e2)
1102                 v.unindent
1103                 v.add_instr("}")
1104                 return e
1105         end
1106 end
1107
1108 redef class ANotExpr
1109         redef meth compile_expr(v)
1110         do
1111                 return " TAG_Bool(!UNTAG_Bool({v.compile_expr(n_expr)}))"
1112         end
1113 end
1114
1115 redef class AEeExpr
1116         redef meth compile_expr(v)
1117         do
1118                 var e = v.compile_expr(n_expr)
1119                 var e2 = v.compile_expr(n_expr2)
1120                 return "TAG_Bool(IS_EQUAL_NN({e},{e2}))"
1121         end
1122 end
1123
1124 redef class AIsaExpr
1125         redef meth compile_expr(v)
1126         do
1127                 var e = v.compile_expr(n_expr)
1128                 return n_type.stype.compile_cast(v, e)
1129         end
1130 end
1131
1132 redef class AAsCastExpr
1133         redef meth compile_expr(v)
1134         do
1135                 var e = v.compile_expr(n_expr)
1136                 n_type.stype.compile_type_check(v, e, self)
1137                 return e
1138         end
1139 end
1140
1141 redef class ATrueExpr
1142         redef meth compile_expr(v)
1143         do
1144                 return " TAG_Bool(true)"
1145         end
1146 end
1147
1148 redef class AFalseExpr
1149         redef meth compile_expr(v)
1150         do
1151                 return " TAG_Bool(false)"
1152         end
1153 end
1154
1155 redef class AIntExpr
1156         redef meth compile_expr(v)
1157         do
1158                 return " TAG_Int({n_number.text})"
1159         end
1160 end
1161
1162 redef class AFloatExpr
1163         redef meth compile_expr(v)
1164         do
1165                 return "BOX_Float({n_float.text})"
1166         end
1167 end
1168
1169 redef class ACharExpr
1170         redef meth compile_expr(v)
1171         do
1172                 return " TAG_Char({n_char.text})"
1173         end
1174 end
1175
1176 redef class AStringFormExpr
1177         redef meth compile_expr(v)
1178         do
1179                 compute_string_info
1180                 var i = v.new_number
1181                 var cvar = v.cfc.get_var
1182                 v.add_decl("static val_t once_value_{i} = NIT_NULL; /* Once value for string {cvar}*/")
1183                 v.add_instr("if (once_value_{i} != NIT_NULL) {cvar} = once_value_{i};")
1184                 v.add_instr("else \{")
1185                 v.indent
1186                 v.cfc.free_var(cvar)
1187                 var e = meth_with_native.compile_constructor_call(v, stype , ["BOX_NativeString(\"{_cstring}\")", "TAG_Int({_cstring_length})"])
1188                 v.add_assignment(cvar, e)
1189                 v.add_instr("once_value_{i} = {cvar};")
1190                 v.unindent
1191                 v.add_instr("}")
1192                 return cvar
1193         end
1194
1195         # The raw string value
1196         protected meth string_text: String is abstract
1197
1198         # The string in a C native format
1199         protected attr _cstring: String
1200
1201         # The string length in bytes
1202         protected attr _cstring_length: Int
1203
1204         # Compute _cstring and _cstring_length using string_text
1205         protected meth compute_string_info
1206         do
1207                 var len = 0
1208                 var str = string_text
1209                 var res = new Buffer
1210                 var i = 0
1211                 while i < str.length do
1212                         var c = str[i]
1213                         if c == '\\' then
1214                                 i = i + 1
1215                                 var c2 = str[i]
1216                                 if c2 != '{' and c2 != '}' then
1217                                         res.add(c)
1218                                 end
1219                                 c = c2
1220                         end
1221                         len = len + 1
1222                         res.add(c)
1223                         i = i + 1
1224                 end
1225                 _cstring = res.to_s
1226                 _cstring_length = len
1227         end
1228 end
1229
1230 redef class AStringExpr
1231         redef meth string_text do return n_string.text.substring(1, n_string.text.length - 2)
1232 end
1233 redef class AStartStringExpr
1234         redef meth string_text do return n_string.text.substring(1, n_string.text.length - 2)
1235 end
1236 redef class AMidStringExpr
1237         redef meth string_text do return n_string.text.substring(1, n_string.text.length - 2)
1238 end
1239 redef class AEndStringExpr
1240         redef meth string_text do return n_string.text.substring(1, n_string.text.length - 2)
1241 end
1242
1243 redef class ASuperstringExpr
1244         redef meth compile_expr(v)
1245         do
1246                 var array = meth_with_capacity.compile_constructor_call(v, atype, ["TAG_Int({n_exprs.length})"])
1247
1248                 for ne in n_exprs do
1249                         var e = v.ensure_var(v.compile_expr(ne))
1250                         if ne.stype != stype then
1251                                 v.add_assignment(e, meth_to_s.compile_call(v, [e]))
1252                         end
1253                         meth_add.compile_call(v, [array, e])
1254                 end
1255
1256                 return meth_to_s.compile_call(v, [array])
1257         end
1258 end
1259
1260 redef class ANullExpr
1261         redef meth compile_expr(v)
1262         do
1263                 return " NIT_NULL /*null*/"
1264         end
1265 end
1266
1267 redef class AArrayExpr
1268         redef meth compile_expr(v)
1269         do
1270                 var recv = meth_with_capacity.compile_constructor_call(v, stype, ["TAG_Int({n_exprs.length})"])
1271
1272                 for ne in n_exprs do
1273                         var e = v.compile_expr(ne)
1274                         meth_add.compile_call(v, [recv, e])
1275                 end
1276                 return recv
1277         end
1278 end
1279
1280 redef class ARangeExpr
1281         redef meth compile_expr(v)
1282         do
1283                 var e = v.compile_expr(n_expr)
1284                 var e2 = v.compile_expr(n_expr2)
1285                 return meth_init.compile_constructor_call(v, stype, [e, e2])
1286         end
1287 end
1288
1289 redef class ASuperExpr
1290         redef meth compile_stmt(v)
1291         do
1292                 var e = compile_expr(v)
1293                 if e != null then v.add_instr("{e};")
1294         end
1295
1296         redef meth compile_expr(v)
1297         do
1298                 var arity = v.nmc.method_params.length - 1
1299                 if init_in_superclass != null then
1300                         arity = init_in_superclass.signature.arity
1301                 end
1302                 var args = new Array[String].with_capacity(arity + 1)
1303                 args.add(v.cfc.varname(v.nmc.method_params[0]))
1304                 if n_args.length != arity then
1305                         for i in [0..arity[ do
1306                                 args.add(v.cfc.varname(v.nmc.method_params[i + 1]))
1307                         end
1308                 else
1309                         for na in n_args do
1310                                 args.add(v.compile_expr(na))
1311                         end
1312                 end
1313                 #return "{prop.cname}({args.join(", ")}) /*super {prop.local_class}::{prop.name}*/"
1314                 if init_in_superclass != null then
1315                         return init_in_superclass.compile_call(v, args)
1316                 else
1317                         if prop.global.is_init then args.add("init_table")
1318                         return prop.compile_super_call(v, args)
1319                 end
1320         end
1321 end
1322
1323 redef class AAttrExpr
1324         redef meth compile_expr(v)
1325         do
1326                 var e = v.compile_expr(n_expr)
1327                 return prop.compile_access(v, e)
1328         end
1329 end
1330
1331 redef class AAttrAssignExpr
1332         redef meth compile_stmt(v)
1333         do
1334                 var e = v.compile_expr(n_expr)
1335                 var e2 = v.compile_expr(n_value)
1336                 v.add_assignment(prop.compile_access(v, e), e2)
1337         end
1338 end
1339 redef class AAttrReassignExpr
1340         redef meth compile_stmt(v)
1341         do
1342                 var e1 = v.compile_expr(n_expr)
1343                 var e2 = prop.compile_access(v, e1)
1344                 var e3 = v.compile_expr(n_value)
1345                 var e4 = assign_method.compile_call(v, [e2, e3])
1346                 v.add_assignment(e2, e4)
1347         end
1348 end
1349
1350 redef class ASendExpr
1351         redef meth compile_expr(v)
1352         do
1353                 var recv = v.compile_expr(n_expr)
1354                 var cargs = new Array[String]
1355                 cargs.add(recv)
1356                 for a in arguments do
1357                         cargs.add(v.compile_expr(a))
1358                 end
1359
1360                 var e: String
1361                 if prop_signature.closures.is_empty then
1362                         e = prop.compile_call(v, cargs)
1363                 else
1364                         var cd = closure_defs
1365                         var arity = 0
1366                         if cd != null then arity = cd.length
1367                         var closcns = new Array[String]
1368                         var ve: String = null
1369
1370                         # Prepare result value.
1371                         # In case of procedure, the return value is still used to intercept breaks
1372                         var old_bv = v.nmc.break_value
1373                         ve = v.cfc.get_var
1374                         v.nmc.break_value = ve
1375
1376                         # Compile closure to c function
1377                         for i in [0..arity[ do
1378                                 var cn = cd[i].compile_closure(v, prop.closure_cname(i))
1379                                 closcns.add(cn)
1380                                 cargs.add(cn)
1381                         end
1382                         for i in [arity..prop_signature.closures.length[ do
1383                                 cargs.add("NULL")
1384                         end
1385
1386                         v.nmc.break_value = old_bv
1387
1388                         # Call
1389                         e = prop.compile_call(v, cargs)
1390                         if e != null then
1391                                 v.add_assignment(ve, e)
1392                                 e = ve
1393                         end
1394
1395                         # Intercept returns and breaks
1396                         for i in [0..arity[ do
1397                                 # A break or a return is intercepted
1398                                 v.add_instr("if ({closcns[i]}->has_broke != NULL) \{")
1399                                 v.indent
1400                                 # A passtrought break or a return is intercepted: go the the next closure
1401                                 v.add_instr("if ({closcns[i]}->has_broke != &({ve})) \{")
1402                                 v.indent
1403                                 if v.cfc.in_closure then v.add_instr("closctx->has_broke = {closcns[i]}->has_broke; closctx->broke_value = {closcns[i]}->broke_value;")
1404                                 v.add_instr("goto {v.nmc.return_label};")
1405                                 v.unindent
1406                                 # A direct break is interpected
1407                                 if e != null then
1408                                         # overwrite the returned value in a function
1409                                         v.add_instr("\} else {ve} = {closcns[i]}->broke_value;")
1410                                 else
1411                                         # Do nothing in a procedure
1412                                         v.add_instr("\}")
1413                                 end
1414                                 v.unindent
1415                                 v.add_instr("\}")
1416                         end
1417                 end
1418
1419                 if prop.global.is_init then
1420                         v.invoke_super_init_calls_after(prop)
1421                 end
1422                 return e
1423         end
1424
1425         redef meth compile_stmt(v)
1426         do
1427                 var e = compile_expr(v)
1428                 if e != null then
1429                         v.add_instr(e + ";")
1430                 end
1431         end
1432 end
1433
1434 redef class ASendReassignExpr
1435         redef meth compile_expr(v)
1436         do
1437                 var recv = v.compile_expr(n_expr)
1438                 var cargs = new Array[String]
1439                 cargs.add(recv)
1440                 for a in arguments do
1441                         cargs.add(v.compile_expr(a))
1442                 end
1443
1444                 var e2 = read_prop.compile_call(v, cargs)
1445                 var e3 = v.compile_expr(n_value)
1446                 var e4 = assign_method.compile_call(v, [e2, e3])
1447                 cargs.add(e4)
1448                 return prop.compile_call(v, cargs)
1449         end
1450 end
1451
1452 redef class ANewExpr
1453         redef meth compile_expr(v)
1454         do
1455                 var cargs = new Array[String]
1456                 for a in arguments do
1457                         cargs.add(v.compile_expr(a))
1458                 end
1459                 return prop.compile_constructor_call(v, stype, cargs)
1460         end
1461 end
1462
1463 redef class PClosureDef
1464         # Compile the closure definition as a function in v.out_contexts
1465         # Return the cname of the function
1466         meth compile_closure(v: CompilerVisitor, closcn: String): String is abstract
1467
1468         # Compile the closure definition inside the current C function.
1469         meth do_compile_inside(v: CompilerVisitor, params: Array[String]): String is abstract
1470 end
1471
1472 redef class AClosureDef
1473         # The cname of the function
1474         readable attr _cname: String
1475
1476         redef meth compile_closure(v, closcn)
1477         do
1478                 var ctx_old = v.ctx
1479                 v.ctx = new CContext
1480                 v.out_contexts.add(v.ctx)
1481
1482                 var cfc_old = v.cfc.in_closure
1483                 v.cfc.in_closure = true
1484
1485                 var old_rv = v.nmc.return_value
1486                 var old_bv = v.nmc.break_value
1487                 if not cfc_old then
1488                         v.nmc.return_value = "closctx->{old_rv}"
1489                         v.nmc.break_value = "closctx->{old_bv}"
1490                 end
1491
1492                 var cname = "OC_{v.nmc.method.cname}_{v.out_contexts.length}"
1493                 _cname = cname
1494                 var args = new Array[String]
1495                 for i in [0..closure.signature.arity[ do
1496                         args.add(" param{i}")
1497                 end
1498
1499                 var cs = decl_csignature(v, args, closcn)
1500
1501                 v.add_instr("{cs} \{")
1502                 v.indent
1503                 var ctx_old2 = v.ctx
1504                 v.ctx = new CContext
1505
1506                 v.add_decl("struct trace_t trace = \{NULL, NULL, {line_number}, LOCATE_{v.nmc.method.cname}};")
1507                 v.add_instr("trace.prev = tracehead; tracehead = &trace;")
1508
1509                 v.add_instr("trace.file = LOCATE_{v.module.name};")
1510                 var s = do_compile_inside(v, args)
1511
1512                 v.add_instr("{v.nmc.return_label}:")
1513                 v.add_instr("tracehead = trace.prev;")
1514                 if s == null then
1515                         v.add_instr("return;")
1516                 else
1517                         v.add_instr("return {s};")
1518                 end
1519
1520                 ctx_old2.append(v.ctx)
1521                 v.ctx = ctx_old2
1522                 v.unindent
1523                 v.add_instr("}")
1524                 v.ctx = ctx_old
1525
1526                 v.cfc.in_closure = cfc_old
1527                 v.nmc.return_value = old_rv
1528                 v.nmc.break_value = old_bv
1529
1530                 # Build closure
1531                 var closcnv = "wbclos{v.new_number}"
1532                 v.add_decl("struct {closcn} {closcnv} = \{{cname}, NULL\};")
1533                 if cfc_old then
1534                         v.add_instr("{closcnv}.variable = closctx->variable;")
1535                         v.add_instr("{closcnv}.closurevariable = closctx->closurevariable;")
1536                 else
1537                         v.add_instr("{closcnv}.variable = variable;")
1538                         v.add_instr("{closcnv}.closurevariable = closurevariable;")
1539                 end
1540
1541                 return "(&{closcnv})"
1542         end
1543
1544         protected meth decl_csignature(v: CompilerVisitor, args: Array[String], closcn: String): String
1545         do
1546                 var params = new Array[String]
1547                 params.add("struct {closcn}* closctx")
1548                 for i in [0..closure.signature.arity[ do
1549                         var p = "val_t {args[i]}"
1550                         params.add(p)
1551                 end
1552                 var ret: String
1553                 if closure.signature.return_type != null then
1554                         ret = "val_t"
1555                 else
1556                         ret = "void"
1557                 end
1558                 var p = params.join(", ")
1559                 var s = "{ret} {cname}({p})"
1560                 v.add_decl("struct {closcn};")
1561                 v.add_decl("typedef {ret} (* {cname}_t)({p});")
1562                 v.add_decl(s + ";")
1563                 return s
1564         end
1565
1566         redef meth do_compile_inside(v, params)
1567         do
1568                 for i in [0..variables.length[ do
1569                         var vacname = v.cfc.register_variable(variables[i])
1570                         v.add_assignment(vacname, params[i])
1571                 end
1572
1573                 var old_cv = v.nmc.continue_value
1574                 var old_cl = v.nmc.continue_label
1575                 var old_bl = v.nmc.break_label
1576
1577                 v.nmc.continue_value = v.cfc.get_var
1578                 v.nmc.continue_label = "continue_label{v.new_number}"
1579                 v.nmc.break_label = v.nmc.return_label
1580
1581                 if n_expr != null then v.compile_stmt(n_expr)
1582
1583                 v.add_instr("{v.nmc.continue_label}: while(false);")
1584
1585                 var ret: String = null
1586                 if closure.signature.return_type != null then ret = v.nmc.continue_value
1587
1588                 v.nmc.continue_value = old_cv
1589                 v.nmc.continue_label = old_cl
1590                 v.nmc.break_label = old_bl
1591
1592                 return ret
1593         end
1594 end
1595
1596 redef class PClosureDecl
1597         meth do_compile_inside(v: CompilerVisitor, params: Array[String]): String is abstract
1598 end
1599 redef class AClosureDecl
1600         redef meth do_compile_inside(v, params)
1601         do
1602                 if n_signature != null then n_signature.compile_parameters(v, variable.closure.signature, params)
1603
1604                 var old_cv = v.nmc.continue_value
1605                 var old_cl = v.nmc.continue_label
1606                 var old_bl = v.nmc.break_label
1607
1608                 v.nmc.continue_value = v.cfc.get_var
1609                 v.nmc.continue_label = "continue_label{v.new_number}"
1610                 v.nmc.break_label = v.nmc.return_label
1611
1612                 if n_expr != null then v.compile_stmt(n_expr)
1613
1614                 v.add_instr("{v.nmc.continue_label}: while(false);")
1615
1616                 var ret: String = null
1617                 if variable.closure.signature.return_type != null then ret = v.nmc.continue_value
1618
1619                 v.nmc.continue_value = old_cv
1620                 v.nmc.continue_label = old_cl
1621                 v.nmc.break_label = old_bl
1622
1623                 return ret
1624         end
1625 end
1626
1627 redef class AClosureCallExpr
1628         redef meth compile_expr(v)
1629         do
1630                 var cargs = new Array[String]
1631                 for a in arguments do cargs.add(v.compile_expr(a))
1632                 var va: String = null
1633                 if variable.closure.signature.return_type != null then va = v.cfc.get_var
1634
1635                 if variable.closure.is_optional then
1636                         v.add_instr("if({v.cfc.varname(variable)}==NULL) \{")
1637                         v.indent
1638                         var n = variable.decl
1639                         assert n isa AClosureDecl
1640                         var s = n.do_compile_inside(v, cargs)
1641                         if s != null then v.add_assignment(va, s)
1642                         v.unindent
1643                         v.add_instr("} else \{")
1644                         v.indent
1645                 end
1646
1647                 var ivar = "(({variable.ctypename})({v.cfc.varname(variable)}))"
1648                 var cargs2 = [ivar]
1649                 cargs2.append(cargs)
1650                 var s = "({ivar}->fun({cargs2.join(", ")})) /* Invoke closure {variable} */"
1651                 if va != null then
1652                         v.add_assignment(va, s)
1653                 else
1654                         v.add_instr("{s};")
1655                 end
1656                 v.add_instr("if ({ivar}->has_broke) \{")
1657                 v.indent
1658                 if n_closure_defs != null and n_closure_defs.length == 1 then do
1659                         n_closure_defs.first.do_compile_inside(v, null)
1660                 end
1661                 if v.cfc.in_closure then v.add_instr("if ({ivar}->has_broke) \{ closctx->has_broke = {ivar}->has_broke; closctx->broke_value = {ivar}->broke_value;\}")
1662                 v.add_instr("goto {v.nmc.return_label};")
1663                 v.unindent
1664                 v.add_instr("\}")
1665
1666                 if variable.closure.is_optional then
1667                         v.unindent
1668                         v.add_instr("\}")
1669                 end
1670                 return va
1671         end
1672 end
1673
1674 redef class AProxyExpr
1675         redef meth compile_expr(v)
1676         do
1677                 return v.compile_expr(n_expr)
1678         end
1679 end
1680
1681 redef class AOnceExpr
1682         redef meth compile_expr(v)
1683         do
1684                 var i = v.new_number
1685                 var cvar = v.cfc.get_var
1686                 v.add_decl("static val_t once_value_{i}; static int once_bool_{i}; /* Once value for {cvar}*/")
1687                 v.add_instr("if (once_bool_{i}) {cvar} = once_value_{i};")
1688                 v.add_instr("else \{")
1689                 v.indent
1690                 v.cfc.free_var(cvar)
1691                 var e = v.compile_expr(n_expr)
1692                 v.add_assignment(cvar, e)
1693                 v.add_instr("once_value_{i} = {cvar};")
1694                 v.add_instr("once_bool_{i} = true;")
1695                 v.unindent
1696                 v.add_instr("}")
1697                 return cvar
1698         end
1699 end