lib/glesv2/glesv2.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # OpenGL graphics rendering library for embedded systems, version 2.0
  18 #
  19 # This is a low-level wrapper, it can be useful for developers already familiar
  20 # with the C API of OpenGL. Most developers will prefer to use higher level
  21 # wrappers such as `mnit` and `gammit`.
  22 #
  23 # Defines the annotations `glsl_vertex_shader` and `glsl_fragment_shader`
  24 # applicable on string literals to check shader code using `glslangValidator`.
  25 # The tool must be in PATH. It can be downloaded from
  26 # https://www.khronos.org/opengles/sdk/tools/Reference-Compiler/
  27 #
  28 # Most services of this module are a direct wrapper of the underlying
  29 # C library. If a method or class is not documented in Nit, refer to
  30 # the official documentation by the Khronos Group at:
  31 # http://www.khronos.org/opengles/sdk/docs/man/
  32 module glesv2 is
  33         pkgconfig
  34         new_annotation glsl_vertex_shader
  35         new_annotation glsl_fragment_shader
  36         ldflags("-lGLESv2")@android
  37 end
  38
  39 import android::aware
  40 intrude import c
  41
  42 in "C Header" `{
  43         #include <GLES2/gl2.h>
  44 `}
  45
  46 # OpenGL ES program to which we attach shaders
  47 extern class GLProgram `{GLuint`}
  48         # Create a new program
  49         #
  50         # The newly created instance should be checked using `is_ok`.
  51         new `{ return glCreateProgram(); `}
  52
  53         # Is this a valid program?
  54         fun is_ok: Bool `{ return glIsProgram(self); `}
  55
  56         # Attach a `shader` to this program
  57         fun attach_shader(shader: GLShader) `{ glAttachShader(self, shader); `}
  58
  59         # Set the location for the attribute by `name`
  60         fun bind_attrib_location(index: Int, name: String) import String.to_cstring `{
  61                 GLchar *c_name = String_to_cstring(name);
  62                 glBindAttribLocation(self, index, c_name);
  63         `}
  64
  65         # Get the location of the attribute by `name`
  66         #
  67         # Returns `-1` if there is no active attribute named `name`.
  68         fun attrib_location(name: String): Int import String.to_cstring `{
  69                 GLchar *c_name = String_to_cstring(name);
  70                 return glGetAttribLocation(self, c_name);
  71         `}
  72
  73         # Get the location of the uniform by `name`
  74         #
  75         # Returns `-1` if there is no active uniform named `name`.
  76         fun uniform_location(name: String): Int import String.to_cstring `{
  77                 GLchar *c_name = String_to_cstring(name);
  78                 return glGetUniformLocation(self, c_name);
  79         `}
  80
  81         # Query information on this program
  82         fun query(pname: Int): Int `{
  83                 int val;
  84                 glGetProgramiv(self, pname, &val);
  85                 return val;
  86         `}
  87
  88         # Try to link this program
  89         #
  90         # Check result using `in_linked` and `info_log`.
  91         fun link `{ glLinkProgram(self); `}
  92
  93         # Is this program linked?
  94         fun is_linked: Bool do return query(0x8B82) != 0
  95
  96         # Use this program for the following operations
  97         fun use `{ glUseProgram(self); `}
  98
  99         # Delete this program
 100         fun delete `{ glDeleteProgram(self); `}
 101
 102         # Has this program been deleted?
 103         fun is_deleted: Bool do return query(0x8B80) != 0
 104
 105         # Validate whether this program can be executed in the current OpenGL state
 106         #
 107         # Check results using `is_validated` and `info_log`.
 108         fun validate `{ glValidateProgram(self); `}
 109
 110         # Boolean result of `validate`, must be called after `validate`
 111         fun is_validated: Bool do return query(0x8B83) != 0
 112
 113         # Retrieve the information log of this program
 114         #
 115         # Useful with `link` and `validate`
 116         fun info_log: String import NativeString.to_s `{
 117                 int size;
 118                 glGetProgramiv(self, GL_INFO_LOG_LENGTH, &size);
 119                 GLchar *msg = malloc(size);
 120                 glGetProgramInfoLog(self, size, NULL, msg);
 121                 return NativeString_to_s(msg);
 122         `}
 123
 124         # Number of active uniform in this program
 125         #
 126         # This should be the number of uniforms declared in all shader, except
 127         # unused uniforms which may have been optimized out.
 128         fun n_active_uniforms: Int do return query(0x8B86)
 129
 130         # Length of the longest uniform name in this program, including `\n`
 131         fun active_uniform_max_length: Int do return query(0x8B87)
 132
 133         # Number of active attributes in this program
 134         #
 135         # This should be the number of uniforms declared in all shader, except
 136         # unused uniforms which may have been optimized out.
 137         fun n_active_attributes: Int do return query(0x8B89)
 138
 139         # Length of the longest uniform name in this program, including `\n`
 140         fun active_attribute_max_length: Int do return query(0x8B8A)
 141
 142         # Number of shaders attached to this program
 143         fun n_attached_shaders: Int do return query(0x8B85)
 144
 145         # Name of the active attribute at `index`
 146         fun active_attrib_name(index: Int): String
 147         do
 148                 var max_size = active_attribute_max_length
 149                 return active_attrib_name_native(index, max_size).to_s
 150         end
 151         private fun active_attrib_name_native(index, max_size: Int): NativeString `{
 152                 // We get more values than we need, for compatibility. At least the
 153                 // NVidia driver tries to fill them even if NULL.
 154
 155                 char *name = malloc(max_size);
 156                 int size;
 157                 GLenum type;
 158                 glGetActiveAttrib(self, index, max_size, NULL, &size, &type, name);
 159                 return name;
 160         `}
 161
 162         # Size of the active attribute at `index`
 163         fun active_attrib_size(index: Int): Int `{
 164                 int size;
 165                 GLenum type;
 166                 glGetActiveAttrib(self, index, 0, NULL, &size, &type, NULL);
 167                 return size;
 168         `}
 169
 170         # Type of the active attribute at `index`
 171         #
 172         # May only be float related data types (single float, vectors and matrix).
 173         fun active_attrib_type(index: Int): GLFloatDataType `{
 174                 int size;
 175                 GLenum type;
 176                 glGetActiveAttrib(self, index, 0, NULL, &size, &type, NULL);
 177                 return type;
 178         `}
 179
 180         # Name of the active uniform at `index`
 181         fun active_uniform_name(index: Int): String
 182         do
 183                 var max_size = active_attribute_max_length
 184                 return active_uniform_name_native(index, max_size).to_s
 185         end
 186         private fun active_uniform_name_native(index, max_size: Int): NativeString `{
 187                 char *name = malloc(max_size);
 188                 int size;
 189                 GLenum type;
 190                 glGetActiveUniform(self, index, max_size, NULL, &size, &type, name);
 191                 return name;
 192         `}
 193
 194         # Size of the active uniform at `index`
 195         fun active_uniform_size(index: Int): Int `{
 196                 int size;
 197                 GLenum type;
 198                 glGetActiveUniform(self, index, 0, NULL, &size, &type, NULL);
 199                 return size;
 200         `}
 201
 202         # Type of the active uniform at `index`
 203         #
 204         # May be any data type supported by OpenGL ES 2.0 shaders.
 205         fun active_uniform_type(index: Int): GLDataType `{
 206                 int size;
 207                 GLenum type = 0;
 208                 glGetActiveUniform(self, index, 0, NULL, &size, &type, NULL);
 209                 return type;
 210         `}
 211 end
 212
 213 # Abstract OpenGL ES shader object, implemented by `GLFragmentShader` and `GLVertexShader`
 214 extern class GLShader `{GLuint`}
 215         # Set the source of the shader
 216         fun source=(code: NativeString) `{
 217                 glShaderSource(self, 1, (GLchar const **)&code, NULL);
 218         `}
 219
 220         # Source of the shader, if available
 221         #
 222         # Returns `null` if the source is not available, usually when the shader
 223         # was created from a binary file.
 224         fun source: nullable String
 225         do
 226                 var size = query(0x8B88)
 227                 if size == 0 then return null
 228                 return source_native(size).to_s
 229         end
 230
 231         private fun source_native(size: Int): NativeString `{
 232                 GLchar *code = malloc(size);
 233                 glGetShaderSource(self, size, NULL, code);
 234                 return code;
 235         `}
 236
 237         # Query information on this shader
 238         protected fun query(pname: Int): Int `{
 239                 int val;
 240                 glGetShaderiv(self, pname, &val);
 241                 return val;
 242         `}
 243
 244         # Try to compile `source` into a binary GPU program
 245         #
 246         # Check the result using `is_compiled` and `info_log`
 247         fun compile `{ glCompileShader(self); `}
 248
 249         # Has this shader been compiled?
 250         fun is_compiled: Bool do return query(0x8B81) != 0
 251
 252         # Delete this shader
 253         fun delete `{ glDeleteShader(self); `}
 254
 255         # Has this shader been deleted?
 256         fun is_deleted: Bool do return query(0x8B80) != 0
 257
 258         # Is this a valid shader?
 259         fun is_ok: Bool `{ return glIsShader(self); `}
 260
 261         # Retrieve the information log of this shader
 262         #
 263         # Useful with `link` and `validate`
 264         fun info_log: String import NativeString.to_s `{
 265                 int size;
 266                 glGetShaderiv(self, GL_INFO_LOG_LENGTH, &size);
 267                 GLchar *msg = malloc(size);
 268                 glGetShaderInfoLog(self, size, NULL, msg);
 269                 return NativeString_to_s(msg);
 270         `}
 271 end
 272
 273 # An OpenGL ES 2.0 fragment shader
 274 extern class GLFragmentShader
 275         super GLShader
 276
 277         # Create a new fragment shader
 278         #
 279         # The newly created instance should be checked using `is_ok`.
 280         new `{ return glCreateShader(GL_FRAGMENT_SHADER); `}
 281 end
 282
 283 # An OpenGL ES 2.0 vertex shader
 284 extern class GLVertexShader
 285         super GLShader
 286
 287         # Create a new fragment shader
 288         #
 289         # The newly created instance should be checked using `is_ok`.
 290         new `{ return glCreateShader(GL_VERTEX_SHADER); `}
 291 end
 292
 293 # An array of `Float` associated to a program variable
 294 class VertexArray
 295         var index: Int
 296
 297         # Number of data per vertex
 298         var count: Int
 299
 300         protected var glfloat_array: NativeGLfloatArray
 301
 302         init(index, count: Int, array: Array[Float])
 303         do
 304                 self.index = index
 305                 self.count = count
 306                 self.glfloat_array = new NativeGLfloatArray(array.length)
 307                 for k in [0..array.length[ do
 308                         glfloat_array[k] = array[k]
 309                 end
 310         end
 311
 312         fun attrib_pointer do attrib_pointer_intern(index, count, glfloat_array)
 313         private fun attrib_pointer_intern(index, count: Int, array: NativeGLfloatArray) `{
 314                 glVertexAttribPointer(index, count, GL_FLOAT, GL_FALSE, 0, array);
 315         `}
 316
 317         fun enable do enable_intern(index)
 318         private fun enable_intern(index: Int) `{ glEnableVertexAttribArray(index); `}
 319
 320         fun draw_arrays_triangles do draw_arrays_triangles_intern(index, count)
 321         private fun draw_arrays_triangles_intern(index, count: Int) `{
 322                 glDrawArrays(GL_TRIANGLES, index, count);
 323         `}
 324 end
 325
 326 # Low level array of `Float`
 327 class GLfloatArray
 328         super CArray[Float]
 329         redef type NATIVE: NativeGLfloatArray
 330
 331         init do native_array = new NativeGLfloatArray(length)
 332
 333         # Create with the content of `array`
 334         new from(array: Array[Float])
 335         do
 336                 var arr = new GLfloatArray(array.length)
 337                 arr.fill_from array
 338                 return arr
 339         end
 340
 341         # Fill with the content of `array`
 342         fun fill_from(array: Array[Float])
 343         do
 344                 assert length >= array.length
 345                 for k in [0..array.length[ do
 346                         self[k] = array[k]
 347                 end
 348         end
 349 end
 350
 351 # An array of `GLfloat` in C (`GLfloat*`)
 352 extern class NativeGLfloatArray `{ GLfloat* `}
 353         super NativeCArray
 354         redef type E: Float
 355
 356         new(size: Int) `{ return calloc(size, sizeof(GLfloat)); `}
 357
 358         redef fun [](index) `{ return self[index]; `}
 359         redef fun []=(index, val) `{ self[index] = val; `}
 360
 361         redef fun +(offset) `{ return self + offset; `}
 362 end
 363
 364 # General type for OpenGL enumerations
 365 extern class GLEnum `{ GLenum `}
 366
 367         redef fun hash `{ return self; `}
 368
 369         redef fun ==(o) do return o != null and is_same_type(o) and o.hash == self.hash
 370 end
 371
 372 # An OpenGL ES 2.0 error code
 373 extern class GLError
 374         super GLEnum
 375
 376         # Is there no error?
 377         fun is_ok: Bool do return is_no_error
 378
 379         # Is this not an error?
 380         fun is_no_error: Bool `{ return self == GL_NO_ERROR; `}
 381
 382         fun is_invalid_enum: Bool `{ return self == GL_INVALID_ENUM; `}
 383         fun is_invalid_value: Bool `{ return self == GL_INVALID_VALUE; `}
 384         fun is_invalid_operation: Bool `{ return self == GL_INVALID_OPERATION; `}
 385         fun is_invalid_framebuffer_operation: Bool `{ return self == GL_INVALID_FRAMEBUFFER_OPERATION; `}
 386         fun is_out_of_memory: Bool `{ return self == GL_OUT_OF_MEMORY; `}
 387
 388         redef fun to_s
 389         do
 390                 if is_no_error then return "No error"
 391                 if is_invalid_enum then return "Invalid enum"
 392                 if is_invalid_value then return "Invalid value"
 393                 if is_invalid_operation then return "Invalid operation"
 394                 if is_invalid_framebuffer_operation then return "invalid framebuffer operation"
 395                 if is_out_of_memory then return "Out of memory"
 396                 return "Truely unknown error"
 397         end
 398 end
 399
 400 fun assert_no_gl_error
 401 do
 402         var error = gl.error
 403         if not error.is_ok then
 404                 print "GL error: {error}"
 405                 abort
 406         end
 407 end
 408
 409 # Does `name` corresponds to a texture?
 410 fun glIsTexture(name: Int): Bool `{ return glIsTexture(name); `}
 411
 412 # Bind the named `texture` to a `target`
 413 fun glBindTexture(target: GLTextureTarget, texture: Int) `{ glBindTexture(target, texture); `}
 414
 415 # Set pixel storage modes
 416 fun glPixelStorei(parameter: GLPack, val: Int) `{ glPixelStorei(parameter, val); `}
 417
 418 # Symbolic name of the parameter to be set with `glPixelStorei`
 419 extern class GLPack
 420         super GLEnum
 421 end
 422
 423 # Parameter to specify the alignment requirements for the start of each pixel row in memory
 424 fun gl_PACK_ALIGNEMENT: GLPack `{ return GL_PACK_ALIGNMENT; `}
 425
 426 # Parameter to specify the alignment requirements for the start of each pixel row in memory
 427 fun gl_UNPACK_ALIGNEMENT: GLPack `{ return GL_UNPACK_ALIGNMENT; `}
 428
 429 # TODO GL_PACK_ROW_LENGTH, GL_PACK_IMAGE_HEIGHT, GL_PACK_SKIP_PIXELS, GL_PACK_SKIP_ROWS, GL_PACK_SKIP_IMAGES
 430 # GL_UNPACK_ROW_LENGTH, GL_UNPACK_IMAGE_HEIGHT, GL_UNPACK_SKIP_PIXELS, GL_UNPACK_SKIP_ROWS, GL_UNPACK_SKIP_IMAGES
 431
 432 # Specify a two-dimensional texture image
 433 fun glTexImage2D(target: GLTextureTarget, level, internalformat, width, height, border: Int,
 434                  format: GLPixelFormat, typ: GLPixelType, data: NativeCByteArray) `{
 435         glTexImage2D(target, level, internalformat, width, height, border, format, typ, data);
 436 `}
 437
 438 # Texture minifying and magnifying function
 439 extern class GLTextureFilter
 440         super GLEnum
 441 end
 442
 443 fun gl_NEAREST: GLTextureFilter `{ return GL_NEAREST; `}
 444 fun gl_LINEAR: GLTextureFilter `{ return GL_LINEAR; `}
 445 fun gl_NEAREST_MIPMAP_NEAREST: GLTextureFilter `{ return GL_NEAREST_MIPMAP_NEAREST; `}
 446 fun gl_LINEAR_MIPMAP_NEAREST: GLTextureFilter `{ return GL_LINEAR_MIPMAP_NEAREST; `}
 447 fun gl_NEAREST_MIPMAP_NINEAR: GLTextureFilter `{ return GL_NEAREST_MIPMAP_LINEAR; `}
 448 fun gl_LINEAR_MIPMAP_LINEAR: GLTextureFilter `{ return GL_LINEAR_MIPMAP_LINEAR; `}
 449
 450 # Wrap parameter of a texture
 451 #
 452 # Used by: `tex_parameter_wrap_*`
 453 extern class GLTextureWrap
 454         super GLEnum
 455
 456         new clamp_to_edge `{ return GL_CLAMP_TO_EDGE; `}
 457         new mirrored_repeat `{ return GL_MIRRORED_REPEAT; `}
 458         new repeat `{ return GL_REPEAT; `}
 459 end
 460
 461 # Target texture
 462 #
 463 # Used by: `tex_parameter_*`
 464 extern class GLTextureTarget
 465         super GLEnum
 466
 467         new flat `{ return GL_TEXTURE_2D; `}
 468         new cube_map `{ return GL_TEXTURE_CUBE_MAP; `}
 469 end
 470
 471 # A server-side capability
 472 class GLCap
 473
 474         # TODO private init
 475
 476         # Internal OpenGL integer for this capability
 477         private var val: Int
 478
 479         # Enable this server-side capability
 480         fun enable do enable_native(val)
 481         private fun enable_native(cap: Int) `{ glEnable(cap); `}
 482
 483         # Disable this server-side capability
 484         fun disable do disable_native(val)
 485         private fun disable_native(cap: Int) `{ glDisable(cap); `}
 486
 487         redef fun hash do return val
 488         redef fun ==(o) do return o != null and is_same_type(o) and o.hash == self.hash
 489 end
 490
 491 # Attach a renderbuffer object to a framebuffer object
 492 fun glFramebufferRenderbuffer(target: GLFramebufferTarget, attachment: GLAttachment,
 493                               renderbuffertarget: GLRenderbufferTarget, renderbuffer: Int) `{
 494         glFramebufferRenderbuffer(target, attachment, renderbuffertarget, renderbuffer);
 495 `}
 496
 497 # Establish data storage, `format` and dimensions of the `target` renderbuffer object's image
 498 fun glRenderbufferStorage(target: GLRenderbufferTarget, format: GLRenderbufferFormat, width, height: Int) `{
 499         glRenderbufferStorage(GL_RENDERBUFFER, format, width, height);
 500 `}
 501
 502 # Format for a renderbuffer
 503 extern class GLRenderbufferFormat
 504         super GLEnum
 505 end
 506
 507 # 4 red, 4 green, 4 blue, 4 alpha bits format
 508 fun gl_RGBA4: GLRenderbufferFormat `{ return GL_RGBA4; `}
 509
 510 # 5 red, 6 green, 5 blue bits format
 511 fun gl_RGB565: GLRenderbufferFormat `{ return GL_RGB565; `}
 512
 513 # 5 red, 5 green, 5 blue, 1 alpha bits format
 514 fun gl_RGB_A1: GLRenderbufferFormat `{ return GL_RGB5_A1; `}
 515
 516 # 16 depth bits format
 517 fun gl_DEPTH_COMPNENT16: GLRenderbufferFormat `{ return GL_DEPTH_COMPONENT16; `}
 518
 519 # 8 stencil bits format
 520 fun gl_STENCIL_INDEX8: GLRenderbufferFormat `{ return GL_STENCIL_INDEX8; `}
 521
 522 # Renderbuffer attachment point to a framebuffer
 523 extern class GLAttachment
 524         super GLEnum
 525 end
 526
 527 # First color attachment point
 528 fun gl_COLOR_ATTACHMENT0: GLAttachment `{ return GL_COLOR_ATTACHMENT0; `}
 529
 530 # Depth attachment point
 531 fun gl_DEPTH_ATTACHMENT: GLAttachment `{ return GL_DEPTH_ATTACHMENT; `}
 532
 533 # Stencil attachment
 534 fun gl_STENCIL_ATTACHMENT: GLAttachment `{ return GL_STENCIL_ATTACHMENT; `}
 535
 536 redef class Sys
 537         private var gles = new GLES is lazy
 538 end
 539
 540 # Entry points to OpenGL ES 2.0 services
 541 fun gl: GLES do return sys.gles
 542
 543 # OpenGL ES 2.0 services
 544 class GLES
 545
 546         # Clear the color buffer to `red`, `green`, `blue` and `alpha`
 547         fun clear_color(red, green, blue, alpha: Float) `{
 548                 glClearColor(red, green, blue, alpha);
 549         `}
 550
 551         # Set the viewport
 552         fun viewport(x, y, width, height: Int) `{ glViewport(x, y, width, height); `}
 553
 554         # Specify mapping of depth values from normalized device coordinates to window coordinates
 555         #
 556         # Default at `gl_depth_range(0.0, 1.0)`
 557         fun depth_range(near, far: Float) `{ glDepthRangef(near, far); `}
 558
 559         # Define front- and back-facing polygons
 560         #
 561         # Front-facing polygons are clockwise if `value`, counter-clockwise otherwise.
 562         fun front_face=(value: Bool) `{ glFrontFace(value? GL_CW: GL_CCW); `}
 563
 564         # Specify whether front- or back-facing polygons can be culled, default is `back` only
 565         #
 566         # One or both of `front` or `back` must be `true`. If you want to deactivate culling
 567         # use `(new GLCap.cull_face).disable`.
 568         #
 569         # Require: `front or back`
 570         fun cull_face(front, back: Bool)
 571         do
 572                 assert not (front or back)
 573                 cull_face_native(front, back)
 574         end
 575
 576         private fun cull_face_native(front, back: Bool) `{
 577                 glCullFace(front? back? GL_FRONT_AND_BACK: GL_BACK: GL_FRONT);
 578         `}
 579
 580         # Clear the `buffer`
 581         fun clear(buffer: GLBuffer) `{ glClear(buffer); `}
 582
 583         # Last error from OpenGL ES 2.0
 584         fun error: GLError `{ return glGetError(); `}
 585
 586         # Query the boolean value at `key`
 587         private fun get_bool(key: Int): Bool `{
 588                 GLboolean val;
 589                 glGetBooleanv(key, &val);
 590                 return val == GL_TRUE;
 591         `}
 592
 593         # Query the floating point value at `key`
 594         private fun get_float(key: Int): Float `{
 595                 GLfloat val;
 596                 glGetFloatv(key, &val);
 597                 return val;
 598         `}
 599
 600         # Query the integer value at `key`
 601         private fun get_int(key: Int): Int `{
 602                 GLint val;
 603                 glGetIntegerv(key, &val);
 604                 return val;
 605         `}
 606
 607         # Does this driver support shader compilation?
 608         #
 609         # Should always return `true` in OpenGL ES 2.0 and 3.0.
 610         fun shader_compiler: Bool do return get_bool(0x8DFA)
 611
 612         # Enable or disable writing into the depth buffer
 613         fun depth_mask(value: Bool) `{ glDepthMask(value); `}
 614
 615         # Set the scale and units used to calculate depth values
 616         fun polygon_offset(factor, units: Float) `{ glPolygonOffset(factor, units); `}
 617
 618         # Specify the width of rasterized lines
 619         fun line_width(width: Float) `{ glLineWidth(width); `}
 620
 621         # Set the pixel arithmetic for the blending operations
 622         #
 623         # Defaultvalues before assignation:
 624         # * `src_factor`: `GLBlendFactor::one`
 625         # * `dst_factor`: `GLBlendFactor::zero`
 626         fun blend_func(src_factor, dst_factor: GLBlendFactor) `{
 627                 glBlendFunc(src_factor, dst_factor);
 628         `}
 629
 630         # Specify the value used for depth buffer comparisons
 631         #
 632         # Default value is `GLDepthFunc::less`
 633         #
 634         # Foreign: glDepthFunc
 635         fun depth_func(func: GLDepthFunc) `{ glDepthFunc(func); `}
 636
 637         # Copy a block of pixels from the framebuffer of `fomat` and `typ` at `data`
 638         #
 639         # Foreign: glReadPixel
 640         fun read_pixels(x, y, width, height: Int, format: GLPixelFormat, typ: GLPixelType, data: Pointer) `{
 641                 glReadPixels(x, y, width, height, format, typ, data);
 642         `}
 643
 644         # Set the texture minifying function
 645         #
 646         # Foreign: glTexParameter with GL_TEXTURE_MIN_FILTER
 647         fun tex_parameter_min_filter(target: GLTextureTarget, value: GLTextureFilter) `{
 648                 glTexParameteri(target, GL_TEXTURE_MIN_FILTER, value);
 649         `}
 650
 651         # Set the texture magnification function
 652         #
 653         # Foreign: glTexParameter with GL_TEXTURE_MAG_FILTER
 654         fun tex_parameter_mag_filter(target: GLTextureTarget, value: GLTextureFilter) `{
 655                 glTexParameteri(target, GL_TEXTURE_MAG_FILTER, value);
 656         `}
 657
 658         # Set the texture wrap parameter for coordinates _s_
 659         #
 660         # Foreign: glTexParameter with GL_TEXTURE_WRAP_S
 661         fun tex_parameter_wrap_s(target: GLTextureTarget, value: GLTextureWrap) `{
 662                 glTexParameteri(target, GL_TEXTURE_WRAP_S, value);
 663         `}
 664
 665         # Set the texture wrap parameter for coordinates _t_
 666         #
 667         # Foreign: glTexParameter with GL_TEXTURE_WRAP_T
 668         fun tex_parameter_wrap_t(target: GLTextureTarget, value: GLTextureWrap) `{
 669                 glTexParameteri(target, GL_TEXTURE_WRAP_T, value);
 670         `}
 671
 672         # Render primitives from array data
 673         #
 674         # Foreign: glDrawArrays
 675         fun draw_arrays(mode: GLDrawMode, from, count: Int) `{ glDrawArrays(mode, from, count); `}
 676
 677         # OpenGL server-side capabilities
 678         var capabilities = new GLCapabilities is lazy
 679 end
 680
 681 # Bind `framebuffer` to a framebuffer target
 682 #
 683 # In OpenGL ES 2.0, `target` must be `gl_FRAMEBUFFER`.
 684 fun glBindFramebuffer(target: GLFramebufferTarget, framebuffer: Int) `{
 685         glBindFramebuffer(target, framebuffer);
 686 `}
 687
 688 # Target of `glBindFramebuffer`
 689 extern class GLFramebufferTarget
 690         super GLEnum
 691 end
 692
 693 # Target both reading and writing on the framebuffer with `glBindFramebuffer`
 694 fun gl_FRAMEBUFFER: GLFramebufferTarget `{ return GL_FRAMEBUFFER; `}
 695
 696 # Bind `renderbuffer` to a renderbuffer target
 697 #
 698 # In OpenGL ES 2.0, `target` must be `gl_RENDERBUFFER`.
 699 fun glBindRenderbuffer(target: GLRenderbufferTarget, renderbuffer: Int) `{
 700         glBindRenderbuffer(target, renderbuffer);
 701 `}
 702
 703 # Target of `glBindRenderbuffer`
 704 extern class GLRenderbufferTarget
 705         super GLEnum
 706 end
 707
 708 # Target a renderbuffer with `glBindRenderbuffer`
 709 fun gl_RENDERBUFFER: GLRenderbufferTarget `{ return GL_RENDERBUFFER; `}
 710
 711 # Specify implementation specific hints
 712 fun glHint(target: GLHintTarget, mode: GLHintMode) `{
 713         glHint(target, mode);
 714 `}
 715
 716 # Generate and fill set of mipmaps for the texture object `target`
 717 fun glGenerateMipmap(target: GLTextureTarget) `{ glGenerateMipmap(target); `}
 718
 719 # Bind the named `buffer` object
 720 fun glBindBuffer(target: GLArrayBuffer, buffer: Int) `{ glBindBuffer(target, buffer); `}
 721
 722 # Target to which bind the buffer with `glBindBuffer`
 723 extern class GLArrayBuffer
 724         super GLEnum
 725 end
 726
 727 # Array buffer target
 728 fun gl_ARRAY_BUFFER: GLArrayBuffer `{ return GL_ARRAY_BUFFER; `}
 729
 730 # Element array buffer
 731 fun gl_ELEMENT_ARRAY_BUFFER: GLArrayBuffer `{ return GL_ELEMENT_ARRAY_BUFFER; `}
 732
 733 # Completeness status of a framebuffer object
 734 fun glCheckFramebufferStatus(target: GLFramebufferTarget): GLFramebufferStatus `{
 735         return glCheckFramebufferStatus(target);
 736 `}
 737
 738 # Return value of `glCheckFramebufferStatus`
 739 extern class GLFramebufferStatus
 740         super GLEnum
 741
 742         redef fun to_s
 743         do
 744                 if self == gl_FRAMEBUFFER_COMPLETE then return "complete"
 745                 if self == gl_FRAMEBUFFER_INCOMPLETE_ATTACHMENT then return "incomplete attachment"
 746                 if self == gl_FRAMEBUFFER_INCOMPLETE_DIMENSIONS then return "incomplete dimension"
 747                 if self == gl_FRAMEBUFFER_INCOMPLETE_MISSING_ATTACHMENT then return "incomplete missing attachment"
 748                 if self == gl_FRAMEBUFFER_UNSUPPORTED then return "unsupported"
 749                 return "unknown"
 750         end
 751 end
 752
 753 # The framebuffer is complete
 754 fun gl_FRAMEBUFFER_COMPLETE: GLFramebufferStatus `{
 755         return GL_FRAMEBUFFER_COMPLETE;
 756 `}
 757
 758 # Not all framebuffer attachment points are framebuffer attachment complete
 759 fun gl_FRAMEBUFFER_INCOMPLETE_ATTACHMENT: GLFramebufferStatus `{
 760         return GL_FRAMEBUFFER_INCOMPLETE_ATTACHMENT;
 761 `}
 762
 763 # Not all attached images have the same width and height
 764 fun gl_FRAMEBUFFER_INCOMPLETE_DIMENSIONS: GLFramebufferStatus `{
 765         return GL_FRAMEBUFFER_INCOMPLETE_DIMENSIONS;
 766 `}
 767
 768 # No images are attached to the framebuffer
 769 fun gl_FRAMEBUFFER_INCOMPLETE_MISSING_ATTACHMENT: GLFramebufferStatus `{
 770         return GL_FRAMEBUFFER_INCOMPLETE_MISSING_ATTACHMENT;
 771 `}
 772
 773 # The combination of internal formats of the attached images violates an implementation-dependent set of restrictions
 774 fun gl_FRAMEBUFFER_UNSUPPORTED: GLFramebufferStatus `{
 775         return GL_FRAMEBUFFER_UNSUPPORTED;
 776 `}
 777
 778 # Hint target for `glHint`
 779 extern class GLHintTarget
 780         super GLEnum
 781 end
 782
 783 # Indicates the quality of filtering when generating mipmap images
 784 fun gl_GENERATE_MIPMAP_HINT: GLHintTarget `{ return GL_GENERATE_MIPMAP_HINT; `}
 785
 786 # Hint mode for `glHint`
 787 extern class GLHintMode
 788         super GLEnum
 789 end
 790
 791 # The most efficient option should be chosen
 792 fun gl_FASTEST: GLHintMode `{ return GL_FASTEST; `}
 793
 794 # The most correct, or highest quality, option should be chosen
 795 fun gl_NICEST: GLHintMode `{ return GL_NICEST; `}
 796
 797 # No preference
 798 fun gl_DONT_CARE: GLHintMode `{ return GL_DONT_CARE; `}
 799
 800 # Attach a level of a texture object as a logical buffer to the currently bound framebuffer object
 801 fun glFramebufferTexture2D(target: GLFramebufferTarget, attachment: GLAttachment,
 802                            texture_target: GLTextureTarget,  texture, level: Int) `{
 803         glFramebufferTexture2D(target, attachment, texture_target, texture, level);
 804 `}
 805
 806 # Entry point to OpenGL server-side capabilities
 807 class GLCapabilities
 808
 809         # GL capability: blend the computed fragment color values
 810         #
 811         # Foreign: GL_BLEND
 812         var blend: GLCap is lazy do return new GLCap(0x0BE2)
 813
 814         # GL capability: cull polygons based of their winding in window coordinates
 815         #
 816         # Foreign: GL_CULL_FACE
 817         var cull_face: GLCap is lazy do return new GLCap(0x0B44)
 818
 819         # GL capability: do depth comparisons and update the depth buffer
 820         #
 821         # Foreign: GL_DEPTH_TEST
 822         var depth_test: GLCap is lazy do return new GLCap(0x0B71)
 823
 824         # GL capability: dither color components or indices before they are written to the color buffer
 825         #
 826         # Foreign: GL_DITHER
 827         var dither: GLCap is lazy do return new GLCap(0x0BE2)
 828
 829         # GL capability: add an offset to depth values of a polygon fragment before depth test
 830         #
 831         # Foreign: GL_POLYGON_OFFSET_FILL
 832         var polygon_offset_fill: GLCap is lazy do return new GLCap(0x8037)
 833
 834         # GL capability: compute a temporary coverage value where each bit is determined by the alpha value at the corresponding location
 835         #
 836         # Foreign: GL_SAMPLE_ALPHA_TO_COVERAGE
 837         var sample_alpha_to_coverage: GLCap is lazy do return new GLCap(0x809E)
 838
 839         # GL capability: AND the fragment coverage with the temporary coverage value
 840         #
 841         # Foreign: GL_SAMPLE_COVERAGE
 842         var sample_coverage: GLCap is lazy do return new GLCap(0x80A0)
 843
 844         # GL capability: discard fragments that are outside the scissor rectangle
 845         #
 846         # Foreign: GL_SCISSOR_TEST
 847         var scissor_test: GLCap is lazy do return new GLCap(0x0C11)
 848
 849         # GL capability: do stencil testing and update the stencil buffer
 850         #
 851         # Foreign: GL_STENCIL_TEST
 852         var stencil_test: GLCap is lazy do return new GLCap(0x0B90)
 853 end
 854
 855 # Float related data types of OpenGL ES 2.0 shaders
 856 #
 857 # Only data types supported by shader attributes, as seen with
 858 # `GLProgram::active_attrib_type`.
 859 extern class GLFloatDataType
 860         super GLEnum
 861
 862         fun is_float: Bool `{ return self == GL_FLOAT; `}
 863         fun is_float_vec2: Bool `{ return self == GL_FLOAT_VEC2; `}
 864         fun is_float_vec3: Bool `{ return self == GL_FLOAT_VEC3; `}
 865         fun is_float_vec4: Bool `{ return self == GL_FLOAT_VEC4; `}
 866         fun is_float_mat2: Bool `{ return self == GL_FLOAT_MAT2; `}
 867         fun is_float_mat3: Bool `{ return self == GL_FLOAT_MAT3; `}
 868         fun is_float_mat4: Bool `{ return self == GL_FLOAT_MAT4; `}
 869
 870         # Instances of `GLFloatDataType` can be equal to instances of `GLDataType`
 871         redef fun ==(o)
 872         do
 873                 return o != null and o isa GLFloatDataType and o.hash == self.hash
 874         end
 875 end
 876
 877 # All data types of OpenGL ES 2.0 shaders
 878 #
 879 # These types can be used by shader uniforms, as seen with
 880 # `GLProgram::active_uniform_type`.
 881 extern class GLDataType
 882         super GLFloatDataType
 883
 884         fun is_int: Bool `{ return self == GL_INT; `}
 885         fun is_int_vec2: Bool `{ return self == GL_INT_VEC2; `}
 886         fun is_int_vec3: Bool `{ return self == GL_INT_VEC3; `}
 887         fun is_int_vec4: Bool `{ return self == GL_INT_VEC4; `}
 888         fun is_bool: Bool `{ return self == GL_BOOL; `}
 889         fun is_bool_vec2: Bool `{ return self == GL_BOOL_VEC2; `}
 890         fun is_bool_vec3: Bool `{ return self == GL_BOOL_VEC3; `}
 891         fun is_bool_vec4: Bool `{ return self == GL_BOOL_VEC4; `}
 892         fun is_sampler_2d: Bool `{ return self == GL_SAMPLER_2D; `}
 893         fun is_sampler_cube: Bool `{ return self == GL_SAMPLER_CUBE; `}
 894 end
 895
 896 # Kind of primitives to render with `GLES::draw_arrays`
 897 extern class GLDrawMode
 898         super GLEnum
 899
 900         new points `{ return GL_POINTS; `}
 901         new line_strip `{ return GL_LINE_STRIP; `}
 902         new line_loop `{ return GL_LINE_LOOP; `}
 903         new lines `{ return GL_LINES; `}
 904         new triangle_strip `{ return GL_TRIANGLE_STRIP; `}
 905         new triangle_fan `{ return GL_TRIANGLE_FAN; `}
 906         new triangles `{ return GL_TRIANGLES; `}
 907 end
 908
 909 # Pixel arithmetic for blending operations
 910 #
 911 # Used by `GLES::blend_func`
 912 extern class GLBlendFactor
 913         super GLEnum
 914
 915         new zero `{ return GL_ZERO; `}
 916         new one `{ return GL_ONE; `}
 917         new src_color `{ return GL_SRC_COLOR; `}
 918         new one_minus_src_color `{ return GL_ONE_MINUS_SRC_COLOR; `}
 919         new dst_color `{ return GL_DST_COLOR; `}
 920         new one_minus_dst_color `{ return GL_ONE_MINUS_DST_COLOR; `}
 921         new src_alpha `{ return GL_SRC_ALPHA; `}
 922         new one_minus_src_alpha `{ return GL_ONE_MINUS_SRC_ALPHA; `}
 923         new dst_alpha `{ return GL_DST_ALPHA; `}
 924         new one_minus_dst_alpha `{ return GL_ONE_MINUS_DST_ALPHA; `}
 925         new constant_color `{ return GL_CONSTANT_COLOR; `}
 926         new one_minus_constant_color `{ return GL_ONE_MINUS_CONSTANT_COLOR; `}
 927         new constant_alpha `{ return GL_CONSTANT_ALPHA; `}
 928         new one_minus_constant_alpha `{ return GL_ONE_MINUS_CONSTANT_ALPHA; `}
 929
 930         # Used for destination only
 931         new src_alpha_saturate `{ return GL_SRC_ALPHA_SATURATE; `}
 932 end
 933
 934 # Condition under which a pixel will be drawn
 935 #
 936 # Used by `GLES::depth_func`
 937 extern class GLDepthFunc
 938         super GLEnum
 939
 940          new never `{ return GL_NEVER; `}
 941          new less `{ return GL_LESS; `}
 942          new equal `{ return GL_EQUAL; `}
 943          new lequal `{ return GL_LEQUAL; `}
 944          new greater `{ return GL_GREATER; `}
 945          new not_equal `{ return GL_NOTEQUAL; `}
 946          new gequal `{ return GL_GEQUAL; `}
 947          new always `{ return GL_ALWAYS; `}
 948 end
 949
 950 # Format of pixel data
 951 #
 952 # Used by `GLES::read_pixels`
 953 extern class GLPixelFormat
 954         super GLEnum
 955
 956         new alpha `{ return GL_ALPHA; `}
 957         new rgb `{ return GL_RGB; `}
 958         new rgba `{ return GL_RGBA; `}
 959 end
 960
 961 # Data type of pixel data
 962 #
 963 # Used by `GLES::read_pixels`
 964 extern class GLPixelType
 965         super GLEnum
 966
 967         new unsigned_byte `{ return GL_UNSIGNED_BYTE; `}
 968         new unsigned_short_5_6_5 `{ return GL_UNSIGNED_SHORT_5_6_5; `}
 969         new unsigned_short_4_4_4_4 `{ return GL_UNSIGNED_SHORT_4_4_4_4; `}
 970         new unsigned_short_5_5_5_1 `{ return GL_UNSIGNED_SHORT_5_5_5_1; `}
 971 end
 972
 973 # Set of buffers as a bitwise OR mask, used by `GLES::clear`
 974 #
 975 # ~~~
 976 # var buffers = (new GLBuffer).color.depth
 977 # gl.clear buffers
 978 # ~~~
 979 extern class GLBuffer `{ GLbitfield `}
 980         # Get an empty set of buffers
 981         new `{ return 0; `}
 982
 983         # Add the color buffer to the returned buffer set
 984         fun color: GLBuffer `{ return self | GL_COLOR_BUFFER_BIT; `}
 985
 986         # Add the depth buffer to the returned buffer set
 987         fun depth: GLBuffer `{ return self | GL_DEPTH_BUFFER_BIT; `}
 988
 989         # Add the stencil buffer to the returned buffer set
 990         fun stencil: GLBuffer `{ return self | GL_STENCIL_BUFFER_BIT; `}
 991 end