contrib/github_search_for_jni/src/github_search_for_jni.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Script to scan Github for repositories possibly using JNI.
  18 module github_search_for_jni
  19
  20 import github::github_curl
  21
  22 # The proprieties introduced by this redef are to be used only on a JSON object
  23 # representing a Github repository.
  24 redef class JsonObject
  25         # The repository has at least 50% Java code
  26         fun has_lots_of_java: Bool
  27         do
  28                 var java_count = 0
  29                 if keys.has("Java") then java_count = self["Java"].as(Int)
  30
  31                 if java_count == 0 then return false
  32
  33                 var total = 0
  34                 for k, v in self do
  35                         assert v isa Int
  36                         total += v
  37                 end
  38
  39                 return java_count * 100 / total > 50
  40         end
  41
  42         # The repository has at least 100 lines of C code
  43         fun has_some_c: Bool
  44         do
  45                 var c_count = 0
  46                 if keys.has("C") then c_count = self["C"].as(Int)
  47                 return c_count > 100
  48         end
  49 end
  50
  51 # Query sent to Github
  52 var main_query = "language:java"
  53
  54 # Curl instance use for all requests
  55 var curl = new GithubCurl("OAUTH TOKEN (replace with your own)", "JNI project finder (nitlanguage.org)")
  56
  57 if "NIT_TESTING".environ == "true" then exit 0
  58
  59 # Current requested page
  60 var page = 0
  61 var per_page = 100
  62 loop
  63         # Get a page of the main query
  64         var uri = "https://api.github.com/search/repositories?q={main_query}&page={page}&per_page={per_page}&sort=stars"
  65         var obj = curl.get_and_check(uri).as(JsonObject)
  66
  67         # Main object has "total_count" and "items"
  68         var items = obj["items"].as(JsonArray)
  69
  70         # "items" is an array of Json objects
  71         for item in items do
  72                 assert item isa JsonObject
  73
  74                 # Each item has "name" and "languages_url"
  75                 assert item.keys.has("name")
  76                 assert item.keys.has("languages_url")
  77
  78                 # Download the language list
  79                 var lang_url = item["languages_url"].as(String)
  80                 var langs = curl.get_and_check(lang_url).as(JsonObject)
  81
  82                 # The project is of interest if it has lots of Java and at least some C
  83                 var may_be_of_interest = langs.has_lots_of_java and langs.has_some_c
  84                 if may_be_of_interest then print "{item["name"].to_s}: {item["forks"].to_s}; {langs.keys.join(", ")}; {item["html_url"].to_s}"
  85         end
  86
  87         # If we got less pages than asked for, we are done!
  88         if items.length < per_page then break
  89
  90         page += 1
  91 end