lib/core/text/abstract_text.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # This file is free software, which comes along with NIT.  This software is
   4 # distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
   5 # without  even  the implied warranty of  MERCHANTABILITY or  FITNESS FOR A
   6 # PARTICULAR PURPOSE.  You can modify it is you want,  provided this header
   7 # is kept unaltered, and a notification of the changes is added.
   8 # You  are  allowed  to  redistribute it and sell it, alone or is a part of
   9 # another product.
  10
  11 # Abstract class for manipulation of sequences of characters
  12 module abstract_text
  13
  14 import native
  15 import math
  16 import collection
  17 intrude import collection::array
  18
  19 in "C" `{
  20         #include <stdio.h>
  21         #include <stdlib.h>
  22         #include <string.h>
  23 `}
  24
  25 # High-level abstraction for all text representations
  26 abstract class Text
  27         super Comparable
  28
  29         redef type OTHER: Text
  30
  31         # Type of self (used for factorization of several methods, ex : substring_from, empty...)
  32         type SELFTYPE: Text
  33
  34         # Gets a view on the chars of the Text object
  35         #
  36         #     assert "hello".chars.to_a == ['h', 'e', 'l', 'l', 'o']
  37         fun chars: SequenceRead[Char] is abstract
  38
  39         # Gets a view on the bytes of the Text object
  40         #
  41         #     assert "hello".bytes.to_a == [104u8, 101u8, 108u8, 108u8, 111u8]
  42         fun bytes: SequenceRead[Byte] is abstract
  43
  44         # Number of characters contained in self.
  45         #
  46         #     assert "12345".length == 5
  47         #     assert "".length == 0
  48         #     assert "あいうえお".length == 5
  49         fun length: Int is abstract
  50
  51         # Number of bytes in `self`
  52         #
  53         #     assert "12345".bytelen == 5
  54         #     assert "あいうえお".bytelen == 15
  55         fun bytelen: Int is abstract
  56
  57         # Create a substring.
  58         #
  59         #     assert "abcd".substring(1, 2)      ==  "bc"
  60         #     assert "abcd".substring(-1, 2)     ==  "a"
  61         #     assert "abcd".substring(1, 0)      ==  ""
  62         #     assert "abcd".substring(2, 5)      ==  "cd"
  63         #     assert "あいうえお".substring(1,3) ==  "いうえ"
  64         #
  65         # A `from` index < 0 will be replaced by 0.
  66         # Unless a `count` value is > 0 at the same time.
  67         # In this case, `from += count` and `count -= from`.
  68         fun substring(from: Int, count: Int): SELFTYPE is abstract
  69
  70         # Iterates on the substrings of self if any
  71         private fun substrings: Iterator[FlatText] is abstract
  72
  73         # Is the current Text empty (== "")
  74         #
  75         #     assert "".is_empty
  76         #     assert not "foo".is_empty
  77         fun is_empty: Bool do return self.length == 0
  78
  79         # Returns an empty Text of the right type
  80         #
  81         # This method is used internally to get the right
  82         # implementation of an empty string.
  83         protected fun empty: SELFTYPE is abstract
  84
  85         # Gets the first char of the Text
  86         #
  87         # DEPRECATED : Use self.chars.first instead
  88         fun first: Char do return self.chars[0]
  89
  90         # Access a character at `index` in the string.
  91         #
  92         #     assert "abcd"[2]         == 'c'
  93         #
  94         # DEPRECATED : Use self.chars.[] instead
  95         fun [](index: Int): Char do return self.chars[index]
  96
  97         # Gets the index of the first occurence of 'c'
  98         #
  99         # Returns -1 if not found
 100         #
 101         # DEPRECATED : Use self.chars.index_of instead
 102         fun index_of(c: Char): Int
 103         do
 104                 return index_of_from(c, 0)
 105         end
 106
 107         # Gets the last char of self
 108         #
 109         # DEPRECATED : Use self.chars.last instead
 110         fun last: Char do return self.chars[length-1]
 111
 112         # Gets the index of the first occurence of ´c´ starting from ´pos´
 113         #
 114         # Returns -1 if not found
 115         #
 116         # DEPRECATED : Use self.chars.index_of_from instead
 117         fun index_of_from(c: Char, pos: Int): Int
 118         do
 119                 var iter = self.chars.iterator_from(pos)
 120                 while iter.is_ok do
 121                         if iter.item == c then return iter.index
 122                         iter.next
 123                 end
 124                 return -1
 125         end
 126
 127         # Gets the last index of char ´c´
 128         #
 129         # Returns -1 if not found
 130         #
 131         # DEPRECATED : Use self.chars.last_index_of instead
 132         fun last_index_of(c: Char): Int
 133         do
 134                 return last_index_of_from(c, length - 1)
 135         end
 136
 137         # Return a null terminated char *
 138         fun to_cstring: NativeString is abstract
 139
 140         # The index of the last occurrence of an element starting from pos (in reverse order).
 141         #
 142         #     var s = "/etc/bin/test/test.nit"
 143         #     assert s.last_index_of_from('/', s.length-1) == 13
 144         #     assert s.last_index_of_from('/', 12)         == 8
 145         #
 146         # Returns -1 if not found
 147         #
 148         # DEPRECATED : Use self.chars.last_index_of_from instead
 149         fun last_index_of_from(item: Char, pos: Int): Int do return chars.last_index_of_from(item, pos)
 150
 151         # Gets an iterator on the chars of self
 152         #
 153         # DEPRECATED : Use self.chars.iterator instead
 154         fun iterator: Iterator[Char]
 155         do
 156                 return self.chars.iterator
 157         end
 158
 159
 160         # Gets an Array containing the chars of self
 161         #
 162         # DEPRECATED : Use self.chars.to_a instead
 163         fun to_a: Array[Char] do return chars.to_a
 164
 165         # Create a substring from `self` beginning at the `from` position
 166         #
 167         #     assert "abcd".substring_from(1)    ==  "bcd"
 168         #     assert "abcd".substring_from(-1)   ==  "abcd"
 169         #     assert "abcd".substring_from(2)    ==  "cd"
 170         #
 171         # As with substring, a `from` index < 0 will be replaced by 0
 172         fun substring_from(from: Int): SELFTYPE
 173         do
 174                 if from >= self.length then return empty
 175                 if from < 0 then from = 0
 176                 return substring(from, length - from)
 177         end
 178
 179         # Does self have a substring `str` starting from position `pos`?
 180         #
 181         #     assert "abcd".has_substring("bc",1)            ==  true
 182         #     assert "abcd".has_substring("bc",2)            ==  false
 183         #
 184         # Returns true iff all characters of `str` are presents
 185         # at the expected index in `self.`
 186         # The first character of `str` being at `pos`, the second
 187         # character being at `pos+1` and so on...
 188         #
 189         # This means that all characters of `str` need to be inside `self`.
 190         #
 191         #     assert "abcd".has_substring("xab", -1)         == false
 192         #     assert "abcd".has_substring("cdx", 2)          == false
 193         #
 194         # And that the empty string is always a valid substring.
 195         #
 196         #     assert "abcd".has_substring("", 2)             == true
 197         #     assert "abcd".has_substring("", 200)           == true
 198         fun has_substring(str: String, pos: Int): Bool
 199         do
 200                 if str.is_empty then return true
 201                 if pos < 0 or pos + str.length > length then return false
 202                 var myiter = self.chars.iterator_from(pos)
 203                 var itsiter = str.chars.iterator
 204                 while myiter.is_ok and itsiter.is_ok do
 205                         if myiter.item != itsiter.item then return false
 206                         myiter.next
 207                         itsiter.next
 208                 end
 209                 if itsiter.is_ok then return false
 210                 return true
 211         end
 212
 213         # Is this string prefixed by `prefix`?
 214         #
 215         #     assert "abcd".has_prefix("ab")           ==  true
 216         #     assert "abcbc".has_prefix("bc")          ==  false
 217         #     assert "ab".has_prefix("abcd")           ==  false
 218         fun has_prefix(prefix: String): Bool do return has_substring(prefix,0)
 219
 220         # Is this string suffixed by `suffix`?
 221         #
 222         #     assert "abcd".has_suffix("abc")        ==  false
 223         #     assert "abcd".has_suffix("bcd")        ==  true
 224         fun has_suffix(suffix: String): Bool do return has_substring(suffix, length - suffix.length)
 225
 226         # Returns `self` as the corresponding integer
 227         #
 228         #     assert "123".to_i        == 123
 229         #     assert "-1".to_i         == -1
 230         #     assert "0x64".to_i       == 100
 231         #     assert "0b1100_0011".to_i== 195
 232         #     assert "--12".to_i       == 12
 233         #
 234         # REQUIRE: `self`.`is_int`
 235         fun to_i: Int is abstract
 236
 237         # If `self` contains a float, return the corresponding float
 238         #
 239         #     assert "123".to_f        == 123.0
 240         #     assert "-1".to_f         == -1.0
 241         #     assert "-1.2e-3".to_f    == -0.0012
 242         fun to_f: Float
 243         do
 244                 # Shortcut
 245                 return to_s.to_cstring.atof
 246         end
 247
 248         # If `self` contains only digits and alpha <= 'f', return the corresponding integer.
 249         #
 250         #     assert "ff".to_hex == 255
 251         fun to_hex(pos, ln: nullable Int): Int do
 252                 var res = 0
 253                 if pos == null then pos = 0
 254                 if ln == null then ln = length - pos
 255                 var max = pos + ln
 256                 for i in [pos .. max[ do
 257                         res <<= 4
 258                         res += self[i].from_hex
 259                 end
 260                 return res
 261         end
 262
 263         # If `self` contains only digits <= '7', return the corresponding integer.
 264         #
 265         #     assert "714".to_oct == 460
 266         fun to_oct: Int do return a_to(8)
 267
 268         # If `self` contains only '0' et '1', return the corresponding integer.
 269         #
 270         #     assert "101101".to_bin == 45
 271         fun to_bin: Int do return a_to(2)
 272
 273         # If `self` contains only digits '0' .. '9', return the corresponding integer.
 274         #
 275         #     assert "108".to_dec == 108
 276         fun to_dec: Int do return a_to(10)
 277
 278         # If `self` contains only digits and letters, return the corresponding integer in a given base
 279         #
 280         #     assert "120".a_to(3)     == 15
 281         fun a_to(base: Int) : Int
 282         do
 283                 var i = 0
 284                 var neg = false
 285
 286                 for j in [0..length[ do
 287                         var c = chars[j]
 288                         var v = c.to_i
 289                         if v > base then
 290                                 if neg then
 291                                         return -i
 292                                 else
 293                                         return i
 294                                 end
 295                         else if v < 0 then
 296                                 neg = true
 297                         else
 298                                 i = i * base + v
 299                         end
 300                 end
 301                 if neg then
 302                         return -i
 303                 else
 304                         return i
 305                 end
 306         end
 307
 308         # Returns `true` if the string contains only Numeric values (and one "," or one "." character)
 309         #
 310         #     assert "123".is_numeric  == true
 311         #     assert "1.2".is_numeric  == true
 312         #     assert "1,2".is_numeric  == true
 313         #     assert "1..2".is_numeric == false
 314         fun is_numeric: Bool
 315         do
 316                 var has_point_or_comma = false
 317                 for i in [0..length[ do
 318                         var c = chars[i]
 319                         if not c.is_numeric then
 320                                 if (c == '.' or c == ',') and not has_point_or_comma then
 321                                         has_point_or_comma = true
 322                                 else
 323                                         return false
 324                                 end
 325                         end
 326                 end
 327                 return true
 328         end
 329
 330         # Returns `true` if the string contains only Hex chars
 331         #
 332         #     assert "048bf".is_hex  == true
 333         #     assert "ABCDEF".is_hex  == true
 334         #     assert "0G".is_hex == false
 335         fun is_hex: Bool
 336         do
 337                 for i in [0..length[ do
 338                         var c = chars[i]
 339                         if not (c >= 'a' and c <= 'f') and
 340                            not (c >= 'A' and c <= 'F') and
 341                            not (c >= '0' and c <= '9') then return false
 342                 end
 343                 return true
 344         end
 345
 346         # Returns `true` if the string contains only Binary digits
 347         #
 348         #     assert "1101100".is_bin  == true
 349         #     assert "1101020".is_bin  == false
 350         fun is_bin: Bool do
 351                 for i in chars do if i != '0' and i != '1' then return false
 352                 return true
 353         end
 354
 355         # Returns `true` if the string contains only Octal digits
 356         #
 357         #     assert "213453".is_oct  == true
 358         #     assert "781".is_oct     == false
 359         fun is_oct: Bool do
 360                 for i in chars do if i < '0' or i > '7' then return false
 361                 return true
 362         end
 363
 364         # Returns `true` if the string contains only Decimal digits
 365         #
 366         #     assert "10839".is_dec == true
 367         #     assert "164F".is_dec  == false
 368         fun is_dec: Bool do
 369                 for i in chars do if i < '0' or i > '9' then return false
 370                 return true
 371         end
 372
 373         # Are all letters in `self` upper-case ?
 374         #
 375         #     assert "HELLO WORLD".is_upper == true
 376         #     assert "%$&%!".is_upper       == true
 377         #     assert "hello world".is_upper == false
 378         #     assert "Hello World".is_upper == false
 379         fun is_upper: Bool
 380         do
 381                 for i in [0..length[ do
 382                         var char = chars[i]
 383                         if char.is_lower then return false
 384                 end
 385                 return true
 386         end
 387
 388         # Are all letters in `self` lower-case ?
 389         #
 390         #     assert "hello world".is_lower == true
 391         #     assert "%$&%!".is_lower       == true
 392         #     assert "Hello World".is_lower == false
 393         fun is_lower: Bool
 394         do
 395                 for i in [0..length[ do
 396                         var char = chars[i]
 397                         if char.is_upper then return false
 398                 end
 399                 return true
 400         end
 401
 402         # Removes the whitespaces at the beginning of self
 403         #
 404         #     assert " \n\thello \n\t".l_trim == "hello \n\t"
 405         #
 406         # `Char::is_whitespace` determines what is a whitespace.
 407         fun l_trim: SELFTYPE
 408         do
 409                 var iter = self.chars.iterator
 410                 while iter.is_ok do
 411                         if not iter.item.is_whitespace then break
 412                         iter.next
 413                 end
 414                 if iter.index == length then return self.empty
 415                 return self.substring_from(iter.index)
 416         end
 417
 418         # Removes the whitespaces at the end of self
 419         #
 420         #     assert " \n\thello \n\t".r_trim == " \n\thello"
 421         #
 422         # `Char::is_whitespace` determines what is a whitespace.
 423         fun r_trim: SELFTYPE
 424         do
 425                 var iter = self.chars.reverse_iterator
 426                 while iter.is_ok do
 427                         if not iter.item.is_whitespace then break
 428                         iter.next
 429                 end
 430                 if iter.index < 0 then return self.empty
 431                 return self.substring(0, iter.index + 1)
 432         end
 433
 434         # Trims trailing and preceding white spaces
 435         #
 436         #     assert "  Hello  World !  ".trim   == "Hello  World !"
 437         #     assert "\na\nb\tc\t".trim          == "a\nb\tc"
 438         #
 439         # `Char::is_whitespace` determines what is a whitespace.
 440         fun trim: SELFTYPE do return (self.l_trim).r_trim
 441
 442         # Is the string non-empty but only made of whitespaces?
 443         #
 444         #     assert " \n\t ".is_whitespace    == true
 445         #     assert "  hello  ".is_whitespace == false
 446         #     assert "".is_whitespace          == false
 447         #
 448         # `Char::is_whitespace` determines what is a whitespace.
 449         fun is_whitespace: Bool
 450         do
 451                 if is_empty then return false
 452                 for c in self.chars do
 453                         if not c.is_whitespace then return false
 454                 end
 455                 return true
 456         end
 457
 458         # Returns `self` removed from its last line terminator (if any).
 459         #
 460         #     assert "Hello\n".chomp == "Hello"
 461         #     assert "Hello".chomp   == "Hello"
 462         #
 463         #     assert "\n".chomp == ""
 464         #     assert "".chomp   == ""
 465         #
 466         # Line terminators are `"\n"`, `"\r\n"` and `"\r"`.
 467         # A single line terminator, the last one, is removed.
 468         #
 469         #     assert "\r\n".chomp     == ""
 470         #     assert "\r\n\n".chomp   == "\r\n"
 471         #     assert "\r\n\r\n".chomp == "\r\n"
 472         #     assert "\r\n\r".chomp   == "\r\n"
 473         #
 474         # Note: unlike with most IO methods like `Reader::read_line`,
 475         # a single `\r` is considered here to be a line terminator and will be removed.
 476         fun chomp: SELFTYPE
 477         do
 478                 var len = length
 479                 if len == 0 then return self
 480                 var l = self.chars.last
 481                 if l == '\r' then
 482                         return substring(0, len-1)
 483                 else if l != '\n' then
 484                         return self
 485                 else if len > 1 and self.chars[len-2] == '\r' then
 486                         return substring(0, len-2)
 487                 else
 488                         return substring(0, len-1)
 489                 end
 490         end
 491
 492         # Justify a self in a space of `length`
 493         #
 494         # `left` is the space ratio on the left side.
 495         # * 0.0 for left-justified (no space at the left)
 496         # * 1.0 for right-justified (all spaces at the left)
 497         # * 0.5 for centered (half the spaces at the left)
 498         #
 499         # Examples
 500         #
 501         #     assert "hello".justify(10, 0.0)  == "hello     "
 502         #     assert "hello".justify(10, 1.0)  == "     hello"
 503         #     assert "hello".justify(10, 0.5)  == "  hello   "
 504         #
 505         # If `length` is not enough, `self` is returned as is.
 506         #
 507         #     assert "hello".justify(2, 0.0)   == "hello"
 508         #
 509         # REQUIRE: `left >= 0.0 and left <= 1.0`
 510         # ENSURE: `self.length <= length implies result.length == length`
 511         # ENSURE: `self.length >= length implies result == self`
 512         fun justify(length: Int, left: Float): String
 513         do
 514                 var diff = length - self.length
 515                 if diff <= 0 then return to_s
 516                 assert left >= 0.0 and left <= 1.0
 517                 var before = (diff.to_f * left).to_i
 518                 return " " * before + self + " " * (diff-before)
 519         end
 520
 521         # Mangle a string to be a unique string only made of alphanumeric characters and underscores.
 522         #
 523         # This method is injective (two different inputs never produce the same
 524         # output) and the returned string always respect the following rules:
 525         #
 526         # * Contains only US-ASCII letters, digits and underscores.
 527         # * Never starts with a digit.
 528         # * Never ends with an underscore.
 529         # * Never contains two contiguous underscores.
 530         #
 531         #     assert "42_is/The answer!".to_cmangle == "_52d2_is_47dThe_32danswer_33d"
 532         #     assert "__".to_cmangle == "_95d_95d"
 533         #     assert "__d".to_cmangle == "_95d_d"
 534         #     assert "_d_".to_cmangle == "_d_95d"
 535         #     assert "_42".to_cmangle == "_95d42"
 536         #     assert "foo".to_cmangle == "foo"
 537         #     assert "".to_cmangle == ""
 538         fun to_cmangle: String
 539         do
 540                 if is_empty then return ""
 541                 var res = new Buffer
 542                 var underscore = false
 543                 var start = 0
 544                 var c = chars[0]
 545
 546                 if c >= '0' and c <= '9' then
 547                         res.add('_')
 548                         res.append(c.code_point.to_s)
 549                         res.add('d')
 550                         start = 1
 551                 end
 552                 for i in [start..length[ do
 553                         c = chars[i]
 554                         if (c >= 'a' and c <= 'z') or (c >='A' and c <= 'Z') then
 555                                 res.add(c)
 556                                 underscore = false
 557                                 continue
 558                         end
 559                         if underscore then
 560                                 res.append('_'.code_point.to_s)
 561                                 res.add('d')
 562                         end
 563                         if c >= '0' and c <= '9' then
 564                                 res.add(c)
 565                                 underscore = false
 566                         else if c == '_' then
 567                                 res.add(c)
 568                                 underscore = true
 569                         else
 570                                 res.add('_')
 571                                 res.append(c.code_point.to_s)
 572                                 res.add('d')
 573                                 underscore = false
 574                         end
 575                 end
 576                 if underscore then
 577                         res.append('_'.code_point.to_s)
 578                         res.add('d')
 579                 end
 580                 return res.to_s
 581         end
 582
 583         # Escape " \ ' and non printable characters using the rules of literal C strings and characters
 584         #
 585         #     assert "abAB12<>&".escape_to_c         == "abAB12<>&"
 586         #     assert "\n\"'\\".escape_to_c         == "\\n\\\"\\'\\\\"
 587         #
 588         # Most non-printable characters (bellow ASCII 32) are escaped to an octal form `\nnn`.
 589         # Three digits are always used to avoid following digits to be interpreted as an element
 590         # of the octal sequence.
 591         #
 592         #     assert "{0.code_point}{1.code_point}{8.code_point}{31.code_point}{32.code_point}".escape_to_c == "\\000\\001\\010\\037 "
 593         #
 594         # The exceptions are the common `\t` and `\n`.
 595         fun escape_to_c: String
 596         do
 597                 var b = new Buffer
 598                 for i in [0..length[ do
 599                         var c = chars[i]
 600                         if c == '\n' then
 601                                 b.append("\\n")
 602                         else if c == '\t' then
 603                                 b.append("\\t")
 604                         else if c == '"' then
 605                                 b.append("\\\"")
 606                         else if c == '\'' then
 607                                 b.append("\\\'")
 608                         else if c == '\\' then
 609                                 b.append("\\\\")
 610                         else if c.code_point < 32 then
 611                                 b.add('\\')
 612                                 var oct = c.code_point.to_base(8, false)
 613                                 # Force 3 octal digits since it is the
 614                                 # maximum allowed in the C specification
 615                                 if oct.length == 1 then
 616                                         b.add('0')
 617                                         b.add('0')
 618                                 else if oct.length == 2 then
 619                                         b.add('0')
 620                                 end
 621                                 b.append(oct)
 622                         else
 623                                 b.add(c)
 624                         end
 625                 end
 626                 return b.to_s
 627         end
 628
 629         # Escape additionnal characters
 630         # The result might no be legal in C but be used in other languages
 631         #
 632         #     assert "ab|\{\}".escape_more_to_c("|\{\}") == "ab\\|\\\{\\\}"
 633         fun escape_more_to_c(chars: String): String
 634         do
 635                 var b = new Buffer
 636                 for c in escape_to_c.chars do
 637                         if chars.chars.has(c) then
 638                                 b.add('\\')
 639                         end
 640                         b.add(c)
 641                 end
 642                 return b.to_s
 643         end
 644
 645         # Escape to C plus braces
 646         #
 647         #     assert "\n\"'\\\{\}".escape_to_nit      == "\\n\\\"\\'\\\\\\\{\\\}"
 648         fun escape_to_nit: String do return escape_more_to_c("\{\}")
 649
 650         # Escape to POSIX Shell (sh).
 651         #
 652         # Abort if the text contains a null byte.
 653         #
 654         #     assert "\n\"'\\\{\}0".escape_to_sh == "'\n\"'\\''\\\{\}0'"
 655         fun escape_to_sh: String do
 656                 var b = new Buffer
 657                 b.chars.add '\''
 658                 for i in [0..length[ do
 659                         var c = chars[i]
 660                         if c == '\'' then
 661                                 b.append("'\\''")
 662                         else
 663                                 assert without_null_byte: c != '\0'
 664                                 b.add(c)
 665                         end
 666                 end
 667                 b.chars.add '\''
 668                 return b.to_s
 669         end
 670
 671         # Escape to include in a Makefile
 672         #
 673         # Unfortunately, some characters are not escapable in Makefile.
 674         # These characters are `;`, `|`, `\`, and the non-printable ones.
 675         # They will be rendered as `"?{hex}"`.
 676         fun escape_to_mk: String do
 677                 var b = new Buffer
 678                 for i in [0..length[ do
 679                         var c = chars[i]
 680                         if c == '$' then
 681                                 b.append("$$")
 682                         else if c == ':' or c == ' ' or c == '#' then
 683                                 b.add('\\')
 684                                 b.add(c)
 685                         else if c.code_point < 32 or c == ';' or c == '|' or c == '\\' or c == '=' then
 686                                 b.append("?{c.code_point.to_base(16, false)}")
 687                         else
 688                                 b.add(c)
 689                         end
 690                 end
 691                 return b.to_s
 692         end
 693
 694         # Return a string where Nit escape sequences are transformed.
 695         #
 696         #     var s = "\\n"
 697         #     assert s.length        ==  2
 698         #     var u = s.unescape_nit
 699         #     assert u.length        ==  1
 700         #     assert u.chars[0].code_point      ==  10 # (the ASCII value of the "new line" character)
 701         fun unescape_nit: String
 702         do
 703                 var res = new Buffer.with_cap(self.length)
 704                 var was_slash = false
 705                 for i in [0..length[ do
 706                         var c = chars[i]
 707                         if not was_slash then
 708                                 if c == '\\' then
 709                                         was_slash = true
 710                                 else
 711                                         res.add(c)
 712                                 end
 713                                 continue
 714                         end
 715                         was_slash = false
 716                         if c == 'n' then
 717                                 res.add('\n')
 718                         else if c == 'r' then
 719                                 res.add('\r')
 720                         else if c == 't' then
 721                                 res.add('\t')
 722                         else if c == '0' then
 723                                 res.add('\0')
 724                         else
 725                                 res.add(c)
 726                         end
 727                 end
 728                 return res.to_s
 729         end
 730
 731         # Returns `self` with all characters escaped with their UTF-16 representation
 732         #
 733         #     assert "Aèあ𐏓".escape_to_utf16 == "\\u0041\\u00e8\\u3042\\ud800\\udfd3"
 734         fun escape_to_utf16: String do
 735                 var buf = new Buffer
 736                 for i in chars do buf.append i.escape_to_utf16
 737                 return buf.to_s
 738         end
 739
 740         # Returns the Unicode char escaped by `self`
 741         #
 742         #     assert "\\u0041".from_utf16_escape == 'A'
 743         #     assert "\\ud800\\udfd3".from_utf16_escape == '𐏓'
 744         #     assert "\\u00e8".from_utf16_escape == 'è'
 745         #     assert "\\u3042".from_utf16_escape == 'あ'
 746         fun from_utf16_escape: Char do
 747                 var ln = length
 748                 if ln != 6 and ln != 12 then return 0xFFFD.code_point
 749                 var cphi = substring(2, 4).to_hex
 750                 if cphi < 0xD800 then return cphi.code_point
 751                 if cphi > 0xDFFF then return cphi.code_point
 752                 if cphi > 0xDBFF then return 0xFFFD.code_point
 753                 var cp = 0
 754                 cp += (cphi - 0xD800) << 10
 755                 var cplo = substring(8, 4).to_hex
 756                 if cplo < 0xDC00 then return 0xFFFD.code_point
 757                 if cplo > 0xDFFF then return 0xFFFD.code_point
 758                 cp += cplo - 0xDC00
 759                 cp += 0x10000
 760                 return cp.code_point
 761         end
 762
 763         # Encode `self` to percent (or URL) encoding
 764         #
 765         #     assert "aBc09-._~".to_percent_encoding == "aBc09-._~"
 766         #     assert "%()< >".to_percent_encoding == "%25%28%29%3c%20%3e"
 767         #     assert ".com/post?e=asdf&f=123".to_percent_encoding == ".com%2fpost%3fe%3dasdf%26f%3d123"
 768         #     assert "éあいう".to_percent_encoding == "%c3%a9%e3%81%82%e3%81%84%e3%81%86"
 769         fun to_percent_encoding: String
 770         do
 771                 var buf = new Buffer
 772
 773                 for i in [0..length[ do
 774                         var c = chars[i]
 775                         if (c >= '0' and c <= '9') or
 776                            (c >= 'a' and c <= 'z') or
 777                            (c >= 'A' and c <= 'Z') or
 778                            c == '-' or c == '.' or
 779                            c == '_' or c == '~'
 780                         then
 781                                 buf.add c
 782                         else
 783                                 var bytes = c.to_s.bytes
 784                                 for b in bytes do buf.append "%{b.to_i.to_hex}"
 785                         end
 786                 end
 787
 788                 return buf.to_s
 789         end
 790
 791         # Decode `self` from percent (or URL) encoding to a clear string
 792         #
 793         # Replace invalid use of '%' with '?'.
 794         #
 795         #     assert "aBc09-._~".from_percent_encoding == "aBc09-._~"
 796         #     assert "%25%28%29%3c%20%3e".from_percent_encoding == "%()< >"
 797         #     assert ".com%2fpost%3fe%3dasdf%26f%3d123".from_percent_encoding == ".com/post?e=asdf&f=123"
 798         #     assert "%25%28%29%3C%20%3E".from_percent_encoding == "%()< >"
 799         #     assert "incomplete %".from_percent_encoding == "incomplete ?"
 800         #     assert "invalid % usage".from_percent_encoding == "invalid ? usage"
 801         #     assert "%c3%a9%e3%81%82%e3%81%84%e3%81%86".from_percent_encoding == "éあいう"
 802         fun from_percent_encoding: String
 803         do
 804                 var len = bytelen
 805                 var has_percent = false
 806                 for c in chars do
 807                         if c == '%' then
 808                                 len -= 2
 809                                 has_percent = true
 810                         end
 811                 end
 812
 813                 # If no transformation is needed, return self as a string
 814                 if not has_percent then return to_s
 815
 816                 var buf = new NativeString(len)
 817                 var i = 0
 818                 var l = 0
 819                 while i < length do
 820                         var c = chars[i]
 821                         if c == '%' then
 822                                 if i + 2 >= length then
 823                                         # What follows % has been cut off
 824                                         buf[l] = '?'.ascii
 825                                 else
 826                                         i += 1
 827                                         var hex_s = substring(i, 2)
 828                                         if hex_s.is_hex then
 829                                                 var hex_i = hex_s.to_hex
 830                                                 buf[l] = hex_i.to_b
 831                                                 i += 1
 832                                         else
 833                                                 # What follows a % is not Hex
 834                                                 buf[l] = '?'.ascii
 835                                                 i -= 1
 836                                         end
 837                                 end
 838                         else buf[l] = c.ascii
 839
 840                         i += 1
 841                         l += 1
 842                 end
 843
 844                 return buf.to_s_with_length(l)
 845         end
 846
 847         # Escape the characters `<`, `>`, `&`, `"`, `'` and `/` as HTML/XML entity references.
 848         #
 849         #     assert "a&b-<>\"x\"/'".html_escape      ==  "a&amp;b-&lt;&gt;&#34;x&#34;&#47;&#39;"
 850         #
 851         # SEE: <https://www.owasp.org/index.php/XSS_%28Cross_Site_Scripting%29_Prevention_Cheat_Sheet#RULE_.231_-_HTML_Escape_Before_Inserting_Untrusted_Data_into_HTML_Element_Content>
 852         fun html_escape: String
 853         do
 854                 var buf = new Buffer
 855
 856                 for i in [0..length[ do
 857                         var c = chars[i]
 858                         if c == '&' then
 859                                 buf.append "&amp;"
 860                         else if c == '<' then
 861                                 buf.append "&lt;"
 862                         else if c == '>' then
 863                                 buf.append "&gt;"
 864                         else if c == '"' then
 865                                 buf.append "&#34;"
 866                         else if c == '\'' then
 867                                 buf.append "&#39;"
 868                         else if c == '/' then
 869                                 buf.append "&#47;"
 870                         else buf.add c
 871                 end
 872
 873                 return buf.to_s
 874         end
 875
 876         # Equality of text
 877         # Two pieces of text are equals if thez have the same characters in the same order.
 878         #
 879         #     assert "hello" == "hello"
 880         #     assert "hello" != "HELLO"
 881         #     assert "hello" == "hel"+"lo"
 882         #
 883         # Things that are not Text are not equal.
 884         #
 885         #     assert "9" != '9'
 886         #     assert "9" != ['9']
 887         #     assert "9" != 9
 888         #
 889         #     assert "9".chars.first == '9'   # equality of Char
 890         #     assert "9".chars       == ['9'] # equality of Sequence
 891         #     assert "9".to_i        == 9     # equality of Int
 892         redef fun ==(o)
 893         do
 894                 if o == null then return false
 895                 if not o isa Text then return false
 896                 if self.is_same_instance(o) then return true
 897                 if self.length != o.length then return false
 898                 return self.chars == o.chars
 899         end
 900
 901         # Lexicographical comparaison
 902         #
 903         #     assert "abc" < "xy"
 904         #     assert "ABC" < "abc"
 905         redef fun <(other)
 906         do
 907                 var self_chars = self.chars.iterator
 908                 var other_chars = other.chars.iterator
 909
 910                 while self_chars.is_ok and other_chars.is_ok do
 911                         if self_chars.item < other_chars.item then return true
 912                         if self_chars.item > other_chars.item then return false
 913                         self_chars.next
 914                         other_chars.next
 915                 end
 916
 917                 if self_chars.is_ok then
 918                         return false
 919                 else
 920                         return true
 921                 end
 922         end
 923
 924         # Escape string used in labels for graphviz
 925         #
 926         #   assert ">><<".escape_to_dot == "\\>\\>\\<\\<"
 927         fun escape_to_dot: String
 928         do
 929                 return escape_more_to_c("|\{\}<>")
 930         end
 931
 932         private var hash_cache: nullable Int = null
 933
 934         redef fun hash
 935         do
 936                 if hash_cache == null then
 937                         # djb2 hash algorithm
 938                         var h = 5381
 939
 940                         for i in [0..length[ do
 941                                 var char = chars[i]
 942                                 h = (h << 5) + h + char.code_point
 943                         end
 944
 945                         hash_cache = h
 946                 end
 947                 return hash_cache.as(not null)
 948         end
 949
 950         # Gives the formatted string back as a Nit string with `args` in place
 951         #
 952         #     assert "This %1 is a %2.".format("String", "formatted String") == "This String is a formatted String."
 953         #     assert "\\%1 This string".format("String") == "\\%1 This string"
 954         fun format(args: Object...): String do
 955                 var s = new Array[Text]
 956                 var curr_st = 0
 957                 var i = 0
 958                 while i < length do
 959                         # Skip escaped characters
 960                         if self[i] == '\\' then
 961                                 i += 1
 962                         # In case of format
 963                         else if self[i] == '%' then
 964                                 var fmt_st = i
 965                                 i += 1
 966                                 var ciph_st = i
 967                                 while i < length and self[i].is_numeric do
 968                                         i += 1
 969                                 end
 970                                 i -= 1
 971                                 var fmt_end = i
 972                                 var ciph_len = fmt_end - ciph_st + 1
 973
 974                                 var arg_index = substring(ciph_st, ciph_len).to_i - 1
 975                                 if arg_index >= args.length then continue
 976
 977                                 s.push substring(curr_st, fmt_st - curr_st)
 978                                 s.push args[arg_index].to_s
 979                                 curr_st = i + 1
 980                         end
 981                         i += 1
 982                 end
 983                 s.push substring(curr_st, length - curr_st)
 984                 return s.plain_to_s
 985         end
 986
 987         # Copies `n` bytes from `self` at `src_offset` into `dest` starting at `dest_offset`
 988         #
 989         # Basically a high-level synonym of NativeString::copy_to
 990         #
 991         # REQUIRE: `n` must be large enough to contain `len` bytes
 992         #
 993         #       var ns = new NativeString(8)
 994         #       "Text is String".copy_to_native(ns, 8, 2, 0)
 995         #       assert ns.to_s_with_length(8) == "xt is St"
 996         #
 997         fun copy_to_native(dest: NativeString, n, src_offset, dest_offset: Int) do
 998                 var mypos = src_offset
 999                 var itspos = dest_offset
1000                 while n > 0 do
1001                         dest[itspos] = self.bytes[mypos]
1002                         itspos += 1
1003                         mypos += 1
1004                         n -= 1
1005                 end
1006         end
1007
1008 end
1009
1010 # All kinds of array-based text representations.
1011 abstract class FlatText
1012         super Text
1013
1014         # Underlying C-String (`char*`)
1015         #
1016         # Warning : Might be void in some subclasses, be sure to check
1017         # if set before using it.
1018         var items: NativeString is noinit
1019
1020         # Returns a char* starting at position `first_byte`
1021         #
1022         # WARNING: If you choose to use this service, be careful of the following.
1023         #
1024         # Strings and NativeString are *ideally* always allocated through a Garbage Collector.
1025         # Since the GC tracks the use of the pointer for the beginning of the char*, it may be
1026         # deallocated at any moment, rendering the pointer returned by this function invalid.
1027         # Any access to freed memory may very likely cause undefined behaviour or a crash.
1028         # (Failure to do so will most certainly result in long and painful debugging hours)
1029         #
1030         # The only safe use of this pointer is if it is ephemeral (e.g. read in a C function
1031         # then immediately return).
1032         #
1033         # As always, do not modify the content of the String in C code, if this is what you want
1034         # copy locally the char* as Nit Strings are immutable.
1035         fun fast_cstring: NativeString is abstract
1036
1037         redef var length = 0
1038
1039         redef var bytelen = 0
1040
1041         redef fun output
1042         do
1043                 var i = 0
1044                 while i < length do
1045                         items[i].output
1046                         i += 1
1047                 end
1048         end
1049
1050         redef fun copy_to_native(dest, n, src_offset, dest_offset) do
1051                 items.copy_to(dest, n, src_offset, dest_offset)
1052         end
1053 end
1054
1055 # Abstract class for the SequenceRead compatible
1056 # views on the chars of any Text
1057 private abstract class StringCharView
1058         super SequenceRead[Char]
1059
1060         type SELFTYPE: Text
1061
1062         var target: SELFTYPE
1063
1064         redef fun is_empty do return target.is_empty
1065
1066         redef fun length do return target.length
1067
1068         redef fun iterator: IndexedIterator[Char] do return self.iterator_from(0)
1069
1070         redef fun reverse_iterator do return self.reverse_iterator_from(self.length - 1)
1071 end
1072
1073 # Abstract class for the SequenceRead compatible
1074 # views on the bytes of any Text
1075 private abstract class StringByteView
1076         super SequenceRead[Byte]
1077
1078         type SELFTYPE: Text
1079
1080         var target: SELFTYPE
1081
1082         redef fun is_empty do return target.is_empty
1083
1084         redef fun length do return target.bytelen
1085
1086         redef fun iterator do return self.iterator_from(0)
1087
1088         redef fun reverse_iterator do return self.reverse_iterator_from(target.bytelen - 1)
1089 end
1090
1091 # Immutable sequence of characters.
1092 #
1093 # String objects may be created using literals.
1094 #
1095 #     assert "Hello World!" isa String
1096 abstract class String
1097         super Text
1098
1099         redef type SELFTYPE: String is fixed
1100
1101         redef fun to_s do return self
1102
1103         # Concatenates `o` to `self`
1104         #
1105         #     assert "hello" + "world"  == "helloworld"
1106         #     assert "" + "hello" + ""  == "hello"
1107         fun +(o: Text): SELFTYPE is abstract
1108
1109         # Concatenates self `i` times
1110         #
1111         #     assert "abc" * 4 == "abcabcabcabc"
1112         #     assert "abc" * 1 == "abc"
1113         #     assert "abc" * 0 == ""
1114         fun *(i: Int): SELFTYPE is abstract
1115
1116         # Insert `s` at `pos`.
1117         #
1118         #     assert "helloworld".insert_at(" ", 5)     == "hello world"
1119         fun insert_at(s: String, pos: Int): SELFTYPE is abstract
1120
1121         redef fun substrings is abstract
1122
1123         # Returns a reversed version of self
1124         #
1125         #     assert "hello".reversed  == "olleh"
1126         #     assert "bob".reversed    == "bob"
1127         #     assert "".reversed       == ""
1128         fun reversed: SELFTYPE is abstract
1129
1130         # A upper case version of `self`
1131         #
1132         #     assert "Hello World!".to_upper     == "HELLO WORLD!"
1133         fun to_upper: SELFTYPE is abstract
1134
1135         # A lower case version of `self`
1136         #
1137         #     assert "Hello World!".to_lower     == "hello world!"
1138         fun to_lower : SELFTYPE is abstract
1139
1140         # Takes a camel case `self` and converts it to snake case
1141         #
1142         #     assert "randomMethodId".to_snake_case == "random_method_id"
1143         #
1144         # The rules are the following:
1145         #
1146         # An uppercase is always converted to a lowercase
1147         #
1148         #     assert "HELLO_WORLD".to_snake_case == "hello_world"
1149         #
1150         # An uppercase that follows a lowercase is prefixed with an underscore
1151         #
1152         #     assert "HelloTheWORLD".to_snake_case == "hello_the_world"
1153         #
1154         # An uppercase that follows an uppercase and is followed by a lowercase, is prefixed with an underscore
1155         #
1156         #     assert "HelloTHEWorld".to_snake_case == "hello_the_world"
1157         #
1158         # All other characters are kept as is; `self` does not need to be a proper CamelCased string.
1159         #
1160         #     assert "=-_H3ll0Th3W0rld_-=".to_snake_case == "=-_h3ll0th3w0rld_-="
1161         fun to_snake_case: SELFTYPE
1162         do
1163                 if self.is_lower then return self
1164
1165                 var new_str = new Buffer.with_cap(self.length)
1166                 var prev_is_lower = false
1167                 var prev_is_upper = false
1168
1169                 for i in [0..length[ do
1170                         var char = chars[i]
1171                         if char.is_lower then
1172                                 new_str.add(char)
1173                                 prev_is_lower = true
1174                                 prev_is_upper = false
1175                         else if char.is_upper then
1176                                 if prev_is_lower then
1177                                         new_str.add('_')
1178                                 else if prev_is_upper and i+1 < length and chars[i+1].is_lower then
1179                                         new_str.add('_')
1180                                 end
1181                                 new_str.add(char.to_lower)
1182                                 prev_is_lower = false
1183                                 prev_is_upper = true
1184                         else
1185                                 new_str.add(char)
1186                                 prev_is_lower = false
1187                                 prev_is_upper = false
1188                         end
1189                 end
1190
1191                 return new_str.to_s
1192         end
1193
1194         # Takes a snake case `self` and converts it to camel case
1195         #
1196         #     assert "random_method_id".to_camel_case == "randomMethodId"
1197         #
1198         # If the identifier is prefixed by an underscore, the underscore is ignored
1199         #
1200         #     assert "_private_field".to_camel_case == "_privateField"
1201         #
1202         # If `self` is upper, it is returned unchanged
1203         #
1204         #     assert "RANDOM_ID".to_camel_case == "RANDOM_ID"
1205         #
1206         # If there are several consecutive underscores, they are considered as a single one
1207         #
1208         #     assert "random__method_id".to_camel_case == "randomMethodId"
1209         fun to_camel_case: SELFTYPE
1210         do
1211                 if self.is_upper then return self
1212
1213                 var new_str = new Buffer
1214                 var is_first_char = true
1215                 var follows_us = false
1216
1217                 for i in [0..length[ do
1218                         var char = chars[i]
1219                         if is_first_char then
1220                                 new_str.add(char)
1221                                 is_first_char = false
1222                         else if char == '_' then
1223                                 follows_us = true
1224                         else if follows_us then
1225                                 new_str.add(char.to_upper)
1226                                 follows_us = false
1227                         else
1228                                 new_str.add(char)
1229                         end
1230                 end
1231
1232                 return new_str.to_s
1233         end
1234
1235         # Returns a capitalized `self`
1236         #
1237         # Letters that follow a letter are lowercased
1238         # Letters that follow a non-letter are upcased.
1239         #
1240         # SEE : `Char::is_letter` for the definition of letter.
1241         #
1242         #     assert "jAVASCRIPT".capitalized == "Javascript"
1243         #     assert "i am root".capitalized == "I Am Root"
1244         #     assert "ab_c -ab0c ab\nc".capitalized == "Ab_C -Ab0C Ab\nC"
1245         fun capitalized: SELFTYPE do
1246                 if length == 0 then return self
1247
1248                 var buf = new Buffer.with_cap(length)
1249
1250                 var curr = chars[0].to_upper
1251                 var prev = curr
1252                 buf[0] = curr
1253
1254                 for i in [1 .. length[ do
1255                         prev = curr
1256                         curr = self[i]
1257                         if prev.is_letter then
1258                                 buf[i] = curr.to_lower
1259                         else
1260                                 buf[i] = curr.to_upper
1261                         end
1262                 end
1263
1264                 return buf.to_s
1265         end
1266 end
1267
1268 # A mutable sequence of characters.
1269 abstract class Buffer
1270         super Text
1271
1272         # Returns an arbitrary subclass of `Buffer` with default parameters
1273         new is abstract
1274
1275         # Returns an instance of a subclass of `Buffer` with `i` base capacity
1276         new with_cap(i: Int) is abstract
1277
1278         redef type SELFTYPE: Buffer is fixed
1279
1280         # Specific implementations MUST set this to `true` in order to invalidate caches
1281         protected var is_dirty = true
1282
1283         # Copy-On-Write flag
1284         #
1285         # If the `Buffer` was to_s'd, the next in-place altering
1286         # operation will cause the current `Buffer` to be re-allocated.
1287         #
1288         # The flag will then be set at `false`.
1289         protected var written = false
1290
1291         # Modifies the char contained at pos `index`
1292         #
1293         # DEPRECATED : Use self.chars.[]= instead
1294         fun []=(index: Int, item: Char) is abstract
1295
1296         # Adds a char `c` at the end of self
1297         #
1298         # DEPRECATED : Use self.chars.add instead
1299         fun add(c: Char) is abstract
1300
1301         # Clears the buffer
1302         #
1303         #     var b = new Buffer
1304         #     b.append "hello"
1305         #     assert not b.is_empty
1306         #     b.clear
1307         #     assert b.is_empty
1308         fun clear is abstract
1309
1310         # Enlarges the subsequent array containing the chars of self
1311         fun enlarge(cap: Int) is abstract
1312
1313         # Adds the content of text `s` at the end of self
1314         #
1315         #     var b = new Buffer
1316         #     b.append "hello"
1317         #     b.append "world"
1318         #     assert b == "helloworld"
1319         fun append(s: Text) is abstract
1320
1321         # `self` is appended in such a way that `self` is repeated `r` times
1322         #
1323         #     var b = new Buffer
1324         #     b.append "hello"
1325         #     b.times 3
1326         #     assert b == "hellohellohello"
1327         fun times(r: Int) is abstract
1328
1329         # Reverses itself in-place
1330         #
1331         #     var b = new Buffer
1332         #     b.append("hello")
1333         #     b.reverse
1334         #     assert b == "olleh"
1335         fun reverse is abstract
1336
1337         # Changes each lower-case char in `self` by its upper-case variant
1338         #
1339         #     var b = new Buffer
1340         #     b.append("Hello World!")
1341         #     b.upper
1342         #     assert b == "HELLO WORLD!"
1343         fun upper is abstract
1344
1345         # Changes each upper-case char in `self` by its lower-case variant
1346         #
1347         #     var b = new Buffer
1348         #     b.append("Hello World!")
1349         #     b.lower
1350         #     assert b == "hello world!"
1351         fun lower is abstract
1352
1353         # Capitalizes each word in `self`
1354         #
1355         # Letters that follow a letter are lowercased
1356         # Letters that follow a non-letter are upcased.
1357         #
1358         # SEE: `Char::is_letter` for the definition of a letter.
1359         #
1360         #     var b = new FlatBuffer.from("jAVAsCriPt")
1361         #     b.capitalize
1362         #     assert b == "Javascript"
1363         #     b = new FlatBuffer.from("i am root")
1364         #     b.capitalize
1365         #     assert b == "I Am Root"
1366         #     b = new FlatBuffer.from("ab_c -ab0c ab\nc")
1367         #     b.capitalize
1368         #     assert b == "Ab_C -Ab0C Ab\nC"
1369         fun capitalize do
1370                 if length == 0 then return
1371                 var c = self[0].to_upper
1372                 self[0] = c
1373                 var prev = c
1374                 for i in [1 .. length[ do
1375                         prev = c
1376                         c = self[i]
1377                         if prev.is_letter then
1378                                 self[i] = c.to_lower
1379                         else
1380                                 self[i] = c.to_upper
1381                         end
1382                 end
1383         end
1384
1385         redef fun hash
1386         do
1387                 if is_dirty then hash_cache = null
1388                 return super
1389         end
1390
1391         # In Buffers, the internal sequence of character is mutable
1392         # Thus, `chars` can be used to modify the buffer.
1393         redef fun chars: Sequence[Char] is abstract
1394 end
1395
1396 # View for chars on Buffer objects, extends Sequence
1397 # for mutation operations
1398 private abstract class BufferCharView
1399         super StringCharView
1400         super Sequence[Char]
1401
1402         redef type SELFTYPE: Buffer
1403
1404 end
1405
1406 # View for bytes on Buffer objects, extends Sequence
1407 # for mutation operations
1408 private abstract class BufferByteView
1409         super StringByteView
1410
1411         redef type SELFTYPE: Buffer
1412 end
1413
1414 redef class Object
1415         # User readable representation of `self`.
1416         fun to_s: String do return inspect
1417
1418         # The class name of the object in NativeString format.
1419         private fun native_class_name: NativeString is intern
1420
1421         # The class name of the object.
1422         #
1423         #     assert 5.class_name == "Int"
1424         fun class_name: String do return native_class_name.to_s
1425
1426         # Developer readable representation of `self`.
1427         # Usually, it uses the form "<CLASSNAME:#OBJECTID bla bla bla>"
1428         fun inspect: String
1429         do
1430                 return "<{inspect_head}>"
1431         end
1432
1433         # Return "CLASSNAME:#OBJECTID".
1434         # This function is mainly used with the redefinition of the inspect method
1435         protected fun inspect_head: String
1436         do
1437                 return "{class_name}:#{object_id.to_hex}"
1438         end
1439 end
1440
1441 redef class Bool
1442         #     assert true.to_s         == "true"
1443         #     assert false.to_s        == "false"
1444         redef fun to_s
1445         do
1446                 if self then
1447                         return once "true"
1448                 else
1449                         return once "false"
1450                 end
1451         end
1452 end
1453
1454 redef class Byte
1455         # C function to calculate the length of the `NativeString` to receive `self`
1456         private fun byte_to_s_len: Int `{
1457                 return snprintf(NULL, 0, "0x%02x", self);
1458         `}
1459
1460         # C function to convert an nit Int to a NativeString (char*)
1461         private fun native_byte_to_s(nstr: NativeString, strlen: Int) `{
1462                 snprintf(nstr, strlen, "0x%02x", self);
1463         `}
1464
1465         # Displayable byte in its hexadecimal form (0x..)
1466         #
1467         #     assert 1.to_b.to_s       == "0x01"
1468         #     assert (-123).to_b.to_s  == "0x85"
1469         redef fun to_s do
1470                 var nslen = byte_to_s_len
1471                 var ns = new NativeString(nslen + 1)
1472                 ns[nslen] = 0u8
1473                 native_byte_to_s(ns, nslen + 1)
1474                 return ns.to_s_with_length(nslen)
1475         end
1476 end
1477
1478 redef class Int
1479
1480         # Wrapper of strerror C function
1481         private fun strerror_ext: NativeString `{ return strerror(self); `}
1482
1483         # Returns a string describing error number
1484         fun strerror: String do return strerror_ext.to_s
1485
1486         # Fill `s` with the digits in base `base` of `self` (and with the '-' sign if 'signed' and negative).
1487         # assume < to_c max const of char
1488         private fun fill_buffer(s: Buffer, base: Int, signed: Bool)
1489         do
1490                 var n: Int
1491                 # Sign
1492                 if self < 0 then
1493                         n = - self
1494                         s.chars[0] = '-'
1495                 else if self == 0 then
1496                         s.chars[0] = '0'
1497                         return
1498                 else
1499                         n = self
1500                 end
1501                 # Fill digits
1502                 var pos = digit_count(base) - 1
1503                 while pos >= 0 and n > 0 do
1504                         s.chars[pos] = (n % base).to_c
1505                         n = n / base # /
1506                         pos -= 1
1507                 end
1508         end
1509
1510         # C function to calculate the length of the `NativeString` to receive `self`
1511         private fun int_to_s_len: Int `{
1512                 return snprintf(NULL, 0, "%ld", self);
1513         `}
1514
1515         # C function to convert an nit Int to a NativeString (char*)
1516         private fun native_int_to_s(nstr: NativeString, strlen: Int) `{
1517                 snprintf(nstr, strlen, "%ld", self);
1518         `}
1519
1520         # return displayable int in base base and signed
1521         fun to_base(base: Int, signed: Bool): String is abstract
1522
1523         # return displayable int in hexadecimal
1524         #
1525         #     assert 1.to_hex  == "1"
1526         #     assert (-255).to_hex  == "-ff"
1527         fun to_hex: String do return to_base(16,false)
1528 end
1529
1530 redef class Float
1531         # Pretty representation of `self`, with decimals as needed from 1 to a maximum of 3
1532         #
1533         #     assert 12.34.to_s       == "12.34"
1534         #     assert (-0120.030).to_s == "-120.03"
1535         #
1536         # see `to_precision` for a custom precision.
1537         redef fun to_s do
1538                 var str = to_precision( 3 )
1539                 if is_inf != 0 or is_nan then return str
1540                 var len = str.length
1541                 for i in [0..len-1] do
1542                         var j = len-1-i
1543                         var c = str.chars[j]
1544                         if c == '0' then
1545                                 continue
1546                         else if c == '.' then
1547                                 return str.substring( 0, j+2 )
1548                         else
1549                                 return str.substring( 0, j+1 )
1550                         end
1551                 end
1552                 return str
1553         end
1554
1555         # `String` representation of `self` with the given number of `decimals`
1556         #
1557         #     assert 12.345.to_precision(0)    == "12"
1558         #     assert 12.345.to_precision(3)    == "12.345"
1559         #     assert (-12.345).to_precision(3) == "-12.345"
1560         #     assert (-0.123).to_precision(3)  == "-0.123"
1561         #     assert 0.999.to_precision(2)     == "1.00"
1562         #     assert 0.999.to_precision(4)     == "0.9990"
1563         fun to_precision(decimals: Int): String
1564         do
1565                 if is_nan then return "nan"
1566
1567                 var isinf = self.is_inf
1568                 if isinf == 1 then
1569                         return "inf"
1570                 else if isinf == -1 then
1571                         return  "-inf"
1572                 end
1573
1574                 if decimals == 0 then return self.to_i.to_s
1575                 var f = self
1576                 for i in [0..decimals[ do f = f * 10.0
1577                 if self > 0.0 then
1578                         f = f + 0.5
1579                 else
1580                         f = f - 0.5
1581                 end
1582                 var i = f.to_i
1583                 if i == 0 then return "0." + "0"*decimals
1584
1585                 # Prepare both parts of the float, before and after the "."
1586                 var s = i.abs.to_s
1587                 var sl = s.length
1588                 var p1
1589                 var p2
1590                 if sl > decimals then
1591                         # Has something before the "."
1592                         p1 = s.substring(0, sl-decimals)
1593                         p2 = s.substring(sl-decimals, decimals)
1594                 else
1595                         p1 = "0"
1596                         p2 = "0"*(decimals-sl) + s
1597                 end
1598
1599                 if i < 0 then p1 = "-" + p1
1600
1601                 return p1 + "." + p2
1602         end
1603 end
1604
1605 redef class Char
1606
1607         # Returns a sequence with the UTF-8 bytes of `self`
1608         #
1609         #     assert 'a'.bytes == [0x61u8]
1610         #     assert 'ま'.bytes == [0xE3u8, 0x81u8, 0xBEu8]
1611         fun bytes: SequenceRead[Byte] do return to_s.bytes
1612
1613         # Is `self` an UTF-16 surrogate pair ?
1614         fun is_surrogate: Bool do
1615                 var cp = code_point
1616                 return cp >= 0xD800 and cp <= 0xDFFF
1617         end
1618
1619         # Length of `self` in a UTF-8 String
1620         private fun u8char_len: Int do
1621                 var c = self.code_point
1622                 if c < 0x80 then return 1
1623                 if c <= 0x7FF then return 2
1624                 if c <= 0xFFFF then return 3
1625                 if c <= 0x10FFFF then return 4
1626                 # Bad character format
1627                 return 1
1628         end
1629
1630         #     assert 'x'.to_s    == "x"
1631         redef fun to_s do
1632                 var ln = u8char_len
1633                 var ns = new NativeString(ln + 1)
1634                 u8char_tos(ns, ln)
1635                 return ns.to_s_with_length(ln)
1636         end
1637
1638         # Returns `self` escaped to UTF-16
1639         #
1640         # i.e. Represents `self`.`code_point` using UTF-16 codets escaped
1641         # with a `\u`
1642         #
1643         #     assert 'A'.escape_to_utf16 == "\\u0041"
1644         #     assert 'è'.escape_to_utf16 == "\\u00e8"
1645         #     assert 'あ'.escape_to_utf16 == "\\u3042"
1646         #     assert '𐏓'.escape_to_utf16 == "\\ud800\\udfd3"
1647         fun escape_to_utf16: String do
1648                 var cp = code_point
1649                 var buf: Buffer
1650                 if cp < 0xD800 or (cp >= 0xE000 and cp <= 0xFFFF) then
1651                         buf = new Buffer.with_cap(6)
1652                         buf.append("\\u0000")
1653                         var hx = cp.to_hex
1654                         var outid = 5
1655                         for i in hx.chars.reverse_iterator do
1656                                 buf[outid] = i
1657                                 outid -= 1
1658                         end
1659                 else
1660                         buf = new Buffer.with_cap(12)
1661                         buf.append("\\u0000\\u0000")
1662                         var lo = (((cp - 0x10000) & 0x3FF) + 0xDC00).to_hex
1663                         var hi = ((((cp - 0x10000) & 0xFFC00) >> 10) + 0xD800).to_hex
1664                         var out = 2
1665                         for i in hi do
1666                                 buf[out] = i
1667                                 out += 1
1668                         end
1669                         out = 8
1670                         for i in lo do
1671                                 buf[out] = i
1672                                 out += 1
1673                         end
1674                 end
1675                 return buf.to_s
1676         end
1677
1678         private fun u8char_tos(r: NativeString, len: Int) `{
1679                 r[len] = '\0';
1680                 switch(len){
1681                         case 1:
1682                                 r[0] = self;
1683                                 break;
1684                         case 2:
1685                                 r[0] = 0xC0 | ((self & 0x7C0) >> 6);
1686                                 r[1] = 0x80 | (self & 0x3F);
1687                                 break;
1688                         case 3:
1689                                 r[0] = 0xE0 | ((self & 0xF000) >> 12);
1690                                 r[1] = 0x80 | ((self & 0xFC0) >> 6);
1691                                 r[2] = 0x80 | (self & 0x3F);
1692                                 break;
1693                         case 4:
1694                                 r[0] = 0xF0 | ((self & 0x1C0000) >> 18);
1695                                 r[1] = 0x80 | ((self & 0x3F000) >> 12);
1696                                 r[2] = 0x80 | ((self & 0xFC0) >> 6);
1697                                 r[3] = 0x80 | (self & 0x3F);
1698                                 break;
1699                 }
1700         `}
1701
1702         # Returns true if the char is a numerical digit
1703         #
1704         #     assert '0'.is_numeric
1705         #     assert '9'.is_numeric
1706         #     assert not 'a'.is_numeric
1707         #     assert not '?'.is_numeric
1708         #
1709         # FIXME: Works on ASCII-range only
1710         fun is_numeric: Bool
1711         do
1712                 return self >= '0' and self <= '9'
1713         end
1714
1715         # Returns true if the char is an alpha digit
1716         #
1717         #     assert 'a'.is_alpha
1718         #     assert 'Z'.is_alpha
1719         #     assert not '0'.is_alpha
1720         #     assert not '?'.is_alpha
1721         #
1722         # FIXME: Works on ASCII-range only
1723         fun is_alpha: Bool
1724         do
1725                 return (self >= 'a' and self <= 'z') or (self >= 'A' and self <= 'Z')
1726         end
1727
1728         # Is `self` an hexadecimal digit ?
1729         #
1730         #     assert 'A'.is_hexdigit
1731         #     assert not 'G'.is_hexdigit
1732         #     assert 'a'.is_hexdigit
1733         #     assert not 'g'.is_hexdigit
1734         #     assert '5'.is_hexdigit
1735         fun is_hexdigit: Bool do return (self >= '0' and self <= '9') or (self >= 'A' and self <= 'F') or
1736                                         (self >= 'a' and self <= 'f')
1737
1738         # Returns true if the char is an alpha or a numeric digit
1739         #
1740         #     assert 'a'.is_alphanumeric
1741         #     assert 'Z'.is_alphanumeric
1742         #     assert '0'.is_alphanumeric
1743         #     assert '9'.is_alphanumeric
1744         #     assert not '?'.is_alphanumeric
1745         #
1746         # FIXME: Works on ASCII-range only
1747         fun is_alphanumeric: Bool
1748         do
1749                 return self.is_numeric or self.is_alpha
1750         end
1751
1752         # Returns `self` to its int value
1753         #
1754         # REQUIRE: `is_hexdigit`
1755         fun from_hex: Int do
1756                 if self >= '0' and self <= '9' then return code_point - 0x30
1757                 if self >= 'A' and self <= 'F' then return code_point - 0x37
1758                 if self >= 'a' and self <= 'f' then return code_point - 0x57
1759                 # Happens if self is not a hexdigit
1760                 assert self.is_hexdigit
1761                 # To make flow analysis happy
1762                 abort
1763         end
1764 end
1765
1766 redef class Collection[E]
1767         # String representation of the content of the collection.
1768         #
1769         # The standard representation is the list of elements separated with commas.
1770         #
1771         # ~~~
1772         # assert [1,2,3].to_s == "[1,2,3]"
1773         # assert [1..3].to_s  == "[1,2,3]"
1774         # assert (new Array[Int]).to_s == "[]" # empty collection
1775         # ~~~
1776         #
1777         # Subclasses may return a more specific string representation.
1778         redef fun to_s
1779         do
1780                 return "[" + join(",") + "]"
1781         end
1782
1783         # Concatenate elements without separators
1784         #
1785         # ~~~
1786         # assert [1,2,3].plain_to_s == "123"
1787         # assert [11..13].plain_to_s  == "111213"
1788         # assert (new Array[Int]).plain_to_s == "" # empty collection
1789         # ~~~
1790         fun plain_to_s: String
1791         do
1792                 var s = new Buffer
1793                 for e in self do if e != null then s.append(e.to_s)
1794                 return s.to_s
1795         end
1796
1797         # Concatenate and separate each elements with `separator`.
1798         #
1799         # Only concatenate if `separator == null`.
1800         #
1801         #     assert [1, 2, 3].join(":")    == "1:2:3"
1802         #     assert [1..3].join(":")       == "1:2:3"
1803         #     assert [1..3].join            == "123"
1804         fun join(separator: nullable Text): String
1805         do
1806                 if is_empty then return ""
1807
1808                 var s = new Buffer # Result
1809
1810                 # Concat first item
1811                 var i = iterator
1812                 var e = i.item
1813                 if e != null then s.append(e.to_s)
1814
1815                 # Concat other items
1816                 i.next
1817                 while i.is_ok do
1818                         if separator != null then s.append(separator)
1819                         e = i.item
1820                         if e != null then s.append(e.to_s)
1821                         i.next
1822                 end
1823                 return s.to_s
1824         end
1825 end
1826
1827 redef class Map[K,V]
1828         # Concatenate couples of key value.
1829         # Key and value are separated by `couple_sep`.
1830         # Couples are separated by `sep`.
1831         #
1832         #     var m = new HashMap[Int, String]
1833         #     m[1] = "one"
1834         #     m[10] = "ten"
1835         #     assert m.join("; ", "=") == "1=one; 10=ten"
1836         fun join(sep, couple_sep: String): String is abstract
1837 end
1838
1839 redef class Sys
1840         private var args_cache: nullable Sequence[String] = null
1841
1842         # The arguments of the program as given by the OS
1843         fun program_args: Sequence[String]
1844         do
1845                 if _args_cache == null then init_args
1846                 return _args_cache.as(not null)
1847         end
1848
1849         # The name of the program as given by the OS
1850         fun program_name: String
1851         do
1852                 return native_argv(0).to_s
1853         end
1854
1855         # Initialize `program_args` with the contents of `native_argc` and `native_argv`.
1856         private fun init_args
1857         do
1858                 var argc = native_argc
1859                 var args = new Array[String].with_capacity(0)
1860                 var i = 1
1861                 while i < argc do
1862                         args[i-1] = native_argv(i).to_s
1863                         i += 1
1864                 end
1865                 _args_cache = args
1866         end
1867
1868         # First argument of the main C function.
1869         private fun native_argc: Int is intern
1870
1871         # Second argument of the main C function.
1872         private fun native_argv(i: Int): NativeString is intern
1873 end
1874
1875 # Comparator that efficienlty use `to_s` to compare things
1876 #
1877 # The comparaison call `to_s` on object and use the result to order things.
1878 #
1879 #     var a = [1, 2, 3, 10, 20]
1880 #     (new CachedAlphaComparator).sort(a)
1881 #     assert a == [1, 10, 2, 20, 3]
1882 #
1883 # Internally the result of `to_s` is cached in a HashMap to counter
1884 # uneficient implementation of `to_s`.
1885 #
1886 # Note: it caching is not usefull, see `alpha_comparator`
1887 class CachedAlphaComparator
1888         super Comparator
1889         redef type COMPARED: Object
1890
1891         private var cache = new HashMap[Object, String]
1892
1893         private fun do_to_s(a: Object): String do
1894                 if cache.has_key(a) then return cache[a]
1895                 var res = a.to_s
1896                 cache[a] = res
1897                 return res
1898         end
1899
1900         redef fun compare(a, b) do
1901                 return do_to_s(a) <=> do_to_s(b)
1902         end
1903 end
1904
1905 # see `alpha_comparator`
1906 private class AlphaComparator
1907         super Comparator
1908         redef fun compare(a, b) do return a.to_s <=> b.to_s
1909 end
1910
1911 # Stateless comparator that naively use `to_s` to compare things.
1912 #
1913 # Note: the result of `to_s` is not cached, thus can be invoked a lot
1914 # on a single instace. See `CachedAlphaComparator` as an alternative.
1915 #
1916 #     var a = [1, 2, 3, 10, 20]
1917 #     alpha_comparator.sort(a)
1918 #     assert a == [1, 10, 2, 20, 3]
1919 fun alpha_comparator: Comparator do return once new AlphaComparator
1920
1921 # The arguments of the program as given by the OS
1922 fun args: Sequence[String]
1923 do
1924         return sys.program_args
1925 end
1926
1927 redef class NativeString
1928         # Returns `self` as a new String.
1929         fun to_s_with_copy: String is abstract
1930
1931         # Returns `self` as a String of `length`.
1932         fun to_s_with_length(length: Int): String is abstract
1933
1934         # Returns `self` as a String with `bytelen` and `length` set
1935         #
1936         # SEE: `abstract_text::Text` for more infos on the difference
1937         # between `Text::bytelen` and `Text::length`
1938         fun to_s_full(bytelen, unilen: Int): String is abstract
1939 end
1940
1941 redef class NativeArray[E]
1942         # Join all the elements using `to_s`
1943         #
1944         # REQUIRE: `self isa NativeArray[String]`
1945         # REQUIRE: all elements are initialized
1946         fun native_to_s: String is abstract
1947 end