lib/gamnit/display_android.nit

   1 # This file is part of NIT (http://www.nitlanguage.org).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #        http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Gamnit display implementation for Android
  16 #
  17 # Generated APK files require OpenGL ES 2.0.
  18 #
  19 # This modules uses `android::native_app_glue` and the Android NDK.
  20 module display_android is
  21         android_manifest """<uses-feature android:glEsVersion="0x00020000"/>"""
  22 end
  23
  24 import ::android::game
  25 intrude import android::load_image
  26
  27 private import gamnit::egl
  28 intrude import textures
  29
  30 redef class GamnitDisplay
  31
  32         redef fun setup
  33         do
  34                 var native_display = egl_default_display
  35                 var native_window = app.native_app_glue.window
  36
  37                 setup_egl_display native_display
  38
  39                 # We need 8 bits per color for selection by color
  40                 select_egl_config(red_bits, green_bits, blue_bits, 0, 8, 0, 0)
  41
  42                 var format = egl_config.attribs(egl_display).native_visual_id
  43                 native_window.set_buffers_geometry(0, 0, format)
  44
  45                 setup_egl_context native_window
  46         end
  47
  48         redef fun close do close_egl
  49 end
  50
  51 redef class TextureAsset
  52
  53         redef fun load_from_platform
  54         do
  55                 jni_env.push_local_frame 4
  56
  57                 var asset_manager = app.asset_manager
  58                 var bmp = asset_manager.bitmap(path)
  59                 if bmp.is_java_null then
  60                         error = new Error("Failed to load texture at '{path}'")
  61                         jni_env.pop_local_frame
  62                         return
  63                 end
  64
  65                 var buf = bmp.copy_pixels(unmultiply=not premultiply_alpha)
  66                 loaded = true
  67                 width = bmp.width.to_f
  68                 height = bmp.height.to_f
  69                 var pixels = buf.native_array
  70
  71                 load_from_pixels(pixels, bmp.width, bmp.height, gl_RGBA)
  72
  73                 jni_env.pop_local_frame
  74         end
  75 end