tests/test_text.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 #alt2 import core
  16
  17 var str = "Woe to you, oh earth and sea for the Devil sends the beast with wrath because he knows the time is short. Let him who hath understanding reckon the number of the beast, for it is a human number, its number is Six Hundred and Sixty-Six."
  18 var spaces = "           "
  19 var numstr = "1001"
  20
  21 var txt: Text
  22 var trimable: Text
  23 var num: Text
  24
  25 txt = str
  26 trimable = spaces + str + spaces
  27 num = numstr
  28
  29 #alt1 txt = new FlatBuffer.from(str)
  30 #alt1 trimable = new FlatBuffer.from(spaces)
  31 #alt1 trimable.append(str)
  32 #alt1 trimable.append(spaces)
  33 #alt1 num = new FlatBuffer.from(numstr)
  34
  35 # Test Text methods on all types of receivers
  36
  37 print txt.substring(0, 105)
  38 print txt.substring_from(106)
  39 print txt.length
  40 assert not txt.is_empty
  41 print txt.index_of('h')
  42 print txt.index_of_from('h', 105)
  43 print txt.index_of('Z')
  44 print txt.last_index_of('L')
  45 print txt.last_index_of_from('D', 105)
  46 print txt.has_substring("Woe", 0)
  47 print txt.has_substring("Let", 106)
  48 assert trimable != txt
  49 assert trimable.trim == txt
  50 assert num.is_numeric
  51 assert txt.has_prefix("Woe")
  52 assert txt.has_suffix("Six.")
  53 assert txt.hash == trimable.trim.hash
  54
  55 # Test Text.chars (SequenceRead[Char]) methods on all receivers
  56
  57 var chars = txt.chars
  58
  59 assert chars != txt.substring_from(106).chars
  60 assert chars[0] == 'W'
  61 assert chars.count('o') == 11
  62 assert chars.first == chars[0]
  63 assert chars.has('L')
  64 assert spaces.chars.has_only(' ')
  65 assert chars.index_of('D') == 37
  66 assert not chars.is_empty
  67 var count = 0
  68 for i in chars do
  69         assert i != '!'
  70         printn i
  71         count += 1
  72 end
  73 printn "\n"
  74 assert count == txt.length
  75 var iter_from = txt.substring_from(105).chars.iterator
  76 var txt_iter_from = chars.iterator_from(105)
  77 while iter_from.is_ok do
  78         assert iter_from.item == txt_iter_from.item
  79         iter_from.next
  80         txt_iter_from.next
  81 end
  82 assert not iter_from.is_ok and not txt_iter_from.is_ok
  83 var txt_reviter = chars.reverse_iterator_from(104)
  84 var sub_reviter = txt.substring(0,105).chars.reverse_iterator
  85 while txt_reviter.is_ok do
  86         assert txt_reviter.item == sub_reviter.item
  87         txt_reviter.next
  88         sub_reviter.next
  89 end
  90 print chars.join(" ")