lib/gamnit/textures.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Load textures, create subtextures and manage their life-cycle
  16 module textures
  17
  18 import display
  19
  20 # Texture composed of pixels, loaded from the assets folder by default
  21 #
  22 # Most textures should be created with `App` (as attributes)
  23 # for the method `on_create` to load them.
  24 #
  25 # ~~~
  26 # import gamnit::flat
  27 #
  28 # redef class App
  29 #     # Create the texture object, it will be loaded automatically
  30 #     var texture = new Texture("path/in/assets.png")
  31 #
  32 #     redef fun on_create()
  33 #     do
  34 #         # Let `on_create` load the texture
  35 #         super
  36 #
  37 #         # Use the texture
  38 #         var sprite = new Sprite(texture, new Point3d[Float](0.0, 0.0, 0.0))
  39 #         app.sprites.add sprite
  40 #     end
  41 # end
  42 # ~~~
  43 #
  44 # Otherwise, they can be loaded and error checked explicitly after `on_create`.
  45 #
  46 # ~~~nitish
  47 # var texture = new Texture("path/in/assets.png")
  48 # texture.load
  49 # var error = texture.error
  50 # if error != null then print_error error
  51 # ~~~
  52 #
  53 # A texture may also be created programmatically, like `CheckerTexture`,
  54 # or derived from another texture, using `subtexture`.
  55 # Textures with actual pixel data (not `Subtexture`) are `RootTexture`.
  56 # Texture loaded from the assets folder may in the PNG or JPG formats.
  57 abstract class Texture
  58
  59         # Prepare a texture located at `path` within the `assets` folder
  60         new (path: Text) do return new TextureAsset(path.to_s)
  61
  62         # Root texture from which `self` is derived
  63         fun root: RootTexture is abstract
  64
  65         # Width in pixels of this texture
  66         var width = 0.0
  67
  68         # Height in pixels of this texture
  69         var height = 0.0
  70
  71         # Load this texture, force reloading it if `force`
  72         fun load(force: nullable Bool) do end
  73
  74         # Last error on this texture
  75         var error: nullable Error = null
  76
  77         # OpenGL handle to this texture
  78         fun gl_texture: Int do return root.gl_texture
  79
  80         # Prepare a subtexture from this texture, from the given pixel offsets
  81         fun subtexture(left, top, width, height: Numeric): Subtexture
  82         do
  83                 return new AbsoluteSubtexture(self, left.to_f, top.to_f, width.to_f, height.to_f)
  84         end
  85
  86         # Offset of the left border on `root` from 0.0 to 1.0
  87         fun offset_left: Float do return 0.0
  88
  89         # Offset of the top border on `root` from 0.0 to 1.0
  90         fun offset_top: Float do return 0.0
  91
  92         # Offset of the right border on `root` from 0.0 to 1.0
  93         fun offset_right: Float do return 1.0
  94
  95         # Offset of the bottom border on `root` from 0.0 to 1.0
  96         fun offset_bottom: Float do return 1.0
  97
  98         # Should this texture be drawn pixelated when magnified? otherwise it is interpolated
  99         #
 100         # This setting affects all the textures based on the same pixel data, or `root`.
 101         #
 102         # Must be set after a successful call to `load`.
 103         fun pixelated=(pixelated: Bool)
 104         do
 105                 if root.gl_texture == -1 then return
 106
 107                 # TODO do not modify `root` by using *sampler objects* in glesv3
 108                 glBindTexture(gl_TEXTURE_2D, root.gl_texture)
 109
 110                 var param = if pixelated then gl_NEAREST else gl_LINEAR
 111                 glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_MAG_FILTER, param)
 112         end
 113 end
 114
 115 # Colorful small texture of 32x32 pixels by default
 116 class CheckerTexture
 117         super RootTexture
 118
 119         # Width and height in pixels, defaults to 32
 120         var size = 32 is optional
 121
 122         redef fun load(force)
 123         do
 124                 if gl_texture != -1 then return
 125                 load_checker size
 126                 loaded = true
 127         end
 128 end
 129
 130 # Custom texture with pixel values filled programmatically
 131 #
 132 # At creation, the texture is composed of `width` by `height` (rounded down)
 133 # transparent pixels. The pixels value can be set using `[]=`.
 134 #
 135 # ~~~
 136 # # Build a texture with 4 colors
 137 # var tex = new CustomTexture(2.0, 2.0)
 138 # tex[0, 0] = [1.0, 0.0, 0.0] # Red
 139 # tex[0, 1] = [0.0, 1.0, 0.0] # Green
 140 # tex[1, 0] = [0.0, 0.0, 1.0] # Blue
 141 # tex[1, 1] = [1.0, 1.0, 1.0, 0.5] # Transparent white
 142 # tex.load
 143 # ~~~
 144 class CustomTexture
 145         super RootTexture
 146
 147         redef var width
 148         redef var height
 149
 150         private var cpixels = new CByteArray(4*width.to_i*height.to_i) is lazy
 151
 152         # Set the `color` of the pixel at `x`, `y` (from the top-left corner)
 153         #
 154         # The argument `color` should be an array of up to 4 floats (RGBA).
 155         # If `color` has less than 4 items, the missing items are replaced by 1.0.
 156         #
 157         # Require: `not loaded and x < width.to_i and y < height.to_i`
 158         fun []=(x, y: Int, color: Array[Float])
 159         do
 160                 assert not loaded else print_error "{class_name}::[]= already loaded"
 161                 assert x < width.to_i and y < height.to_i else print_error "{class_name}::[] out of bounds"
 162
 163                 # Simple conversion from [0.0..1.0] to [0..255]
 164                 var bytes = [for c in color do (c*255.0).round.to_i.clamp(0, 255).to_bytes.last]
 165                 while bytes.length < 4 do bytes.add 255u8
 166
 167                 var offset = 4*(x + y*width.to_i)
 168                 for i in [0..4[ do cpixels[offset+i] = bytes[i]
 169         end
 170
 171         # Overwrite all pixels with `color`
 172         #
 173         # The argument `color` should be an array of up to 4 floats (RGBA).
 174         # If `color` has less than 4 items, the missing items are replaced by 1.0.
 175         #
 176         # Require: `not loaded`
 177         fun fill(color: Array[Float])
 178         do
 179                 assert not loaded else print_error "{class_name}::fill already loaded"
 180
 181                 # Simple conversion from [0.0..1.0] to [0..255]
 182                 var bytes = [for c in color do (c*255.0).round.to_i.clamp(0, 255).to_bytes.last]
 183                 while bytes.length < 4 do bytes.add 255u8
 184
 185                 var i = 0
 186                 for x in [0..width.to_i[ do
 187                         for y in [0..height.to_i[ do
 188                                 for j in [0..4[ do cpixels[i+j] = bytes[j]
 189                                 i += 4
 190                         end
 191                 end
 192         end
 193
 194         redef fun load(force)
 195         do
 196                 if loaded then return
 197
 198                 # Round down the desired dimension
 199                 var width = width.to_i
 200                 var height = height.to_i
 201                 self.width = width.to_f
 202                 self.height = height.to_f
 203
 204                 load_from_pixels(cpixels.native_array, width, height, gl_RGBA)
 205
 206                 cpixels.destroy
 207                 loaded = true
 208         end
 209 end
 210
 211 # Texture with its own pixel data
 212 class RootTexture
 213         super Texture
 214
 215         redef fun root do return self
 216
 217         # Has this texture been loaded yet?
 218         var loaded = false
 219
 220         redef var gl_texture = -1
 221
 222         init do all_root_textures.add self
 223
 224         # Should the pixels RGB values be premultiplied by their alpha value at loading?
 225         #
 226         # All gamnit textures must have premultiplied alpha, it provides a better
 227         # alpha blending, avoids artifacts and allows for additive blending.
 228         #
 229         # When at `true`, the default, pixels RGB values are premultiplied
 230         # at loading. Set to `false` if pixels RGB values are already
 231         # premultiplied in the source data.
 232         #
 233         # This value must be set before calling `load`.
 234         var premultiply_alpha = true is writable
 235
 236         private fun load_from_pixels(pixels: Pointer, width, height: Int, format: GLPixelFormat)
 237         do
 238                 var max_texture_size = glGetIntegerv(gl_MAX_TEXTURE_SIZE, 0)
 239                 if width > max_texture_size or height > max_texture_size then
 240                         error = new Error("Texture {self} width or height is over the GL_MAX_TEXTURE_SIZE of {max_texture_size}")
 241                         return
 242                 end
 243
 244                 # Premultiply alpha?
 245                 if premultiply_alpha and format == gl_RGBA then
 246                         pixels.premultiply_alpha(width, height)
 247                 end
 248
 249                 glPixelStorei(gl_UNPACK_ALIGNEMENT, 1)
 250                 var tex = glGenTextures(1)[0]
 251                 gl_texture = tex
 252
 253                 glBindTexture(gl_TEXTURE_2D, tex)
 254                 glTexImage2D(gl_TEXTURE_2D, 0, format, width, height, 0, format, gl_UNSIGNED_BYTE, pixels)
 255
 256                 glHint(gl_GENERATE_MIPMAP_HINT, gl_NICEST)
 257                 glGenerateMipmap(gl_TEXTURE_2D)
 258                 glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_MIN_FILTER, gl_LINEAR_MIPMAP_LINEAR)
 259
 260                 glBindTexture(gl_TEXTURE_2D, 0)
 261         end
 262
 263         private fun load_checker(size: Int)
 264         do
 265                 var cpixels = new CByteArray(3*size*size)
 266
 267                 var i = 0
 268                 for x in [0..size[ do
 269                         var quadrant_x = if x < size/2 then 0 else 1
 270                         for y in [0..size[ do
 271                                 var quadrant_y = if y < size/2 then 0 else 1
 272                                 var color = if quadrant_x == quadrant_y then
 273                                         [0u8, 0u8, 0u8, 255u8]
 274                                 else [255u8, 255u8, 255u8, 255u8]
 275
 276                                 for j in [0..3[ do cpixels[i+j] = color[j]
 277                                 i += 3
 278                         end
 279                 end
 280
 281                 width = size.to_f
 282                 height = size.to_f
 283                 load_from_pixels(cpixels.native_array, size, size, gl_RGB)
 284
 285                 cpixels.destroy
 286         end
 287
 288         # Has this resource been deleted?
 289         var deleted = false
 290
 291         # Delete this texture and free all its resources
 292         #
 293         # Use caution with this service as the subtextures may rely on the deleted data.
 294         fun delete
 295         do
 296                 if deleted or not loaded then return
 297
 298                 deleted = true
 299         end
 300 end
 301
 302 # Texture loaded from the assets folder
 303 class TextureAsset
 304         super RootTexture
 305
 306         # Path to this texture within the `assets` folder
 307         var path: String
 308
 309         redef fun load(force)
 310         do
 311                 if loaded and force != true then return
 312
 313                 load_from_platform
 314
 315                 # If no pixel data was loaded, load the pixel default texture
 316                 if gl_texture == -1 then load_checker 32
 317
 318                 loaded = true
 319         end
 320
 321         # Partially load this texture from platform-specific features
 322         #
 323         # This method should fill `width`, `height` and `pixels`.
 324         private fun load_from_platform is abstract
 325
 326         redef fun to_s do return "<{class_name} path:{path}>"
 327 end
 328
 329 # Texture derived from another texture, does not own its pixels
 330 abstract class Subtexture
 331         super Texture
 332
 333         # Parent texture, from which this texture was created
 334         var parent: Texture
 335
 336         redef var root = parent.root is lateinit
 337
 338         redef fun load(force) do root.load(force)
 339 end
 340
 341 # Subtexture created from pixel coordinates within `parent`
 342 class AbsoluteSubtexture
 343         super Subtexture
 344
 345         # Left border of this texture relative to `parent`
 346         var left: Float
 347
 348         # Top border of this texture relative to `parent`
 349         var top: Float
 350
 351         private fun set_wh(width, height: Float)
 352         is autoinit do
 353                 self.width = width
 354                 self.height = height
 355         end
 356
 357         redef var offset_left = parent.offset_left + left / root.width is lazy
 358         redef var offset_top = parent.offset_top + top / root.height is lazy
 359         redef var offset_right = offset_left + width / root.width is lazy
 360         redef var offset_bottom = offset_top + height / root.height is lazy
 361 end
 362
 363 # Subtexture created from relative coordinates ([0..1]) out of the `root` texture
 364 class RelativeSubtexture
 365         super Subtexture
 366
 367         redef var offset_left
 368         redef var offset_top
 369         redef var offset_right
 370         redef var offset_bottom
 371
 372         redef fun width do return root.width * (offset_right - offset_left)
 373         redef fun height do return root.height * (offset_bottom - offset_top)
 374 end
 375
 376 redef class Sys
 377         # All declared root textures
 378         var all_root_textures = new TextureSet
 379 end
 380
 381 # Group of `Texture`
 382 class TextureSet
 383         super HashSet[Texture]
 384
 385         # Load all texture of this set
 386         fun load_all do for t in self do t.load
 387 end
 388
 389 redef class Pointer
 390         # Multiply RBG values by their alpha value
 391         private fun premultiply_alpha(width, height: Int) `{
 392                 uint8_t *bytes = (uint8_t *)self;
 393                 int x, y, i = 0;
 394                 for(y = 0; y < height; y ++) {
 395                         for(x = 0; x < width; x ++) {
 396                                 int a = bytes[i+3];
 397                                 bytes[i  ] = bytes[i  ] * a / 255;
 398                                 bytes[i+1] = bytes[i+1] * a / 255;
 399                                 bytes[i+2] = bytes[i+2] * a / 255;
 400                                 i += 4;
 401                         }
 402                 }
 403         `}
 404 end