lib/popcorn/pop_tests.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Popcorn testing services
  16 #
  17 # ## Blackbox testing
  18 #
  19 # Popcorn allows you to test your apps using nitunit blackbox testing.
  20 #
  21 # With blackbox testing you compare the output of your program with a result file.
  22 #
  23 # To get started with blackbox testing, create a nitunit test suite and imports
  24 # the `pop_tests` module.
  25 #
  26 # You then need to build the app that will be tested by nitunit as shown in the
  27 # `test_example_hello` method.
  28 # Calling `run_test` will automatically set the `host` and `port` used for testing.
  29 #
  30 # Redefine the `client_test` method to write your scenario.
  31 # Here we use `curl` to access some URI on the app.
  32 #
  33 # ~~~nitish
  34 # module test_example_hello is test
  35 #
  36 # import pop_tests
  37 # import example_hello
  38 #
  39 # class TestExampleHello
  40 #       super TestPopcorn
  41 #       test
  42 #
  43 #       fun example_hello is test do
  44 #               var app = new App
  45 #               app.use("/", new HelloHandler)
  46 #               run_test(app)
  47 #       end
  48 #
  49 #       redef fun client_test do
  50 #               system "curl -s {host}:{port}"
  51 #               system "curl -s {host}:{port}/"
  52 #               system "curl -s {host}:{port}///////////"
  53 #               system "curl -s {host}:{port}/not_found"
  54 #               system "curl -s {host}:{port}/not_found/not_found"
  55 #       end
  56 # end
  57 # ~~~
  58 #
  59 # The blackbox testing needs a reference result file against wich the test output
  60 # will be compared.
  61 # Create your expected result file in `test_example_hello.sav/test_example_hello.res`.
  62 #
  63 # Test your app by running nitunit:
  64 #
  65 # ~~~bash
  66 # nitunit ./example_hello.nit
  67 # ~~~
  68 #
  69 # See `examples/hello_world` for the complete example.
  70 module pop_tests
  71
  72 import popcorn
  73 import pthreads
  74
  75 redef class Sys
  76
  77         # Use localhost for testing
  78         var test_host = "localhost"
  79
  80         # Return a new port for each instance
  81         fun test_port: Int do
  82                 return testing_id % 20000 + 10000
  83         end
  84
  85         # Nitdoc testing ID
  86         fun testing_id: Int do return "NIT_TESTING_ID".environ.to_i
  87 end
  88
  89 # Thread running the App to test.
  90 class AppThread
  91         super Thread
  92
  93         # Host used by tested App.
  94         var host: String
  95
  96         # Port used by tested App.
  97         var port: Int
  98
  99         # App to test.
 100         var app: App
 101
 102         redef fun main
 103         do
 104                 # Hide testing concept to force nitcorn to actually run
 105                 "NIT_TESTING".setenv("false")
 106                 app.quiet = true
 107                 app.listen(host, port)
 108                 return null
 109         end
 110 end
 111
 112 # Thread running the test client.
 113 class ClientThread
 114         super Thread
 115
 116         # Test suite to execute.
 117         var test_suite: TestPopcorn
 118
 119         redef fun main do
 120                 test_suite.client_test
 121                 print ""
 122                 return null
 123         end
 124 end
 125
 126 # TestSuite for Popcorn blackbox testing.
 127 class TestPopcorn
 128
 129         # Host used to run App.
 130         var host: String = test_host
 131
 132         # Port used to run App.
 133         var port: Int = test_port
 134
 135         # Directory of the current test suite
 136         #
 137         # Useful when your tested app need to load some external files.
 138         var test_path: String = "NIT_TESTING_PATH".environ.dirname
 139
 140         # Run the test suite on the App.
 141         fun run_test(app: App) do
 142                 var server = new AppThread(host, port, app)
 143                 server.start
 144                 0.1.sleep
 145
 146                 var client = new ClientThread(self)
 147                 client.start
 148                 client.join
 149                 0.1.sleep
 150
 151                 exit 0
 152         end
 153
 154         # Redefine this method to implement your test scenario.
 155         fun client_test do end
 156
 157         # Regex to catch and hide the port from the output to get consistent results
 158         var host_re: Regex = "localhost:\[0-9\]+".to_re
 159
 160         # Execute a System function.
 161         fun system(cmd: String, title: nullable String)
 162         do
 163                 title = title or else cmd
 164                 title = title.replace(host_re, "localhost:*****")
 165                 print "\n[Client] {title}"
 166                 sys.system cmd
 167         end
 168 end