src/nitls.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Simple tool to list Nit source files
  18 module nitls
  19
  20 intrude import modelbuilder
  21 import ordered_tree
  22
  23 class ProjTree
  24         super OrderedTree[Object]
  25
  26         var opt_paths = false
  27
  28         redef fun display(o)
  29         do
  30                 if o isa MGroup then
  31                         if opt_paths then
  32                                 return o.filepath.as(not null)
  33                         else
  34                                 return "{o.name} ({o.filepath})"
  35                         end
  36                 else if o isa ModulePath then
  37                         if opt_paths then
  38                                 return o.filepath
  39                         else
  40                                 return "{o.name} ({o.filepath})"
  41                         end
  42                 else
  43                         abort
  44                 end
  45         end
  46 end
  47
  48 var tc = new ToolContext
  49 var model = new Model
  50 var mb = new ModelBuilder(model, tc)
  51
  52 var opt_keep = new OptionBool("Ignore errors and files that are not a Nit source file", "-k", "--keep")
  53 var opt_recursive = new OptionBool("Process directories recussively", "-r", "--recursive")
  54 var opt_tree = new OptionBool("List source files in their groups and projects", "-t", "--tree")
  55 var opt_source = new OptionBool("List source files", "-s", "--source")
  56 var opt_project = new OptionBool("List projects paths (default)", "-p", "--project")
  57 var opt_depends = new OptionBool("List dependencies of given modules", "-d", "--depends")
  58 var opt_paths = new OptionBool("List only path (instead of name + path)", "-p", "--path")
  59
  60 tc.option_context.add_option(opt_keep, opt_recursive, opt_tree, opt_source, opt_project, opt_depends, opt_paths)
  61 tc.tooldescription = "Usage: nitls [OPTION]... <file.nit|directory>...\nLists the projects and/or paths of Nit sources files."
  62 tc.process_options(args)
  63
  64 var sum = opt_tree.value.to_i + opt_source.value.to_i + opt_project.value.to_i
  65 if sum > 1 then
  66         print "Error: options --tree, --source, and --project are exclusives."
  67         print tc.tooldescription
  68         exit 1
  69 end
  70
  71 if opt_depends.value then
  72         if opt_recursive.value then
  73                 print "-M incompatible with -r"
  74                 exit 1
  75         end
  76
  77         mb.parse(tc.option_context.rest)
  78 else
  79         var files
  80         if opt_recursive.value then
  81                 files = new Array[String]
  82                 for d in tc.option_context.rest do
  83                         var pipe = new IProcess("find", d, "-name", "*.nit")
  84                         while not pipe.eof do
  85                                 var l = pipe.read_line
  86                                 if l == "" then break # last line
  87                                 l = l.substring(0,l.length-1) # strip last oef
  88                                 files.add l
  89                         end
  90                         pipe.close
  91                         pipe.wait
  92                         if pipe.status != 0 and not opt_keep.value then exit 1
  93                 end
  94         else
  95                 files = tc.option_context.rest
  96         end
  97
  98         for a in files do
  99                 var mp = mb.identify_file(a)
 100                 if mp == null then
 101                         if not opt_keep.value then tc.check_errors
 102                 end
 103         end
 104 end
 105
 106 if sum == 0 then opt_project.value = true
 107
 108 if opt_tree.value then
 109         var ot = new ProjTree
 110         ot.opt_paths = opt_paths.value
 111         for p in model.mprojects do
 112                 for g in p.mgroups do
 113                         ot.add(g.parent, g)
 114                         for mp in g.module_paths do
 115                                 ot.add(g, mp)
 116                         end
 117                 end
 118         end
 119         ot.sort_with(new CachedAlphaComparator)
 120         ot.write_to(stdout)
 121 end
 122
 123 if opt_source.value then
 124         var list = new Array[String]
 125         for p in model.mprojects do
 126                 for g in p.mgroups do
 127                         for mp in g.module_paths do
 128                                 if opt_paths.value then
 129                                         list.add(mp.filepath)
 130                                 else
 131                                         list.add("{g.full_name}/{mp.name} ({mp.filepath})")
 132                                 end
 133                         end
 134                 end
 135         end
 136         alpha_comparator.sort(list)
 137         for l in list do print l
 138 end
 139
 140 if opt_project.value then
 141         var list = new Array[String]
 142         for p in model.mprojects do
 143                 var path = p.root.filepath.as(not null)
 144                 if opt_paths.value then
 145                         list.add(path)
 146                 else
 147                         list.add("{p.name} ({path})")
 148                 end
 149         end
 150         alpha_comparator.sort(list)
 151         for l in list do print l
 152 end