contrib/nitiwiki/src/wiki_html.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # HTML wiki rendering
  16 module wiki_html
  17
  18 import wiki_links
  19 import markdown::decorators
  20
  21 redef class Nitiwiki
  22
  23         # Render HTML output looking for changes in the markdown sources.
  24         redef fun render do
  25                 super
  26                 if not root_section.is_dirty and not force_render then return
  27                 var out_dir = expand_path(config.root_dir, config.out_dir)
  28                 out_dir.mkdir
  29                 copy_assets
  30                 root_section.add_child make_sitemap
  31                 root_section.render
  32         end
  33
  34         # Copy the asset directory to the (public) output directory.
  35         private fun copy_assets do
  36                 var src = expand_path(config.root_dir, config.assets_dir)
  37                 var out = expand_path(config.root_dir, config.out_dir)
  38                 if need_render(src, expand_path(out, config.assets_dir)) then
  39                         if src.file_exists then sys.system "cp -R {src} {out}"
  40                 end
  41         end
  42
  43         # Build the wiki sitemap page.
  44         private fun make_sitemap: WikiSitemap do
  45                 var sitemap = new WikiSitemap(self, "sitemap")
  46                 sitemap.is_dirty = true
  47                 return sitemap
  48         end
  49
  50         # Markdown processor used for inline element such as titles in TOC.
  51         private var inline_processor: MarkdownProcessor is lazy do
  52                 var proc = new MarkdownProcessor
  53                 proc.emitter.decorator = new InlineDecorator
  54                 return proc
  55         end
  56
  57         # Inline markdown (remove h1, p, ... elements).
  58         private fun inline_md(md: Writable): Writable do
  59                 return inline_processor.process(md.write_to_string)
  60         end
  61 end
  62
  63 redef class WikiEntry
  64         # Get a `<a>` template link to `self`
  65         fun tpl_link(context: WikiEntry): Writable do
  66                 return "<a href=\"{href_from(context)}\">{title}</a>"
  67         end
  68 end
  69
  70 redef class WikiSection
  71
  72         # Output directory (where to ouput the HTML pages for this section).
  73         redef fun out_path: String do
  74                 if parent == null then
  75                         return wiki.config.out_dir
  76                 else
  77                         return wiki.expand_path(parent.out_path, name)
  78                 end
  79         end
  80
  81         redef fun render do
  82                 if not is_dirty and not wiki.force_render then return
  83                 if is_new then
  84                         out_full_path.mkdir
  85                 else
  86                         sys.system "touch {out_full_path}"
  87                 end
  88                 if has_source then
  89                         wiki.message("Render section {out_path}", 1)
  90                         copy_files
  91                 end
  92                 var index = self.index
  93                 if index isa WikiSectionIndex then
  94                         wiki.message("Render auto-index for section {out_path}", 1)
  95                         index.is_dirty = true
  96                         add_child index
  97                 end
  98                 super
  99         end
 100
 101         # Copy attached files from `src_path` to `out_path`.
 102         private fun copy_files do
 103                 assert has_source
 104                 var dir = src_full_path.to_s
 105                 for name in dir.files do
 106                         if name == wiki.config_filename then continue
 107                         if name.has_suffix(".md") then continue
 108                         if has_child(name) then continue
 109                         var src = wiki.expand_path(dir, name)
 110                         var out = wiki.expand_path(out_full_path, name)
 111                         if not wiki.need_render(src, out) then continue
 112                         sys.system "cp -R {src} {out_full_path}"
 113                 end
 114         end
 115
 116         redef fun tpl_link(context) do return index.tpl_link(context)
 117
 118         # Render the section hierarchy as a html tree.
 119         #
 120         # `limit` is used to specify the max-depth of the tree.
 121         #
 122         # The generated tree will be something like this:
 123         #
 124         # ~~~html
 125         # <ul>
 126         #  <li>section 1</li>
 127         #  <li>section 2
 128         #   <ul>
 129         #    <li>section 2.1</li>
 130         #    <li>section 2.2</li>
 131         #   </ul>
 132         #  </li>
 133         # </ul>
 134         # ~~~
 135         fun tpl_tree(limit: Int): Template do
 136                 return tpl_tree_intern(limit, 1, self)
 137         end
 138
 139         # Build the template tree for this section recursively.
 140         protected fun tpl_tree_intern(limit, count: Int, context: WikiEntry): Template do
 141                 var out = new Template
 142                 var index = index
 143                 out.add "<li>"
 144                 out.add tpl_link(context)
 145                 if (limit < 0 or count < limit) and
 146                    (children.length > 1 or (children.length == 1)) then
 147                         out.add " <ul>"
 148                         for child in children.values do
 149                                 if child == index then continue
 150                                 if child isa WikiArticle then
 151                                         out.add "<li>"
 152                                         out.add child.tpl_link(context)
 153                                         out.add "</li>"
 154                                 else if child isa WikiSection and not child.is_hidden then
 155                                         out.add child.tpl_tree_intern(limit, count + 1, context)
 156                                 end
 157                         end
 158                         out.add " </ul>"
 159                 end
 160                 out.add "</li>"
 161                 return out
 162         end
 163 end
 164
 165 redef class WikiArticle
 166
 167         redef fun out_path: String do
 168                 if parent == null then
 169                         return wiki.expand_path(wiki.config.out_dir, "{name}.html")
 170                 else
 171                         return wiki.expand_path(parent.out_path, "{name}.html")
 172                 end
 173         end
 174
 175         redef fun render do
 176                 super
 177                 if not is_dirty and not wiki.force_render then return
 178                 wiki.message("Render article {name}", 2)
 179                 var file = out_full_path
 180                 file.dirname.mkdir
 181                 tpl_page.write_to_file file
 182         end
 183
 184
 185         # Load a template and resolve page-related macros
 186         fun load_template(template_file: String): TemplateString do
 187                 var tpl = wiki.load_template(template_file)
 188                 return tpl
 189         end
 190
 191         # Replace macros in the template by wiki data.
 192         private fun tpl_page: TemplateString do
 193                 var tpl = load_template(template_file)
 194                 if tpl.has_macro("TOP_MENU") then
 195                         tpl.replace("TOP_MENU", tpl_menu)
 196                 end
 197                 if tpl.has_macro("HEADER") then
 198                         tpl.replace("HEADER", tpl_header)
 199                 end
 200                 if tpl.has_macro("BODY") then
 201                         tpl.replace("BODY", tpl_article)
 202                 end
 203                 if tpl.has_macro("FOOTER") then
 204                         tpl.replace("FOOTER", tpl_footer)
 205                 end
 206                 return tpl
 207         end
 208
 209         # Generate the HTML header for this article.
 210         fun tpl_header: Writable do
 211                 var file = header_file
 212                 if not wiki.has_template(file) then return ""
 213                 return load_template(file)
 214         end
 215
 216         # Generate the HTML page for this article.
 217         fun tpl_article: TplArticle do
 218                 var article = new TplArticle
 219                 article.body = content
 220                 if wiki.config.auto_breadcrumbs then
 221                         article.breadcrumbs = new TplBreadcrumbs(self)
 222                 end
 223                 article.sidebar = tpl_sidebar
 224                 article.sidebar_pos = wiki.config.sidebar
 225                 return article
 226         end
 227
 228         # Sidebar for this page.
 229         var tpl_sidebar: TplSidebar is lazy do
 230                 var res = new TplSidebar
 231                 if wiki.config.auto_summary then
 232                         res.blocks.add tpl_summary
 233                 end
 234                 res.blocks.add_all sidebar.blocks
 235                 return res
 236         end
 237
 238         # Generate the HTML summary for this article.
 239         #
 240         # Based on `headlines`
 241         fun tpl_summary: Writable do
 242                 var headlines = self.headlines
 243                 var tpl = new Template
 244                 tpl.add "<ul class=\"summary list-unstyled\">"
 245                 var iter = headlines.iterator
 246                 while iter.is_ok do
 247                         var hl = iter.item
 248                         # parse title as markdown
 249                         var title = wiki.inline_md(hl.title)
 250                         tpl.add "<li><a href=\"#{hl.id}\">{title}</a>"
 251                         iter.next
 252                         if iter.is_ok then
 253                                 if iter.item.level > hl.level then
 254                                         tpl.add "<ul class=\"list-unstyled\">"
 255                                 else if iter.item.level < hl.level then
 256                                         tpl.add "</li>"
 257                                         tpl.add "</ul>"
 258                                 end
 259                         else
 260                                 tpl.add "</li>"
 261                         end
 262                 end
 263                 tpl.add "</ul>"
 264                 return tpl
 265         end
 266
 267         # Generate the HTML menu for this article.
 268         fun tpl_menu: Writable do
 269                 var file = menu_file
 270                 if not wiki.has_template(file) then return ""
 271                 var tpl = load_template(file)
 272                 if tpl.has_macro("MENUS") then
 273                         var items = new Template
 274                         for child in wiki.root_section.children.values do
 275                                 if child isa WikiArticle and child.is_index then continue
 276                                 if child isa WikiSection and child.is_hidden then continue
 277                                 items.add "<li"
 278                                 if self == child or self.breadcrumbs.has(child) then
 279                                         items.add " class=\"active\""
 280                                 end
 281                                 items.add ">"
 282                                 items.add child.tpl_link(self)
 283                                 items.add "</li>"
 284                         end
 285                         tpl.replace("MENUS", items)
 286                 end
 287                 return tpl
 288         end
 289
 290         # Generate the HTML footer for this article.
 291         fun tpl_footer: Writable do
 292                 var file = footer_file
 293                 if not wiki.has_template(file) then return ""
 294                 var tpl = load_template(file)
 295                 var time = new Tm.gmtime
 296                 if tpl.has_macro("YEAR") then
 297                         tpl.replace("YEAR", (time.year + 1900).to_s)
 298                 end
 299                 if tpl.has_macro("GEN_TIME") then
 300                         tpl.replace("GEN_TIME", time.to_s)
 301                 end
 302                 if tpl.has_macro("LAST_CHANGES") then
 303                         var url = "{wiki.config.last_changes}{src_path or else ""}"
 304                         tpl.replace("LAST_CHANGES", url)
 305                 end
 306                 if tpl.has_macro("EDIT") then
 307                         var url = "{wiki.config.edit}{src_path or else ""}"
 308                         tpl.replace("EDIT", url)
 309                 end
 310                 return tpl
 311         end
 312 end
 313
 314 # A `WikiArticle` that contains the sitemap tree.
 315 class WikiSitemap
 316         super WikiArticle
 317
 318         redef fun tpl_article do
 319                 var article = new TplArticle.with_title("Sitemap")
 320                 article.body = new TplPageTree(wiki.root_section, -1)
 321                 return article
 322         end
 323
 324         redef var is_dirty = false
 325 end
 326
 327 # A `WikiArticle` that contains the section index tree.
 328 redef class WikiSectionIndex
 329
 330         redef var is_dirty = false
 331
 332         redef fun tpl_article do
 333                 var article = new TplArticle.with_title(section.title)
 334                 article.body = new TplPageTree(section, -1)
 335                 article.breadcrumbs = new TplBreadcrumbs(self)
 336                 return article
 337         end
 338 end
 339
 340 # Article HTML output.
 341 class TplArticle
 342         super Template
 343
 344         # Article title.
 345         var title: nullable Writable = null
 346
 347         # Article HTML body.
 348         var body: nullable Writable = null
 349
 350         # Sidebar of this article (if any).
 351         var sidebar: nullable TplSidebar = null
 352
 353         # Position of the sidebar.
 354         #
 355         # See `WikiConfig::sidebar`.
 356         var sidebar_pos: String = "left"
 357
 358         # Breadcrumbs from wiki root to this article.
 359         var breadcrumbs: nullable TplBreadcrumbs = null
 360
 361         # Init `self` with a `title`.
 362         init with_title(title: Writable) do
 363                 self.title = title
 364         end
 365
 366         redef fun rendering do
 367                 if sidebar_pos == "left" then render_sidebar
 368                 if sidebar == null then
 369                         add "<div class=\"col-sm-12 content\">"
 370                 else
 371                         add "<div class=\"col-sm-9 content\">"
 372                 end
 373                 if body != null then
 374                         add "<article>"
 375                         if breadcrumbs != null then
 376                                 add breadcrumbs.as(not null)
 377                         end
 378                         if title != null then
 379                                 add "<h1>"
 380                                 add title.as(not null)
 381                                 add "</h1>"
 382                         end
 383                         add     body.as(not null)
 384                         add " </article>"
 385                 end
 386                 add "</div>"
 387                 if sidebar_pos == "right" then render_sidebar
 388         end
 389
 390         private fun render_sidebar do
 391                 if sidebar == null then return
 392                 add "<div class=\"col-sm-3 sidebar\">"
 393                 add sidebar.as(not null)
 394                 add "</div>"
 395         end
 396 end
 397
 398 # A collection of HTML blocks displayed on the side of a page.
 399 class TplSidebar
 400         super Template
 401
 402         # Blocks are `Stremable` pieces that will be rendered in the sidebar.
 403         var blocks = new Array[Writable]
 404
 405         redef fun rendering do
 406                 for block in blocks do
 407                         add "<nav class=\"sideblock\">"
 408                         add block
 409                         add "</nav>"
 410                 end
 411         end
 412 end
 413
 414 # An HTML breadcrumbs that show the path from a `WikiArticle` to the `Nitiwiki` root.
 415 class TplBreadcrumbs
 416         super Template
 417
 418         # Bread crumb article.
 419         var article: WikiArticle
 420
 421         redef fun rendering do
 422                 var path = article.breadcrumbs
 423                 if path.is_empty or path.length <= 2 and article.is_index then return
 424                 add "<ol class=\"breadcrumb\">"
 425                 for entry in path do
 426                         if entry == path.last then
 427                                 add "<li class=\"active\">"
 428                                 add entry.title
 429                                 add "</li>"
 430                         else
 431                                 if article.parent == entry and article.is_index then continue
 432                                 add "<li>"
 433                                 add entry.tpl_link(article)
 434                                 add "</li>"
 435                         end
 436                 end
 437                 add "</ol>"
 438         end
 439 end
 440
 441 # An HTML tree that show the section pages structure.
 442 class TplPageTree
 443         super Template
 444
 445         # Builds the page tree from `root`.
 446         var root: WikiSection
 447
 448         # Limits the tree depth to `max_depth` levels.
 449         var max_depth: Int
 450
 451         redef fun rendering do
 452                 add "<ul>"
 453                 add root.tpl_tree(-1)
 454                 add "</ul>"
 455         end
 456 end