lib/standard/string.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2004-2008 Jean Privat <jean@pryen.org>
   4 # Copyright 2006-2008 Floréal Morandat <morandat@lirmm.fr>
   5 #
   6 # This file is free software, which comes along with NIT.  This software is
   7 # distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
   8 # without  even  the implied warranty of  MERCHANTABILITY or  FITNESS FOR A
   9 # PARTICULAR PURPOSE.  You can modify it is you want,  provided this header
  10 # is kept unaltered, and a notification of the changes is added.
  11 # You  are  allowed  to  redistribute it and sell it, alone or is a part of
  12 # another product.
  13
  14 # Basic manipulations of strings of characters
  15 module string
  16
  17 import math
  18 import collection
  19 intrude import collection::array
  20
  21 `{
  22 #include <stdio.h>
  23 #include <string.h>
  24 `}
  25
  26 ###############################################################################
  27 # String                                                                      #
  28 ###############################################################################
  29
  30 # High-level abstraction for all text representations
  31 abstract class Text
  32         super Comparable
  33
  34         redef type OTHER: Text
  35
  36         # Type of self (used for factorization of several methods, ex : substring_from, empty...)
  37         type SELFTYPE: Text
  38
  39         # Gets a view on the chars of the Text object
  40         #
  41         #     assert "hello".chars.to_a == ['h', 'e', 'l', 'l', 'o']
  42         fun chars: SequenceRead[Char] is abstract
  43
  44         # Number of characters contained in self.
  45         #
  46         #     assert "12345".length == 5
  47         #     assert "".length == 0
  48         fun length: Int is abstract
  49
  50         # Create a substring.
  51         #
  52         #     assert "abcd".substring(1, 2)      ==  "bc"
  53         #     assert "abcd".substring(-1, 2)     ==  "a"
  54         #     assert "abcd".substring(1, 0)      ==  ""
  55         #     assert "abcd".substring(2, 5)      ==  "cd"
  56         #
  57         # A `from` index < 0 will be replaced by 0.
  58         # Unless a `count` value is > 0 at the same time.
  59         # In this case, `from += count` and `count -= from`.
  60         fun substring(from: Int, count: Int): SELFTYPE is abstract
  61
  62         # Iterates on the substrings of self if any
  63         fun substrings: Iterator[Text] is abstract
  64
  65         # Is the current Text empty (== "")
  66         #
  67         #     assert "".is_empty
  68         #     assert not "foo".is_empty
  69         fun is_empty: Bool do return self.length == 0
  70
  71         # Returns an empty Text of the right type
  72         #
  73         # This method is used internally to get the right
  74         # implementation of an empty string.
  75         protected fun empty: SELFTYPE is abstract
  76
  77         # Gets the first char of the Text
  78         #
  79         # DEPRECATED : Use self.chars.first instead
  80         fun first: Char do return self.chars[0]
  81
  82         # Access a character at `index` in the string.
  83         #
  84         #     assert "abcd"[2]         == 'c'
  85         #
  86         # DEPRECATED : Use self.chars.[] instead
  87         fun [](index: Int): Char do return self.chars[index]
  88
  89         # Gets the index of the first occurence of 'c'
  90         #
  91         # Returns -1 if not found
  92         #
  93         # DEPRECATED : Use self.chars.index_of instead
  94         fun index_of(c: Char): Int
  95         do
  96                 return index_of_from(c, 0)
  97         end
  98
  99         # Gets the last char of self
 100         #
 101         # DEPRECATED : Use self.chars.last instead
 102         fun last: Char do return self.chars[length-1]
 103
 104         # Gets the index of the first occurence of ´c´ starting from ´pos´
 105         #
 106         # Returns -1 if not found
 107         #
 108         # DEPRECATED : Use self.chars.index_of_from instead
 109         fun index_of_from(c: Char, pos: Int): Int
 110         do
 111                 var iter = self.chars.iterator_from(pos)
 112                 while iter.is_ok do
 113                         if iter.item == c then return iter.index
 114                         iter.next
 115                 end
 116                 return -1
 117         end
 118
 119         # Gets the last index of char ´c´
 120         #
 121         # Returns -1 if not found
 122         #
 123         # DEPRECATED : Use self.chars.last_index_of instead
 124         fun last_index_of(c: Char): Int
 125         do
 126                 return last_index_of_from(c, length - 1)
 127         end
 128
 129         # Return a null terminated char *
 130         fun to_cstring: NativeString do return flatten.to_cstring
 131
 132         # The index of the last occurrence of an element starting from pos (in reverse order).
 133         #
 134         #     var s = "/etc/bin/test/test.nit"
 135         #     assert s.last_index_of_from('/', s.length-1) == 13
 136         #     assert s.last_index_of_from('/', 12)         == 8
 137         #
 138         # Returns -1 if not found
 139         #
 140         # DEPRECATED : Use self.chars.last_index_of_from instead
 141         fun last_index_of_from(item: Char, pos: Int): Int
 142         do
 143                 var iter = self.chars.reverse_iterator_from(pos)
 144                 while iter.is_ok do
 145                         if iter.item == item then return iter.index
 146                         iter.next
 147                 end
 148                 return -1
 149         end
 150
 151         # Gets an iterator on the chars of self
 152         #
 153         # DEPRECATED : Use self.chars.iterator instead
 154         fun iterator: Iterator[Char]
 155         do
 156                 return self.chars.iterator
 157         end
 158
 159
 160         # Gets an Array containing the chars of self
 161         #
 162         # DEPRECATED : Use self.chars.to_a instead
 163         fun to_a: Array[Char] do return chars.to_a
 164
 165         # Create a substring from `self` beginning at the `from` position
 166         #
 167         #     assert "abcd".substring_from(1)    ==  "bcd"
 168         #     assert "abcd".substring_from(-1)   ==  "abcd"
 169         #     assert "abcd".substring_from(2)    ==  "cd"
 170         #
 171         # As with substring, a `from` index < 0 will be replaced by 0
 172         fun substring_from(from: Int): SELFTYPE
 173         do
 174                 if from >= self.length then return empty
 175                 if from < 0 then from = 0
 176                 return substring(from, length - from)
 177         end
 178
 179         # Does self have a substring `str` starting from position `pos`?
 180         #
 181         #     assert "abcd".has_substring("bc",1)            ==  true
 182         #     assert "abcd".has_substring("bc",2)            ==  false
 183         #
 184         # Returns true iff all characters of `str` are presents
 185         # at the expected index in `self.`
 186         # The first character of `str` being at `pos`, the second
 187         # character being at `pos+1` and so on...
 188         #
 189         # This means that all characters of `str` need to be inside `self`.
 190         #
 191         #     assert "abcd".has_substring("xab", -1)         == false
 192         #     assert "abcd".has_substring("cdx", 2)          == false
 193         #
 194         # And that the empty string is always a valid substring.
 195         #
 196         #     assert "abcd".has_substring("", 2)             == true
 197         #     assert "abcd".has_substring("", 200)           == true
 198         fun has_substring(str: String, pos: Int): Bool
 199         do
 200                 if str.is_empty then return true
 201                 if pos < 0 or pos + str.length > length then return false
 202                 var myiter = self.chars.iterator_from(pos)
 203                 var itsiter = str.chars.iterator
 204                 while myiter.is_ok and itsiter.is_ok do
 205                         if myiter.item != itsiter.item then return false
 206                         myiter.next
 207                         itsiter.next
 208                 end
 209                 if itsiter.is_ok then return false
 210                 return true
 211         end
 212
 213         # Is this string prefixed by `prefix`?
 214         #
 215         #     assert "abcd".has_prefix("ab")           ==  true
 216         #     assert "abcbc".has_prefix("bc")          ==  false
 217         #     assert "ab".has_prefix("abcd")           ==  false
 218         fun has_prefix(prefix: String): Bool do return has_substring(prefix,0)
 219
 220         # Is this string suffixed by `suffix`?
 221         #
 222         #     assert "abcd".has_suffix("abc")        ==  false
 223         #     assert "abcd".has_suffix("bcd")        ==  true
 224         fun has_suffix(suffix: String): Bool do return has_substring(suffix, length - suffix.length)
 225
 226         # If `self` contains only digits, return the corresponding integer
 227         #
 228         #     assert "123".to_i        == 123
 229         #     assert "-1".to_i         == -1
 230         fun to_i: Int
 231         do
 232                 # Shortcut
 233                 return to_s.to_cstring.atoi
 234         end
 235
 236         # If `self` contains a float, return the corresponding float
 237         #
 238         #     assert "123".to_f        == 123.0
 239         #     assert "-1".to_f         == -1.0
 240         #     assert "-1.2e-3".to_f    == -0.0012
 241         fun to_f: Float
 242         do
 243                 # Shortcut
 244                 return to_s.to_cstring.atof
 245         end
 246
 247         # If `self` contains only digits and alpha <= 'f', return the corresponding integer.
 248         #
 249         #     assert "ff".to_hex == 255
 250         fun to_hex: Int do return a_to(16)
 251
 252         # If `self` contains only digits and letters, return the corresponding integer in a given base
 253         #
 254         #     assert "120".a_to(3)     == 15
 255         fun a_to(base: Int) : Int
 256         do
 257                 var i = 0
 258                 var neg = false
 259
 260                 for j in [0..length[ do
 261                         var c = chars[j]
 262                         var v = c.to_i
 263                         if v > base then
 264                                 if neg then
 265                                         return -i
 266                                 else
 267                                         return i
 268                                 end
 269                         else if v < 0 then
 270                                 neg = true
 271                         else
 272                                 i = i * base + v
 273                         end
 274                 end
 275                 if neg then
 276                         return -i
 277                 else
 278                         return i
 279                 end
 280         end
 281
 282         # Returns `true` if the string contains only Numeric values (and one "," or one "." character)
 283         #
 284         #     assert "123".is_numeric  == true
 285         #     assert "1.2".is_numeric  == true
 286         #     assert "1,2".is_numeric  == true
 287         #     assert "1..2".is_numeric == false
 288         fun is_numeric: Bool
 289         do
 290                 var has_point_or_comma = false
 291                 for i in [0..length[ do
 292                         var c = chars[i]
 293                         if not c.is_numeric then
 294                                 if (c == '.' or c == ',') and not has_point_or_comma then
 295                                         has_point_or_comma = true
 296                                 else
 297                                         return false
 298                                 end
 299                         end
 300                 end
 301                 return true
 302         end
 303
 304         # Returns `true` if the string contains only Hex chars
 305         #
 306         #     assert "048bf".is_hex  == true
 307         #     assert "ABCDEF".is_hex  == true
 308         #     assert "0G".is_hex == false
 309         fun is_hex: Bool
 310         do
 311                 for i in [0..length[ do
 312                         var c = chars[i]
 313                         if not (c >= 'a' and c <= 'f') and
 314                            not (c >= 'A' and c <= 'F') and
 315                            not (c >= '0' and c <= '9') then return false
 316                 end
 317                 return true
 318         end
 319
 320         # Are all letters in `self` upper-case ?
 321         #
 322         #     assert "HELLO WORLD".is_upper == true
 323         #     assert "%$&%!".is_upper       == true
 324         #     assert "hello world".is_upper == false
 325         #     assert "Hello World".is_upper == false
 326         fun is_upper: Bool
 327         do
 328                 for i in [0..length[ do
 329                         var char = chars[i]
 330                         if char.is_lower then return false
 331                 end
 332                 return true
 333         end
 334
 335         # Are all letters in `self` lower-case ?
 336         #
 337         #     assert "hello world".is_lower == true
 338         #     assert "%$&%!".is_lower       == true
 339         #     assert "Hello World".is_lower == false
 340         fun is_lower: Bool
 341         do
 342                 for i in [0..length[ do
 343                         var char = chars[i]
 344                         if char.is_upper then return false
 345                 end
 346                 return true
 347         end
 348
 349         # Removes the whitespaces at the beginning of self
 350         #
 351         #     assert " \n\thello \n\t".l_trim == "hello \n\t"
 352         #
 353         # `Char::is_whitespace` determines what is a whitespace.
 354         fun l_trim: SELFTYPE
 355         do
 356                 var iter = self.chars.iterator
 357                 while iter.is_ok do
 358                         if not iter.item.is_whitespace then break
 359                         iter.next
 360                 end
 361                 if iter.index == length then return self.empty
 362                 return self.substring_from(iter.index)
 363         end
 364
 365         # Removes the whitespaces at the end of self
 366         #
 367         #     assert " \n\thello \n\t".r_trim == " \n\thello"
 368         #
 369         # `Char::is_whitespace` determines what is a whitespace.
 370         fun r_trim: SELFTYPE
 371         do
 372                 var iter = self.chars.reverse_iterator
 373                 while iter.is_ok do
 374                         if not iter.item.is_whitespace then break
 375                         iter.next
 376                 end
 377                 if iter.index < 0 then return self.empty
 378                 return self.substring(0, iter.index + 1)
 379         end
 380
 381         # Trims trailing and preceding white spaces
 382         #
 383         #     assert "  Hello  World !  ".trim   == "Hello  World !"
 384         #     assert "\na\nb\tc\t".trim          == "a\nb\tc"
 385         #
 386         # `Char::is_whitespace` determines what is a whitespace.
 387         fun trim: SELFTYPE do return (self.l_trim).r_trim
 388
 389         # Is the string non-empty but only made of whitespaces?
 390         #
 391         #    assert " \n\t ".is_whitespace    == true
 392         #    assert "  hello  ".is_whitespace == false
 393         #    assert "".is_whitespace          == false
 394         #
 395         # `Char::is_whitespace` determines what is a whitespace.
 396         fun is_whitespace: Bool
 397         do
 398                 if is_empty then return false
 399                 for c in self.chars do
 400                         if not c.is_whitespace then return false
 401                 end
 402                 return true
 403         end
 404
 405         # Returns `self` removed from its last line terminator (if any).
 406         #
 407         #    assert "Hello\n".chomp == "Hello"
 408         #    assert "Hello".chomp   == "Hello"
 409         #
 410         #    assert "\n".chomp == ""
 411         #    assert "".chomp   == ""
 412         #
 413         # Line terminators are `"\n"`, `"\r\n"` and `"\r"`.
 414         # A single line terminator, the last one, is removed.
 415         #
 416         #    assert "\r\n".chomp     == ""
 417         #    assert "\r\n\n".chomp   == "\r\n"
 418         #    assert "\r\n\r\n".chomp == "\r\n"
 419         #    assert "\r\n\r".chomp   == "\r\n"
 420         #
 421         # Note: unlike with most IO methods like `Reader::read_line`,
 422         # a single `\r` is considered here to be a line terminator and will be removed.
 423         fun chomp: SELFTYPE
 424         do
 425                 var len = length
 426                 if len == 0 then return self
 427                 var l = self.chars.last
 428                 if l == '\r' then
 429                         return substring(0, len-1)
 430                 else if l != '\n' then
 431                         return self
 432                 else if len > 1 and self.chars[len-2] == '\r' then
 433                         return substring(0, len-2)
 434                 else
 435                         return substring(0, len-1)
 436                 end
 437         end
 438
 439         # Justify a self in a space of `length`
 440         #
 441         # `left` is the space ratio on the left side.
 442         # * 0.0 for left-justified (no space at the left)
 443         # * 1.0 for right-justified (all spaces at the left)
 444         # * 0.5 for centered (half the spaces at the left)
 445         #
 446         # Examples
 447         #
 448         #     assert "hello".justify(10, 0.0)  == "hello     "
 449         #     assert "hello".justify(10, 1.0)  == "     hello"
 450         #     assert "hello".justify(10, 0.5)  == "  hello   "
 451         #
 452         # If `length` is not enough, `self` is returned as is.
 453         #
 454         #     assert "hello".justify(2, 0.0)   == "hello"
 455         #
 456         # REQUIRE: `left >= 0.0 and left <= 1.0`
 457         # ENSURE: `self.length <= length implies result.length == length`
 458         # ENSURE: `self.length >= length implies result == self`
 459         fun justify(length: Int, left: Float): String
 460         do
 461                 var diff = length - self.length
 462                 if diff <= 0 then return to_s
 463                 assert left >= 0.0 and left <= 1.0
 464                 var before = (diff.to_f * left).to_i
 465                 return " " * before + self + " " * (diff-before)
 466         end
 467
 468         # Mangle a string to be a unique string only made of alphanumeric characters and underscores.
 469         #
 470         # This method is injective (two different inputs never produce the same
 471         # output) and the returned string always respect the following rules:
 472         #
 473         # * Contains only US-ASCII letters, digits and underscores.
 474         # * Never starts with a digit.
 475         # * Never ends with an underscore.
 476         # * Never contains two contiguous underscores.
 477         #
 478         #     assert "42_is/The answer!".to_cmangle == "_52d2_is_47dThe_32danswer_33d"
 479         #     assert "__".to_cmangle == "_95d_95d"
 480         #     assert "__d".to_cmangle == "_95d_d"
 481         #     assert "_d_".to_cmangle == "_d_95d"
 482         #     assert "_42".to_cmangle == "_95d42"
 483         #     assert "foo".to_cmangle == "foo"
 484         #     assert "".to_cmangle == ""
 485         fun to_cmangle: String
 486         do
 487                 if is_empty then return ""
 488                 var res = new FlatBuffer
 489                 var underscore = false
 490                 var start = 0
 491                 var c = chars[0]
 492
 493                 if c >= '0' and c <= '9' then
 494                         res.add('_')
 495                         res.append(c.ascii.to_s)
 496                         res.add('d')
 497                         start = 1
 498                 end
 499                 for i in [start..length[ do
 500                         c = chars[i]
 501                         if (c >= 'a' and c <= 'z') or (c >='A' and c <= 'Z') then
 502                                 res.add(c)
 503                                 underscore = false
 504                                 continue
 505                         end
 506                         if underscore then
 507                                 res.append('_'.ascii.to_s)
 508                                 res.add('d')
 509                         end
 510                         if c >= '0' and c <= '9' then
 511                                 res.add(c)
 512                                 underscore = false
 513                         else if c == '_' then
 514                                 res.add(c)
 515                                 underscore = true
 516                         else
 517                                 res.add('_')
 518                                 res.append(c.ascii.to_s)
 519                                 res.add('d')
 520                                 underscore = false
 521                         end
 522                 end
 523                 if underscore then
 524                         res.append('_'.ascii.to_s)
 525                         res.add('d')
 526                 end
 527                 return res.to_s
 528         end
 529
 530         # Escape " \ ' and non printable characters using the rules of literal C strings and characters
 531         #
 532         #     assert "abAB12<>&".escape_to_c         == "abAB12<>&"
 533         #     assert "\n\"'\\".escape_to_c         == "\\n\\\"\\'\\\\"
 534         #
 535         # Most non-printable characters (bellow ASCII 32) are escaped to an octal form `\nnn`.
 536         # Three digits are always used to avoid following digits to be interpreted as an element
 537         # of the octal sequence.
 538         #
 539         #     assert "{0.ascii}{1.ascii}{8.ascii}{31.ascii}{32.ascii}".escape_to_c == "\\000\\001\\010\\037 "
 540         #
 541         # The exceptions are the common `\t` and `\n`.
 542         fun escape_to_c: String
 543         do
 544                 var b = new FlatBuffer
 545                 for i in [0..length[ do
 546                         var c = chars[i]
 547                         if c == '\n' then
 548                                 b.append("\\n")
 549                         else if c == '\t' then
 550                                 b.append("\\t")
 551                         else if c == '\0' then
 552                                 b.append("\\000")
 553                         else if c == '"' then
 554                                 b.append("\\\"")
 555                         else if c == '\'' then
 556                                 b.append("\\\'")
 557                         else if c == '\\' then
 558                                 b.append("\\\\")
 559                         else if c.ascii < 32 then
 560                                 b.add('\\')
 561                                 var oct = c.ascii.to_base(8, false)
 562                                 # Force 3 octal digits since it is the
 563                                 # maximum allowed in the C specification
 564                                 if oct.length == 1 then
 565                                         b.add('0')
 566                                         b.add('0')
 567                                 else if oct.length == 2 then
 568                                         b.add('0')
 569                                 end
 570                                 b.append(oct)
 571                         else
 572                                 b.add(c)
 573                         end
 574                 end
 575                 return b.to_s
 576         end
 577
 578         # Escape additionnal characters
 579         # The result might no be legal in C but be used in other languages
 580         #
 581         #     assert "ab|\{\}".escape_more_to_c("|\{\}") == "ab\\|\\\{\\\}"
 582         fun escape_more_to_c(chars: String): String
 583         do
 584                 var b = new FlatBuffer
 585                 for c in escape_to_c.chars do
 586                         if chars.chars.has(c) then
 587                                 b.add('\\')
 588                         end
 589                         b.add(c)
 590                 end
 591                 return b.to_s
 592         end
 593
 594         # Escape to C plus braces
 595         #
 596         #     assert "\n\"'\\\{\}".escape_to_nit      == "\\n\\\"\\'\\\\\\\{\\\}"
 597         fun escape_to_nit: String do return escape_more_to_c("\{\}")
 598
 599         # Escape to POSIX Shell (sh).
 600         #
 601         # Abort if the text contains a null byte.
 602         #
 603         #     assert "\n\"'\\\{\}0".escape_to_sh == "'\n\"'\\''\\\{\}0'"
 604         fun escape_to_sh: String do
 605                 var b = new FlatBuffer
 606                 b.chars.add '\''
 607                 for i in [0..length[ do
 608                         var c = chars[i]
 609                         if c == '\'' then
 610                                 b.append("'\\''")
 611                         else
 612                                 assert without_null_byte: c != '\0'
 613                                 b.add(c)
 614                         end
 615                 end
 616                 b.chars.add '\''
 617                 return b.to_s
 618         end
 619
 620         # Escape to include in a Makefile
 621         #
 622         # Unfortunately, some characters are not escapable in Makefile.
 623         # These characters are `;`, `|`, `\`, and the non-printable ones.
 624         # They will be rendered as `"?{hex}"`.
 625         fun escape_to_mk: String do
 626                 var b = new FlatBuffer
 627                 for i in [0..length[ do
 628                         var c = chars[i]
 629                         if c == '$' then
 630                                 b.append("$$")
 631                         else if c == ':' or c == ' ' or c == '#' then
 632                                 b.add('\\')
 633                                 b.add(c)
 634                         else if c.ascii < 32 or c == ';' or c == '|' or c == '\\' or c == '=' then
 635                                 b.append("?{c.ascii.to_base(16, false)}")
 636                         else
 637                                 b.add(c)
 638                         end
 639                 end
 640                 return b.to_s
 641         end
 642
 643         # Return a string where Nit escape sequences are transformed.
 644         #
 645         #     var s = "\\n"
 646         #     assert s.length        ==  2
 647         #     var u = s.unescape_nit
 648         #     assert u.length        ==  1
 649         #     assert u.chars[0].ascii      ==  10 # (the ASCII value of the "new line" character)
 650         fun unescape_nit: String
 651         do
 652                 var res = new FlatBuffer.with_capacity(self.length)
 653                 var was_slash = false
 654                 for i in [0..length[ do
 655                         var c = chars[i]
 656                         if not was_slash then
 657                                 if c == '\\' then
 658                                         was_slash = true
 659                                 else
 660                                         res.add(c)
 661                                 end
 662                                 continue
 663                         end
 664                         was_slash = false
 665                         if c == 'n' then
 666                                 res.add('\n')
 667                         else if c == 'r' then
 668                                 res.add('\r')
 669                         else if c == 't' then
 670                                 res.add('\t')
 671                         else if c == '0' then
 672                                 res.add('\0')
 673                         else
 674                                 res.add(c)
 675                         end
 676                 end
 677                 return res.to_s
 678         end
 679
 680         # Encode `self` to percent (or URL) encoding
 681         #
 682         #     assert "aBc09-._~".to_percent_encoding == "aBc09-._~"
 683         #     assert "%()< >".to_percent_encoding == "%25%28%29%3c%20%3e"
 684         #     assert ".com/post?e=asdf&f=123".to_percent_encoding == ".com%2fpost%3fe%3dasdf%26f%3d123"
 685         fun to_percent_encoding: String
 686         do
 687                 var buf = new FlatBuffer
 688
 689                 for i in [0..length[ do
 690                         var c = chars[i]
 691                         if (c >= '0' and c <= '9') or
 692                            (c >= 'a' and c <= 'z') or
 693                            (c >= 'A' and c <= 'Z') or
 694                            c == '-' or c == '.' or
 695                            c == '_' or c == '~'
 696                         then
 697                                 buf.add c
 698                         else buf.append "%{c.ascii.to_hex}"
 699                 end
 700
 701                 return buf.to_s
 702         end
 703
 704         # Decode `self` from percent (or URL) encoding to a clear string
 705         #
 706         # Replace invalid use of '%' with '?'.
 707         #
 708         #     assert "aBc09-._~".from_percent_encoding == "aBc09-._~"
 709         #     assert "%25%28%29%3c%20%3e".from_percent_encoding == "%()< >"
 710         #     assert ".com%2fpost%3fe%3dasdf%26f%3d123".from_percent_encoding == ".com/post?e=asdf&f=123"
 711         #     assert "%25%28%29%3C%20%3E".from_percent_encoding == "%()< >"
 712         #     assert "incomplete %".from_percent_encoding == "incomplete ?"
 713         #     assert "invalid % usage".from_percent_encoding == "invalid ? usage"
 714         fun from_percent_encoding: String
 715         do
 716                 var buf = new FlatBuffer
 717
 718                 var i = 0
 719                 while i < length do
 720                         var c = chars[i]
 721                         if c == '%' then
 722                                 if i + 2 >= length then
 723                                         # What follows % has been cut off
 724                                         buf.add '?'
 725                                 else
 726                                         i += 1
 727                                         var hex_s = substring(i, 2)
 728                                         if hex_s.is_hex then
 729                                                 var hex_i = hex_s.to_hex
 730                                                 buf.add hex_i.ascii
 731                                                 i += 1
 732                                         else
 733                                                 # What follows a % is not Hex
 734                                                 buf.add '?'
 735                                                 i -= 1
 736                                         end
 737                                 end
 738                         else buf.add c
 739
 740                         i += 1
 741                 end
 742
 743                 return buf.to_s
 744         end
 745
 746         # Escape the characters `<`, `>`, `&`, `"`, `'` and `/` as HTML/XML entity references.
 747         #
 748         #     assert "a&b-<>\"x\"/'".html_escape      ==  "a&amp;b-&lt;&gt;&#34;x&#34;&#47;&#39;"
 749         #
 750         # SEE: <https://www.owasp.org/index.php/XSS_%28Cross_Site_Scripting%29_Prevention_Cheat_Sheet#RULE_.231_-_HTML_Escape_Before_Inserting_Untrusted_Data_into_HTML_Element_Content>
 751         fun html_escape: String
 752         do
 753                 var buf = new FlatBuffer
 754
 755                 for i in [0..length[ do
 756                         var c = chars[i]
 757                         if c == '&' then
 758                                 buf.append "&amp;"
 759                         else if c == '<' then
 760                                 buf.append "&lt;"
 761                         else if c == '>' then
 762                                 buf.append "&gt;"
 763                         else if c == '"' then
 764                                 buf.append "&#34;"
 765                         else if c == '\'' then
 766                                 buf.append "&#39;"
 767                         else if c == '/' then
 768                                 buf.append "&#47;"
 769                         else buf.add c
 770                 end
 771
 772                 return buf.to_s
 773         end
 774
 775         # Equality of text
 776         # Two pieces of text are equals if thez have the same characters in the same order.
 777         #
 778         #     assert "hello" == "hello"
 779         #     assert "hello" != "HELLO"
 780         #     assert "hello" == "hel"+"lo"
 781         #
 782         # Things that are not Text are not equal.
 783         #
 784         #     assert "9" != '9'
 785         #     assert "9" != ['9']
 786         #     assert "9" != 9
 787         #
 788         #     assert "9".chars.first == '9'   # equality of Char
 789         #     assert "9".chars       == ['9'] # equality of Sequence
 790         #     assert "9".to_i        == 9     # equality of Int
 791         redef fun ==(o)
 792         do
 793                 if o == null then return false
 794                 if not o isa Text then return false
 795                 if self.is_same_instance(o) then return true
 796                 if self.length != o.length then return false
 797                 return self.chars == o.chars
 798         end
 799
 800         # Lexicographical comparaison
 801         #
 802         #     assert "abc" < "xy"
 803         #     assert "ABC" < "abc"
 804         redef fun <(other)
 805         do
 806                 var self_chars = self.chars.iterator
 807                 var other_chars = other.chars.iterator
 808
 809                 while self_chars.is_ok and other_chars.is_ok do
 810                         if self_chars.item < other_chars.item then return true
 811                         if self_chars.item > other_chars.item then return false
 812                         self_chars.next
 813                         other_chars.next
 814                 end
 815
 816                 if self_chars.is_ok then
 817                         return false
 818                 else
 819                         return true
 820                 end
 821         end
 822
 823         # Escape string used in labels for graphviz
 824         #
 825         #   assert ">><<".escape_to_dot == "\\>\\>\\<\\<"
 826         fun escape_to_dot: String
 827         do
 828                 return escape_more_to_c("|\{\}<>")
 829         end
 830
 831         # Flat representation of self
 832         fun flatten: FlatText is abstract
 833
 834         private var hash_cache: nullable Int = null
 835
 836         redef fun hash
 837         do
 838                 if hash_cache == null then
 839                         # djb2 hash algorithm
 840                         var h = 5381
 841
 842                         for i in [0..length[ do
 843                                 var char = chars[i]
 844                                 h = h.lshift(5) + h + char.ascii
 845                         end
 846
 847                         hash_cache = h
 848                 end
 849                 return hash_cache.as(not null)
 850         end
 851
 852 end
 853
 854 # All kinds of array-based text representations.
 855 abstract class FlatText
 856         super Text
 857
 858         # Underlying C-String (`char*`)
 859         #
 860         # Warning : Might be void in some subclasses, be sure to check
 861         # if set before using it.
 862         private var items: NativeString is noinit
 863
 864         # Real items, used as cache for to_cstring is called
 865         private var real_items: nullable NativeString = null
 866
 867         # Returns a char* starting at position `index_from`
 868         #
 869         # WARNING: If you choose to use this service, be careful of the following.
 870         #
 871         # Strings and NativeString are *ideally* always allocated through a Garbage Collector.
 872         # Since the GC tracks the use of the pointer for the beginning of the char*, it may be
 873         # deallocated at any moment, rendering the pointer returned by this function invalid.
 874         # Any access to freed memory may very likely cause undefined behaviour or a crash.
 875         # (Failure to do so will most certainly result in long and painful debugging hours)
 876         #
 877         # The only safe use of this pointer is if it is ephemeral (e.g. read in a C function
 878         # then immediately return).
 879         #
 880         # As always, do not modify the content of the String in C code, if this is what you want
 881         # copy locally the char* as Nit Strings are immutable.
 882         private fun fast_cstring: NativeString is abstract
 883
 884         redef var length: Int = 0
 885
 886         redef fun output
 887         do
 888                 var i = 0
 889                 while i < length do
 890                         items[i].output
 891                         i += 1
 892                 end
 893         end
 894
 895         redef fun flatten do return self
 896 end
 897
 898 # Abstract class for the SequenceRead compatible
 899 # views on String and Buffer objects
 900 private abstract class StringCharView
 901         super SequenceRead[Char]
 902
 903         type SELFTYPE: Text
 904
 905         var target: SELFTYPE
 906
 907         redef fun is_empty do return target.is_empty
 908
 909         redef fun length do return target.length
 910
 911         redef fun iterator: IndexedIterator[Char] do return self.iterator_from(0)
 912
 913         redef fun reverse_iterator do return self.reverse_iterator_from(self.length - 1)
 914 end
 915
 916 # View on Buffer objects, extends Sequence
 917 # for mutation operations
 918 private abstract class BufferCharView
 919         super StringCharView
 920         super Sequence[Char]
 921
 922         redef type SELFTYPE: Buffer
 923
 924 end
 925
 926 # A `String` holds and manipulates an arbitrary sequence of characters.
 927 #
 928 # String objects may be created using literals.
 929 #
 930 #     assert "Hello World!" isa String
 931 abstract class String
 932         super Text
 933
 934         redef type SELFTYPE: String is fixed
 935
 936         redef fun to_s do return self
 937
 938         # Concatenates `o` to `self`
 939         #
 940         #     assert "hello" + "world"  == "helloworld"
 941         #     assert "" + "hello" + ""  == "hello"
 942         fun +(o: Text): SELFTYPE is abstract
 943
 944         # Concatenates self `i` times
 945         #
 946         #     assert "abc" * 4 == "abcabcabcabc"
 947         #     assert "abc" * 1 == "abc"
 948         #     assert "abc" * 0 == ""
 949         fun *(i: Int): SELFTYPE is abstract
 950
 951         # Insert `s` at `pos`.
 952         #
 953         #     assert "helloworld".insert_at(" ", 5)     == "hello world"
 954         fun insert_at(s: String, pos: Int): SELFTYPE is abstract
 955
 956         redef fun substrings: Iterator[String] is abstract
 957
 958         # Returns a reversed version of self
 959         #
 960         #     assert "hello".reversed  == "olleh"
 961         #     assert "bob".reversed    == "bob"
 962         #     assert "".reversed       == ""
 963         fun reversed: SELFTYPE is abstract
 964
 965         # A upper case version of `self`
 966         #
 967         #     assert "Hello World!".to_upper     == "HELLO WORLD!"
 968         fun to_upper: SELFTYPE is abstract
 969
 970         # A lower case version of `self`
 971         #
 972         #     assert "Hello World!".to_lower     == "hello world!"
 973         fun to_lower : SELFTYPE is abstract
 974
 975         # Takes a camel case `self` and converts it to snake case
 976         #
 977         #     assert "randomMethodId".to_snake_case == "random_method_id"
 978         #
 979         # The rules are the following:
 980         #
 981         # An uppercase is always converted to a lowercase
 982         #
 983         #     assert "HELLO_WORLD".to_snake_case == "hello_world"
 984         #
 985         # An uppercase that follows a lowercase is prefixed with an underscore
 986         #
 987         #     assert "HelloTheWORLD".to_snake_case == "hello_the_world"
 988         #
 989         # An uppercase that follows an uppercase and is followed by a lowercase, is prefixed with an underscore
 990         #
 991         #     assert "HelloTHEWorld".to_snake_case == "hello_the_world"
 992         #
 993         # All other characters are kept as is; `self` does not need to be a proper CamelCased string.
 994         #
 995         #     assert "=-_H3ll0Th3W0rld_-=".to_snake_case == "=-_h3ll0th3w0rld_-="
 996         fun to_snake_case: SELFTYPE
 997         do
 998                 if self.is_lower then return self
 999
1000                 var new_str = new FlatBuffer.with_capacity(self.length)
1001                 var prev_is_lower = false
1002                 var prev_is_upper = false
1003
1004                 for i in [0..length[ do
1005                         var char = chars[i]
1006                         if char.is_lower then
1007                                 new_str.add(char)
1008                                 prev_is_lower = true
1009                                 prev_is_upper = false
1010                         else if char.is_upper then
1011                                 if prev_is_lower then
1012                                         new_str.add('_')
1013                                 else if prev_is_upper and i+1 < length and chars[i+1].is_lower then
1014                                         new_str.add('_')
1015                                 end
1016                                 new_str.add(char.to_lower)
1017                                 prev_is_lower = false
1018                                 prev_is_upper = true
1019                         else
1020                                 new_str.add(char)
1021                                 prev_is_lower = false
1022                                 prev_is_upper = false
1023                         end
1024                 end
1025
1026                 return new_str.to_s
1027         end
1028
1029         # Takes a snake case `self` and converts it to camel case
1030         #
1031         #     assert "random_method_id".to_camel_case == "randomMethodId"
1032         #
1033         # If the identifier is prefixed by an underscore, the underscore is ignored
1034         #
1035         #     assert "_private_field".to_camel_case == "_privateField"
1036         #
1037         # If `self` is upper, it is returned unchanged
1038         #
1039         #     assert "RANDOM_ID".to_camel_case == "RANDOM_ID"
1040         #
1041         # If there are several consecutive underscores, they are considered as a single one
1042         #
1043         #     assert "random__method_id".to_camel_case == "randomMethodId"
1044         fun to_camel_case: SELFTYPE
1045         do
1046                 if self.is_upper then return self
1047
1048                 var new_str = new FlatBuffer
1049                 var is_first_char = true
1050                 var follows_us = false
1051
1052                 for i in [0..length[ do
1053                         var char = chars[i]
1054                         if is_first_char then
1055                                 new_str.add(char)
1056                                 is_first_char = false
1057                         else if char == '_' then
1058                                 follows_us = true
1059                         else if follows_us then
1060                                 new_str.add(char.to_upper)
1061                                 follows_us = false
1062                         else
1063                                 new_str.add(char)
1064                         end
1065                 end
1066
1067                 return new_str.to_s
1068         end
1069
1070         # Returns a capitalized `self`
1071         #
1072         # Letters that follow a letter are lowercased
1073         # Letters that follow a non-letter are upcased.
1074         #
1075         # SEE : `Char::is_letter` for the definition of letter.
1076         #
1077         #     assert "jAVASCRIPT".capitalized == "Javascript"
1078         #     assert "i am root".capitalized == "I Am Root"
1079         #     assert "ab_c -ab0c ab\nc".capitalized == "Ab_C -Ab0C Ab\nC"
1080         fun capitalized: SELFTYPE do
1081                 if length == 0 then return self
1082
1083                 var buf = new FlatBuffer.with_capacity(length)
1084
1085                 var curr = chars[0].to_upper
1086                 var prev = curr
1087                 buf[0] = curr
1088
1089                 for i in [1 .. length[ do
1090                         prev = curr
1091                         curr = self[i]
1092                         if prev.is_letter then
1093                                 buf[i] = curr.to_lower
1094                         else
1095                                 buf[i] = curr.to_upper
1096                         end
1097                 end
1098
1099                 return buf.to_s
1100         end
1101 end
1102
1103 private class FlatSubstringsIter
1104         super Iterator[FlatText]
1105
1106         var tgt: nullable FlatText
1107
1108         redef fun item do
1109                 assert is_ok
1110                 return tgt.as(not null)
1111         end
1112
1113         redef fun is_ok do return tgt != null
1114
1115         redef fun next do tgt = null
1116 end
1117
1118 # Immutable strings of characters.
1119 class FlatString
1120         super FlatText
1121         super String
1122
1123         # Index in _items of the start of the string
1124         private var index_from: Int is noinit
1125
1126         # Indes in _items of the last item of the string
1127         private var index_to: Int is noinit
1128
1129         redef var chars: SequenceRead[Char] = new FlatStringCharView(self) is lazy
1130
1131         redef fun [](index)
1132         do
1133                 # Check that the index (+ index_from) is not larger than indexTo
1134                 # In other terms, if the index is valid
1135                 assert index >= 0
1136                 assert (index + index_from) <= index_to
1137                 return items[index + index_from]
1138         end
1139
1140         ################################################
1141         #       AbstractString specific methods        #
1142         ################################################
1143
1144         redef fun reversed
1145         do
1146                 var native = new NativeString(self.length + 1)
1147                 var length = self.length
1148                 var items = self.items
1149                 var pos = 0
1150                 var ipos = length-1
1151                 while pos < length do
1152                         native[pos] = items[ipos]
1153                         pos += 1
1154                         ipos -= 1
1155                 end
1156                 return native.to_s_with_length(self.length)
1157         end
1158
1159         redef fun fast_cstring do return items.fast_cstring(index_from)
1160
1161         redef fun substring(from, count)
1162         do
1163                 assert count >= 0
1164
1165                 if from < 0 then
1166                         count += from
1167                         if count < 0 then count = 0
1168                         from = 0
1169                 end
1170
1171                 var new_from = index_from + from
1172
1173                 if (new_from + count) > index_to then
1174                         var new_len = index_to - new_from + 1
1175                         if new_len <= 0 then return empty
1176                         return new FlatString.with_infos(items, new_len, new_from, index_to)
1177                 end
1178
1179                 if count <= 0 then return empty
1180
1181                 var to = new_from + count - 1
1182
1183                 return new FlatString.with_infos(items, to - new_from + 1, new_from, to)
1184         end
1185
1186         redef fun empty do return "".as(FlatString)
1187
1188         redef fun to_upper
1189         do
1190                 var outstr = new NativeString(self.length + 1)
1191                 var out_index = 0
1192
1193                 var myitems = self.items
1194                 var index_from = self.index_from
1195                 var max = self.index_to
1196
1197                 while index_from <= max do
1198                         outstr[out_index] = myitems[index_from].to_upper
1199                         out_index += 1
1200                         index_from += 1
1201                 end
1202
1203                 outstr[self.length] = '\0'
1204
1205                 return outstr.to_s_with_length(self.length)
1206         end
1207
1208         redef fun to_lower
1209         do
1210                 var outstr = new NativeString(self.length + 1)
1211                 var out_index = 0
1212
1213                 var myitems = self.items
1214                 var index_from = self.index_from
1215                 var max = self.index_to
1216
1217                 while index_from <= max do
1218                         outstr[out_index] = myitems[index_from].to_lower
1219                         out_index += 1
1220                         index_from += 1
1221                 end
1222
1223                 outstr[self.length] = '\0'
1224
1225                 return outstr.to_s_with_length(self.length)
1226         end
1227
1228         redef fun output
1229         do
1230                 var i = self.index_from
1231                 var imax = self.index_to
1232                 while i <= imax do
1233                         items[i].output
1234                         i += 1
1235                 end
1236         end
1237
1238         ##################################################
1239         #              String Specific Methods           #
1240         ##################################################
1241
1242         # Low-level creation of a new string with given data.
1243         #
1244         # `items` will be used as is, without copy, to retrieve the characters of the string.
1245         # Aliasing issues is the responsibility of the caller.
1246         private init with_infos(items: NativeString, length: Int, from: Int, to: Int)
1247         do
1248                 self.items = items
1249                 self.length = length
1250                 index_from = from
1251                 index_to = to
1252         end
1253
1254         redef fun to_cstring: NativeString
1255         do
1256                 if real_items != null then
1257                         return real_items.as(not null)
1258                 else
1259                         var newItems = new NativeString(length + 1)
1260                         self.items.copy_to(newItems, length, index_from, 0)
1261                         newItems[length] = '\0'
1262                         self.real_items = newItems
1263                         return newItems
1264                 end
1265         end
1266
1267         redef fun ==(other)
1268         do
1269                 if not other isa FlatString then return super
1270
1271                 if self.object_id == other.object_id then return true
1272
1273                 var my_length = length
1274
1275                 if other.length != my_length then return false
1276
1277                 var my_index = index_from
1278                 var its_index = other.index_from
1279
1280                 var last_iteration = my_index + my_length
1281
1282                 var itsitems = other.items
1283                 var myitems = self.items
1284
1285                 while my_index < last_iteration do
1286                         if myitems[my_index] != itsitems[its_index] then return false
1287                         my_index += 1
1288                         its_index += 1
1289                 end
1290
1291                 return true
1292         end
1293
1294         redef fun <(other)
1295         do
1296                 if not other isa FlatString then return super
1297
1298                 if self.object_id == other.object_id then return false
1299
1300                 var my_curr_char : Char
1301                 var its_curr_char : Char
1302
1303                 var curr_id_self = self.index_from
1304                 var curr_id_other = other.index_from
1305
1306                 var my_items = self.items
1307                 var its_items = other.items
1308
1309                 var my_length = self.length
1310                 var its_length = other.length
1311
1312                 var max_iterations = curr_id_self + my_length
1313
1314                 while curr_id_self < max_iterations do
1315                         my_curr_char = my_items[curr_id_self]
1316                         its_curr_char = its_items[curr_id_other]
1317
1318                         if my_curr_char != its_curr_char then
1319                                 if my_curr_char < its_curr_char then return true
1320                                 return false
1321                         end
1322
1323                         curr_id_self += 1
1324                         curr_id_other += 1
1325                 end
1326
1327                 return my_length < its_length
1328         end
1329
1330         redef fun +(s)
1331         do
1332                 var my_length = self.length
1333                 var its_length = s.length
1334
1335                 var total_length = my_length + its_length
1336
1337                 var target_string = new NativeString(my_length + its_length + 1)
1338
1339                 self.items.copy_to(target_string, my_length, index_from, 0)
1340                 if s isa FlatString then
1341                         s.items.copy_to(target_string, its_length, s.index_from, my_length)
1342                 else if s isa FlatBuffer then
1343                         s.items.copy_to(target_string, its_length, 0, my_length)
1344                 else
1345                         var curr_pos = my_length
1346                         for i in [0..s.length[ do
1347                                 var c = s.chars[i]
1348                                 target_string[curr_pos] = c
1349                                 curr_pos += 1
1350                         end
1351                 end
1352
1353                 target_string[total_length] = '\0'
1354
1355                 return target_string.to_s_with_length(total_length)
1356         end
1357
1358         redef fun *(i)
1359         do
1360                 assert i >= 0
1361
1362                 var my_length = self.length
1363
1364                 var final_length = my_length * i
1365
1366                 var my_items = self.items
1367
1368                 var target_string = new NativeString(final_length + 1)
1369
1370                 target_string[final_length] = '\0'
1371
1372                 var current_last = 0
1373
1374                 for iteration in [1 .. i] do
1375                         my_items.copy_to(target_string, my_length, 0, current_last)
1376                         current_last += my_length
1377                 end
1378
1379                 return target_string.to_s_with_length(final_length)
1380         end
1381
1382         redef fun hash
1383         do
1384                 if hash_cache == null then
1385                         # djb2 hash algorithm
1386                         var h = 5381
1387                         var i = index_from
1388
1389                         var myitems = items
1390
1391                         while i <= index_to do
1392                                 h = h.lshift(5) + h + myitems[i].ascii
1393                                 i += 1
1394                         end
1395
1396                         hash_cache = h
1397                 end
1398
1399                 return hash_cache.as(not null)
1400         end
1401
1402         redef fun substrings do return new FlatSubstringsIter(self)
1403 end
1404
1405 private class FlatStringReverseIterator
1406         super IndexedIterator[Char]
1407
1408         var target: FlatString
1409
1410         var target_items: NativeString
1411
1412         var curr_pos: Int
1413
1414         init with_pos(tgt: FlatString, pos: Int)
1415         do
1416                 target = tgt
1417                 target_items = tgt.items
1418                 curr_pos = pos + tgt.index_from
1419         end
1420
1421         redef fun is_ok do return curr_pos >= target.index_from
1422
1423         redef fun item do return target_items[curr_pos]
1424
1425         redef fun next do curr_pos -= 1
1426
1427         redef fun index do return curr_pos - target.index_from
1428
1429 end
1430
1431 private class FlatStringIterator
1432         super IndexedIterator[Char]
1433
1434         var target: FlatString
1435
1436         var target_items: NativeString
1437
1438         var curr_pos: Int
1439
1440         init with_pos(tgt: FlatString, pos: Int)
1441         do
1442                 target = tgt
1443                 target_items = tgt.items
1444                 curr_pos = pos + target.index_from
1445         end
1446
1447         redef fun is_ok do return curr_pos <= target.index_to
1448
1449         redef fun item do return target_items[curr_pos]
1450
1451         redef fun next do curr_pos += 1
1452
1453         redef fun index do return curr_pos - target.index_from
1454
1455 end
1456
1457 private class FlatStringCharView
1458         super StringCharView
1459
1460         redef type SELFTYPE: FlatString
1461
1462         redef fun [](index)
1463         do
1464                 # Check that the index (+ index_from) is not larger than indexTo
1465                 # In other terms, if the index is valid
1466                 assert index >= 0
1467                 var target = self.target
1468                 assert (index + target.index_from) <= target.index_to
1469                 return target.items[index + target.index_from]
1470         end
1471
1472         redef fun iterator_from(start) do return new FlatStringIterator.with_pos(target, start)
1473
1474         redef fun reverse_iterator_from(start) do return new FlatStringReverseIterator.with_pos(target, start)
1475
1476 end
1477
1478 # A mutable sequence of characters.
1479 abstract class Buffer
1480         super Text
1481
1482         redef type SELFTYPE: Buffer is fixed
1483
1484         # Specific implementations MUST set this to `true` in order to invalidate caches
1485         protected var is_dirty = true
1486
1487         # Copy-On-Write flag
1488         #
1489         # If the `Buffer` was to_s'd, the next in-place altering
1490         # operation will cause the current `Buffer` to be re-allocated.
1491         #
1492         # The flag will then be set at `false`.
1493         protected var written = false
1494
1495         # Modifies the char contained at pos `index`
1496         #
1497         # DEPRECATED : Use self.chars.[]= instead
1498         fun []=(index: Int, item: Char) is abstract
1499
1500         # Adds a char `c` at the end of self
1501         #
1502         # DEPRECATED : Use self.chars.add instead
1503         fun add(c: Char) is abstract
1504
1505         # Clears the buffer
1506         #
1507         #     var b = new FlatBuffer
1508         #     b.append "hello"
1509         #     assert not b.is_empty
1510         #     b.clear
1511         #     assert b.is_empty
1512         fun clear is abstract
1513
1514         # Enlarges the subsequent array containing the chars of self
1515         fun enlarge(cap: Int) is abstract
1516
1517         # Adds the content of text `s` at the end of self
1518         #
1519         #     var b = new FlatBuffer
1520         #     b.append "hello"
1521         #     b.append "world"
1522         #     assert b == "helloworld"
1523         fun append(s: Text) is abstract
1524
1525         # `self` is appended in such a way that `self` is repeated `r` times
1526         #
1527         #     var b = new FlatBuffer
1528         #     b.append "hello"
1529         #     b.times 3
1530         #     assert b == "hellohellohello"
1531         fun times(r: Int) is abstract
1532
1533         # Reverses itself in-place
1534         #
1535         #     var b = new FlatBuffer
1536         #     b.append("hello")
1537         #     b.reverse
1538         #     assert b == "olleh"
1539         fun reverse is abstract
1540
1541         # Changes each lower-case char in `self` by its upper-case variant
1542         #
1543         #     var b = new FlatBuffer
1544         #     b.append("Hello World!")
1545         #     b.upper
1546         #     assert b == "HELLO WORLD!"
1547         fun upper is abstract
1548
1549         # Changes each upper-case char in `self` by its lower-case variant
1550         #
1551         #     var b = new FlatBuffer
1552         #     b.append("Hello World!")
1553         #     b.lower
1554         #     assert b == "hello world!"
1555         fun lower is abstract
1556
1557         # Capitalizes each word in `self`
1558         #
1559         # Letters that follow a letter are lowercased
1560         # Letters that follow a non-letter are upcased.
1561         #
1562         # SEE: `Char::is_letter` for the definition of a letter.
1563         #
1564         #     var b = new FlatBuffer.from("jAVAsCriPt")
1565         #     b.capitalize
1566         #     assert b == "Javascript"
1567         #     b = new FlatBuffer.from("i am root")
1568         #     b.capitalize
1569         #     assert b == "I Am Root"
1570         #     b = new FlatBuffer.from("ab_c -ab0c ab\nc")
1571         #     b.capitalize
1572         #     assert b == "Ab_C -Ab0C Ab\nC"
1573         fun capitalize do
1574                 if length == 0 then return
1575                 var c = self[0].to_upper
1576                 self[0] = c
1577                 var prev = c
1578                 for i in [1 .. length[ do
1579                         prev = c
1580                         c = self[i]
1581                         if prev.is_letter then
1582                                 self[i] = c.to_lower
1583                         else
1584                                 self[i] = c.to_upper
1585                         end
1586                 end
1587         end
1588
1589         redef fun hash
1590         do
1591                 if is_dirty then hash_cache = null
1592                 return super
1593         end
1594
1595         # In Buffers, the internal sequence of character is mutable
1596         # Thus, `chars` can be used to modify the buffer.
1597         redef fun chars: Sequence[Char] is abstract
1598 end
1599
1600 # Mutable strings of characters.
1601 class FlatBuffer
1602         super FlatText
1603         super Buffer
1604
1605         redef var chars: Sequence[Char] = new FlatBufferCharView(self) is lazy
1606
1607         private var capacity: Int = 0
1608
1609         redef fun fast_cstring do return items.fast_cstring(0)
1610
1611         redef fun substrings do return new FlatSubstringsIter(self)
1612
1613         # Re-copies the `NativeString` into a new one and sets it as the new `Buffer`
1614         #
1615         # This happens when an operation modifies the current `Buffer` and
1616         # the Copy-On-Write flag `written` is set at true.
1617         private fun reset do
1618                 var nns = new NativeString(capacity)
1619                 items.copy_to(nns, length, 0, 0)
1620                 items = nns
1621                 written = false
1622         end
1623
1624         redef fun [](index)
1625         do
1626                 assert index >= 0
1627                 assert index  < length
1628                 return items[index]
1629         end
1630
1631         redef fun []=(index, item)
1632         do
1633                 is_dirty = true
1634                 if index == length then
1635                         add(item)
1636                         return
1637                 end
1638                 if written then reset
1639                 assert index >= 0 and index < length
1640                 items[index] = item
1641         end
1642
1643         redef fun add(c)
1644         do
1645                 is_dirty = true
1646                 if capacity <= length then enlarge(length + 5)
1647                 items[length] = c
1648                 length += 1
1649         end
1650
1651         redef fun clear do
1652                 is_dirty = true
1653                 if written then reset
1654                 length = 0
1655         end
1656
1657         redef fun empty do return new FlatBuffer
1658
1659         redef fun enlarge(cap)
1660         do
1661                 var c = capacity
1662                 if cap <= c then return
1663                 while c <= cap do c = c * 2 + 2
1664                 # The COW flag can be set at false here, since
1665                 # it does a copy of the current `Buffer`
1666                 written = false
1667                 var a = new NativeString(c+1)
1668                 if length > 0 then items.copy_to(a, length, 0, 0)
1669                 items = a
1670                 capacity = c
1671         end
1672
1673         redef fun to_s: String
1674         do
1675                 written = true
1676                 if length == 0 then items = new NativeString(1)
1677                 return new FlatString.with_infos(items, length, 0, length - 1)
1678         end
1679
1680         redef fun to_cstring
1681         do
1682                 if is_dirty then
1683                         var new_native = new NativeString(length + 1)
1684                         new_native[length] = '\0'
1685                         if length > 0 then items.copy_to(new_native, length, 0, 0)
1686                         real_items = new_native
1687                         is_dirty = false
1688                 end
1689                 return real_items.as(not null)
1690         end
1691
1692         # Create a new empty string.
1693         init do end
1694
1695         # Low-level creation a new buffer with given data.
1696         #
1697         # `items` will be used as is, without copy, to store the characters of the buffer.
1698         # Aliasing issues is the responsibility of the caller.
1699         #
1700         # If `items` is shared, `written` should be set to true after the creation
1701         # so that a modification will do a copy-on-write.
1702         private init with_infos(items: NativeString, capacity, length: Int)
1703         do
1704                 self.items = items
1705                 self.length = length
1706                 self.capacity = capacity
1707         end
1708
1709         # Create a new string copied from `s`.
1710         init from(s: Text)
1711         do
1712                 capacity = s.length + 1
1713                 length = s.length
1714                 items = new NativeString(capacity)
1715                 if s isa FlatString then
1716                         s.items.copy_to(items, length, s.index_from, 0)
1717                 else if s isa FlatBuffer then
1718                         s.items.copy_to(items, length, 0, 0)
1719                 else
1720                         var curr_pos = 0
1721                         for i in [0..s.length[ do
1722                                 var c = s.chars[i]
1723                                 items[curr_pos] = c
1724                                 curr_pos += 1
1725                         end
1726                 end
1727         end
1728
1729         # Create a new empty string with a given capacity.
1730         init with_capacity(cap: Int)
1731         do
1732                 assert cap >= 0
1733                 items = new NativeString(cap+1)
1734                 capacity = cap
1735                 length = 0
1736         end
1737
1738         redef fun append(s)
1739         do
1740                 if s.is_empty then return
1741                 is_dirty = true
1742                 var sl = s.length
1743                 if capacity < length + sl then enlarge(length + sl)
1744                 if s isa FlatString then
1745                         s.items.copy_to(items, sl, s.index_from, length)
1746                 else if s isa FlatBuffer then
1747                         s.items.copy_to(items, sl, 0, length)
1748                 else
1749                         var curr_pos = self.length
1750                         for i in [0..s.length[ do
1751                                 var c = s.chars[i]
1752                                 items[curr_pos] = c
1753                                 curr_pos += 1
1754                         end
1755                 end
1756                 length += sl
1757         end
1758
1759         # Copies the content of self in `dest`
1760         fun copy(start: Int, len: Int, dest: Buffer, new_start: Int)
1761         do
1762                 var self_chars = self.chars
1763                 var dest_chars = dest.chars
1764                 for i in [0..len-1] do
1765                         dest_chars[new_start+i] = self_chars[start+i]
1766                 end
1767         end
1768
1769         redef fun substring(from, count)
1770         do
1771                 assert count >= 0
1772                 count += from
1773                 if from < 0 then from = 0
1774                 if count > length then count = length
1775                 if from < count then
1776                         var len = count - from
1777                         var r_items = new NativeString(len)
1778                         items.copy_to(r_items, len, from, 0)
1779                         var r = new FlatBuffer.with_infos(r_items, len, len)
1780                         return r
1781                 else
1782                         return new FlatBuffer
1783                 end
1784         end
1785
1786         redef fun reverse
1787         do
1788                 written = false
1789                 var ns = new NativeString(capacity)
1790                 var si = length - 1
1791                 var ni = 0
1792                 var it = items
1793                 while si >= 0 do
1794                         ns[ni] = it[si]
1795                         ni += 1
1796                         si -= 1
1797                 end
1798                 items = ns
1799         end
1800
1801         redef fun times(repeats)
1802         do
1803                 var x = new FlatString.with_infos(items, length, 0, length - 1)
1804                 for i in [1..repeats[ do
1805                         append(x)
1806                 end
1807         end
1808
1809         redef fun upper
1810         do
1811                 if written then reset
1812                 var it = items
1813                 var id = length - 1
1814                 while id >= 0 do
1815                         it[id] = it[id].to_upper
1816                         id -= 1
1817                 end
1818         end
1819
1820         redef fun lower
1821         do
1822                 if written then reset
1823                 var it = items
1824                 var id = length - 1
1825                 while id >= 0 do
1826                         it[id] = it[id].to_lower
1827                         id -= 1
1828                 end
1829         end
1830 end
1831
1832 private class FlatBufferReverseIterator
1833         super IndexedIterator[Char]
1834
1835         var target: FlatBuffer
1836
1837         var target_items: NativeString
1838
1839         var curr_pos: Int
1840
1841         init with_pos(tgt: FlatBuffer, pos: Int)
1842         do
1843                 target = tgt
1844                 if tgt.length > 0 then target_items = tgt.items
1845                 curr_pos = pos
1846         end
1847
1848         redef fun index do return curr_pos
1849
1850         redef fun is_ok do return curr_pos >= 0
1851
1852         redef fun item do return target_items[curr_pos]
1853
1854         redef fun next do curr_pos -= 1
1855
1856 end
1857
1858 private class FlatBufferCharView
1859         super BufferCharView
1860
1861         redef type SELFTYPE: FlatBuffer
1862
1863         redef fun [](index) do return target.items[index]
1864
1865         redef fun []=(index, item)
1866         do
1867                 assert index >= 0 and index <= length
1868                 if index == length then
1869                         add(item)
1870                         return
1871                 end
1872                 target.items[index] = item
1873         end
1874
1875         redef fun push(c)
1876         do
1877                 target.add(c)
1878         end
1879
1880         redef fun add(c)
1881         do
1882                 target.add(c)
1883         end
1884
1885         fun enlarge(cap: Int)
1886         do
1887                 target.enlarge(cap)
1888         end
1889
1890         redef fun append(s)
1891         do
1892                 var s_length = s.length
1893                 if target.capacity < s.length then enlarge(s_length + target.length)
1894         end
1895
1896         redef fun iterator_from(pos) do return new FlatBufferIterator.with_pos(target, pos)
1897
1898         redef fun reverse_iterator_from(pos) do return new FlatBufferReverseIterator.with_pos(target, pos)
1899
1900 end
1901
1902 private class FlatBufferIterator
1903         super IndexedIterator[Char]
1904
1905         var target: FlatBuffer
1906
1907         var target_items: NativeString
1908
1909         var curr_pos: Int
1910
1911         init with_pos(tgt: FlatBuffer, pos: Int)
1912         do
1913                 target = tgt
1914                 if tgt.length > 0 then target_items = tgt.items
1915                 curr_pos = pos
1916         end
1917
1918         redef fun index do return curr_pos
1919
1920         redef fun is_ok do return curr_pos < target.length
1921
1922         redef fun item do return target_items[curr_pos]
1923
1924         redef fun next do curr_pos += 1
1925
1926 end
1927
1928 ###############################################################################
1929 # Refinement                                                                  #
1930 ###############################################################################
1931
1932 redef class Object
1933         # User readable representation of `self`.
1934         fun to_s: String do return inspect
1935
1936         # The class name of the object in NativeString format.
1937         private fun native_class_name: NativeString is intern
1938
1939         # The class name of the object.
1940         #
1941         #     assert 5.class_name == "Int"
1942         fun class_name: String do return native_class_name.to_s
1943
1944         # Developer readable representation of `self`.
1945         # Usually, it uses the form "<CLASSNAME:#OBJECTID bla bla bla>"
1946         fun inspect: String
1947         do
1948                 return "<{inspect_head}>"
1949         end
1950
1951         # Return "CLASSNAME:#OBJECTID".
1952         # This function is mainly used with the redefinition of the inspect method
1953         protected fun inspect_head: String
1954         do
1955                 return "{class_name}:#{object_id.to_hex}"
1956         end
1957 end
1958
1959 redef class Bool
1960         #     assert true.to_s         == "true"
1961         #     assert false.to_s        == "false"
1962         redef fun to_s
1963         do
1964                 if self then
1965                         return once "true"
1966                 else
1967                         return once "false"
1968                 end
1969         end
1970 end
1971
1972 redef class Int
1973
1974         # Wrapper of strerror C function
1975         private fun strerror_ext: NativeString is extern "strerror"
1976
1977         # Returns a string describing error number
1978         fun strerror: String do return strerror_ext.to_s
1979
1980         # Fill `s` with the digits in base `base` of `self` (and with the '-' sign if 'signed' and negative).
1981         # assume < to_c max const of char
1982         private fun fill_buffer(s: Buffer, base: Int, signed: Bool)
1983         do
1984                 var n: Int
1985                 # Sign
1986                 if self < 0 then
1987                         n = - self
1988                         s.chars[0] = '-'
1989                 else if self == 0 then
1990                         s.chars[0] = '0'
1991                         return
1992                 else
1993                         n = self
1994                 end
1995                 # Fill digits
1996                 var pos = digit_count(base) - 1
1997                 while pos >= 0 and n > 0 do
1998                         s.chars[pos] = (n % base).to_c
1999                         n = n / base # /
2000                         pos -= 1
2001                 end
2002         end
2003
2004         # C function to calculate the length of the `NativeString` to receive `self`
2005         private fun int_to_s_len: Int is extern "native_int_length_str"
2006
2007         # C function to convert an nit Int to a NativeString (char*)
2008         private fun native_int_to_s(nstr: NativeString, strlen: Int) is extern "native_int_to_s"
2009
2010         # return displayable int in base 10 and signed
2011         #
2012         #     assert 1.to_s            == "1"
2013         #     assert (-123).to_s       == "-123"
2014         redef fun to_s do
2015                 # Fast case for common numbers
2016                 if self == 0 then return "0"
2017                 if self == 1 then return "1"
2018
2019                 var nslen = int_to_s_len
2020                 var ns = new NativeString(nslen + 1)
2021                 ns[nslen] = '\0'
2022                 native_int_to_s(ns, nslen + 1)
2023                 return ns.to_s_with_length(nslen)
2024         end
2025
2026         # return displayable int in hexadecimal
2027         #
2028         #     assert 1.to_hex  == "1"
2029         #     assert (-255).to_hex  == "-ff"
2030         fun to_hex: String do return to_base(16,false)
2031
2032         # return displayable int in base base and signed
2033         fun to_base(base: Int, signed: Bool): String
2034         do
2035                 var l = digit_count(base)
2036                 var s = new FlatBuffer.from(" " * l)
2037                 fill_buffer(s, base, signed)
2038                 return s.to_s
2039         end
2040 end
2041
2042 redef class Float
2043         # Pretty representation of `self`, with decimals as needed from 1 to a maximum of 3
2044         #
2045         #     assert 12.34.to_s       == "12.34"
2046         #     assert (-0120.030).to_s == "-120.03"
2047         #
2048         # see `to_precision` for a custom precision.
2049         redef fun to_s do
2050                 var str = to_precision( 3 )
2051                 if is_inf != 0 or is_nan then return str
2052                 var len = str.length
2053                 for i in [0..len-1] do
2054                         var j = len-1-i
2055                         var c = str.chars[j]
2056                         if c == '0' then
2057                                 continue
2058                         else if c == '.' then
2059                                 return str.substring( 0, j+2 )
2060                         else
2061                                 return str.substring( 0, j+1 )
2062                         end
2063                 end
2064                 return str
2065         end
2066
2067         # `String` representation of `self` with the given number of `decimals`
2068         #
2069         #     assert 12.345.to_precision(0)    == "12"
2070         #     assert 12.345.to_precision(3)    == "12.345"
2071         #     assert (-12.345).to_precision(3) == "-12.345"
2072         #     assert (-0.123).to_precision(3)  == "-0.123"
2073         #     assert 0.999.to_precision(2)     == "1.00"
2074         #     assert 0.999.to_precision(4)     == "0.9990"
2075         fun to_precision(decimals: Int): String
2076         do
2077                 if is_nan then return "nan"
2078
2079                 var isinf = self.is_inf
2080                 if isinf == 1 then
2081                         return "inf"
2082                 else if isinf == -1 then
2083                         return  "-inf"
2084                 end
2085
2086                 if decimals == 0 then return self.to_i.to_s
2087                 var f = self
2088                 for i in [0..decimals[ do f = f * 10.0
2089                 if self > 0.0 then
2090                         f = f + 0.5
2091                 else
2092                         f = f - 0.5
2093                 end
2094                 var i = f.to_i
2095                 if i == 0 then return "0." + "0"*decimals
2096
2097                 # Prepare both parts of the float, before and after the "."
2098                 var s = i.abs.to_s
2099                 var sl = s.length
2100                 var p1
2101                 var p2
2102                 if sl > decimals then
2103                         # Has something before the "."
2104                         p1 = s.substring(0, sl-decimals)
2105                         p2 = s.substring(sl-decimals, decimals)
2106                 else
2107                         p1 = "0"
2108                         p2 = "0"*(decimals-sl) + s
2109                 end
2110
2111                 if i < 0 then p1 = "-" + p1
2112
2113                 return p1 + "." + p2
2114         end
2115 end
2116
2117 redef class Char
2118         #     assert 'x'.to_s    == "x"
2119         redef fun to_s
2120         do
2121                 var s = new FlatBuffer.with_capacity(1)
2122                 s.chars[0] = self
2123                 return s.to_s
2124         end
2125
2126         # Returns true if the char is a numerical digit
2127         #
2128         #     assert '0'.is_numeric
2129         #     assert '9'.is_numeric
2130         #     assert not 'a'.is_numeric
2131         #     assert not '?'.is_numeric
2132         fun is_numeric: Bool
2133         do
2134                 return self >= '0' and self <= '9'
2135         end
2136
2137         # Returns true if the char is an alpha digit
2138         #
2139         #     assert 'a'.is_alpha
2140         #     assert 'Z'.is_alpha
2141         #     assert not '0'.is_alpha
2142         #     assert not '?'.is_alpha
2143         fun is_alpha: Bool
2144         do
2145                 return (self >= 'a' and self <= 'z') or (self >= 'A' and self <= 'Z')
2146         end
2147
2148         # Returns true if the char is an alpha or a numeric digit
2149         #
2150         #     assert 'a'.is_alphanumeric
2151         #     assert 'Z'.is_alphanumeric
2152         #     assert '0'.is_alphanumeric
2153         #     assert '9'.is_alphanumeric
2154         #     assert not '?'.is_alphanumeric
2155         fun is_alphanumeric: Bool
2156         do
2157                 return self.is_numeric or self.is_alpha
2158         end
2159 end
2160
2161 redef class Collection[E]
2162         # Concatenate elements.
2163         redef fun to_s
2164         do
2165                 var s = new FlatBuffer
2166                 for e in self do if e != null then s.append(e.to_s)
2167                 return s.to_s
2168         end
2169
2170         # Concatenate and separate each elements with `sep`.
2171         #
2172         #     assert [1, 2, 3].join(":")         == "1:2:3"
2173         #     assert [1..3].join(":")            == "1:2:3"
2174         fun join(sep: Text): String
2175         do
2176                 if is_empty then return ""
2177
2178                 var s = new FlatBuffer # Result
2179
2180                 # Concat first item
2181                 var i = iterator
2182                 var e = i.item
2183                 if e != null then s.append(e.to_s)
2184
2185                 # Concat other items
2186                 i.next
2187                 while i.is_ok do
2188                         s.append(sep)
2189                         e = i.item
2190                         if e != null then s.append(e.to_s)
2191                         i.next
2192                 end
2193                 return s.to_s
2194         end
2195 end
2196
2197 redef class Array[E]
2198
2199         # Fast implementation
2200         redef fun to_s
2201         do
2202                 var l = length
2203                 if l == 0 then return ""
2204                 if l == 1 then if self[0] == null then return "" else return self[0].to_s
2205                 var its = _items
2206                 var na = new NativeArray[String](l)
2207                 var i = 0
2208                 var sl = 0
2209                 var mypos = 0
2210                 while i < l do
2211                         var itsi = its[i]
2212                         if itsi == null then
2213                                 i += 1
2214                                 continue
2215                         end
2216                         var tmp = itsi.to_s
2217                         sl += tmp.length
2218                         na[mypos] = tmp
2219                         i += 1
2220                         mypos += 1
2221                 end
2222                 var ns = new NativeString(sl + 1)
2223                 ns[sl] = '\0'
2224                 i = 0
2225                 var off = 0
2226                 while i < mypos do
2227                         var tmp = na[i]
2228                         var tpl = tmp.length
2229                         if tmp isa FlatString then
2230                                 tmp.items.copy_to(ns, tpl, tmp.index_from, off)
2231                                 off += tpl
2232                         else
2233                                 for j in tmp.substrings do
2234                                         var s = j.as(FlatString)
2235                                         var slen = s.length
2236                                         s.items.copy_to(ns, slen, s.index_from, off)
2237                                         off += slen
2238                                 end
2239                         end
2240                         i += 1
2241                 end
2242                 return ns.to_s_with_length(sl)
2243         end
2244 end
2245
2246 redef class NativeArray[E]
2247         # Join all the elements using `to_s`
2248         #
2249         # REQUIRE: `self isa NativeArray[String]`
2250         # REQUIRE: all elements are initialized
2251         fun native_to_s: String
2252         do
2253                 assert self isa NativeArray[String]
2254                 var l = length
2255                 var na = self
2256                 var i = 0
2257                 var sl = 0
2258                 var mypos = 0
2259                 while i < l do
2260                         sl += na[i].length
2261                         i += 1
2262                         mypos += 1
2263                 end
2264                 var ns = new NativeString(sl + 1)
2265                 ns[sl] = '\0'
2266                 i = 0
2267                 var off = 0
2268                 while i < mypos do
2269                         var tmp = na[i]
2270                         var tpl = tmp.length
2271                         if tmp isa FlatString then
2272                                 tmp.items.copy_to(ns, tpl, tmp.index_from, off)
2273                                 off += tpl
2274                         else
2275                                 for j in tmp.substrings do
2276                                         var s = j.as(FlatString)
2277                                         var slen = s.length
2278                                         s.items.copy_to(ns, slen, s.index_from, off)
2279                                         off += slen
2280                                 end
2281                         end
2282                         i += 1
2283                 end
2284                 return ns.to_s_with_length(sl)
2285         end
2286 end
2287
2288 redef class Map[K,V]
2289         # Concatenate couple of 'key value'.
2290         # key and value are separated by `couple_sep`.
2291         # each couple is separated each couple with `sep`.
2292         #
2293         #     var m = new ArrayMap[Int, String]
2294         #     m[1] = "one"
2295         #     m[10] = "ten"
2296         #     assert m.join("; ", "=") == "1=one; 10=ten"
2297         fun join(sep: String, couple_sep: String): String
2298         do
2299                 if is_empty then return ""
2300
2301                 var s = new FlatBuffer # Result
2302
2303                 # Concat first item
2304                 var i = iterator
2305                 var k = i.key
2306                 var e = i.item
2307                 s.append("{k or else "<null>"}{couple_sep}{e or else "<null>"}")
2308
2309                 # Concat other items
2310                 i.next
2311                 while i.is_ok do
2312                         s.append(sep)
2313                         k = i.key
2314                         e = i.item
2315                         s.append("{k or else "<null>"}{couple_sep}{e or else "<null>"}")
2316                         i.next
2317                 end
2318                 return s.to_s
2319         end
2320 end
2321
2322 ###############################################################################
2323 # Native classes                                                              #
2324 ###############################################################################
2325
2326 # Native strings are simple C char *
2327 extern class NativeString `{ char* `}
2328         # Creates a new NativeString with a capacity of `length`
2329         new(length: Int) is intern
2330
2331         # Returns a char* starting at `index`.
2332         #
2333         # WARNING: Unsafe for extern code, use only for temporary
2334         # pointer manipulation purposes (e.g. write to file or such)
2335         fun fast_cstring(index: Int): NativeString is intern
2336
2337         # Get char at `index`.
2338         fun [](index: Int): Char is intern
2339
2340         # Set char `item` at index.
2341         fun []=(index: Int, item: Char) is intern
2342
2343         # Copy `self` to `dest`.
2344         fun copy_to(dest: NativeString, length: Int, from: Int, to: Int) is intern
2345
2346         # Position of the first nul character.
2347         fun cstring_length: Int
2348         do
2349                 var l = 0
2350                 while self[l] != '\0' do l += 1
2351                 return l
2352         end
2353
2354         # Parse `self` as an Int.
2355         fun atoi: Int is intern
2356
2357         # Parse `self` as a Float.
2358         fun atof: Float is extern "atof"
2359
2360         redef fun to_s
2361         do
2362                 return to_s_with_length(cstring_length)
2363         end
2364
2365         # Returns `self` as a String of `length`.
2366         fun to_s_with_length(length: Int): FlatString
2367         do
2368                 assert length >= 0
2369                 var str = new FlatString.with_infos(self, length, 0, length - 1)
2370                 return str
2371         end
2372
2373         # Returns `self` as a new String.
2374         fun to_s_with_copy: FlatString
2375         do
2376                 var length = cstring_length
2377                 var new_self = new NativeString(length + 1)
2378                 copy_to(new_self, length, 0, 0)
2379                 var str = new FlatString.with_infos(new_self, length, 0, length - 1)
2380                 new_self[length] = '\0'
2381                 str.real_items = new_self
2382                 return str
2383         end
2384 end
2385
2386 redef class Sys
2387         private var args_cache: nullable Sequence[String]
2388
2389         # The arguments of the program as given by the OS
2390         fun program_args: Sequence[String]
2391         do
2392                 if _args_cache == null then init_args
2393                 return _args_cache.as(not null)
2394         end
2395
2396         # The name of the program as given by the OS
2397         fun program_name: String
2398         do
2399                 return native_argv(0).to_s
2400         end
2401
2402         # Initialize `program_args` with the contents of `native_argc` and `native_argv`.
2403         private fun init_args
2404         do
2405                 var argc = native_argc
2406                 var args = new Array[String].with_capacity(0)
2407                 var i = 1
2408                 while i < argc do
2409                         args[i-1] = native_argv(i).to_s
2410                         i += 1
2411                 end
2412                 _args_cache = args
2413         end
2414
2415         # First argument of the main C function.
2416         private fun native_argc: Int is intern
2417
2418         # Second argument of the main C function.
2419         private fun native_argv(i: Int): NativeString is intern
2420 end
2421
2422 # Comparator that efficienlty use `to_s` to compare things
2423 #
2424 # The comparaison call `to_s` on object and use the result to order things.
2425 #
2426 #     var a = [1, 2, 3, 10, 20]
2427 #     (new CachedAlphaComparator).sort(a)
2428 #     assert a == [1, 10, 2, 20, 3]
2429 #
2430 # Internally the result of `to_s` is cached in a HashMap to counter
2431 # uneficient implementation of `to_s`.
2432 #
2433 # Note: it caching is not usefull, see `alpha_comparator`
2434 class CachedAlphaComparator
2435         super Comparator
2436         redef type COMPARED: Object
2437
2438         private var cache = new HashMap[Object, String]
2439
2440         private fun do_to_s(a: Object): String do
2441                 if cache.has_key(a) then return cache[a]
2442                 var res = a.to_s
2443                 cache[a] = res
2444                 return res
2445         end
2446
2447         redef fun compare(a, b) do
2448                 return do_to_s(a) <=> do_to_s(b)
2449         end
2450 end
2451
2452 # see `alpha_comparator`
2453 private class AlphaComparator
2454         super Comparator
2455         redef fun compare(a, b) do return a.to_s <=> b.to_s
2456 end
2457
2458 # Stateless comparator that naively use `to_s` to compare things.
2459 #
2460 # Note: the result of `to_s` is not cached, thus can be invoked a lot
2461 # on a single instace. See `CachedAlphaComparator` as an alternative.
2462 #
2463 #     var a = [1, 2, 3, 10, 20]
2464 #     alpha_comparator.sort(a)
2465 #     assert a == [1, 10, 2, 20, 3]
2466 fun alpha_comparator: Comparator do return once new AlphaComparator
2467
2468 # The arguments of the program as given by the OS
2469 fun args: Sequence[String]
2470 do
2471         return sys.program_args
2472 end