contrib/nitiwiki/src/wiki_links.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Wiki internal links handling.
  16 module wiki_links
  17
  18 import wiki_base
  19 import markdown::wikilinks
  20
  21 redef class Nitiwiki
  22         # Looks up a WikiEntry by its `name`.
  23         #
  24         # Rules are:
  25         # 1. Looks in the current section
  26         # 2. Looks in the current section children
  27         # 3. Looks in the current section parent
  28         # 4. Looks up to wiki root
  29         #
  30         # Returns `null` if no article can be found.
  31         fun lookup_entry_by_name(context: WikiEntry, name: String): nullable WikiEntry do
  32                 var section: nullable WikiEntry = context.parent or else context
  33                 var res = section.lookup_entry_by_name(name)
  34                 if res != null then return res
  35                 while section != null do
  36                         if section.name == name then return section
  37                         if section.children.has_key(name) then return section.children[name]
  38                         section = section.parent
  39                 end
  40                 return null
  41         end
  42
  43         # Looks up a WikiEntry by its `title`.
  44         #
  45         # Rules are:
  46         # 1. Looks in the current section
  47         # 2. Looks in the current section children
  48         # 3. Looks in the current section parent
  49         # 4. Looks up to wiki root
  50         #
  51         # Returns `null` if no article can be found.
  52         fun lookup_entry_by_title(context: WikiEntry, title: String): nullable WikiEntry do
  53                 var section: nullable WikiEntry = context.parent or else context
  54                 var res = section.lookup_entry_by_title(title)
  55                 if res != null then return res
  56                 while section != null do
  57                         if section.title == title then return section
  58                         for child in section.children.values do
  59                                 if child.title == title then return child
  60                         end
  61                         section = section.parent
  62                 end
  63                 return null
  64         end
  65
  66         # Looks up a WikiEntry by its `path`.
  67         #
  68         # Path can be relative from `context` like `context/entry`.
  69         # Or absolute like `/entry1/entry2`.
  70         #
  71         # Returns `null` if no article can be found.
  72         fun lookup_entry_by_path(context: WikiEntry, path: String): nullable WikiEntry do
  73                 var entry: nullable WikiEntry = context.parent or else context
  74                 var parts = path.split_with("/")
  75                 if path.has_prefix("/") then
  76                         entry = root_section
  77                         if parts.is_empty then return root_section.index
  78                         parts.shift
  79                 end
  80                 while not parts.is_empty do
  81                         var name = parts.shift
  82                         if name.is_empty then continue
  83                         if not entry.children.has_key(name) then return null
  84                         entry = entry.children[name]
  85                 end
  86                 return entry
  87         end
  88 end
  89
  90 redef class WikiEntry
  91
  92         # Url to `self` once generated.
  93         fun url: String do return wiki.config.root_url.join_path(breadcrumbs.join("/"))
  94
  95         redef fun render do
  96                 super
  97                 if not is_dirty and not wiki.force_render then return
  98         end
  99
 100         # Search in `self` then `self.children` if an entry has the name `name`.
 101         fun lookup_entry_by_name(name: String): nullable WikiEntry do
 102                 if children.has_key(name) then return children[name]
 103                 for child in children.values do
 104                         var res = child.lookup_entry_by_name(name)
 105                         if res != null then return res
 106                 end
 107                 return null
 108         end
 109
 110         # Search in `self` then `self.children` if an entry has the title `title`.
 111         fun lookup_entry_by_title(title: String): nullable WikiEntry do
 112                 for child in children.values do
 113                         if child.title == title then return child
 114                 end
 115                 for child in children.values do
 116                         var res = child.lookup_entry_by_title(title)
 117                         if res != null then return res
 118                 end
 119                 return null
 120         end
 121
 122         private var md_proc: NitiwikiMdProcessor is lazy do
 123                 return new NitiwikiMdProcessor(wiki, self)
 124         end
 125 end
 126
 127 redef class WikiSection
 128
 129         # The index page for this section.
 130         #
 131         # If no file `index.md` exists for this section,
 132         # a summary is generated using contained articles.
 133         var index: WikiArticle is lazy do
 134                 for child in children.values do
 135                         if child isa WikiArticle and child.is_index then return child
 136                 end
 137                 return new WikiSectionIndex(wiki, "index", self)
 138         end
 139 end
 140
 141 redef class WikiArticle
 142
 143         # Headlines ids and titles.
 144         var headlines = new ArrayMap[String, HeadLine]
 145
 146         # Is `self` an index page?
 147         #
 148         # Checks if `self.name == "index"`.
 149         fun is_index: Bool do return name == "index"
 150
 151         redef fun url do
 152                 if parent == null then
 153                         return wiki.config.root_url.join_path("{name}.html")
 154                 else
 155                         return parent.url.join_path("{name}.html")
 156                 end
 157         end
 158
 159         redef fun render do
 160                 super
 161                 if not is_dirty and not wiki.force_render or not has_source then return
 162                 content = md_proc.process(md.as(not null))
 163                 headlines.recover_with(md_proc.emitter.decorator.headlines)
 164         end
 165 end
 166
 167 # A `WikiArticle` that contains the section index tree.
 168 class WikiSectionIndex
 169         super WikiArticle
 170
 171         # The section described by `self`.
 172         var section: WikiSection
 173
 174         redef fun title do return section.title
 175
 176         redef fun url do return section.url
 177 end
 178
 179 # A MarkdownProcessor able to parse wiki links.
 180 class NitiwikiMdProcessor
 181         super MarkdownProcessor
 182
 183         # Wiki used to resolve links.
 184         var wiki: Nitiwiki
 185
 186         # Article parsed by `self`.
 187         #
 188         # Used to contextualize links.
 189         var context: WikiEntry
 190
 191         init do
 192                 emitter = new MarkdownEmitter(self)
 193                 emitter.decorator = new NitiwikiDecorator(wiki, context)
 194         end
 195 end
 196
 197 private class NitiwikiDecorator
 198         super HTMLDecorator
 199
 200         # Wiki used to resolve links.
 201         var wiki: Nitiwiki
 202
 203         # Article used to contextualize links.
 204         var context: WikiEntry
 205
 206         redef fun add_wikilink(v, link, name, comment) do
 207                 var wiki = v.processor.as(NitiwikiMdProcessor).wiki
 208                 var target: nullable WikiEntry = null
 209                 var anchor: nullable String = null
 210                 if link.has("#") then
 211                         var parts = link.split_with("#")
 212                         link = parts.first
 213                         anchor = parts.subarray(1, parts.length - 1).join("#")
 214                 end
 215                 if link.has("/") then
 216                         target = wiki.lookup_entry_by_path(context, link.to_s)
 217                 else
 218                         target = wiki.lookup_entry_by_name(context, link.to_s)
 219                         if target == null then
 220                                 target = wiki.lookup_entry_by_title(context, link.to_s)
 221                         end
 222                 end
 223                 v.add "<a "
 224                 if target != null then
 225                         if name == null then name = target.title
 226                         link = target.url
 227                 else
 228                         var loc = context.src_path or else context.name
 229                         wiki.message("Warning: unknown wikilink `{link}` (in {loc})", 0)
 230                         v.add "class=\"broken\" "
 231                 end
 232                 v.add "href=\""
 233                 append_value(v, link)
 234                 if anchor != null then append_value(v, "#{anchor}")
 235                 v.add "\""
 236                 if comment != null and not comment.is_empty then
 237                         v.add " title=\""
 238                         append_value(v, comment)
 239                         v.add "\""
 240                 end
 241                 v.add ">"
 242                 if name == null then name = link
 243                 v.emit_text(name)
 244                 v.add "</a>"
 245         end
 246 end